configure.ac

   1 dnl $Id: configure.ac 2604 2007-09-02 20:03:17Z dhozac $
   2
   3 dnl Copyright (C) 2003,2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18 dnl
  19 dnl
  20 dnl As a special exception to the GNU General Public License, if you
  21 dnl distribute this file as part of a program that contains a configuration
  22 dnl script generated by Autoconf, you may include it under the same
  23 dnl distribution terms that you use for the rest of that program.
  24 dnl
  25
  26 AC_PREREQ(2.57)
  27 AC_INIT(util-vserver, 0.30.214, vserver@list.linux-vserver.org)
  28 AC_CONFIG_SRCDIR([src/capchroot.c])
  29 AC_CONFIG_HEADER([config.h])
  30
  31 AM_INIT_AUTOMAKE([1.9 gnits dist-bzip2 subdir-objects])
  32 AM_MAINTAINER_MODE
  33
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36
  37 AC_SUBST(GPG_KEY, "0xFFD316AC53ACA43A!")
  38
  39 # Checks for programs.
  40 AC_PROG_CXX
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 AC_PROG_LN_S
  44 AM_PROG_CC_C_O
  45 ENSC_CXXCOMPILER
  46 ENSC_C99COMPILER
  47
  48 ENSC_SET_SEARCHPATH([$PATH:/sbin:/usr/sbin:/usr/local/sbin])
  49 ENSC_PATHPROG_STANDARD_TOOLS
  50
  51 ENSC_PATHPROG(IP,        ip,,      [Usually, this tool is shipped in the 'iproute' or 'iproute2' package of your distribution])
  52 ENSC_PATHPROG(IPTABLES,  iptables)
  53 ENSC_PATHPROG(MODPROBE,  modprobe)
  54 ENSC_PATHPROG(NAMEIF,    nameif)
  55 ENSC_PATHPROG(NOHUP,     nohup)
  56 ENSC_PATHPROG(RMMOD,     rmmod)
  57 ENSC_PATHPROG(VCONFIG,   vconfig,, [See http://www.candelatech.com/~greear/vlan.html; usually this tool is shipped in the 'vconfig' or 'vlan' package of your distribution])
  58 ENSC_PATHPROG(WGET,      wget)
  59 ENSC_PATHPROG(FILE,      file,    [file])
  60 ENSC_PATHPROG(GZIP,      gzip,    [gzip])
  61 ENSC_PATHPROG(BZIP2,     bzip2,   [bzip2])
  62 ENSC_PATHPROG(CPIO,      cpio,    [cpio])
  63 ENSC_PATHPROG(RESTORE,   restore, [restore])
  64 ENSC_PATHPROG(RSYNC,     rsync,   [rsync])
  65 ENSC_PATHPROG(STRACE,    strace,  [strace])
  66
  67 ENSC_PATHPROG(DOXYGEN,   doxygen,  [:])
  68 ENSC_PATHPROG(XSLTP,     xsltp,    [:])
  69 ENSC_PATHPROG(XSLTPROC,  xsltproc, [:])
  70
  71
  72 AM_CONDITIONAL(HAVE_XSLTP,    test "$XSLTP"    != ':')
  73 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != ':')
  74
  75 if test x"$prefix" = x/; then
  76         prefix=
  77 fi
  78
  79 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
  80 ENSC_CHECK_CXX_FLAG([-ansi   -Wall -pedantic -W -fmessage-length=0])
  81
  82 AC_MSG_CHECKING([whether to enable extra optimizations])
  83 AC_ARG_ENABLE([extra-optimizations],
  84               [AC_HELP_STRING([--disable-extra-optimizations],
  85                               [disable certain extra optimizations (default: no)])],
  86               [case "$enableval" in
  87                   (yes) use_extra_optimizations=1;;
  88                   (no)  use_extra_optimizations=;;
  89                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--disable-extra-optimizations']);;
  90                esac],
  91               [use_extra_optimizations=1])
  92
  93 if test x"$use_extra_optimizations" = x; then
  94         AC_MSG_RESULT(no)
  95 else
  96         AC_MSG_RESULT(yes)
  97         ENSC_CHECK_CC_FLAG([-funit-at-a-time])
  98         ENSC_CHECK_CXX_FLAG([-funit-at-a-time])
  99 fi
 100
 101 AC_MSG_CHECKING([whether to enable debug-code in library])
 102 AC_ARG_ENABLE([lib-debug],
 103               [AC_HELP_STRING([--enable-lib-debug],
 104                               [enable additional debug code in library (default: no)])],
 105               [case "$enableval" in
 106                   (yes) use_lib_debug=1;;
 107                   (no)  use_lib_debug=;;
 108                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
 109                esac],
 110               [ use_lib_debug= ])
 111
 112 if test x"$use_lib_debug" = x; then
 113         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
 114         AC_MSG_RESULT(no)
 115 else
 116         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
 117         AC_MSG_RESULT(yes)
 118 fi
 119
 120 AC_MSG_CHECKING([whether to enable expensive tests])
 121 AC_ARG_ENABLE([expensive-tests],
 122               [AC_HELP_STRING([--enable-expensive-tests],
 123                               [disable tests which might be expensive on some systems (default: no)])],
 124               [case "$enableval" in
 125                  (yes|no)  use_expensive_tests=$enableval;;
 126                  (*)       AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-expensive-tests']);;
 127                esac],
 128               [ use_expensive_tests=no ])
 129 AC_MSG_RESULT($use_expensive_tests)
 130
 131 AC_SUBST(ENSC_USE_EXPENSIVE_TESTS, "$use_expensive_tests")
 132
 133
 134 ENSC_CHECK_PERSONALITY_FLAGS
 135
 136 AC_ARG_VAR(CC, [The C compiler])
 137
 138 ENSC_INITRDDIR(initrddir)
 139 ENSC_RELEASE(RELEASE_CPPFLAGS)
 140
 141 # HACK: This needs to be before ENSC_DIETLIBC_NEED_COMPAT, or the alternative
 142 # syscalls will never be enabled for glibc.
 143 ENSC_SYSCALLNR(vserver,273,[lib/syscall-fallback.h])
 144 ENSC_SYSCALL
 145
 146 dnl ###########################
 147 dnl
 148 dnl {some dietlibc related tests
 149 dnl
 150
 151 case $host_cpu in
 152         (i*86|athlon)   min_diet_ver=0.25;;
 153         (ia64|hppa*)    min_diet_ver=0.29;;
 154         (sparc*)        min_diet_ver=0.30;;
 155         (x86_64)        min_diet_ver=0.27;;
 156         (*)             min_diet_ver=0.28;;
 157 esac
 158
 159 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC, [$min_diet_ver])
 160
 161 if test x"$ensc_have_dietlibc" = xno; then
 162         AC_MSG_WARN([***                                                         ***])
 163         AC_MSG_WARN([*** it is strongly recommended to link util-vserver against ***])
 164         AC_MSG_WARN([*** dietlibc;  glibc's NSS functions are very unreliable in ***])
 165         AC_MSG_WARN([*** chroot() environments,  so you have to  expect problems ***])
 166         AC_MSG_WARN([*** there.                                                  ***])
 167         AC_MSG_WARN([***                                                         ***])
 168         AM_CONDITIONAL(USE_DIETLIBC_COMPAT, false)
 169 else
 170         # HACK: libtool does not have cmdline options to build only
 171         # dynamic libraries; this can be done with the
 172         # '--disable-static' ./configure option only.  As our static
 173         # libraries will be build with dietlibc, we have to do set
 174         # this option which is evaluated by 'AC_PROG_LIBTOOL'
 175         # below.  Therefore, this macro must not be called earlier.
 176         enable_static=no
 177
 178         ENSC_DIETLIBC_NEED_COMPAT(USE_DIETLIBC_COMPAT)
 179 fi
 180
 181 AM_CONDITIONAL(ENSC_USE_DIETLIBC, test x"$ensc_have_dietlibc" = xyes)
 182 AM_CONDITIONAL(ENSC_USE_GLIBC,    true)
 183
 184 # HACK: see comments at 'enable_static' above
 185 AC_PROG_LIBTOOL
 186 dnl
 187 dnl dietlibc stuff ends here}
 188 dnl
 189 dnl ##########################
 190
 191
 192 ENSC_UV_VROOTDIR(vserverdir)
 193 ENSC_CHANGELOG
 194
 195
 196 dnl ##########################
 197 dnl
 198 dnl {Check whether to use external kernel headers
 199 dnl
 200 AC_MSG_CHECKING([whether to use internal kernel headers])
 201 AC_ARG_ENABLE([internal-headers],
 202               [AC_HELP_STRING([--disable-internal-headers],
 203                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
 204               [case "$enableval" in
 205                   (yes|no) ;;
 206                   (*)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
 207                esac],
 208               [enable_internal_headers=yes])
 209
 210 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
 211 AC_MSG_RESULT([$enable_internal_headers])
 212 dnl
 213 dnl the check regarding external kernel headers ends here}
 214 dnl
 215 dnl ##########################
 216
 217 dnl ##########################
 218 dnl
 219 dnl {Check for the APIs to be used
 220 dnl
 221 AH_TEMPLATE(VC_ENABLE_API_COMPAT,   [Enable support for compatibility syscall API])
 222 AH_TEMPLATE(VC_ENABLE_API_LEGACY,   [Enable support for old, /proc parsing API])
 223 AH_TEMPLATE(VC_ENABLE_API_V11,      [Enable support for API of vserver 1.1.x])
 224 AH_TEMPLATE(VC_ENABLE_API_FSCOMPAT, [Enable support for filesystem compatibility API])
 225 AH_TEMPLATE(VC_ENABLE_API_V13OBS,   [Enable support for some obsoleted API of vserver 1.3.x])
 226 AH_TEMPLATE(VC_ENABLE_API_V13,      [Enable support for API of vserver 1.3.x])
 227 AH_TEMPLATE(VC_ENABLE_API_NET,      [Enable support for network context API])
 228 AH_TEMPLATE(VC_ENABLE_API_V21,      [Enable support for API of vserver 2.1.x])
 229 AH_TEMPLATE(VC_ENABLE_API_V22,      [Enable support for API of vserver 2.2.x])
 230 AH_TEMPLATE(VC_ENABLE_API_V23,      [Enable support for API of vserver 2.3.x])
 231 AH_TEMPLATE(VC_ENABLE_API_NETV2,    [Enable support for new networking API])
 232 AH_TEMPLATE(VC_ENABLE_API_OLDPROC,  [Enable API for a backward compatible /proc parsing])
 233 AH_TEMPLATE(VC_ENABLE_API_OLDUTS,   [Enable API for a backward compatible uts handling])
 234
 235 AC_MSG_CHECKING([for supported APIs])
 236 AC_ARG_ENABLE([apis],
 237               [AC_HELP_STRING([--enable-apis=APIS],
 238                               [enable support for the given apis; possible values are: legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2 ALL,NOLEGACY (default: v13,net,v21,v22,v23,netv2)])],
 239               [],
 240               [enable_apis=v13,net,v21,v22,v23,netv2])
 241
 242 test x"$enable_apis" != xALL      || enable_apis='legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2'
 243 test x"$enable_apis" != xNOLEGACY || enable_apis='compat,v11,fscompat,v13,net,v21,v22,v23,netv2'
 244 enable_api_oldproc=
 245 enable_api_olduts=
 246 old_IFS=$IFS
 247 IFS=,;
 248
 249 for i in $enable_apis; do
 250         case "$i" in
 251                 (compat)        AC_DEFINE(VC_ENABLE_API_COMPAT,   1)
 252                                 enable_api_oldproc=${enable_api_oldproc:-1}
 253                                 enable_api_olduts=${enable_api_olduts:-1}
 254                                 ;;
 255                 (legacy)        AC_DEFINE(VC_ENABLE_API_LEGACY,   1)
 256                                 enable_api_oldproc=${enable_api_oldproc:-1}
 257                                 enable_api_olduts=${enable_api_olduts:-1}
 258                                 ;;
 259                 (v11)           AC_DEFINE(VC_ENABLE_API_V11,      1)
 260                                 enable_api_oldproc=${enable_api_oldproc:-1}
 261                                 enable_api_olduts=${enable_api_olduts:-1}
 262                                 ;;
 263                 (fscompat)      AC_DEFINE(VC_ENABLE_API_FSCOMPAT, 1);;
 264                 (v13obs)        AC_DEFINE(VC_ENABLE_API_V13OBS,   1)
 265                                 AC_DEFINE(VC_ENABLE_API_V13,      1);;
 266                 (v13)           AC_DEFINE(VC_ENABLE_API_V13,      1);;
 267                 (net)           AC_DEFINE(VC_ENABLE_API_NET,      1);;
 268                 (v21)           AC_DEFINE(VC_ENABLE_API_V21,      1);;
 269                 (v22)           AC_DEFINE(VC_ENABLE_API_V22,      1);;
 270                 (v23)           AC_DEFINE(VC_ENABLE_API_V23,      1);;
 271                 (netv2)         AC_DEFINE(VC_ENABLE_API_NETV2,    1);;
 272                 (oldproc)       enable_api_oldproc=2;;
 273                 (olduts)        enable_api_olduts=2;;
 274                 (*)             AC_MSG_ERROR(['$i' is not a supported API]);;
 275         esac
 276 done
 277 IFS=$old_IFS
 278 if test x"$enable_api_oldproc" != x; then
 279         AC_DEFINE(VC_ENABLE_API_OLDPROC, 1)
 280         test x"$enable_api_oldproc" != x2 && enable_apis="$enable_apis,oldproc"
 281 fi
 282 if test x"$enable_api_olduts" != x; then
 283         AC_DEFINE(VC_ENABLE_API_OLDUTS, 1)
 284         test x"$enable_api_olduts" != x2 && enable_apis="$enable_apis,olduts"
 285 fi
 286 AC_MSG_RESULT([$enable_apis])
 287 dnl
 288 dnl the check for used APIs ends here}
 289 dnl
 290 dnl ##########################
 291
 292
 293 ENSC_CHECK_EXT2FS_HEADER
 294 AC_CHECK_FUNCS([vserver])
 295 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
 296 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
 297 AC_CHECK_TYPES(nid_t,,,[#include <sys/types.h>])
 298 AC_CHECK_TYPES(tag_t,,,[#include <sys/types.h>])
 299
 300 AC_CHECK_HEADERS([sys/capability.h])
 301
 302 dnl vlogin might need -lutil
 303 if test x"$ensc_have_dietlibc" = xno; then
 304         AC_CHECK_FUNC([openpty],, [AC_CHECK_LIB([util], [openpty],, [AC_MSG_ERROR([
 305 ****
 306 **** openpty could not be found
 307 ****])])])
 308 fi
 309
 310
 311 dnl ########################
 312 dnl
 313 dnl {check for beecrypt
 314 dnl
 315 if test x"$ensc_cv_c99_c99compiler" = xyes; then
 316         ensc_have_beecrypt=yes
 317
 318         if test x"$ensc_have_beecrypt" = xyes; then
 319                 AC_CHECK_HEADER([beecrypt/beecrypt.h], [ : ],
 320                                 [ ensc_have_beecrypt=no ])
 321         fi
 322
 323         if test x"$ensc_have_beecrypt" = xyes; then
 324                 AC_CHECK_LIB(beecrypt, hashFunctionContextInit, [ : ],
 325                              [ ensc_have_beecrypt=no ])
 326         fi
 327
 328         if test x"$ensc_have_beecrypt" != xyes; then
 329                 AC_MSG_WARN([
 330 ****
 331 **** 'beecrypt' could not be found;
 332 **** this will disable the build of 'vhashify'
 333 ****])
 334         fi
 335 else
 336         ensc_have_beecrypt=no
 337 fi
 338
 339 AM_CONDITIONAL(ENSC_HAVE_BEECRYPT, test x"$ensc_have_beecrypt" = xyes)
 340 AM_CONDITIONAL(ENSC_CAN_BEECRYPT_WITH_DIETLIBC, false)
 341 dnl
 342 dnl beecrypt stuff ends here}
 343 dnl
 344 dnl ########################
 345
 346
 347 dnl Check what distro this is, use Gentoo initscripts if appropriate
 348 AC_MSG_CHECKING([for host initscripts])
 349 AC_ARG_WITH(initscripts, AC_HELP_STRING([--with-initscripts=TYPE], [force host initscripts; valid values are 'gentoo' and 'sysv' (default: guess)]), [
 350         case "$withval" in
 351         gentoo) ensc_with_init=gentoo;;
 352         sysv)   ensc_with_init=sysv;;
 353         *)      AC_MSG_ERROR([invalid initscripts value, only gentoo and sysv are supported]);;
 354         esac
 355         ], [
 356         if test -e /etc/gentoo-release; then
 357                 ensc_with_init=gentoo
 358         else
 359                 ensc_with_init=sysv
 360         fi
 361         ])
 362 AC_MSG_RESULT([$ensc_with_init])
 363 AM_CONDITIONAL(HAVE_GENTOO_INIT, test x"$ensc_with_init" = xgentoo)
 364 AM_CONDITIONAL(HAVE_SYSV_INIT, test x"$ensc_with_init" = xsysv)
 365
 366
 367 dnl BIG HACK! Do some autodetection here!
 368 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
 369
 370 if false; then
 371         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
 372 fi
 373
 374 AC_DEFINE(_FILE_OFFSET_BITS, [64], [Use 64bit interface for filesystem operations])
 375
 376 dnl ########################
 377 dnl
 378 dnl {The final info-page
 379 dnl
 380 ensc_cxx_affected=" (affected: vbuild, vcheck)"
 381 ensc_c99_affected=" (affected: vunify, vcopy, vhashify, vdlimit)"
 382 ensc_diet_msg=" (you have been warned)"
 383 ensc_diet_version_msg=" ($ensc_version_dietlibc)"
 384 ensc_diet_compat_msg=" (using -lcompat)"
 385 test x"$ensc_cv_cxx_cxxcompiler"    = xno || ensc_cxx_affected=
 386 test x"$ensc_cv_c99_c99compiler"    = xno || ensc_c99_affected=
 387 test x"$ensc_have_dietlibc"         = xno || ensc_diet_msg=
 388 test x"$ensc_version_dietlibc"     != x   || ensc_diet_version_msg=
 389 test x"$ensc_have_dietlibc$ensc_cv_c_dietlibc_compat" = xyesyes || ensc_diet_compat_msg=
 390
 391 AH_BOTTOM([#include "compat.h"
 392 ])
 393 AC_CONFIG_COMMANDS_PRE([
 394                         FEATURES_TXT="\
 395 Features:
 396                        CC: $CC, $($CC   --version | sed -e '1p;d')
 397                       CXX: $CXX, $($CXX --version | sed -e '1p;d')
 398                  CPPFLAGS: '$CPPFLAGS'
 399                    CFLAGS: '$CFLAGS'
 400                  CXXFLAGS: '$CXXFLAGS'
 401                build/host: $build/$host
 402              Use dietlibc: $ensc_have_dietlibc$ensc_diet_version_msg$ensc_diet_msg$ensc_diet_compat_msg
 403        Build C++ programs: $ensc_cv_cxx_cxxcompiler$ensc_cxx_affected
 404        Build C99 programs: $ensc_cv_c99_c99compiler$ensc_c99_affected
 405            Available APIs: $enable_apis
 406             ext2fs Source: $ensc_cv_test_ext2fs_header
 407     syscall(2) invocation: $with_syscall
 408       vserver(2) syscall#: $ensc_cv_value_syscall_vserver
 409
 410 Paths:
 411                    prefix: $prefix
 412         sysconf-Directory: $sysconfdir
 413             cfg-Directory: $sysconfdir/vservers
 414          initrd-Directory: $initrddir
 415        pkgstate-Directory: $localstatedir/run/vservers
 416           vserver-Rootdir: $vserverdir
 417 "
 418                         echo "$FEATURES_TXT" >FEATURES.txt
 419                         ])
 420 dnl
 421 dnl final info-page ends here}
 422 dnl
 423 dnl ########################
 424
 425 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile lib/apidoc/Doxyfile])
 426 AC_OUTPUT
 427
 428 AC_MSG_NOTICE([
 429
 430 $PACKAGE_STRING
 431
 432 $FEATURES_TXT])