arch/arm/boot/bootp/init.S

   1 /*
   2  *  linux/arch/arm/boot/bootp/init.S
   3  *
   4  *  Copyright (C) 2000-2003 Russell King.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  "Header" file for splitting kernel + initrd.  Note that we pass
  11  *  r0 through to r3 straight through.
  12  *
  13  *  This demonstrates how to append code to the start of the kernel
  14  *  zImage, and boot the kernel without copying it around.  This
  15  *  example would be simpler; if we didn't have an object of unknown
  16  *  size immediately following the kernel, we could build this into
  17  *  a binary blob, and concatenate the zImage using the cat command.
  18  */
  19                 .section .start,#alloc,#execinstr
  20                 .type   _start, #function
  21                 .globl  _start
  22
  23 _start:         adr     r13, data
  24                 ldmia   r13!, {r4-r6}           @ r5 = dest, r6 = length
  25                 bl      move                    @ move the initrd
  26
  27 /*
  28  * Setup the initrd parameters to pass to the kernel.  This can only be
  29  * passed in via the tagged list.
  30  */
  31                 ldmia   r13, {r5-r9}            @ get size and addr of initrd
  32                                                 @ r5 = ATAG_CORE
  33                                                 @ r6 = ATAG_INITRD2
  34                                                 @ r7 = initrd start
  35                                                 @ r8 = initrd end
  36                                                 @ r9 = param_struct address
  37
  38                 ldr     r10, [r9, #4]           @ get first tag
  39                 teq     r10, r5                 @ is it ATAG_CORE?
  40 /*
  41  * If we didn't find a valid tag list, create a dummy ATAG_CORE entry.
  42  */
  43                 movne   r10, #0                 @ terminator
  44                 movne   r4, #2                  @ Size of this entry (2 words)
  45                 stmneia r9, {r4, r5, r10}       @ Size, ATAG_CORE, terminator
  46
  47 /*
  48  * find the end of the tag list, and then add an INITRD tag on the end.
  49  * If there is already an INITRD tag, then we ignore it; the last INITRD
  50  * tag takes precidence.
  51  */
  52 taglist:        ldr     r10, [r9, #0]           @ tag length
  53                 teq     r10, #0                 @ last tag (zero length)?
  54                 addne   r9, r9, r10, lsl #2
  55                 bne     taglist
  56
  57                 mov     r5, #4                  @ Size of initrd tag (4 words)
  58                 stmia   r9, {r5, r6, r7, r8, r10}
  59                 b       kernel_start            @ call kernel
  60
  61 /*
  62  * Move the block of memory length r6 from address r4 to address r5
  63  */
  64 move:           ldmia   r4!, {r7 - r10}         @ move 32-bytes at a time
  65                 stmia   r5!, {r7 - r10}
  66                 ldmia   r4!, {r7 - r10}
  67                 stmia   r5!, {r7 - r10}
  68                 subs    r6, r6, #8 * 4
  69                 bcs     move
  70                 mov     pc, lr
  71
  72                 .size   _start, . - _start
  73
  74                 .type   data,#object
  75 data:           .word   initrd_start            @ source initrd address
  76                 .word   initrd_phys             @ destination initrd address
  77                 .word   initrd_size             @ initrd size
  78
  79                 .word   0x54410001              @ r5 = ATAG_CORE
  80                 .word   0x54420005              @ r6 = ATAG_INITRD2
  81                 .word   initrd_phys             @ r7
  82                 .word   initrd_size             @ r8
  83                 .word   params_phys             @ r9
  84                 .size   data, . - data