m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (yes) coverage=true ;;
  26         (no)  coverage=false ;;
  27         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  28       esac],
  29      [coverage=false])
  30    if $coverage; then
  31      CFLAGS="$CFLAGS -O0 --coverage"
  32      LDFLAGS="$LDFLAGS --coverage"
  33    fi])
  34
  35 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  36 AC_DEFUN([OVS_CHECK_NDEBUG],
  37   [AC_ARG_ENABLE(
  38      [ndebug],
  39      [AC_HELP_STRING([--enable-ndebug],
  40                      [Disable debugging features for max performance])],
  41      [case "${enableval}" in
  42         (yes) ndebug=true ;;
  43         (no)  ndebug=false ;;
  44         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  45       esac],
  46      [ndebug=false])
  47    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  48
  49 dnl Checks for ESX.
  50 AC_DEFUN([OVS_CHECK_ESX],
  51   [AC_CHECK_HEADER([vmware.h],
  52                    [ESX=yes],
  53                    [ESX=no])
  54    AM_CONDITIONAL([ESX], [test "$ESX" = yes])
  55    if test "$ESX" = yes; then
  56       AC_DEFINE([ESX], [1], [Define to 1 if building on ESX.])
  57    fi])
  58
  59 dnl Checks for WINDOWS.
  60 AC_DEFUN([OVS_CHECK_WIN32],
  61   [AC_CHECK_HEADER([windows.h],
  62                    [WIN32=yes],
  63                    [WIN32=no])
  64    AM_CONDITIONAL([WIN32], [test "$WIN32" = yes])
  65    if test "$WIN32" = yes; then
  66       AC_DEFINE([WIN32], [1], [Define to 1 if building on WIN32.])
  67       AH_BOTTOM([#ifdef WIN32
  68 #include "include/windows/windefs.h"
  69 #endif])
  70    fi])
  71
  72 dnl Checks for Netlink support.
  73 AC_DEFUN([OVS_CHECK_NETLINK],
  74   [AC_CHECK_HEADER([linux/netlink.h],
  75                    [HAVE_NETLINK=yes],
  76                    [HAVE_NETLINK=no],
  77                    [#include <sys/socket.h>
  78    #include <linux/types.h>
  79    ])
  80    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  81    if test "$HAVE_NETLINK" = yes; then
  82       AC_DEFINE([HAVE_NETLINK], [1],
  83                 [Define to 1 if Netlink protocol is available.])
  84    fi])
  85
  86 dnl Checks for OpenSSL.
  87 AC_DEFUN([OVS_CHECK_OPENSSL],
  88   [AC_ARG_ENABLE(
  89      [ssl],
  90      [AC_HELP_STRING([--disable-ssl], [Disable OpenSSL support])],
  91      [case "${enableval}" in
  92         (yes) ssl=true ;;
  93         (no)  ssl=false ;;
  94         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  95       esac],
  96      [ssl=check])
  97
  98    if test "$ssl" != false; then
  99        AX_CHECK_OPENSSL(
 100          [HAVE_OPENSSL=yes],
 101          [HAVE_OPENSSL=no
 102           if test "$ssl" = check; then
 103             AC_MSG_WARN([Cannot find openssl:
 104
 105 $SSL_PKG_ERRORS
 106
 107 OpenFlow connections over SSL will not be supported.
 108 (You may use --disable-ssl to suppress this warning.)])
 109           else
 110             AC_MSG_ERROR([Cannot find openssl (use --disable-ssl to configure without SSL support)])
 111           fi])
 112    else
 113        HAVE_OPENSSL=no
 114    fi
 115    AC_SUBST([HAVE_OPENSSL])
 116    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
 117    if test "$HAVE_OPENSSL" = yes; then
 118       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
 119    fi])
 120
 121 dnl Checks for libraries needed by lib/socket-util.c.
 122 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 123   [AC_CHECK_LIB([socket], [connect])
 124    AC_SEARCH_LIBS([gethostbyname], [resolv])])
 125
 126 dnl Checks for the directory in which to store the PKI.
 127 AC_DEFUN([OVS_CHECK_PKIDIR],
 128   [AC_ARG_WITH(
 129      [pkidir],
 130      AC_HELP_STRING([--with-pkidir=DIR],
 131                     [PKI hierarchy directory [[LOCALSTATEDIR/lib/openvswitch/pki]]]),
 132      [PKIDIR=$withval],
 133      [PKIDIR='${localstatedir}/lib/openvswitch/pki'])
 134    AC_SUBST([PKIDIR])])
 135
 136 dnl Checks for the directory in which to store pidfiles.
 137 AC_DEFUN([OVS_CHECK_RUNDIR],
 138   [AC_ARG_WITH(
 139      [rundir],
 140      AC_HELP_STRING([--with-rundir=DIR],
 141                     [directory used for pidfiles
 142                     [[LOCALSTATEDIR/run/openvswitch]]]),
 143      [RUNDIR=$withval],
 144      [RUNDIR='${localstatedir}/run/openvswitch'])
 145    AC_SUBST([RUNDIR])])
 146
 147 dnl Checks for the directory in which to store logs.
 148 AC_DEFUN([OVS_CHECK_LOGDIR],
 149   [AC_ARG_WITH(
 150      [logdir],
 151      AC_HELP_STRING([--with-logdir=DIR],
 152                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 153      [LOGDIR=$withval],
 154      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 155    AC_SUBST([LOGDIR])])
 156
 157 dnl Checks for the directory in which to store the Open vSwitch database.
 158 AC_DEFUN([OVS_CHECK_DBDIR],
 159   [AC_ARG_WITH(
 160      [dbdir],
 161      AC_HELP_STRING([--with-dbdir=DIR],
 162                     [directory used for conf.db [[SYSCONFDIR/PACKAGE]]]),
 163      [DBDIR=$withval],
 164      [DBDIR='${sysconfdir}/${PACKAGE}'])
 165    AC_SUBST([DBDIR])])
 166
 167 dnl Defines HAVE_BACKTRACE if backtrace() is found.
 168 AC_DEFUN([OVS_CHECK_BACKTRACE],
 169   [AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace],
 170                   [AC_DEFINE([HAVE_BACKTRACE], [1],
 171                              [Define to 1 if you have backtrace(3).])])])
 172
 173 dnl Checks for __malloc_hook, etc., supported by glibc.
 174 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 175   [AC_CACHE_CHECK(
 176     [whether libc supports hooks for malloc and related functions],
 177     [ovs_cv_malloc_hooks],
 178     [AC_COMPILE_IFELSE(
 179       [AC_LANG_PROGRAM(
 180          [#include <malloc.h>
 181          ],
 182          [(void) __malloc_hook;
 183           (void) __realloc_hook;
 184           (void) __free_hook;])],
 185       [ovs_cv_malloc_hooks=yes],
 186       [ovs_cv_malloc_hooks=no])])
 187    if test $ovs_cv_malloc_hooks = yes; then
 188      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 189                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 190                 __free_hook in <malloc.h>.])
 191    fi])
 192
 193 dnl Checks for valgrind/valgrind.h.
 194 AC_DEFUN([OVS_CHECK_VALGRIND],
 195   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 196
 197 dnl Checks for Python 2.x, x >= 4.
 198 AC_DEFUN([OVS_CHECK_PYTHON],
 199   [AC_CACHE_CHECK(
 200      [for Python 2.x for x >= 4],
 201      [ovs_cv_python],
 202      [if test -n "$PYTHON"; then
 203         ovs_cv_python=$PYTHON
 204       else
 205         ovs_cv_python=no
 206         for binary in python python2.4 python2.5; do
 207           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 208           for dir in $PATH; do
 209             IFS=$ovs_save_IFS
 210             test -z "$dir" && dir=.
 211             if test -x "$dir"/"$binary" && "$dir"/"$binary" -c 'import sys
 212 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 213     sys.exit(0)
 214 else:
 215     sys.exit(1)'; then
 216               ovs_cv_python=$dir/$binary
 217               break 2
 218             fi
 219           done
 220         done
 221       fi])
 222    AC_SUBST([HAVE_PYTHON])
 223    AM_MISSING_PROG([PYTHON], [python])
 224    if test $ovs_cv_python != no; then
 225      PYTHON=$ovs_cv_python
 226      HAVE_PYTHON=yes
 227    else
 228      HAVE_PYTHON=no
 229    fi
 230    AM_CONDITIONAL([HAVE_PYTHON], [test "$HAVE_PYTHON" = yes])])
 231
 232 dnl Checks for dot.
 233 AC_DEFUN([OVS_CHECK_DOT],
 234   [AC_CACHE_CHECK(
 235     [for dot],
 236     [ovs_cv_dot],
 237     [dnl "dot" writes -V output to stderr:
 238      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 239        ovs_cv_dot=yes
 240      else
 241        ovs_cv_dot=no
 242      fi])
 243    AM_CONDITIONAL([HAVE_DOT], [test "$ovs_cv_dot" = yes])])
 244
 245 dnl Checks for pyuic4.
 246 AC_DEFUN([OVS_CHECK_PYUIC4],
 247   [AC_CACHE_CHECK(
 248     [for pyuic4],
 249     [ovs_cv_pyuic4],
 250     [if (pyuic4 --version) >/dev/null 2>&1; then
 251        ovs_cv_pyuic4=pyuic4
 252      else
 253        ovs_cv_pyuic4=no
 254      fi])
 255    AM_MISSING_PROG([PYUIC4], [pyuic4])
 256    if test $ovs_cv_pyuic4 != no; then
 257      PYUIC4=$ovs_cv_pyuic4
 258    fi])
 259
 260 dnl Checks whether $PYTHON supports the module given as $1
 261 AC_DEFUN([OVS_CHECK_PYTHON_MODULE],
 262   [AC_REQUIRE([OVS_CHECK_PYTHON])
 263    AC_CACHE_CHECK(
 264      [for $1 Python module],
 265      [ovs_cv_py_[]AS_TR_SH([$1])],
 266      [ovs_cv_py_[]AS_TR_SH([$1])=no
 267       if test $HAVE_PYTHON = yes; then
 268         AS_ECHO(["running $PYTHON -c 'import $1
 269 import sys
 270 sys.exit(0)'..."]) >&AS_MESSAGE_LOG_FD 2>&1
 271         if $PYTHON -c 'import $1
 272 import sys
 273 sys.exit(0)' >&AS_MESSAGE_LOG_FD 2>&1; then
 274           ovs_cv_py_[]AS_TR_SH([$1])=yes
 275         fi
 276       fi])])
 277
 278 dnl Checks for Python modules needed by ovsdbmonitor.
 279 AC_DEFUN([OVS_CHECK_OVSDBMONITOR],
 280   [OVS_CHECK_PYTHON_MODULE([PySide.QtCore])
 281    OVS_CHECK_PYTHON_MODULE([PyQt4.QtCore])
 282    OVS_CHECK_PYTHON_MODULE([twisted.conch.ssh])
 283    OVS_CHECK_PYTHON_MODULE([twisted.internet])
 284    OVS_CHECK_PYTHON_MODULE([twisted.application])
 285    OVS_CHECK_PYTHON_MODULE([json])
 286    OVS_CHECK_PYTHON_MODULE([zope.interface])
 287    if (test $ovs_cv_py_PySide_QtCore = yes \
 288        || test $ovs_cv_py_PyQt4_QtCore = yes) \
 289       && test $ovs_cv_py_twisted_conch_ssh = yes \
 290       && test $ovs_cv_py_twisted_internet = yes \
 291       && test $ovs_cv_py_twisted_application = yes \
 292       && test $ovs_cv_py_json = yes \
 293       && test $ovs_cv_py_zope_interface = yes; then
 294      BUILD_OVSDBMONITOR=yes
 295    else
 296      BUILD_OVSDBMONITOR=no
 297    fi
 298    AC_MSG_CHECKING([whether to build ovsdbmonitor])
 299    AC_MSG_RESULT([$BUILD_OVSDBMONITOR])
 300    AM_CONDITIONAL([BUILD_OVSDBMONITOR], [test $BUILD_OVSDBMONITOR = yes])])
 301
 302 dnl Checks for missing python modules at build time
 303 AC_DEFUN([OVS_CHECK_PYTHON_COMPAT],
 304   [OVS_CHECK_PYTHON_MODULE([uuid])
 305    if test $ovs_cv_py_uuid = yes; then
 306      INCLUDE_PYTHON_COMPAT=no
 307    else
 308      INCLUDE_PYTHON_COMPAT=yes
 309    fi
 310    AC_MSG_CHECKING([whether to add python/compat to PYTHONPATH])
 311    AC_MSG_RESULT([$INCLUDE_PYTHON_COMPAT])
 312    AM_CONDITIONAL([INCLUDE_PYTHON_COMPAT], [test $INCLUDE_PYTHON_COMPAT = yes])])
 313
 314 dnl Checks for groff.
 315 AC_DEFUN([OVS_CHECK_GROFF],
 316   [AC_CACHE_CHECK(
 317     [for groff],
 318     [ovs_cv_groff],
 319     [if (groff -v) >/dev/null 2>&1; then
 320        ovs_cv_groff=yes
 321      else
 322        ovs_cv_groff=no
 323      fi])
 324    AM_CONDITIONAL([HAVE_GROFF], [test "$ovs_cv_groff" = yes])])
 325
 326 dnl Checks for thread-local storage support.
 327 dnl
 328 dnl Checks whether the compiler and linker support the C11
 329 dnl thread_local macro from <threads.h>, and if so defines
 330 dnl HAVE_THREAD_LOCAL.  If not, checks whether the compiler and linker
 331 dnl support the GCC __thread extension, and if so defines
 332 dnl HAVE___THREAD.
 333 AC_DEFUN([OVS_CHECK_TLS],
 334   [AC_CACHE_CHECK(
 335      [whether $CC has <threads.h> that supports thread_local],
 336      [ovs_cv_thread_local],
 337      [AC_LINK_IFELSE(
 338         [AC_LANG_PROGRAM([#include <threads.h>
 339 static thread_local int var;], [return var;])],
 340         [ovs_cv_thread_local=yes],
 341         [ovs_cv_thread_local=no])])
 342    if test $ovs_cv_thread_local = yes; then
 343      AC_DEFINE([HAVE_THREAD_LOCAL], [1],
 344                [Define to 1 if the C compiler and linker supports the C11
 345                 thread_local matcro defined in <threads.h>.])
 346    else
 347      AC_CACHE_CHECK(
 348        [whether $CC supports __thread],
 349        [ovs_cv___thread],
 350        [AC_LINK_IFELSE(
 351           [AC_LANG_PROGRAM([static __thread int var;], [return var;])],
 352           [ovs_cv___thread=yes],
 353           [ovs_cv___thread=no])])
 354      if test $ovs_cv___thread = yes; then
 355        AC_DEFINE([HAVE___THREAD], [1],
 356                  [Define to 1 if the C compiler and linker supports the
 357                   GCC __thread extenions.])
 358      fi
 359    fi])
 360
 361 dnl OVS_CHECK_ATOMIC_LIBS
 362 dnl
 363 dnl Check to see if -latomic is need for GCC atomic built-ins.
 364 AC_DEFUN([OVS_CHECK_ATOMIC_LIBS],
 365    [AC_SEARCH_LIBS([__atomic_load_8], [atomic])])
 366
 367 dnl OVS_CHECK_GCC4_ATOMICS
 368 dnl
 369 dnl Checks whether the compiler and linker support GCC 4.0+ atomic built-ins.
 370 dnl A compile-time only check is not enough because the compiler defers
 371 dnl unimplemented built-ins to libgcc, which sometimes also lacks
 372 dnl implementations.
 373 AC_DEFUN([OVS_CHECK_GCC4_ATOMICS],
 374   [AC_CACHE_CHECK(
 375      [whether $CC supports GCC 4.0+ atomic built-ins],
 376      [ovs_cv_gcc4_atomics],
 377      [AC_LINK_IFELSE(
 378         [AC_LANG_PROGRAM([[#include <stdlib.h>
 379
 380 #define ovs_assert(expr) if (!(expr)) abort();
 381 #define TEST_ATOMIC_TYPE(TYPE)                  \
 382     {                                           \
 383         TYPE x = 1;                             \
 384         TYPE orig;                              \
 385                                                 \
 386         __sync_synchronize();                   \
 387         ovs_assert(x == 1);                     \
 388                                                 \
 389         __sync_synchronize();                   \
 390         x = 3;                                  \
 391         __sync_synchronize();                   \
 392         ovs_assert(x == 3);                     \
 393                                                 \
 394         orig = __sync_fetch_and_add(&x, 1);     \
 395         ovs_assert(orig == 3);                  \
 396         __sync_synchronize();                   \
 397         ovs_assert(x == 4);                     \
 398                                                 \
 399         orig = __sync_fetch_and_sub(&x, 2);     \
 400         ovs_assert(orig == 4);                  \
 401         __sync_synchronize();                   \
 402         ovs_assert(x == 2);                     \
 403                                                 \
 404         orig = __sync_fetch_and_or(&x, 6);      \
 405         ovs_assert(orig == 2);                  \
 406         __sync_synchronize();                   \
 407         ovs_assert(x == 6);                     \
 408                                                 \
 409         orig = __sync_fetch_and_and(&x, 10);    \
 410         ovs_assert(orig == 6);                  \
 411         __sync_synchronize();                   \
 412         ovs_assert(x == 2);                     \
 413                                                 \
 414         orig = __sync_fetch_and_xor(&x, 10);    \
 415         ovs_assert(orig == 2);                  \
 416         __sync_synchronize();                   \
 417         ovs_assert(x == 8);                     \
 418     }]], [dnl
 419 TEST_ATOMIC_TYPE(char);
 420 TEST_ATOMIC_TYPE(unsigned char);
 421 TEST_ATOMIC_TYPE(signed char);
 422 TEST_ATOMIC_TYPE(short);
 423 TEST_ATOMIC_TYPE(unsigned short);
 424 TEST_ATOMIC_TYPE(int);
 425 TEST_ATOMIC_TYPE(unsigned int);
 426 TEST_ATOMIC_TYPE(long int);
 427 TEST_ATOMIC_TYPE(unsigned long int);
 428 TEST_ATOMIC_TYPE(long long int);
 429 TEST_ATOMIC_TYPE(unsigned long long int);
 430 ])],
 431         [ovs_cv_gcc4_atomics=yes],
 432         [ovs_cv_gcc4_atomics=no])])
 433    if test $ovs_cv_gcc4_atomics = yes; then
 434      AC_DEFINE([HAVE_GCC4_ATOMICS], [1],
 435                [Define to 1 if the C compiler and linker supports the GCC 4.0+
 436                 atomic built-ins.])
 437    fi])
 438
 439 dnl OVS_CHECK_ATOMIC_ALWAYS_LOCK_FREE(SIZE)
 440 dnl
 441 dnl Checks __atomic_always_lock_free(SIZE, 0)
 442 AC_DEFUN([OVS_CHECK_ATOMIC_ALWAYS_LOCK_FREE],
 443   [AC_CACHE_CHECK(
 444     [value of __atomic_always_lock_free($1)],
 445     [ovs_cv_atomic_always_lock_free_$1],
 446     [AC_COMPUTE_INT(
 447         [ovs_cv_atomic_always_lock_free_$1],
 448         [__atomic_always_lock_free($1, 0)],
 449         [],
 450         [ovs_cv_atomic_always_lock_free_$1=unsupported])])
 451    if test ovs_cv_atomic_always_lock_free_$1 != unsupported; then
 452      AC_DEFINE_UNQUOTED(
 453        [ATOMIC_ALWAYS_LOCK_FREE_$1B],
 454        [$ovs_cv_atomic_always_lock_free_$1],
 455        [If the C compiler is GCC 4.7 or later, define to the return value of
 456         __atomic_always_lock_free($1, 0).  If the C compiler is not GCC or is
 457         an older version of GCC, the value does not matter.])
 458    fi])
 459
 460 dnl OVS_CHECK_POSIX_AIO
 461 AC_DEFUN([OVS_CHECK_POSIX_AIO],
 462   [AC_SEARCH_LIBS([aio_write], [rt])
 463    AM_CONDITIONAL([HAVE_POSIX_AIO], [test "$ac_cv_search_aio_write" != no])])
 464
 465 dnl OVS_CHECK_INCLUDE_NEXT
 466 AC_DEFUN([OVS_CHECK_INCLUDE_NEXT],
 467   [AC_REQUIRE([gl_CHECK_NEXT_HEADERS])
 468    gl_CHECK_NEXT_HEADERS([$1])])