acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_CHECK_LINUX26
  18 dnl
  19 dnl Configure linux kernel source tree
  20 AC_DEFUN([OVS_CHECK_LINUX26], [
  21   AC_ARG_WITH([l26],
  22               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  23                               [Specify the linux 2.6 kernel build directory])],
  24               [KBUILD26="$withval"], [KBUILD26=])dnl
  25   AC_ARG_WITH([l26-source],
  26               [AC_HELP_STRING([--with-l26-source=/path/to/linux-2.6-source],
  27                               [Specify the linux 2.6 kernel source directory
  28                                (usually figured out automatically from build
  29                                directory)])],
  30               [KSRC26="$withval"], [KSRC26=])dnl
  31   if test -n "$KBUILD26"; then
  32     KBUILD26=`eval echo "$KBUILD26"`
  33     case $KBUILD26 in
  34         /*) ;;
  35         *) KBUILD26=`pwd`/$KBUILD26 ;;
  36     esac
  37
  38     # The build directory is what the user provided.
  39     # Make sure that it exists.
  40     AC_MSG_CHECKING([for Linux 2.6 build directory])
  41     if test -d "$KBUILD26"; then
  42         AC_MSG_RESULT([$KBUILD26])
  43         AC_SUBST(KBUILD26)
  44     else
  45         AC_MSG_RESULT([no])
  46         AC_ERROR([source dir $KBUILD26 doesn't exist])
  47     fi
  48
  49     # Debian breaks kernel headers into "source" header and "build" headers.
  50     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  51     # Use heuristics to find the source headers.
  52     AC_MSG_CHECKING([for Linux 2.6 source directory])
  53     if test -n "$KSRC26"; then
  54       KSRC26=`eval echo "$KSRC26"`
  55       case $KSRC26 in
  56           /*) ;;
  57           *) KSRC26=`pwd`/$KSRC26 ;;
  58       esac
  59       if test ! -e $KSRC26/include/linux/kernel.h; then
  60         AC_MSG_ERROR([$KSRC26 is not a kernel source directory)])
  61       fi
  62     else
  63       KSRC26=$KBUILD26
  64       if test ! -e $KSRC26/include/linux/kernel.h; then
  65         case `echo "$KBUILD26" | sed 's,/*$,,'` in # (
  66           */build)
  67             KSRC26=`echo "$KBUILD26" | sed 's,/build/*$,/source,'`
  68             ;; # (
  69           *)
  70             KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  71             ;;
  72         esac
  73       fi
  74       if test ! -e $KSRC26/include/linux/kernel.h; then
  75         AC_MSG_ERROR([cannot find source directory (please use --with-l26-source)])
  76       fi
  77     fi
  78     AC_MSG_RESULT([$KSRC26])
  79
  80     AC_MSG_CHECKING([for kernel version])
  81     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  82     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  83     if test -z "$patchlevel" || test -z "$sublevel"; then
  84        AC_ERROR([cannot determine kernel version])
  85     fi
  86     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  87     if test "2.$patchlevel" != '2.6'; then
  88        if test "$BUILD26" = "$KSRC26"; then
  89          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
  90        else
  91          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
  92        fi
  93     fi
  94     if test ! -e "$KBUILD26"/include/linux/version.h || \
  95        (test ! -e "$KBUILD26"/include/linux/autoconf.h && \
  96         test ! -e "$KBUILD26"/include/generated/autoconf.h); then
  97         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
  98     fi
  99     OVS_CHECK_LINUX26_COMPAT
 100   elif test -n "$KSRC26"; then
 101     AC_MSG_ERROR([--with-l26-source may not be specified without --with-l26])
 102   fi
 103   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
 104 ])
 105
 106 dnl OVS_GREP_IFELSE(FILE, REGEX, IF-MATCH, IF-NO-MATCH)
 107 dnl
 108 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 109 AC_DEFUN([OVS_GREP_IFELSE], [
 110   AC_MSG_CHECKING([whether $2 matches in $1])
 111   grep '$2' $1 >/dev/null 2>&1
 112   status=$?
 113   case $status in
 114     0)
 115       AC_MSG_RESULT([yes])
 116       $3
 117       ;;
 118     1)
 119       AC_MSG_RESULT([no])
 120       $4
 121       ;;
 122     *)
 123       AC_MSG_ERROR([grep exited with status $status])
 124       ;;
 125   esac
 126 ])
 127
 128 dnl OVS_DEFINE(NAME)
 129 dnl
 130 dnl Defines NAME to 1 in kcompat.h.
 131 AC_DEFUN([OVS_DEFINE], [
 132   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 133 ])
 134
 135 AC_DEFUN([OVS_CHECK_LOG2_H], [
 136   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 137   if test -e $KSRC26/include/linux/log2.h; then
 138     AC_MSG_RESULT([yes])
 139     OVS_DEFINE([HAVE_LOG2_H])
 140   else
 141     AC_MSG_RESULT([no])
 142   fi
 143 ])
 144
 145 dnl OVS_CHECK_LINUX26_COMPAT
 146 dnl
 147 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 148 dnl the directory in $KBUILD26.
 149 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 150   rm -f datapath/linux-2.6/kcompat.h.new
 151   mkdir -p datapath/linux-2.6
 152   : > datapath/linux-2.6/kcompat.h.new
 153
 154   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST],
 155                   [OVS_DEFINE([HAVE_ERR_CAST])])
 156
 157   OVS_GREP_IFELSE([$KSRC26/include/linux/in.h], [ipv4_is_multicast],
 158                   [OVS_DEFINE([HAVE_IPV4_IS_MULTICAST])])
 159
 160   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_disable_lro],
 161                   [OVS_DEFINE([HAVE_DEV_DISABLE_LRO])])
 162   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_get_stats],
 163                   [OVS_DEFINE([HAVE_DEV_GET_STATS])])
 164
 165   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 166   # is necessary because some versions of this header remove the
 167   # member but retain the kerneldoc comment that describes it (which
 168   # starts with @).  The brackets must be doubled because of m4
 169   # quoting rules.
 170   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 171                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 172   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 173                   [OVS_DEFINE([HAVE_MAC_RAW])])
 174   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_dst(],
 175                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 176   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 177                   [skb_copy_from_linear_data_offset],
 178                   [OVS_DEFINE([HAVE_SKB_COPY_FROM_LINEAR_DATA_OFFSET])])
 179   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow_head],
 180                   [OVS_DEFINE([HAVE_SKB_COW_HEAD])])
 181   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 182                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 183   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_warn_if_lro],
 184                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 185
 186   OVS_GREP_IFELSE([$KSRC26/include/linux/string.h $KSRC26/include/linux/slab.h],
 187                   [kmemdup], [OVS_DEFINE([HAVE_KMEMDUP])])
 188
 189   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [bool],
 190                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 191
 192   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold],
 193                   [OVS_DEFINE([HAVE_CSUM_UNFOLD])])
 194
 195   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING],
 196                   [OVS_DEFINE([HAVE_NLA_NUL_STRING])])
 197   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_get_be16],
 198                   [OVS_DEFINE([HAVE_NLA_GET_BE16])])
 199
 200   OVS_CHECK_LOG2_H
 201
 202   if cmp -s datapath/linux-2.6/kcompat.h.new \
 203             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 204     rm datapath/linux-2.6/kcompat.h.new
 205   else
 206     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 207   fi
 208 ])
 209
 210 dnl Checks for net/if_packet.h.
 211 AC_DEFUN([OVS_CHECK_IF_PACKET],
 212   [AC_CHECK_HEADER([net/if_packet.h],
 213                    [HAVE_IF_PACKET=yes],
 214                    [HAVE_IF_PACKET=no])
 215    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 216    if test "$HAVE_IF_PACKET" = yes; then
 217       AC_DEFINE([HAVE_IF_PACKET], [1],
 218                 [Define to 1 if net/if_packet.h is available.])
 219    fi])
 220
 221 dnl Checks for buggy strtok_r.
 222 dnl
 223 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 224 dnl with optimization that can cause segfaults:
 225 dnl
 226 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 227 AC_DEFUN([OVS_CHECK_STRTOK_R],
 228   [AC_CACHE_CHECK(
 229      [whether strtok_r macro segfaults on some inputs],
 230      [ovs_cv_strtok_r_bug],
 231      [AC_RUN_IFELSE(
 232         [AC_LANG_PROGRAM([#include <stdio.h>
 233                           #include <string.h>
 234                          ],
 235                          [[char string[] = ":::";
 236                            char *save_ptr = (char *) 0xc0ffee;
 237                            char *token1, *token2;
 238                            token1 = strtok_r(string, ":", &save_ptr);
 239                            token2 = strtok_r(NULL, ":", &save_ptr);
 240                            freopen ("/dev/null", "w", stdout);
 241                            printf ("%s %s\n", token1, token2);
 242                            return 0;
 243                           ]])],
 244         [ovs_cv_strtok_r_bug=no],
 245         [ovs_cv_strtok_r_bug=yes],
 246         [ovs_cv_strtok_r_bug=yes])])
 247    if test $ovs_cv_strtok_r_bug = yes; then
 248      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 249                [Define if strtok_r macro segfaults on some inputs])
 250    fi
 251 ])
 252
 253 dnl ----------------------------------------------------------------------
 254 dnl These macros are from GNU PSPP, with the following original license:
 255 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 256 dnl This file is free software; the Free Software Foundation
 257 dnl gives unlimited permission to copy and/or distribute it,
 258 dnl with or without modifications, as long as this notice is preserved.
 259
 260 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 261 dnl Check whether the given C compiler OPTION is accepted.
 262 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 263 AC_DEFUN([OVS_CHECK_CC_OPTION],
 264 [
 265   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 266   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 267     [ovs_save_CFLAGS="$CFLAGS"
 268      CFLAGS="$CFLAGS $1"
 269      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 270      CFLAGS="$ovs_save_CFLAGS"])
 271   if test $ovs_cv_name = yes; then
 272     m4_if([$2], [], [:], [$2])
 273   else
 274     m4_if([$3], [], [:], [$3])
 275   fi
 276 ])
 277
 278 dnl OVS_ENABLE_OPTION([OPTION])
 279 dnl Check whether the given C compiler OPTION is accepted.
 280 dnl If so, add it to WARNING_FLAGS.
 281 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 282 AC_DEFUN([OVS_ENABLE_OPTION],
 283   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 284    AC_SUBST([WARNING_FLAGS])])
 285
 286 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 287 dnl Check whether the given C compiler OPTION is accepted.
 288 dnl If so, enable the given Automake CONDITIONAL.
 289
 290 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 291 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 292   [OVS_CHECK_CC_OPTION(
 293     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 294    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 295 dnl ----------------------------------------------------------------------