m4/ensc_syscall.m4

   1 dnl $Id: ensc_syscall.m4,v 1.2.2.2 2004/03/04 03:12:34 ensc Exp $
   2
   3 dnl Copyright (C) 2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; version 2 of the License.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17
  18 dnl Usage: ENSC_SYSCALL
  19
  20 AC_DEFUN([ENSC_SYSCALL],
  21 [
  22         AC_REQUIRE([ENSC_KERNEL_HEADERS])
  23         AC_MSG_CHECKING([for syscall(2) invocation method])
  24         AC_ARG_WITH([syscall],
  25                     [AC_HELP_STRING([--with-syscall=METHOD],
  26                                     [call syscall(2) with the specified METHOD; valid values are 'fast', 'traditional' and 'auto' (default: auto)])],
  27                     [],
  28                     [with_syscall=auto])
  29         AC_MSG_RESULT([$with_syscall])
  30
  31         case x"$with_syscall" in
  32             xauto)
  33                 AC_CACHE_CHECK([which syscall(2) invocation works], [ensc_cv_test_syscall],
  34                                [
  35                                 AC_LANG_PUSH(C)
  36                                 AC_COMPILE_IFELSE([
  37 #include <asm/unistd.h>
  38 #include <syscall.h>
  39 #include <errno.h>
  40 #define __NR_foo0       300
  41 #define __NR_foo1       301
  42 #define __NR_foo2       302
  43 #define __NR_foo3       303
  44 #define __NR_foo4       304
  45 #define __NR_foo5       305
  46 inline static _syscall0(int, foo0)
  47 inline static _syscall1(int, foo1, int, a)
  48 inline static _syscall2(int, foo2, int, a, int, b)
  49 inline static _syscall3(int, foo3, int, a, int, b, int, c)
  50 inline static _syscall4(int, foo4, int, a, int, b, int, c, int, d)
  51 inline static _syscall5(int, foo5, int, a, int, b, int, c, int, d, int, e)
  52
  53 int main() {
  54   return foo0() || \
  55          foo1(1) || \
  56          foo2(1,2) || \
  57          foo3(1,2,3) || \
  58          foo4(1,2,3,4) || \
  59          foo5(1,2,3,4,5);
  60 }
  61                                 ],
  62                                 [ensc_cv_test_syscall=fast],
  63                                 [ensc_cv_test_syscall=traditional])
  64
  65                                 AC_LANG_POP
  66                 ])
  67                 with_syscall=$ensc_cv_test_syscall
  68                 ;;
  69             xfast|xtraditional)
  70                 ;;
  71             *)
  72                 AC_MSG_ERROR(['$with_syscall' is not a valid value for '--with-syscall'])
  73                 ;;
  74         esac
  75
  76         if test x"$with_syscall" = xtraditional; then
  77             AC_DEFINE(ENSC_SYSCALL_TRADITIONAL,  1, [Define to 1 when the fast syscall(2) invocation does not work])
  78         fi
  79
  80         AH_BOTTOM([
  81 #if defined(__pic__) && defined(__i386) && !defined(ENSC_SYSCALL_TRADITIONAL)
  82 #  define ENSC_SYSCALL_TRADITIONAL      1
  83 #endif])
  84 ])