1 ; -*- fundamental -*- (asm-mode sucks)
2 ; $Id: ldlinux.asm,v 1.181 2005/01/18 13:13:50 hpa Exp $
3 ; ****************************************************************************
7 ; A program to boot Linux kernels off an MS-DOS formatted floppy disk. This
8 ; functionality is good to have for installation floppies, where it may
9 ; be hard to find a functional Linux system to run LILO off.
11 ; This program allows manipulation of the disk to take place entirely
12 ; from MS-LOSS, and can be especially useful in conjunction with the
15 ; Copyright (C) 1994-2004 H. Peter Anvin
17 ; This program is free software; you can redistribute it and/or modify
18 ; it under the terms of the GNU General Public License as published by
19 ; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
20 ; Boston MA 02111-1307, USA; either version 2 of the License, or
21 ; (at your option) any later version; incorporated herein by reference.
23 ; ****************************************************************************
32 %include "tracers.inc"
35 ; Some semi-configurable constants... change on your own risk.
38 FILENAME_MAX_LG2 equ 4 ; log2(Max filename size Including final null)
39 FILENAME_MAX equ 11 ; Max mangled filename size
40 NULLFILE equ ' ' ; First char space == null filename
41 NULLOFFSET equ 0 ; Position in which to look
42 retry_count equ 6 ; How patient are we with the disk?
43 %assign HIGHMEM_SLOP 0 ; Avoid this much memory near the top
44 LDLINUX_MAGIC equ 0x3eb202fe ; A random number to identify ourselves with
46 MAX_OPEN_LG2 equ 6 ; log2(Max number of open files)
47 MAX_OPEN equ (1 << MAX_OPEN_LG2)
50 SECTOR_SIZE equ (1 << SECTOR_SHIFT)
53 ; This is what we need to do when idle
63 ; The following structure is used for "virtual kernels"; i.e. LILO-style
64 ; option labels. The options we permit here are `kernel' and `append
65 ; Since there is no room in the bottom 64K for all of these, we
66 ; stick them at vk_seg:0000 and copy them down before we need them.
69 vk_vname: resb FILENAME_MAX ; Virtual name **MUST BE FIRST!**
70 vk_rname: resb FILENAME_MAX ; Real name
73 vk_append: resb max_cmd_len+1 ; Command line
75 vk_end: equ $ ; Should be <= vk_size
79 ; Segment assignments in the bottom 640K
80 ; Stick to the low 512K in case we're using something like M-systems flash
81 ; which load a driver into low RAM (evil!!)
83 ; 0000h - main code/data segment (and BIOS segment)
85 real_mode_seg equ 4000h
86 cache_seg equ 3000h ; 64K area for metadata cache
87 vk_seg equ 2000h ; Virtual kernels
88 xfer_buf_seg equ 1000h ; Bounce buffer for I/O to high mem
89 comboot_seg equ real_mode_seg ; COMBOOT image loading zone
92 ; File structure. This holds the information for each currently open file.
95 file_sector resd 1 ; Sector pointer (0 = structure free)
96 file_left resd 1 ; Number of sectors left
100 %if (open_file_t_size & (open_file_t_size-1))
101 %error "open_file_t is not a power of 2"
105 ; ---------------------------------------------------------------------------
107 ; ---------------------------------------------------------------------------
110 ; Memory below this point is reserved for the BIOS and the MBR
113 trackbufsize equ 8192
114 trackbuf resb trackbufsize ; Track buffer goes here
115 getcbuf resb trackbufsize
121 ; Expanded superblock
123 resq 16 ; The first 16 bytes expanded 8 times
124 FAT resd 1 ; Location of (first) FAT
125 RootDirArea resd 1 ; Location of root directory area
126 RootDir resd 1 ; Location of root directory proper
127 DataArea resd 1 ; Location of data area
128 RootDirSize resd 1 ; Root dir size in sectors
129 TotalSectors resd 1 ; Total number of sectors
130 EndSector resd 1 ; Location of filesystem end
131 ClustSize resd 1 ; Bytes/cluster
132 ClustMask resd 1 ; Sectors/cluster - 1
133 CopySuper resb 1 ; Distinguish .bs versus .bss
134 DriveNumber resb 1 ; BIOS drive number
135 ClustShift resb 1 ; Shift count for sectors/cluster
136 ClustByteShift resb 1 ; Shift count for bytes/cluster
138 alignb open_file_t_size
139 Files resb MAX_OPEN*open_file_t_size
142 ; Constants for the xfer_buf_seg
144 ; The xfer_buf_seg is also used to store message file buffers. We
145 ; need two trackbuffers (text and graphics), plus a work buffer
146 ; for the graphics decompressor.
148 xbs_textbuf equ 0 ; Also hard-coded, do not change
149 xbs_vgabuf equ trackbufsize
150 xbs_vgatmpbuf equ 2*trackbufsize
155 ; Some of the things that have to be saved very early are saved
156 ; "close" to the initial stack pointer offset, in order to
157 ; reduce the code size...
159 StackBuf equ $-44-32 ; Start the stack here (grow down - 4K)
160 PartInfo equ StackBuf ; Saved partition table entry
161 FloppyTable equ PartInfo+16 ; Floppy info table (must follow PartInfo)
162 OrigFDCTabPtr equ StackBuf-4 ; The high dword on the stack
165 ; Primary entry point. Tempting as though it may be, we can't put the
166 ; initial "cli" here; the jmp opcode in the first byte is part of the
167 ; "magic number" (using the term very loosely) for the DOS superblock.
170 jmp short start ; 2 bytes
173 ; "Superblock" follows -- it's in the boot sector, so it's already
174 ; loaded and ready for us
176 bsOemName db 'SYSLINUX' ; The SYS command sets this, so...
178 ; These are the fields we actually care about. We end up expanding them
179 ; all to dword size early in the code, so generate labels for both
180 ; the expanded and unexpanded versions.
183 bx %+ %1 equ SuperInfo+($-superblock)*8+4
188 bx %+ %1 equ SuperInfo+($-superblock)*8
193 bx %+ %1 equ $ ; no expansion for dwords
208 superinfo_size equ ($-superblock)-1 ; How much to expand
212 ; This is as far as FAT12/16 and FAT32 are consistent
214 zb 54 ; FAT12/16 need 26 more bytes,
215 ; FAT32 need 54 more bytes
216 superblock_len equ $-superblock
218 SecPerClust equ bxSecPerClust
220 ; Note we don't check the constraints above now; we did that at install
224 cli ; No interrupts yet, please
231 mov sp,StackBuf ; Just below BSS
234 ; DS:SI may contain a partition table entry. Preserve it for us.
236 mov cx,8 ; Save partition info
240 mov ds,ax ; Now we can initialize DS...
243 ; Now sautee the BIOS floppy info block to that it will support decent-
244 ; size transfers; the floppy block is 11 bytes and is stored in the
245 ; INT 1Eh vector (brilliant waste of resources, eh?)
247 ; Of course, if BIOSes had been properly programmed, we wouldn't have
248 ; had to waste precious space with this code.
251 lfs si,[bx] ; FS:SI -> original fdctab
252 push fs ; Save on stack in case we need to bail
255 ; Save the old fdctab even if hard disk so the stack layout
256 ; is the same. The instructions above do not change the flags
257 mov [DriveNumber],dl ; Save drive number in DL
258 and dl,dl ; If floppy disk (00-7F), assume no
263 mov cl,6 ; 12 bytes (CX == 0)
264 ; es:di -> FloppyTable already
265 ; This should be safe to do now, interrupts are off...
266 mov [bx],di ; FloppyTable
267 mov [bx+2],ax ; Segment 0
268 fs rep movsw ; Faster to move words
269 mov cl,[bsSecPerTrack] ; Patch the sector count
272 int 13h ; Some BIOSes need this
274 jmp short not_harddisk
276 ; The drive number and possibly partition information was passed to us
277 ; by the BIOS or previous boot loader (MBR). Current "best practice" is to
278 ; trust that rather than what the superblock contains.
280 ; Would it be better to zero out bsHidden if we don't have a partition table?
282 ; Note: di points to beyond the end of PartInfo
285 test byte [di-16],7Fh ; Sanity check: "active flag" should
286 jnz no_partition ; be 00 or 80
287 mov eax,[di-8] ; Partition offset (dword)
291 ; Get disk drive parameters (don't trust the superblock.) Don't do this for
292 ; floppy drives -- INT 13:08 on floppy drives will (may?) return info about
293 ; what the *drive* supports, not about the *media*. Fortunately floppy disks
294 ; tend to have a fixed, well-defined geometry which is stored in the superblock.
296 ; DL == drive # still
303 inc dx ; Contains # of heads - 1
306 mov [bsSecPerTrack],cx
310 ; Ready to enable interrupts, captain
316 ; Do we have EBIOS (EDD)?
320 mov ah,41h ; EDD existence query
326 test cl,1 ; Extended disk access functionality set
329 ; We have EDD support...
331 mov byte [getlinsec.jmp+1],getlinsec_ebios-(getlinsec.jmp+2)
335 ; Load the first sector of LDLINUX.SYS; this used to be all proper
336 ; with parsing the superblock and root directory; it doesn't fit
337 ; together with EBIOS support, unfortunately.
339 mov eax,[FirstSector] ; Sector start
340 mov bx,ldlinux_sys ; Where to load it
343 ; Some modicum of integrity checking
344 cmp dword [ldlinux_magic],LDLINUX_MAGIC
346 cmp dword [ldlinux_magic+4],HEXDATE
353 ; kaboom: write a message and bail out.
358 mov sp,StackBuf-4 ; Reset stack
359 mov ds,si ; Reset data segment
360 pop dword [fdctab] ; Restore FDC table
361 .patch: mov si,bailmsg
362 call writestr ; Returns with AL = 0
364 int 16h ; Wait for keypress
365 int 19h ; And try once more to boot...
366 .norge: jmp short .norge ; If int 19h returned; this is the end
370 ; writestr: write a null-terminated string to the console
371 ; This assumes we're on page 0. This is only used for early
372 ; messages, so it should be OK.
378 mov ah,0Eh ; Write to screen as TTY
379 mov bx,0007h ; Attribute
385 ; xint13: wrapper for int 13h which will retry 6 times and then die,
386 ; AND save all registers except BP
398 jmp strict near kaboom ; Patched
402 ; getonesec: get one disk sector
405 mov bp,1 ; One sector
409 ; getlinsec: load a sequence of BP floppy sector given by the linear sector
410 ; number in EAX into the buffer at ES:BX. We try to optimize
411 ; by loading up to a whole track at a time, but the user
412 ; is responsible for not crossing a 64K boundary.
413 ; (Yes, BP is weird for a count, but it was available...)
415 ; On return, BX points to the first byte after the transferred
418 ; This routine assumes CS == DS, and trashes most registers.
420 ; Stylistic note: use "xchg" instead of "mov" when the source is a register
421 ; that is dead from that point; this saves space. However, please keep
422 ; the order to dst,src to keep things sane.
425 add eax,[bsHidden] ; Add partition offset
426 .jmp: jmp strict short getlinsec_cbios ; This is patched
431 ; getlinsec implementation for EBIOS (EDD)
434 mov si,dapa ; Load up the DAPA
439 push bp ; Sectors left
440 call maxtrans ; Enforce maximum transfer size
444 mov ah,42h ; Extended Read
447 movzx eax,word [si+2] ; Sectors we read
448 add [si+8],eax ; Advance sector pointer
449 sub bp,ax ; Sectors left
450 shl ax,9 ; 512-byte sectors
451 add [si+4],ax ; Advance buffer pointer
454 mov eax,[si+8] ; Next sector
455 mov bx,[si+4] ; Buffer pointer
461 ; getlinsec implementation for legacy CBIOS
469 movzx esi,word [bsSecPerTrack]
470 movzx edi,word [bsHeads]
472 ; Dividing by sectors to get (track,sector): we may have
473 ; up to 2^18 tracks, so we need to use 32-bit arithmetric.
475 xor edx,edx ; Zero-extend LBA to 64 bits
478 xchg cx,dx ; CX <- sector index (0-based)
481 div edi ; Convert track to head/cyl
483 ; Now we have AX = cyl, DX = head, CX = sector (0-based),
484 ; BP = sectors to transfer, SI = bsSecPerTrack,
485 ; ES:BX = data target
488 call maxtrans ; Enforce maximum transfer size
490 ; Must not cross track boundaries, so BP <= SI-CX
497 shl ah,6 ; Because IBM was STOOPID
498 ; and thought 8 bits were enough
499 ; then thought 10 bits were enough...
500 inc cx ; Sector numbers are 1-based, sigh
505 xchg ax,bp ; Sector to transfer count
506 mov ah,02h ; Read sectors
509 shl ax,9 ; Convert sectors in AL to bytes in AX
520 ; Truncate BP to MaxTransfer
529 ; Error message on failure
531 bailmsg: db 'Boot failed', 0Dh, 0Ah, 0
534 ; EBIOS disk address packet
539 .count: dw 0 ; Block count
540 .off: dw 0 ; Offset of buffer
541 .seg: dw 0 ; Segment of buffer
542 .lba: dd 0 ; LBA (LSW)
547 bs_checkpt_off equ ($-$$)
549 %if bs_checkpt_off > 1F8h
550 %error "Boot sector overflow"
556 FirstSector dd 0xDEADBEEF ; Location of sector 1
557 MaxTransfer dw 0x007F ; Max transfer size
558 bootsignature dw 0AA55h
561 ; ===========================================================================
563 ; ===========================================================================
564 ; Start of LDLINUX.SYS
565 ; ===========================================================================
569 syslinux_banner db 0Dh, 0Ah
575 db version_str, ' ', date, ' ', 0
576 db 0Dh, 0Ah, 1Ah ; EOF if we "type" this in DOS
579 ldlinux_magic dd LDLINUX_MAGIC
583 ; This area is patched by the installer. It is found by looking for
584 ; LDLINUX_MAGIC, plus 8 bytes.
587 LDLDwords dw 0 ; Total dwords starting at ldlinux_sys
588 LDLSectors dw 0 ; Number of sectors - (bootsec+this sec)
589 CheckSum dd 0 ; Checksum starting at ldlinux_sys
590 ; value = LDLINUX_MAGIC - [sum of dwords]
592 ; Space for up to 64 sectors, the theoretical maximum
593 SectorPtrs times 64 dd 0
597 ; Note that some BIOSes are buggy and run the boot sector at 07C0:0000
598 ; instead of 0000:7C00 and the like. We don't want to add anything
599 ; more to the boot sector, so it is written to not assume a fixed
600 ; value in CS, but we don't want to deal with that anymore from now
607 ; Tell the user we got this far
609 mov si,syslinux_banner
613 ; Patch disk error handling
615 mov word [xint13.disk_error+1],do_disk_error-(xint13.disk_error+3)
618 ; Now we read the rest of LDLINUX.SYS. Don't bother loading the first
619 ; sector again, though.
623 mov bx,7C00h+2*SECTOR_SIZE ; Where we start loading
629 lodsd ; First sector of this chunk
637 inc edx ; Next linear sector
638 cmp [esi],edx ; Does it match
639 jnz .chunk_ready ; If not, this is it
640 add esi,4 ; If so, add sector to chunk
641 jmp short .make_chunk
652 ; All loaded up, verify that we got what we needed.
653 ; Note: the checksum field is embedded in the checksum region, so
654 ; by the time we get to the end it should all cancel out.
659 mov edx,-LDLINUX_MAGIC
665 and edx,edx ; Should be zero
666 jz all_read ; We're cool, go for it!
669 ; Uh-oh, something went bad...
671 mov si,checksumerr_msg
676 ; -----------------------------------------------------------------------------
677 ; Subroutines that have to be in the first sector
678 ; -----------------------------------------------------------------------------
681 ; getlinsecsr: save registers, call getlinsec, restore registers
689 ; This routine captures disk errors, and tries to decide if it is
690 ; time to reduce the transfer size.
695 shr al,1 ; Try reducing the transfer size
697 jz kaboom ; If we can't, we're dead...
698 jmp xint13 ; Try again
709 ; Checksum error message
711 checksumerr_msg db 'Load error - ', 0 ; Boot failed appended
718 cmp word [Debug_Magic],0D00Dh
723 rl_checkpt equ $ ; Must be <= 8000h
725 rl_checkpt_off equ ($-$$)
727 %if rl_checkpt_off > 400h
728 %error "Sector 1 overflow"
732 ; ----------------------------------------------------------------------------
733 ; End of code and data that have to be in the first sector
734 ; ----------------------------------------------------------------------------
738 ; Let the user (and programmer!) know we got this far. This used to be
739 ; in Sector 1, but makes a lot more sense here.
746 ; Insane hack to expand the superblock to dwords
752 mov cx,superinfo_size
756 stosd ; Store expanded word
758 stosd ; Store expanded byte
762 ; Compute some information about this filesystem.
765 ; First, generate the map of regions
770 mov edx,[bsHugeSectors]
772 mov [TotalSectors],edx
777 mov eax,[bxResSectors]
778 mov [FAT],eax ; Beginning of FAT
782 mov edx,[bootsec+36] ; FAT32 BPB_FATsz32
786 mov [RootDirArea],eax ; Beginning of root directory
787 mov [RootDir],eax ; For FAT12/16 == root dir location
789 mov edx,[bxRootDirEnts]
790 add dx,SECTOR_SIZE/32-1
791 shr dx,SECTOR_SHIFT-5
792 mov [RootDirSize],edx
794 mov [DataArea],eax ; Beginning of data area
796 ; Next, generate a cluster size shift count and mask
797 mov eax,[bxSecPerClust]
802 mov [ClustByteShift],cl
811 ; FAT12, FAT16 or FAT28^H^H32? This computation is fscking ridiculous.
816 shr eax,cl ; cl == ClustShift
817 mov cl,nextcluster_fat12-(nextcluster+2)
818 cmp eax,4085 ; FAT12 limit
820 mov cl,nextcluster_fat16-(nextcluster+2)
821 cmp eax,65525 ; FAT16 limit
824 ; FAT32, root directory is a cluster chain
827 mov eax,[bootsec+44] ; Root directory cluster
832 mov cl,nextcluster_fat28-(nextcluster+2)
834 mov byte [nextcluster+1],cl
837 ; Common initialization code
839 %include "cpuinit.inc"
843 ; Clear Files structures
846 mov cx,(MAX_OPEN*open_file_t_size)/4
851 ; Initialize the metadata cache
856 ; Now, everything is "up and running"... patch kaboom for more
857 ; verbosity and using the full screen system
860 mov dword [kaboom.patch],0e9h+((kaboom2-(kaboom.patch+3)) << 8)
863 ; Now we're all set to start with our *real* business. First load the
864 ; configuration file (if any) and parse it.
866 ; In previous versions I avoided using 32-bit registers because of a
867 ; rumour some BIOSes clobbered the upper half of 32-bit registers at
868 ; random. I figure, though, that if there are any of those still left
869 ; they probably won't be trying to install Linux on them...
871 ; The code is still ripe with 16-bitisms, though. Not worth the hassle
872 ; to take'm out. In fact, we may want to put them back if we're going
873 ; to boot ELKS at some point.
877 ; Load configuration file
884 ; Now we have the config file open. Parse the config file and
885 ; run the user interface.
890 ; Linux kernel loading code is common.
892 %include "runkernel.inc"
895 ; COMBOOT-loading code
897 %include "comboot.inc"
899 %include "cmdline.inc"
902 ; Boot sector loading code
904 %include "bootsect.inc"
907 ; abort_check: let the user abort with <ESC> or <Ctrl-C>
918 ac_kill: mov si,aborted_msg
921 ; abort_load: Called by various routines which wants to print a fatal
922 ; error message and return to the command prompt. Since this
923 ; may happen at just about any stage of the boot process, assume
924 ; our state is messed up, and just reset the segment registers
925 ; and the stack forcibly.
927 ; SI = offset (in _text) of error message to print
930 mov ax,cs ; Restore CS = DS = ES
934 mov sp,StackBuf-2*3 ; Reset stack
935 mov ss,ax ; Just in case...
937 call cwritestr ; Expects SI -> error msg
938 al_ok: jmp enter_command ; Return to command prompt
946 ; allocate_file: Allocate a file structure
959 .check: cmp dword [bx], byte 0
961 add bx,open_file_t_size ; ZF = 0
963 ; ZF = 0 if we fell out of the loop
969 ; Search the root directory for a pre-mangled filename in DS:DI.
971 ; NOTE: This file considers finding a zero-length file an
972 ; error. This is so we don't have to deal with that special
973 ; case elsewhere in the program (most loops have the test
979 ; DX:AX = file length in bytes
993 mov eax,[RootDir] ; First root directory sector
997 ; GS:SI now points to this sector
999 mov cx,SECTOR_SIZE/32 ; 32 == directory entry size
1002 jz .failure ; Hit directory high water mark
1016 jnc .scansector ; CF is set if we're at end
1018 ; If we get here, we failed
1026 mov eax,[gs:si+28] ; File size
1027 add eax,SECTOR_SIZE-1
1028 shr eax,SECTOR_SHIFT
1029 jz .failure ; Zero-length file
1033 mov dx,[gs:si+20] ; High cluster word
1035 mov dx,[gs:si+26] ; Low cluster word
1039 mov [bx],edx ; Starting sector
1041 mov eax,[gs:si+28] ; File length again
1042 mov dx,[gs:si+30] ; 16-bitism, sigh
1044 and eax,eax ; ZF <- 0
1051 ; writechr: Write a single character in AL to the console without
1052 ; mangling any registers; handle video pages correctly.
1055 call write_serial ; write to serial port if needed
1057 test byte [cs:DisplayCon], 01h
1061 mov bl,07h ; attribute
1062 mov bh,[cs:BIOS_page] ; current page
1071 ; kaboom2: once everything is loaded, replace the part of kaboom
1072 ; starting with "kaboom.patch" with this part
1075 mov si,err_bootfailed
1079 int 19h ; And try once more to boot...
1080 .norge: jmp short .norge ; If int 19h returned; this is the end
1083 ; mangle_name: Mangle a DOS filename pointed to by DS:SI into a buffer pointed
1084 ; to by ES:DI; ends on encountering any whitespace
1088 mov cx,11 ; # of bytes to write
1091 cmp al,' ' ; If control or space, end
1093 cmp al,'.' ; Period -> space-fill
1100 jmp short mn_not_lower
1101 mn_is_period: mov al,' ' ; We need to space-fill
1102 mn_period_loop: cmp cx,3 ; If <= 3 characters left
1103 jbe mn_loop ; Just ignore it
1104 stosb ; Otherwise, write a period
1105 loop mn_period_loop ; Dec CX and (always) jump
1106 mn_not_uslower: cmp al,ucase_low
1110 mov bx,ucase_tab-ucase_low
1113 loop mn_loop ; Don't continue if too long
1115 mov al,' ' ; Space-fill name
1116 rep stosb ; Doesn't do anything if CX=0
1120 ; Upper-case table for extended characters; this is technically code page 865,
1121 ; but code page 437 users will probably not miss not being able to use the
1122 ; cent sign in kernel images too much :-)
1124 ; The table only covers the range 129 to 164; the rest we can deal with.
1128 ucase_tab db 154, 144, 'A', 142, 'A', 143, 128, 'EEEIII'
1129 db 142, 143, 144, 146, 146, 'O', 153, 'OUUY', 153, 154
1130 db 157, 156, 157, 158, 159, 'AIOU', 165
1133 ; unmangle_name: Does the opposite of mangle_name; converts a DOS-mangled
1134 ; filename to the conventional representation. This is needed
1135 ; for the BOOT_IMAGE= parameter for the kernel.
1136 ; NOTE: A 13-byte buffer is mandatory, even if the string is
1137 ; known to be shorter.
1139 ; DS:SI -> input mangled file name
1140 ; ES:DI -> output buffer
1142 ; On return, DI points to the first byte after the output name,
1143 ; which is set to a null byte.
1146 push si ; Save pointer to original name
1154 mov bp,di ; Position of last nonblank+1
1155 un_cb_space: loop un_copy_body
1157 mov al,'.' ; Don't save
1166 un_ce_space: loop un_copy_ext
1173 ; lower_case: Lower case a character in AL
1182 lc_1: cmp al,lcase_low
1187 mov bx,lcase_tab-lcase_low
1193 ; getfssec_edx: Get multiple sectors from a file
1195 ; This routine makes sure the subtransfers do not cross a 64K boundary,
1196 ; and will correct the situation if it does, UNLESS *sectors* cross
1200 ; EDX -> Current sector number
1201 ; CX -> Sector count (0FFFFh = until end of file)
1202 ; Must not exceed the ES segment
1203 ; Returns EDX=0, CF=1 on EOF (not necessarily error)
1204 ; All arguments are advanced to reflect data read.
1210 xor ebp,ebp ; Fragment sector count
1211 push edx ; Starting sector pointer
1219 add ax,bx ; Now AX = how far into 64K block we are
1220 not ax ; Bytes left in 64K block
1222 shr eax,SECTOR_SHIFT ; Sectors left in 64K block
1224 jnb .do_read ; Unless there is at least 1 more sector room...
1225 mov eax,edx ; Current sector
1226 inc edx ; Predict it's the linearly next sector
1229 cmp edx,eax ; Did it match?
1232 pop eax ; Starting sector pointer
1234 lea eax,[eax+ebp-1] ; This is the last sector actually read
1236 add bx,bp ; Adjust buffer pointer
1252 ; getfssec: Get multiple sectors from a file
1254 ; Same as above, except SI is a pointer to a open_file_t
1257 ; DS:SI -> Pointer to open_file_t
1258 ; CX -> Sector count (0FFFFh = until end of file)
1259 ; Must not exceed the ES segment
1260 ; Returns CF=1 on EOF (not necessarily error)
1261 ; All arguments are advanced to reflect data read.
1279 ; nextcluster: Advance a cluster pointer in EDI to the next cluster
1280 ; pointed at in the FAT tables. CF=0 on return if end of file.
1283 jmp strict short nextcluster_fat28 ; This gets patched
1293 pushf ; Save the shifted-out LSB (=CF)
1322 ; FAT16 decoding routine.
1329 shr eax,SECTOR_SHIFT-1
1334 movzx edi,word [gs:si+bx]
1341 ; FAT28 ("FAT32") decoding routine.
1348 shr eax,SECTOR_SHIFT-2
1354 mov edi,dword [gs:si+bx]
1355 and edi,0FFFFFFFh ; 28 bits only
1363 ; nextsector: Given a sector in EAX on input, return the next sector
1364 ; of the same filesystem object, which may be the root
1365 ; directory or a cluster chain. Returns EOF.
1385 test edi,[ClustMask]
1388 ; It's not the final sector in a cluster
1393 push gs ; nextcluster trashes gs
1400 ; Now EDI contains the cluster number
1403 jc .exit ; There isn't anything else...
1405 ; New cluster number now in EDI
1407 shl edi,cl ; CF <- 0, unless something is very wrong
1418 ; getfatsector: Check for a particular sector (in EAX) in the FAT cache,
1419 ; and return a pointer in GS:SI, loading it if needed.
1424 add eax,[FAT] ; FAT starting address
1427 ; -----------------------------------------------------------------------------
1429 ; -----------------------------------------------------------------------------
1431 %include "getc.inc" ; getc et al
1432 %include "conio.inc" ; Console I/O
1433 %include "writestr.inc" ; String output
1434 %include "parseconfig.inc" ; High-level config file handling
1435 %include "parsecmd.inc" ; Low-level config file handling
1436 %include "bcopy32.inc" ; 32-bit bcopy
1437 %include "loadhigh.inc" ; Load a file into high memory
1438 %include "font.inc" ; VGA font stuff
1439 %include "graphics.inc" ; VGA graphics
1440 %include "highmem.inc" ; High memory sizing
1441 %include "strcpy.inc" ; strcpy()
1442 %include "cache.inc" ; Metadata disk cache
1444 ; -----------------------------------------------------------------------------
1445 ; Begin data section
1446 ; -----------------------------------------------------------------------------
1450 ; Lower-case table for codepage 865
1454 lcase_tab db 135, 129, 130, 131, 132, 133, 134, 135, 136, 137, 138
1455 db 139, 140, 141, 132, 134, 130, 145, 145, 147, 148, 149
1456 db 150, 151, 152, 148, 129, 155, 156, 155, 158, 159, 160
1457 db 161, 162, 163, 164, 164
1459 copyright_str db ' Copyright (C) 1994-', year, ' H. Peter Anvin'
1461 boot_prompt db 'boot: ', 0
1462 wipe_char db BS, ' ', BS, 0
1463 err_notfound db 'Could not find kernel image: ',0
1464 err_notkernel db CR, LF, 'Invalid or corrupt kernel image.', CR, LF, 0
1465 err_noram db 'It appears your computer has less than '
1467 db 'K of low ("DOS")'
1469 db 'RAM. Linux needs at least this amount to boot. If you get'
1471 db 'this message in error, hold down the Ctrl key while'
1473 db 'booting, and I will take your word for it.', CR, LF, 0
1474 err_badcfg db 'Unknown keyword in syslinux.cfg.', CR, LF, 0
1475 err_noparm db 'Missing parameter in syslinux.cfg.', CR, LF, 0
1476 err_noinitrd db CR, LF, 'Could not find ramdisk image: ', 0
1477 err_nohighmem db 'Not enough memory to load specified kernel.', CR, LF, 0
1478 err_highload db CR, LF, 'Kernel transfer failure.', CR, LF, 0
1479 err_oldkernel db 'Cannot load a ramdisk with an old kernel image.'
1481 err_notdos db ': attempted DOS system call', CR, LF, 0
1482 err_comlarge db 'COMBOOT image too large.', CR, LF, 0
1483 err_a20 db CR, LF, 'A20 gate not responding!', CR, LF, 0
1484 err_bootfailed db CR, LF, 'Boot failed: please change disks and press '
1485 db 'a key to continue.', CR, LF, 0
1486 ready_msg db 'Ready.', CR, LF, 0
1487 crlfloading_msg db CR, LF
1488 loading_msg db 'Loading ', 0
1491 aborted_msg db ' aborted.' ; Fall through to crlf_msg!
1494 crff_msg db CR, FF, 0
1495 syslinux_cfg db 'SYSLINUXCFG' ; Mangled form
1496 ConfigName db 'syslinux.cfg',0 ; Unmangled form
1498 manifest db 'MANIFEST '
1501 ; Command line options we'd like to take a look at
1503 ; mem= and vga= are handled as normal 32-bit integer values
1504 initrd_cmd db 'initrd='
1505 initrd_cmd_len equ 7
1508 ; Config file keyword table
1510 %include "keywords.inc"
1513 ; Extensions to search for (in *forward* order).
1515 exten_table: db 'CBT',0 ; COMBOOT (specific)
1516 db 'BSS',0 ; Boot Sector (add superblock)
1517 db 'BS ',0 ; Boot Sector
1518 db 'COM',0 ; COMBOOT (same as DOS)
1521 dd 0, 0 ; Need 8 null bytes here
1524 ; Misc initialized (data) variables
1526 %ifdef debug ; This code for debugging only
1527 debug_magic dw 0D00Dh ; Debug code sentinel
1531 BufSafe dw trackbufsize/SECTOR_SIZE ; Clusters we can load into trackbuf
1532 BufSafeSec dw trackbufsize/SECTOR_SIZE ; = how many sectors?
1533 BufSafeBytes dw trackbufsize ; = how many bytes?
1534 EndOfGetCBuf dw getcbuf+trackbufsize ; = getcbuf+BufSafeBytes
1536 %if ( trackbufsize % SECTOR_SIZE ) != 0
1537 %error trackbufsize must be a multiple of SECTOR_SIZE