arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10 #include <asm/segment.h>
  11
  12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  13 OUTPUT_ARCH(i386)
  14 ENTRY(phys_startup_32)
  15 jiffies = jiffies_64;
  16 SECTIONS
  17 {
  18   . = LOAD_OFFSET + KERN_PHYS_OFFSET;
  19   phys_startup_32 = startup_32 - LOAD_OFFSET;
  20   /* read-only */
  21   _text = .;                    /* Text and read-only data */
  22   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  23         *(.text)
  24         SCHED_TEXT
  25         LOCK_TEXT
  26         *(.fixup)
  27         *(.gnu.warning)
  28         } = 0x9090
  29
  30   _etext = .;                   /* End of text section */
  31
  32   . = ALIGN(16);                /* Exception table */
  33   __start___ex_table = .;
  34   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  35   __stop___ex_table = .;
  36
  37   RODATA
  38
  39   /* writeable */
  40   .data : AT(ADDR(.data) - LOAD_OFFSET) {                       /* Data */
  41         *(.data)
  42         CONSTRUCTORS
  43         }
  44
  45   . = ALIGN(4096);
  46   __nosave_begin = .;
  47   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  48   . = ALIGN(4096);
  49   __nosave_end = .;
  50
  51   . = ALIGN(4096);
  52   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) { *(.data.idt) }
  53
  54   . = ALIGN(32);
  55   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  56         *(.data.cacheline_aligned)
  57   }
  58
  59   _edata = .;                   /* End of data section */
  60
  61   . = ALIGN(THREAD_SIZE);       /* init_task */
  62   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) { *(.data.init_task) }
  63
  64   /* will be freed after init */
  65   . = ALIGN(4096);              /* Init code and data */
  66   __init_begin = .;
  67   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  68         _sinittext = .;
  69         *(.init.text)
  70         _einittext = .;
  71   }
  72   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
  73   . = ALIGN(16);
  74   __setup_start = .;
  75   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
  76   __setup_end = .;
  77   __initcall_start = .;
  78   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
  79         *(.initcall1.init)
  80         *(.initcall2.init)
  81         *(.initcall3.init)
  82         *(.initcall4.init)
  83         *(.initcall5.init)
  84         *(.initcall6.init)
  85         *(.initcall7.init)
  86   }
  87   __initcall_end = .;
  88   __con_initcall_start = .;
  89   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
  90         *(.con_initcall.init)
  91   }
  92   __con_initcall_end = .;
  93   SECURITY_INIT
  94   . = ALIGN(4);
  95   __alt_instructions = .;
  96   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
  97         *(.altinstructions)
  98   }
  99   __alt_instructions_end = .;
 100  .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 101         *(.altinstr_replacement)
 102  }
 103   /* .exit.text is discard at runtime, not link time, to deal with references
 104      from .altinstructions and .eh_frame */
 105   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 106   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 107   . = ALIGN(4096);
 108   __initramfs_start = .;
 109   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 110   __initramfs_end = .;
 111   . = ALIGN(32);
 112   __per_cpu_start = .;
 113   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 114   __per_cpu_end = .;
 115   . = ALIGN(4096);
 116   __init_end = .;
 117   /* freed after init ends here */
 118
 119   __bss_start = .;              /* BSS */
 120   .bss.page_aligned  : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 121         *(.bss.page_aligned) }
 122   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 123         *(.bss)
 124   }
 125   . = ALIGN(4);
 126   __bss_stop = .;
 127
 128   _end = . ;
 129
 130   /* This is where the kernel creates the early boot page tables */
 131   . = ALIGN(4096);
 132   pg0 = .;
 133
 134   /* Sections to be discarded */
 135   /DISCARD/ : {
 136         *(.exitcall.exit)
 137         }
 138
 139   /* Stabs debugging sections.  */
 140   .stab 0 : { *(.stab) }
 141   .stabstr 0 : { *(.stabstr) }
 142   .stab.excl 0 : { *(.stab.excl) }
 143   .stab.exclstr 0 : { *(.stab.exclstr) }
 144   .stab.index 0 : { *(.stab.index) }
 145   .stab.indexstr 0 : { *(.stab.indexstr) }
 146   .comment 0 : { *(.comment) }
 147 }