third-party/codemirror-3.15/mode/q/index.html

   1 <!doctype html>
   2 <html>
   3   <head>
   4     <meta charset="utf-8">
   5     <title>CodeMirror: Q mode</title>
   6     <link rel="stylesheet" href="../../lib/codemirror.css">
   7     <script src="../../lib/codemirror.js"></script>
   8     <script src="../../addon/edit/matchbrackets.js"></script>
   9     <script src="q.js"></script>
  10     <link rel="stylesheet" href="../../doc/docs.css">
  11     <style type="text/css">.CodeMirror {border-top: 1px solid black; border-bottom: 1px solid black;}</style>
  12   </head>
  13   <body>
  14     <h1>CodeMirror: Q mode</h1>
  15
  16 <div><textarea id="code" name="code">
  17 / utilities to quickly load a csv file - for more exhaustive analysis of the csv contents see csvguess.q
  18 / 2009.09.20 - updated to match latest csvguess.q
  19
  20 / .csv.colhdrs[file] - return a list of colhdrs from file
  21 / info:.csv.info[file] - return a table of information about the file
  22 / columns are:
  23 /       c - column name; ci - column index; t - load type; mw - max width;
  24 /       dchar - distinct characters in values; rule - rule that caught the type
  25 /       maybe - needs checking, _could_ be say a date, but perhaps just a float?
  26 / .csv.info0[file;onlycols] - like .csv.info except that it only analyses <onlycols>
  27 / example:
  28 /       info:.csv.info0[file;(.csv.colhdrs file)like"*price"]
  29 /       info:.csv.infolike[file;"*price"]
  30 /       show delete from info where t=" "
  31 / .csv.data[file;info] - use the info from .csv.info to read the data
  32 / .csv.data10[file;info] - like .csv.data but only returns the first 10 rows
  33 / bulkload[file;info] - bulk loads file into table DATA (which must be already defined :: DATA:() )
  34 / .csv.read[file]/read10[file] - for when you don't care about checking/tweaking the <info> before reading
  35
  36 \d .csv
  37 DELIM:","
  38 ZAPHDRS:0b / lowercase and remove _ from colhdrs (junk characters are always removed)
  39 WIDTHHDR:25000 / number of characters read to get the header
  40 READLINES:222 / number of lines read and used to guess the types
  41 SYMMAXWIDTH:11 / character columns narrower than this are stored as symbols
  42 SYMMAXGR:10 / max symbol granularity% before we give up and keep as a * string
  43 FORCECHARWIDTH:30 / every field (of any type) with values this wide or more is forced to character "*"
  44 DISCARDEMPTY:0b / completely ignore empty columns if true else set them to "C"
  45 CHUNKSIZE:50000000 / used in fs2 (modified .Q.fs)
  46
  47 k)nameltrim:{$[~@x;.z.s'x;~(*x)in aA:.Q.a,.Q.A;(+/&\~x in aA)_x;x]}
  48 k)fs2:{[f;s]((-7!s)>){[f;s;x]i:1+last@&0xa=r:1:(s;x;CHUNKSIZE);f@`\:i#r;x+i}[f;s]/0j}
  49 cleanhdrs:{{$[ZAPHDRS;lower x except"_";x]}x where x in DELIM,.Q.an}
  50 cancast:{nw:x$"";if[not x in"BXCS";nw:(min 0#;max 0#;::)@\:nw];$[not any nw in x$(11&count y)#y;$[11<count y;not any nw in x$y;1b];0b]}
  51
  52 read:{[file]data[file;info[file]]}
  53 read10:{[file]data10[file;info[file]]}
  54
  55 colhdrs:{[file]
  56         `$nameltrim DELIM vs cleanhdrs first read0(file;0;1+first where 0xa=read1(file;0;WIDTHHDR))}
  57 data:{[file;info]
  58         (exec c from info where not t=" ")xcol(exec t from info;enlist DELIM)0:file}
  59 data10:{[file;info]
  60         data[;info](file;0;1+last 11#where 0xa=read1(file;0;15*WIDTHHDR))}
  61 info0:{[file;onlycols]
  62         colhdrs:`$nameltrim DELIM vs cleanhdrs first head:read0(file;0;1+last where 0xa=read1(file;0;WIDTHHDR));
  63         loadfmts:(count colhdrs)#"S";if[count onlycols;loadfmts[where not colhdrs in onlycols]:"C"];
  64         breaks:where 0xa=read1(file;0;floor(10+READLINES)*WIDTHHDR%count head);
  65         nas:count as:colhdrs xcol(loadfmts;enlist DELIM)0:(file;0;1+last((1+READLINES)&count breaks)#breaks);
  66         info:([]c:key flip as;v:value flip as);as:();
  67         reserved:key`.q;reserved,:.Q.res;reserved,:`i;
  68         info:update res:c in reserved from info;
  69         info:update ci:i,t:"?",ipa:0b,mdot:0,mw:0,rule:0,gr:0,ndv:0,maybe:0b,empty:0b,j10:0b,j12:0b from info;
  70         info:update ci:`s#ci from info;
  71         if[count onlycols;info:update t:" ",rule:10 from info where not c in onlycols];
  72         info:update sdv:{string(distinct x)except`}peach v from info;
  73         info:update ndv:count each sdv from info;
  74         info:update gr:floor 0.5+100*ndv%nas,mw:{max count each x}peach sdv from info where 0<ndv;
  75         info:update t:"*",rule:20 from info where mw>.csv.FORCECHARWIDTH; / long values
  76         info:update t:"C "[.csv.DISCARDEMPTY],rule:30,empty:1b from info where t="?",mw=0; / empty columns
  77         info:update dchar:{asc distinct raze x}peach sdv from info where t="?";
  78         info:update mdot:{max sum each"."=x}peach sdv from info where t="?",{"."in x}each dchar;
  79         info:update t:"n",rule:40 from info where t="?",{any x in"0123456789"}each dchar; / vaguely numeric..
  80         info:update t:"I",rule:50,ipa:1b from info where t="n",mw within 7 15,mdot=3,{all x in".0123456789"}each dchar,.csv.cancast["I"]peach sdv; / ip-address
  81         info:update t:"J",rule:60 from info where t="n",mdot=0,{all x in"+-0123456789"}each dchar,.csv.cancast["J"]peach sdv;
  82         info:update t:"I",rule:70 from info where t="J",mw<12,.csv.cancast["I"]peach sdv;
  83         info:update t:"H",rule:80 from info where t="I",mw<7,.csv.cancast["H"]peach sdv;
  84         info:update t:"F",rule:90 from info where t="n",mdot<2,mw>1,.csv.cancast["F"]peach sdv;
  85         info:update t:"E",rule:100,maybe:1b from info where t="F",mw<9;
  86         info:update t:"M",rule:110,maybe:1b from info where t in"nIHEF",mdot<2,mw within 4 7,.csv.cancast["M"]peach sdv;
  87         info:update t:"D",rule:120,maybe:1b from info where t in"nI",mdot in 0 2,mw within 6 11,.csv.cancast["D"]peach sdv;
  88         info:update t:"V",rule:130,maybe:1b from info where t="I",mw in 5 6,7<count each dchar,{all x like"*[0-9][0-5][0-9][0-5][0-9]"}peach sdv,.csv.cancast["V"]peach sdv; / 235959 12345
  89         info:update t:"U",rule:140,maybe:1b from info where t="H",mw in 3 4,7<count each dchar,{all x like"*[0-9][0-5][0-9]"}peach sdv,.csv.cancast["U"]peach sdv; /2359
  90         info:update t:"U",rule:150,maybe:0b from info where t="n",mw in 4 5,mdot=0,{all x like"*[0-9]:[0-5][0-9]"}peach sdv,.csv.cancast["U"]peach sdv;
  91         info:update t:"T",rule:160,maybe:0b from info where t="n",mw within 7 12,mdot<2,{all x like"*[0-9]:[0-5][0-9]:[0-5][0-9]*"}peach sdv,.csv.cancast["T"]peach sdv;
  92         info:update t:"V",rule:170,maybe:0b from info where t="T",mw in 7 8,mdot=0,.csv.cancast["V"]peach sdv;
  93         info:update t:"T",rule:180,maybe:1b from info where t in"EF",mw within 7 10,mdot=1,{all x like"*[0-9][0-5][0-9][0-5][0-9].*"}peach sdv,.csv.cancast["T"]peach sdv;
  94         info:update t:"Z",rule:190,maybe:0b from info where t="n",mw within 11 24,mdot<4,.csv.cancast["Z"]peach sdv;
  95         info:update t:"P",rule:200,maybe:1b from info where t="n",mw within 12 29,mdot<4,{all x like"[12]*"}peach sdv,.csv.cancast["P"]peach sdv;
  96         info:update t:"N",rule:210,maybe:1b from info where t="n",mw within 3 28,mdot=1,.csv.cancast["N"]peach sdv;
  97         info:update t:"?",rule:220,maybe:0b from info where t="n"; / reset remaining maybe numeric
  98         info:update t:"C",rule:230,maybe:0b from info where t="?",mw=1; / char
  99         info:update t:"B",rule:240,maybe:0b from info where t in"HC",mw=1,mdot=0,{$[all x in"01tTfFyYnN";(any"0fFnN"in x)and any"1tTyY"in x;0b]}each dchar; / boolean
 100         info:update t:"B",rule:250,maybe:1b from info where t in"HC",mw=1,mdot=0,{all x in"01tTfFyYnN"}each dchar; / boolean
 101         info:update t:"X",rule:260,maybe:0b from info where t="?",mw=2,{$[all x in"0123456789abcdefABCDEF";(any .Q.n in x)and any"abcdefABCDEF"in x;0b]}each dchar; /hex
 102         info:update t:"S",rule:270,maybe:1b from info where t="?",mw<.csv.SYMMAXWIDTH,mw>1,gr<.csv.SYMMAXGR; / symbols (max width permitting)
 103         info:update t:"*",rule:280,maybe:0b from info where t="?"; / the rest as strings
 104         / flag those S/* columns which could be encoded to integers (.Q.j10/x10/j12/x12) to avoid symbols
 105         info:update j12:1b from info where t in"S*",mw<13,{all x in .Q.nA}each dchar;
 106         info:update j10:1b from info where t in"S*",mw<11,{all x in .Q.b6}each dchar;
 107         select c,ci,t,maybe,empty,res,j10,j12,ipa,mw,mdot,rule,gr,ndv,dchar from info}
 108 info:info0[;()] / by default don't restrict columns
 109 infolike:{[file;pattern] info0[file;{x where x like y}[lower colhdrs[file];pattern]]} / .csv.infolike[file;"*time"]
 110
 111 \d .
 112 / DATA:()
 113 bulkload:{[file;info]
 114         if[not`DATA in system"v";'`DATA.not.defined];
 115         if[count DATA;'`DATA.not.empty];
 116         loadhdrs:exec c from info where not t=" ";loadfmts:exec t from info;
 117         .csv.fs2[{[file;loadhdrs;loadfmts] `DATA insert $[count DATA;flip loadhdrs!(loadfmts;.csv.DELIM)0:file;loadhdrs xcol(loadfmts;enlist .csv.DELIM)0:file]}[file;loadhdrs;loadfmts]];
 118         count DATA}
 119 @[.:;"\\l csvutil.custom.q";::]; / save your custom settings in csvutil.custom.q to override those set at the beginning of the file
 120 </textarea></div>
 121
 122     <script>
 123       var editor = CodeMirror.fromTextArea(document.getElementById("code"), {
 124         lineNumbers: true,
 125         matchBrackets: true
 126       });
 127     </script>
 128
 129     <p><strong>MIME type defined:</strong> <code>text/x-q</code>.</p>
 130   </body>
 131 </html>