m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (yes) coverage=true ;;
  26         (no)  coverage=false ;;
  27         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  28       esac],
  29      [coverage=false])
  30    if $coverage; then
  31      CFLAGS="$CFLAGS -O0 --coverage"
  32      LDFLAGS="$LDFLAGS --coverage"
  33    fi])
  34
  35 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  36 AC_DEFUN([OVS_CHECK_NDEBUG],
  37   [AC_ARG_ENABLE(
  38      [ndebug],
  39      [AC_HELP_STRING([--enable-ndebug],
  40                      [Disable debugging features for max performance])],
  41      [case "${enableval}" in
  42         (yes) ndebug=true ;;
  43         (no)  ndebug=false ;;
  44         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  45       esac],
  46      [ndebug=false])
  47    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  48
  49 dnl Checks for --enable-cache-time and defines CACHE_TIME if it is specified.
  50 AC_DEFUN([OVS_CHECK_CACHE_TIME],
  51   [AC_ARG_ENABLE(
  52      [cache-time],
  53      [AC_HELP_STRING([--enable-cache-time],
  54                      [Override time caching default (for testing only)])],
  55      [case "${enableval}" in
  56         (yes) cache_time=1;;
  57         (no)  cache_time=0;;
  58         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-cache-time]) ;;
  59       esac
  60       AC_DEFINE_UNQUOTED([CACHE_TIME], [$cache_time],
  61           [Define to 1 to enable time caching, to 0 to disable time caching, or
  62            leave undefined to use the default (as one should
  63            ordinarily do).])])])
  64
  65 dnl Checks for ESX.
  66 AC_DEFUN([OVS_CHECK_ESX],
  67   [AC_CHECK_HEADER([vmware.h],
  68                    [ESX=yes],
  69                    [ESX=no])
  70    AM_CONDITIONAL([ESX], [test "$ESX" = yes])
  71    if test "$ESX" = yes; then
  72       AC_DEFINE([ESX], [1], [Define to 1 if building on ESX.])
  73    fi])
  74
  75 dnl Checks for Netlink support.
  76 AC_DEFUN([OVS_CHECK_NETLINK],
  77   [AC_CHECK_HEADER([linux/netlink.h],
  78                    [HAVE_NETLINK=yes],
  79                    [HAVE_NETLINK=no],
  80                    [#include <sys/socket.h>
  81    #include <linux/types.h>
  82    ])
  83    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  84    if test "$HAVE_NETLINK" = yes; then
  85       AC_DEFINE([HAVE_NETLINK], [1],
  86                 [Define to 1 if Netlink protocol is available.])
  87    fi])
  88
  89 dnl Checks for OpenSSL.
  90 AC_DEFUN([OVS_CHECK_OPENSSL],
  91   [AC_ARG_ENABLE(
  92      [ssl],
  93      [AC_HELP_STRING([--disable-ssl], [Disable OpenSSL support])],
  94      [case "${enableval}" in
  95         (yes) ssl=true ;;
  96         (no)  ssl=false ;;
  97         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  98       esac],
  99      [ssl=check])
 100
 101    if test "$ssl" != false; then
 102        AX_CHECK_OPENSSL(
 103          [HAVE_OPENSSL=yes],
 104          [HAVE_OPENSSL=no
 105           if test "$ssl" = check; then
 106             AC_MSG_WARN([Cannot find openssl:
 107
 108 $SSL_PKG_ERRORS
 109
 110 OpenFlow connections over SSL will not be supported.
 111 (You may use --disable-ssl to suppress this warning.)])
 112           else
 113             AC_MSG_ERROR([Cannot find openssl (use --disable-ssl to configure without SSL support)])
 114           fi])
 115    else
 116        HAVE_OPENSSL=no
 117    fi
 118    AC_SUBST([HAVE_OPENSSL])
 119    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
 120    if test "$HAVE_OPENSSL" = yes; then
 121       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
 122    fi])
 123
 124 dnl Checks for libraries needed by lib/socket-util.c.
 125 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 126   [AC_CHECK_LIB([socket], [connect])
 127    AC_SEARCH_LIBS([gethostbyname], [resolv], [RESOLVER_LIBS=-lresolv])])
 128
 129 dnl Checks for the directory in which to store the PKI.
 130 AC_DEFUN([OVS_CHECK_PKIDIR],
 131   [AC_ARG_WITH(
 132      [pkidir],
 133      AC_HELP_STRING([--with-pkidir=DIR],
 134                     [PKI hierarchy directory [[LOCALSTATEDIR/lib/openvswitch/pki]]]),
 135      [PKIDIR=$withval],
 136      [PKIDIR='${localstatedir}/lib/openvswitch/pki'])
 137    AC_SUBST([PKIDIR])])
 138
 139 dnl Checks for the directory in which to store pidfiles.
 140 AC_DEFUN([OVS_CHECK_RUNDIR],
 141   [AC_ARG_WITH(
 142      [rundir],
 143      AC_HELP_STRING([--with-rundir=DIR],
 144                     [directory used for pidfiles
 145                     [[LOCALSTATEDIR/run/openvswitch]]]),
 146      [RUNDIR=$withval],
 147      [RUNDIR='${localstatedir}/run/openvswitch'])
 148    AC_SUBST([RUNDIR])])
 149
 150 dnl Checks for the directory in which to store logs.
 151 AC_DEFUN([OVS_CHECK_LOGDIR],
 152   [AC_ARG_WITH(
 153      [logdir],
 154      AC_HELP_STRING([--with-logdir=DIR],
 155                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 156      [LOGDIR=$withval],
 157      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 158    AC_SUBST([LOGDIR])])
 159
 160 dnl Checks for the directory in which to store the Open vSwitch database.
 161 AC_DEFUN([OVS_CHECK_DBDIR],
 162   [AC_ARG_WITH(
 163      [dbdir],
 164      AC_HELP_STRING([--with-dbdir=DIR],
 165                     [directory used for conf.db [[SYSCONFDIR/PACKAGE]]]),
 166      [DBDIR=$withval],
 167      [DBDIR='${sysconfdir}/${PACKAGE}'])
 168    AC_SUBST([DBDIR])])
 169
 170 dnl Defines HAVE_BACKTRACE if backtrace() is found.
 171 AC_DEFUN([OVS_CHECK_BACKTRACE],
 172   [AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])])
 173
 174 dnl Checks for __malloc_hook, etc., supported by glibc.
 175 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 176   [AC_CACHE_CHECK(
 177     [whether libc supports hooks for malloc and related functions],
 178     [ovs_cv_malloc_hooks],
 179     [AC_COMPILE_IFELSE(
 180       [AC_LANG_PROGRAM(
 181          [#include <malloc.h>
 182          ],
 183          [(void) __malloc_hook;
 184           (void) __realloc_hook;
 185           (void) __free_hook;])],
 186       [ovs_cv_malloc_hooks=yes],
 187       [ovs_cv_malloc_hooks=no])])
 188    if test $ovs_cv_malloc_hooks = yes; then
 189      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 190                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 191                 __free_hook in <malloc.h>.])
 192    fi])
 193
 194 dnl Checks for valgrind/valgrind.h.
 195 AC_DEFUN([OVS_CHECK_VALGRIND],
 196   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 197
 198 dnl Checks for Python 2.x, x >= 4.
 199 AC_DEFUN([OVS_CHECK_PYTHON],
 200   [AC_CACHE_CHECK(
 201      [for Python 2.x for x >= 4],
 202      [ovs_cv_python],
 203      [if test -n "$PYTHON"; then
 204         ovs_cv_python=$PYTHON
 205       else
 206         ovs_cv_python=no
 207         for binary in python python2.4 python2.5; do
 208           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 209           for dir in $PATH; do
 210             IFS=$ovs_save_IFS
 211             test -z "$dir" && dir=.
 212             if test -x $dir/$binary && $dir/$binary -c 'import sys
 213 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 214     sys.exit(0)
 215 else:
 216     sys.exit(1)'; then
 217               ovs_cv_python=$dir/$binary
 218               break 2
 219             fi
 220           done
 221         done
 222       fi])
 223    AC_SUBST([HAVE_PYTHON])
 224    AM_MISSING_PROG([PYTHON], [python])
 225    if test $ovs_cv_python != no; then
 226      PYTHON=$ovs_cv_python
 227      HAVE_PYTHON=yes
 228    else
 229      HAVE_PYTHON=no
 230    fi
 231    AM_CONDITIONAL([HAVE_PYTHON], [test "$HAVE_PYTHON" = yes])])
 232
 233 dnl Checks for dot.
 234 AC_DEFUN([OVS_CHECK_DOT],
 235   [AC_CACHE_CHECK(
 236     [for dot],
 237     [ovs_cv_dot],
 238     [dnl "dot" writes -V output to stderr:
 239      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 240        ovs_cv_dot=yes
 241      else
 242        ovs_cv_dot=no
 243      fi])
 244    AM_CONDITIONAL([HAVE_DOT], [test "$ovs_cv_dot" = yes])])
 245
 246 dnl Checks for pyuic4.
 247 AC_DEFUN([OVS_CHECK_PYUIC4],
 248   [AC_CACHE_CHECK(
 249     [for pyuic4],
 250     [ovs_cv_pyuic4],
 251     [if (pyuic4 --version) >/dev/null 2>&1; then
 252        ovs_cv_pyuic4=pyuic4
 253      else
 254        ovs_cv_pyuic4=no
 255      fi])
 256    AM_MISSING_PROG([PYUIC4], [pyuic4])
 257    if test $ovs_cv_pyuic4 != no; then
 258      PYUIC4=$ovs_cv_pyuic4
 259    fi])
 260
 261 dnl Checks whether $PYTHON supports the module given as $1
 262 AC_DEFUN([OVS_CHECK_PYTHON_MODULE],
 263   [AC_REQUIRE([OVS_CHECK_PYTHON])
 264    AC_CACHE_CHECK(
 265      [for $1 Python module],
 266      [ovs_cv_py_[]AS_TR_SH([$1])],
 267      [ovs_cv_py_[]AS_TR_SH([$1])=no
 268       if test $HAVE_PYTHON = yes; then
 269         AS_ECHO(["running $PYTHON -c 'import $1
 270 import sys
 271 sys.exit(0)'..."]) >&AS_MESSAGE_LOG_FD 2>&1
 272         if $PYTHON -c 'import $1
 273 import sys
 274 sys.exit(0)' >&AS_MESSAGE_LOG_FD 2>&1; then
 275           ovs_cv_py_[]AS_TR_SH([$1])=yes
 276         fi
 277       fi])])
 278
 279 dnl Checks for Python modules needed by ovsdbmonitor.
 280 AC_DEFUN([OVS_CHECK_OVSDBMONITOR],
 281   [OVS_CHECK_PYTHON_MODULE([PySide.QtCore])
 282    OVS_CHECK_PYTHON_MODULE([PyQt4.QtCore])
 283    OVS_CHECK_PYTHON_MODULE([twisted.conch.ssh])
 284    OVS_CHECK_PYTHON_MODULE([twisted.internet])
 285    OVS_CHECK_PYTHON_MODULE([twisted.application])
 286    OVS_CHECK_PYTHON_MODULE([json])
 287    OVS_CHECK_PYTHON_MODULE([zope.interface])
 288    if (test $ovs_cv_py_PySide_QtCore = yes \
 289        || test $ovs_cv_py_PyQt4_QtCore = yes) \
 290       && test $ovs_cv_py_twisted_conch_ssh = yes \
 291       && test $ovs_cv_py_twisted_internet = yes \
 292       && test $ovs_cv_py_twisted_application = yes \
 293       && test $ovs_cv_py_json = yes \
 294       && test $ovs_cv_py_zope_interface = yes; then
 295      BUILD_OVSDBMONITOR=yes
 296    else
 297      BUILD_OVSDBMONITOR=no
 298    fi
 299    AC_MSG_CHECKING([whether to build ovsdbmonitor])
 300    AC_MSG_RESULT([$BUILD_OVSDBMONITOR])
 301    AM_CONDITIONAL([BUILD_OVSDBMONITOR], [test $BUILD_OVSDBMONITOR = yes])])
 302
 303 # OVS_LINK2_IFELSE(SOURCE1, SOURCE2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 304 # -------------------------------------------------------------
 305 # Based on AC_LINK_IFELSE, but tries to link both SOURCE1 and SOURCE2
 306 # into a program.
 307 #
 308 # This macro is borrowed from acinclude.m4 in GNU PSPP, which has the
 309 # following license:
 310 #
 311 #     Copyright (C) 2005, 2006, 2007, 2009 Free Software Foundation, Inc.
 312 #     This file is free software; the Free Software Foundation
 313 #     gives unlimited permission to copy and/or distribute it,
 314 #     with or without modifications, as long as this notice is preserved.
 315 #
 316 m4_define([OVS_LINK2_IFELSE],
 317 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
 318 mv conftest.$ac_ext conftest1.$ac_ext
 319 m4_ifvaln([$2], [AC_LANG_CONFTEST([$2])])dnl
 320 mv conftest.$ac_ext conftest2.$ac_ext
 321 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest$ac_exeext
 322 ovs_link2='$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest1.$ac_ext conftest2.$ac_ext $LIBS >&5'
 323 AS_IF([_AC_DO_STDERR($ovs_link2) && {
 324          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
 325          test ! -s conftest.err
 326        } && test -s conftest$ac_exeext && {
 327          test "$cross_compiling" = yes ||
 328          AS_TEST_X([conftest$ac_exeext])
 329        }],
 330       [$3],
 331       [echo "$as_me: failed source file 1 of 2 was:" >&5
 332 sed 's/^/| /' conftest1.$ac_ext >&5
 333 echo "$as_me: failed source file 2 of 2 was:" >&5
 334 sed 's/^/| /' conftest2.$ac_ext >&5
 335         $4])
 336 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
 337 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
 338 dnl as it would interfere with the next link command.
 339 rm -rf conftest.dSYM conftest1.dSYM conftest2.dSYM
 340 rm -f core conftest.err conftest1.err conftest2.err
 341 rm -f conftest1.$ac_objext conftest2.$ac_objext conftest*_ipa8_conftest*.oo
 342 rm -f conftest$ac_exeext
 343 rm -f m4_ifval([$1], [conftest1.$ac_ext]) m4_ifval([$2], [conftest1.$ac_ext])[]dnl
 344 ])# OVS_LINK2_IFELSE
 345
 346 dnl Defines USE_LINKER_SECTIONS to 1 if the compiler supports putting
 347 dnl variables in sections with user-defined names and the linker
 348 dnl automatically defines __start_SECNAME and __stop_SECNAME symbols
 349 dnl that designate the start and end of the sections.
 350 AC_DEFUN([OVS_CHECK_LINKER_SECTIONS],
 351   [AC_CACHE_CHECK(
 352     [for user-defined linker section support],
 353     [ovs_cv_use_linker_sections],
 354     [OVS_LINK2_IFELSE(
 355       [AC_LANG_SOURCE(
 356         [int a __attribute__((__section__("mysection"))) = 1;
 357          int b __attribute__((__section__("mysection"))) = 2;
 358          int c __attribute__((__section__("mysection"))) = 3;])],
 359       [AC_LANG_PROGRAM(
 360         [#include <stdio.h>
 361          extern int __start_mysection;
 362          extern int __stop_mysection;],
 363         [int n_ints = &__stop_mysection - &__start_mysection;
 364          int *i;
 365          for (i = &__start_mysection; i < &__start_mysection + n_ints; i++) {
 366              printf("%d\n", *i);
 367          }])],
 368       [ovs_cv_use_linker_sections=yes],
 369       [ovs_cv_use_linker_sections=no])])
 370    if test $ovs_cv_use_linker_sections = yes; then
 371      AC_DEFINE([USE_LINKER_SECTIONS], [1],
 372                [Define to 1 if the compiler support putting variables
 373                 into sections with user-defined names and the linker
 374                 automatically defines __start_SECNAME and __stop_SECNAME
 375                 symbols that designate the start and end of the section.])
 376    fi
 377    AM_CONDITIONAL(
 378      [USE_LINKER_SECTIONS], [test $ovs_cv_use_linker_sections = yes])])
 379
 380 dnl Checks for groff.
 381 AC_DEFUN([OVS_CHECK_GROFF],
 382   [AC_CACHE_CHECK(
 383     [for groff],
 384     [ovs_cv_groff],
 385     [if (groff -v) >/dev/null 2>&1; then
 386        ovs_cv_groff=yes
 387      else
 388        ovs_cv_groff=no
 389      fi])
 390    AM_CONDITIONAL([HAVE_GROFF], [test "$ovs_cv_groff" = yes])])