pcucontrol/models/exp/DRAC.exp

   1 #!/usr/bin/expect
   2
   3 set timeout 60
   4 set method [lindex $argv 0]
   5 set host [lindex $argv 1]
   6 set user [lindex $argv 2]
   7 set password [lindex $argv 3]
   8 set dryrun [lindex $argv 4]
   9 set model [lindex $argv 5]
  10
  11 log_user 0
  12 if { "$dryrun" == "True" } {
  13     set reset_msg "Test: No error"
  14 } else {
  15     set reset_msg "Reset: No error"
  16 }
  17
  18
  19 if { "$method" == "ssh" } {
  20     #send_user "spawn ssh -o StrictHostKeyChecking=no -o PasswordAuthentication=yes -o PubkeyAuthentication=no $user@$host\n"
  21     set cont 0
  22     for { set retry 0 } { $retry < 2 } { incr retry 1 } {
  23
  24         # NOTE: For unknown reason, some DRAC modules work only with
  25         #       stderr redirected to stdout, others only work without it.
  26         if { $retry == 0 } {
  27             spawn ssh -o StrictHostKeyChecking=no -o PasswordAuthentication=yes -o PubkeyAuthentication=no $user@$host
  28         } else {
  29             spawn ssh -o StrictHostKeyChecking=no -o PasswordAuthentication=yes -o PubkeyAuthentication=no $user@$host 2>&1
  30         }
  31
  32         expect {
  33             "Are you sure you want to continue connecting (yes/no)? " { send "yes\n" ; exp_continue }
  34             "password: " { send "$password\n" ; exp_continue }
  35             "Permission denied" { send_user "DRAC ssh: username/password: $expect_out(0,string)"; exit }
  36             "Could not resolve hostname" { send_user "DRAC ssh: $expect_out(0,string)"; exit }
  37             "Connection timed out" { send_user "DRAC ssh: $expect_out(0,string)"; exit }
  38             -re "Received disconnect.*" { send_user "DRAC ssh: $expect_out(0,string)"; exit}
  39             -re "\\$|/.*>|.*$user.*#" { send "\r"; }
  40             timeout { send_user "DRAC ssh: timeout" ; exit; }
  41             eof { if { $cont == 1 } { send_user "DRAC ssh failed twice"; exit ; } ; set cont 1 }
  42         }
  43         if { $cont == 0 } { break; }
  44
  45     }
  46
  47     if { "$dryrun" == "True" } {
  48         expect {
  49             -re "\\$|/.*>" { send "racadm getsysinfo\r"; }
  50             -re ".*$user.*#" { send "getsysinfo\r" }
  51         }
  52     } else {
  53         expect {
  54             -re "\\$|/.*>" { send "racadm serveraction powercycle\r"; }
  55             -re ".*$user.*#" { send "serveraction powercycle\r" }
  56         }
  57     }
  58     expect -re "\\$|/.*>|.*$user.*#" { send "exit\r"; }
  59
  60     expect eof { send_user "$reset_msg\n" }
  61
  62 } else {
  63     if { [string match "*racadm*" $method] } {
  64         if { "$dryrun" == "True" } {
  65             set rac_cmd "getsysinfo"
  66         } else {
  67             set rac_cmd "serveraction powercycle"
  68         }
  69         #send_user "/opt/dell/srvadmin/bin/$method -r $host -u $user -p '$password' $rac_cmd\n";
  70         set cont 0
  71         for { set retry 0 } { $retry < 2 } { incr retry 1 } {
  72
  73             # NOTE: For unknown reason, placing the pasword
  74             #       on the cmdline causes racadm to fail.
  75             # NOTE: For unknown reason, some DRAC modules work only with
  76             #       stderr redirected to stdout, others only work without it.
  77             if { $retry == 0 } {
  78                 set x [ spawn /opt/dell/srvadmin/rac5/bin/$method -i -r $host $rac_cmd 2>&1 ]
  79             } else {
  80                 set x [ spawn /opt/dell/srvadmin/rac5/bin/$method -i -r $host $rac_cmd  ]
  81             }
  82
  83             expect {
  84                 -re "ERROR:.*" { send_user "DRAC: $expect_out(0,string)"; exit }
  85                 -re "UserName:|username:" { send "$user\r" ; exp_continue };
  86                 -re "Password:|password:" { send "$password\r" };
  87                 timeout { send_user "DRAC: timeout" ; exit }
  88                 eof { send_user "DRAC: early EOF"; exit ; }
  89             }
  90
  91             expect {
  92                 -re "Authentication failed.*" { send_user "DRAC: $expect_out(0,string)"; exit }
  93                 -re "This.*not support remote RACADM" { send_user "DRAC: $expect_out(0,string)" ; exit }
  94                 -re "ERROR: The syntax of the command specified is not correct." { set cont 1 }
  95                 -re "INVALID ARGUMENT" { send_user "DRAC: received 'INVALID ARGUMENT'"; exit }
  96                 -re "RAC Information:" { sleep .1; }
  97                 timeout { send_user "DRAC: timeout" ; exit }
  98                 eof { send_user "DRAC: early EOF"; exit ; }
  99                 #-re "ERROR:.*" { send_user "DRAC: $expect_out(0,string)"; exit }
 100             }
 101             if { $cont == 0 } { break; }
 102         }
 103         # If one of these are present, then the status information has been returned.
 104         # otherwise an expect error will be thrown, signaling the caller.
 105         expect {
 106             -re "Power Status.*" { sleep .1; }
 107             -re "RAC Firmware.*" { sleep .1; }
 108             eof { send_user "DRAC: early EOF"; exit ; }
 109         }
 110         expect eof { send_user "$reset_msg\n" }
 111     }
 112 }