m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (yes) coverage=true ;;
  26         (no)  coverage=false ;;
  27         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  28       esac],
  29      [coverage=false])
  30    if $coverage; then
  31      CFLAGS="$CFLAGS -O0 --coverage"
  32      LDFLAGS="$LDFLAGS --coverage"
  33    fi])
  34
  35 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  36 AC_DEFUN([OVS_CHECK_NDEBUG],
  37   [AC_ARG_ENABLE(
  38      [ndebug],
  39      [AC_HELP_STRING([--enable-ndebug],
  40                      [Disable debugging features for max performance])],
  41      [case "${enableval}" in
  42         (yes) ndebug=true ;;
  43         (no)  ndebug=false ;;
  44         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  45       esac],
  46      [ndebug=false])
  47    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  48
  49 dnl Checks for --enable-cache-time and defines CACHE_TIME if it is specified.
  50 AC_DEFUN([OVS_CHECK_CACHE_TIME],
  51   [AC_ARG_ENABLE(
  52      [cache-time],
  53      [AC_HELP_STRING([--enable-cache-time],
  54                      [Override time caching default (for testing only)])],
  55      [case "${enableval}" in
  56         (yes) cache_time=1;;
  57         (no)  cache_time=0;;
  58         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-cache-time]) ;;
  59       esac
  60       AC_DEFINE_UNQUOTED([CACHE_TIME], [$cache_time],
  61           [Define to 1 to enable time caching, to 0 to disable time caching, or
  62            leave undefined to use the default (as one should
  63            ordinarily do).])])])
  64
  65 dnl Checks for ESX.
  66 AC_DEFUN([OVS_CHECK_ESX],
  67   [AC_CHECK_HEADER([vmware.h],
  68                    [ESX=yes],
  69                    [ESX=no])
  70    AM_CONDITIONAL([ESX], [test "$ESX" = yes])
  71    if test "$ESX" = yes; then
  72       AC_DEFINE([ESX], [1], [Define to 1 if building on ESX.])
  73    fi])
  74
  75 dnl Checks for Netlink support.
  76 AC_DEFUN([OVS_CHECK_NETLINK],
  77   [AC_CHECK_HEADER([linux/netlink.h],
  78                    [HAVE_NETLINK=yes],
  79                    [HAVE_NETLINK=no],
  80                    [#include <sys/socket.h>
  81    #include <linux/types.h>
  82    ])
  83    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  84    if test "$HAVE_NETLINK" = yes; then
  85       AC_DEFINE([HAVE_NETLINK], [1],
  86                 [Define to 1 if Netlink protocol is available.])
  87    fi])
  88
  89 dnl Checks for OpenSSL.
  90 AC_DEFUN([OVS_CHECK_OPENSSL],
  91   [AC_ARG_ENABLE(
  92      [ssl],
  93      [AC_HELP_STRING([--disable-ssl], [Disable OpenSSL support])],
  94      [case "${enableval}" in
  95         (yes) ssl=true ;;
  96         (no)  ssl=false ;;
  97         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  98       esac],
  99      [ssl=check])
 100
 101    if test "$ssl" != false; then
 102        m4_ifndef([PKG_CHECK_MODULES], [m4_fatal([Please install pkg-config.])])
 103        PKG_CHECK_MODULES([SSL], [openssl],
 104          [HAVE_OPENSSL=yes],
 105          [HAVE_OPENSSL=no
 106           if test "$ssl" = check; then
 107             AC_MSG_WARN([Cannot find openssl:
 108
 109 $SSL_PKG_ERRORS
 110
 111 OpenFlow connections over SSL will not be supported.
 112 (You may use --disable-ssl to suppress this warning.)])
 113           else
 114             AC_MSG_ERROR([Cannot find openssl (use --disable-ssl to configure without SSL support)])
 115           fi])
 116    else
 117        HAVE_OPENSSL=no
 118    fi
 119    AC_SUBST([HAVE_OPENSSL])
 120    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
 121    if test "$HAVE_OPENSSL" = yes; then
 122       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
 123    fi])
 124
 125 dnl Checks for libraries needed by lib/socket-util.c.
 126 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 127   [AC_CHECK_LIB([socket], [connect])
 128    AC_SEARCH_LIBS([gethostbyname], [resolv], [RESOLVER_LIBS=-lresolv])])
 129
 130 dnl Checks for the directory in which to store the PKI.
 131 AC_DEFUN([OVS_CHECK_PKIDIR],
 132   [AC_ARG_WITH(
 133      [pkidir],
 134      AC_HELP_STRING([--with-pkidir=DIR],
 135                     [PKI hierarchy directory [[LOCALSTATEDIR/lib/openvswitch/pki]]]),
 136      [PKIDIR=$withval],
 137      [PKIDIR='${localstatedir}/lib/openvswitch/pki'])
 138    AC_SUBST([PKIDIR])])
 139
 140 dnl Checks for the directory in which to store pidfiles.
 141 AC_DEFUN([OVS_CHECK_RUNDIR],
 142   [AC_ARG_WITH(
 143      [rundir],
 144      AC_HELP_STRING([--with-rundir=DIR],
 145                     [directory used for pidfiles
 146                     [[LOCALSTATEDIR/run/openvswitch]]]),
 147      [RUNDIR=$withval],
 148      [RUNDIR='${localstatedir}/run/openvswitch'])
 149    AC_SUBST([RUNDIR])])
 150
 151 dnl Checks for the directory in which to store logs.
 152 AC_DEFUN([OVS_CHECK_LOGDIR],
 153   [AC_ARG_WITH(
 154      [logdir],
 155      AC_HELP_STRING([--with-logdir=DIR],
 156                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 157      [LOGDIR=$withval],
 158      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 159    AC_SUBST([LOGDIR])])
 160
 161 dnl Checks for the directory in which to store the Open vSwitch database.
 162 AC_DEFUN([OVS_CHECK_DBDIR],
 163   [AC_ARG_WITH(
 164      [dbdir],
 165      AC_HELP_STRING([--with-dbdir=DIR],
 166                     [directory used for conf.db [[SYSCONFDIR/PACKAGE]]]),
 167      [DBDIR=$withval],
 168      [DBDIR='${sysconfdir}/${PACKAGE}'])
 169    AC_SUBST([DBDIR])])
 170
 171 dnl Defines HAVE_BACKTRACE if backtrace() is declared in <execinfo.h>
 172 dnl and exists in libc.
 173 AC_DEFUN([OVS_CHECK_BACKTRACE],
 174   [AC_CHECK_HEADER([execinfo.h], [AC_CHECK_FUNCS([backtrace])])])
 175
 176 dnl Checks for __malloc_hook, etc., supported by glibc.
 177 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 178   [AC_CACHE_CHECK(
 179     [whether libc supports hooks for malloc and related functions],
 180     [ovs_cv_malloc_hooks],
 181     [AC_COMPILE_IFELSE(
 182       [AC_LANG_PROGRAM(
 183          [#include <malloc.h>
 184          ],
 185          [(void) __malloc_hook;
 186           (void) __realloc_hook;
 187           (void) __free_hook;])],
 188       [ovs_cv_malloc_hooks=yes],
 189       [ovs_cv_malloc_hooks=no])])
 190    if test $ovs_cv_malloc_hooks = yes; then
 191      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 192                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 193                 __free_hook in <malloc.h>.])
 194    fi])
 195
 196 dnl Checks for valgrind/valgrind.h.
 197 AC_DEFUN([OVS_CHECK_VALGRIND],
 198   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 199
 200 dnl Checks for Python 2.x, x >= 4.
 201 AC_DEFUN([OVS_CHECK_PYTHON],
 202   [AC_CACHE_CHECK(
 203      [for Python 2.x for x >= 4],
 204      [ovs_cv_python],
 205      [if test -n "$PYTHON"; then
 206         ovs_cv_python=$PYTHON
 207       else
 208         ovs_cv_python=no
 209         for binary in python python2.4 python2.5; do
 210           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 211           for dir in $PATH; do
 212             IFS=$ovs_save_IFS
 213             test -z "$dir" && dir=.
 214             if test -x $dir/$binary && $dir/$binary -c 'import sys
 215 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 216     sys.exit(0)
 217 else:
 218     sys.exit(1)'; then
 219               ovs_cv_python=$dir/$binary
 220               break 2
 221             fi
 222           done
 223         done
 224       fi])
 225    AC_SUBST([HAVE_PYTHON])
 226    AM_MISSING_PROG([PYTHON], [python])
 227    if test $ovs_cv_python != no; then
 228      PYTHON=$ovs_cv_python
 229      HAVE_PYTHON=yes
 230    else
 231      HAVE_PYTHON=no
 232    fi
 233    AM_CONDITIONAL([HAVE_PYTHON], [test "$HAVE_PYTHON" = yes])])
 234
 235 dnl Checks for dot.
 236 AC_DEFUN([OVS_CHECK_DOT],
 237   [AC_CACHE_CHECK(
 238     [for dot],
 239     [ovs_cv_dot],
 240     [dnl "dot" writes -V output to stderr:
 241      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 242        ovs_cv_dot=yes
 243      else
 244        ovs_cv_dot=no
 245      fi])
 246    AM_CONDITIONAL([HAVE_DOT], [test "$ovs_cv_dot" = yes])])
 247
 248 dnl Checks for pyuic4.
 249 AC_DEFUN([OVS_CHECK_PYUIC4],
 250   [AC_CACHE_CHECK(
 251     [for pyuic4],
 252     [ovs_cv_pyuic4],
 253     [if (pyuic4 --version) >/dev/null 2>&1; then
 254        ovs_cv_pyuic4=pyuic4
 255      else
 256        ovs_cv_pyuic4=no
 257      fi])
 258    AM_MISSING_PROG([PYUIC4], [pyuic4])
 259    if test $ovs_cv_pyuic4 != no; then
 260      PYUIC4=$ovs_cv_pyuic4
 261    fi])
 262
 263 dnl Checks whether $PYTHON supports the module given as $1
 264 AC_DEFUN([OVS_CHECK_PYTHON_MODULE],
 265   [AC_REQUIRE([OVS_CHECK_PYTHON])
 266    AC_CACHE_CHECK(
 267      [for $1 Python module],
 268      [ovs_cv_py_[]AS_TR_SH([$1])],
 269      [ovs_cv_py_[]AS_TR_SH([$1])=no
 270       if test $HAVE_PYTHON = yes; then
 271         AS_ECHO(["running $PYTHON -c 'import $1
 272 import sys
 273 sys.exit(0)'..."]) >&AS_MESSAGE_LOG_FD 2>&1
 274         if $PYTHON -c 'import $1
 275 import sys
 276 sys.exit(0)' >&AS_MESSAGE_LOG_FD 2>&1; then
 277           ovs_cv_py_[]AS_TR_SH([$1])=yes
 278         fi
 279       fi])])
 280
 281 dnl Checks for Python modules needed by ovsdbmonitor.
 282 AC_DEFUN([OVS_CHECK_OVSDBMONITOR],
 283   [OVS_CHECK_PYTHON_MODULE([PySide.QtCore])
 284    OVS_CHECK_PYTHON_MODULE([PyQt4.QtCore])
 285    OVS_CHECK_PYTHON_MODULE([twisted.conch.ssh])
 286    OVS_CHECK_PYTHON_MODULE([twisted.internet])
 287    OVS_CHECK_PYTHON_MODULE([twisted.application])
 288    OVS_CHECK_PYTHON_MODULE([json])
 289    OVS_CHECK_PYTHON_MODULE([zope.interface])
 290    if (test $ovs_cv_py_PySide_QtCore = yes \
 291        || test $ovs_cv_py_PyQt4_QtCore = yes) \
 292       && test $ovs_cv_py_twisted_conch_ssh = yes \
 293       && test $ovs_cv_py_twisted_internet = yes \
 294       && test $ovs_cv_py_twisted_application = yes \
 295       && test $ovs_cv_py_json = yes \
 296       && test $ovs_cv_py_zope_interface = yes; then
 297      BUILD_OVSDBMONITOR=yes
 298    else
 299      BUILD_OVSDBMONITOR=no
 300    fi
 301    AC_MSG_CHECKING([whether to build ovsdbmonitor])
 302    AC_MSG_RESULT([$BUILD_OVSDBMONITOR])
 303    AM_CONDITIONAL([BUILD_OVSDBMONITOR], [test $BUILD_OVSDBMONITOR = yes])])
 304
 305 # OVS_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 306 # -------------------------------------------------------------
 307 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 308 # into a program.
 309 #
 310 # This macro is borrowed from acinclude.m4 in GNU PSPP, which has the
 311 # following license:
 312 #
 313 #     Copyright (C) 2005, 2006, 2007, 2009 Free Software Foundation, Inc.
 314 #     This file is free software; the Free Software Foundation
 315 #     gives unlimited permission to copy and/or distribute it,
 316 #     with or without modifications, as long as this notice is preserved.
 317 #
 318 m4_define([OVS_LINK2_IFELSE],
 319 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 320 mv conftest.$ac_ext conftest1.$ac_ext
 321 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 322 mv conftest.$ac_ext conftest2.$ac_ext
 323 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 324 ovs_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 325 AS_IF([_AC_DO_STDERR($ovs_link2) && {
 326          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 327          test ! -s conftest.err
 328        } && test -s conftest$ac_exeext && {
 329          test "$cross_compiling" = yes ||
 330          AS_TEST_X([conftest$ac_exeext])
 331        }],
 332       [$3],
 333       [echo "$as_me: failed source file 1 of 2 was:" >&5
 334 sed 's/^/| /' conftest1.$ac_ext >&5
 335 echo "$as_me: failed source file 2 of 2 was:" >&5
 336 sed 's/^/| /' conftest2.$ac_ext >&5
 337         $4])
 338 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 339 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 340 dnl as it would interfere with the next link command.
 341 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 342 rm -f core conftest.err conftest1.err conftest2.err
 343 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 344 rm -f conftest$ac_exeext
 345 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 346 ])# OVS_LINK2_IFELSE
 347
 348 dnl Defines USE_LINKER_SECTIONS to 1 if the compiler supports putting
 349 dnl variables in sections with user-defined names and the linker
 350 dnl automatically defines __start_SECNAME and __stop_SECNAME symbols
 351 dnl that designate the start and end of the sections.
 352 AC_DEFUN([OVS_CHECK_LINKER_SECTIONS],
 353   [AC_CACHE_CHECK(
 354     [for user-defined linker section support],
 355     [ovs_cv_use_linker_sections],
 356     [OVS_LINK2_IFELSE(
 357       [AC_LANG_SOURCE(
 358         [int a __attribute__((__section__("mysection"))) = 1;
 359          int b __attribute__((__section__("mysection"))) = 2;
 360          int c __attribute__((__section__("mysection"))) = 3;])],
 361       [AC_LANG_PROGRAM(
 362         [#include <stdio.h>
 363          extern int __start_mysection;
 364          extern int __stop_mysection;],
 365         [int n_ints = &__stop_mysection - &__start_mysection;
 366          int *i;
 367          for (i = &__start_mysection; i < &__start_mysection + n_ints; i++) {
 368              printf("%d\n", *i);
 369          }])],
 370       [ovs_cv_use_linker_sections=yes],
 371       [ovs_cv_use_linker_sections=no])])
 372    if test $ovs_cv_use_linker_sections = yes; then
 373      AC_DEFINE([USE_LINKER_SECTIONS], [1],
 374                [Define to 1 if the compiler support putting variables
 375                 into sections with user-defined names and the linker
 376                 automatically defines __start_SECNAME and __stop_SECNAME
 377                 symbols that designate the start and end of the section.])
 378    fi
 379    AM_CONDITIONAL(
 380      [USE_LINKER_SECTIONS], [test $ovs_cv_use_linker_sections = yes])])
 381
 382 dnl Checks for groff.
 383 AC_DEFUN([OVS_CHECK_GROFF],
 384   [AC_CACHE_CHECK(
 385     [for groff],
 386     [ovs_cv_groff],
 387     [if (groff -v) >/dev/null 2>&1; then
 388        ovs_cv_groff=yes
 389      else
 390        ovs_cv_groff=no
 391      fi])
 392    AM_CONDITIONAL([HAVE_GROFF], [test "$ovs_cv_groff" = yes])])