arch/arm/kernel/head.S

   1 /*
   2  *  linux/arch/arm/kernel/head.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Kernel startup code for all 32-bit CPUs
  11  */
  12 #include <linux/config.h>
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15
  16 #include <asm/assembler.h>
  17 #include <asm/domain.h>
  18 #include <asm/mach-types.h>
  19 #include <asm/procinfo.h>
  20 #include <asm/ptrace.h>
  21 #include <asm/constants.h>
  22 #include <asm/system.h>
  23
  24 #define PROCINFO_MMUFLAGS       8
  25 #define PROCINFO_INITFUNC       12
  26
  27 #define MACHINFO_PHYSRAM        4
  28 #define MACHINFO_PHYSIO         8
  29 #define MACHINFO_PGOFFIO        12
  30
  31 #ifndef CONFIG_XIP_KERNEL
  32 /*
  33  * We place the page tables 16K below TEXTADDR.  Therefore, we must make sure
  34  * that TEXTADDR is correctly set.  Currently, we expect the least significant
  35  * 16 bits to be 0x8000, but we could probably relax this restriction to
  36  * TEXTADDR >= PAGE_OFFSET + 0x4000
  37  *
  38  * Note that swapper_pg_dir is the virtual address of the page tables, and
  39  * pgtbl gives us a position-independent reference to these tables.  We can
  40  * do this because stext == TEXTADDR
  41  */
  42 #if (TEXTADDR & 0xffff) != 0x8000
  43 #error TEXTADDR must start at 0xXXXX8000
  44 #endif
  45
  46         .globl  swapper_pg_dir
  47         .equ    swapper_pg_dir, TEXTADDR - 0x4000
  48
  49         .macro  pgtbl, rd, phys
  50         adr     \rd, stext
  51         sub     \rd, \rd, #0x4000
  52         .endm
  53 #else
  54 /*
  55  * XIP Kernel:
  56  *
  57  * We place the page tables 16K below DATAADDR.  Therefore, we must make sure
  58  * that DATAADDR is correctly set.  Currently, we expect the least significant
  59  * 16 bits to be 0x8000, but we could probably relax this restriction to
  60  * DATAADDR >= PAGE_OFFSET + 0x4000
  61  *
  62  * Note that pgtbl is meant to return the physical address of swapper_pg_dir.
  63  * We can't make it relative to the kernel position in this case since
  64  * the kernel can physically be anywhere.
  65  */
  66 #if (DATAADDR & 0xffff) != 0x8000
  67 #error DATAADDR must start at 0xXXXX8000
  68 #endif
  69
  70         .globl  swapper_pg_dir
  71         .equ    swapper_pg_dir, DATAADDR - 0x4000
  72
  73         .macro  pgtbl, rd, phys
  74         ldr     \rd, =((DATAADDR - 0x4000) - VIRT_OFFSET)
  75         add     \rd, \rd, \phys
  76         .endm
  77 #endif
  78
  79 /*
  80  * Kernel startup entry point.
  81  * ---------------------------
  82  *
  83  * This is normally called from the decompressor code.  The requirements
  84  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  85  * r1 = machine nr.
  86  *
  87  * This code is mostly position independent, so if you link the kernel at
  88  * 0xc0008000, you call this at __pa(0xc0008000).
  89  *
  90  * See linux/arch/arm/tools/mach-types for the complete list of machine
  91  * numbers for r1.
  92  *
  93  * We're trying to keep crap to a minimum; DO NOT add any machine specific
  94  * crap here - that's what the boot loader (or in extreme, well justified
  95  * circumstances, zImage) is for.
  96  */
  97         __INIT
  98         .type   stext, %function
  99 ENTRY(stext)
 100         msr     cpsr_c, #PSR_F_BIT | PSR_I_BIT | MODE_SVC @ ensure svc mode
 101                                                 @ and irqs disabled
 102         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
 103         movs    r10, r5                         @ invalid processor (r5=0)?
 104         moveq   r0, #'p'                        @ yes, error 'p'
 105         beq     __error
 106         bl      __lookup_machine_type           @ r5=machinfo
 107         movs    r8, r5                          @ invalid machine (r5=0)?
 108         moveq   r0, #'a'                        @ yes, error 'a'
 109         beq     __error
 110         bl      __create_page_tables
 111
 112         /*
 113          * The following calls CPU specific code in a position independent
 114          * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of
 115          * xxx_proc_info structure selected by __lookup_machine_type
 116          * above.  On return, the CPU will be ready for the MMU to be
 117          * turned on, and r0 will hold the CPU control register value.
 118          */
 119         ldr     r13, __switch_data              @ address to jump to after
 120                                                 @ mmu has been enabled
 121         adr     lr, __enable_mmu                @ return (PIC) address
 122         add     pc, r10, #PROCINFO_INITFUNC
 123
 124         .type   __switch_data, %object
 125 __switch_data:
 126         .long   __mmap_switched
 127         .long   __data_loc                      @ r4
 128         .long   __data_start                    @ r5
 129         .long   __bss_start                     @ r6
 130         .long   _end                            @ r7
 131         .long   processor_id                    @ r4
 132         .long   __machine_arch_type             @ r5
 133         .long   cr_alignment                    @ r6
 134         .long   init_thread_union+8192          @ sp
 135
 136 /*
 137  * The following fragment of code is executed with the MMU on, and uses
 138  * absolute addresses; this is not position independent.
 139  *
 140  *  r0  = cp#15 control register
 141  *  r1  = machine ID
 142  *  r9  = processor ID
 143  */
 144         .type   __mmap_switched, %function
 145 __mmap_switched:
 146         adr     r3, __switch_data + 4
 147
 148         ldmia   r3!, {r4, r5, r6, r7}
 149         cmp     r4, r5                          @ Copy data segment if needed
 150 1:      cmpne   r5, r6
 151         ldrne   fp, [r4], #4
 152         strne   fp, [r5], #4
 153         bne     1b
 154
 155         mov     fp, #0                          @ Clear BSS (and zero fp)
 156 1:      cmp     r6, r7
 157         strcc   fp, [r6],#4
 158         bcc     1b
 159
 160         ldmia   r3, {r4, r5, r6, sp}
 161         str     r9, [r4]                        @ Save processor ID
 162         str     r1, [r5]                        @ Save machine type
 163         bic     r4, r0, #CR_A                   @ Clear 'A' bit
 164         stmia   r6, {r0, r4}                    @ Save control register values
 165         b       start_kernel
 166
 167
 168
 169 /*
 170  * Setup common bits before finally enabling the MMU.  Essentially
 171  * this is just loading the page table pointer and domain access
 172  * registers.
 173  */
 174         .type   __enable_mmu, %function
 175 __enable_mmu:
 176 #ifdef CONFIG_ALIGNMENT_TRAP
 177         orr     r0, r0, #CR_A
 178 #else
 179         bic     r0, r0, #CR_A
 180 #endif
 181 #ifdef CONFIG_CPU_DCACHE_DISABLE
 182         bic     r0, r0, #CR_C
 183 #endif
 184 #ifdef CONFIG_CPU_BPREDICT_DISABLE
 185         bic     r0, r0, #CR_Z
 186 #endif
 187 #ifdef CONFIG_CPU_ICACHE_DISABLE
 188         bic     r0, r0, #CR_I
 189 #endif
 190         mov     r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
 191                       domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
 192                       domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
 193                       domain_val(DOMAIN_IO, DOMAIN_CLIENT))
 194         mcr     p15, 0, r5, c3, c0, 0           @ load domain access register
 195         mcr     p15, 0, r4, c2, c0, 0           @ load page table pointer
 196         b       __turn_mmu_on
 197
 198 /*
 199  * Enable the MMU.  This completely changes the structure of the visible
 200  * memory space.  You will not be able to trace execution through this.
 201  * If you have an enquiry about this, *please* check the linux-arm-kernel
 202  * mailing list archives BEFORE sending another post to the list.
 203  *
 204  *  r0  = cp#15 control register
 205  *  r13 = *virtual* address to jump to upon completion
 206  *
 207  * other registers depend on the function called upon completion
 208  */
 209         .align  5
 210         .type   __turn_mmu_on, %function
 211 __turn_mmu_on:
 212         mov     r0, r0
 213         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
 214         mrc     p15, 0, r3, c0, c0, 0           @ read id reg
 215         mov     r3, r3
 216         mov     r3, r3
 217         mov     pc, r13
 218
 219
 220
 221 /*
 222  * Setup the initial page tables.  We only setup the barest
 223  * amount which are required to get the kernel running, which
 224  * generally means mapping in the kernel code.
 225  *
 226  * r8  = machinfo
 227  * r9  = cpuid
 228  * r10 = procinfo
 229  *
 230  * Returns:
 231  *  r0, r3, r5, r6, r7 corrupted
 232  *  r4 = physical page table address
 233  */
 234         .type   __create_page_tables, %function
 235 __create_page_tables:
 236         ldr     r5, [r8, #MACHINFO_PHYSRAM]     @ physram
 237         pgtbl   r4, r5                          @ page table address
 238
 239         /*
 240          * Clear the 16K level 1 swapper page table
 241          */
 242         mov     r0, r4
 243         mov     r3, #0
 244         add     r6, r0, #0x4000
 245 1:      str     r3, [r0], #4
 246         str     r3, [r0], #4
 247         str     r3, [r0], #4
 248         str     r3, [r0], #4
 249         teq     r0, r6
 250         bne     1b
 251
 252         ldr     r7, [r10, #PROCINFO_MMUFLAGS]   @ mmuflags
 253
 254         /*
 255          * Create identity mapping for first MB of kernel to
 256          * cater for the MMU enable.  This identity mapping
 257          * will be removed by paging_init().  We use our current program
 258          * counter to determine corresponding section base address.
 259          */
 260         mov     r6, pc, lsr #20                 @ start of kernel section
 261         orr     r3, r7, r6, lsl #20             @ flags + kernel base
 262         str     r3, [r4, r6, lsl #2]            @ identity mapping
 263
 264         /*
 265          * Now setup the pagetables for our kernel direct
 266          * mapped region.  We round TEXTADDR down to the
 267          * nearest megabyte boundary.  It is assumed that
 268          * the kernel fits within 4 contigous 1MB sections.
 269          */
 270         add     r0, r4,  #(TEXTADDR & 0xff000000) >> 18 @ start of kernel
 271         str     r3, [r0, #(TEXTADDR & 0x00f00000) >> 18]!
 272         add     r3, r3, #1 << 20
 273         str     r3, [r0, #4]!                   @ KERNEL + 1MB
 274         add     r3, r3, #1 << 20
 275         str     r3, [r0, #4]!                   @ KERNEL + 2MB
 276         add     r3, r3, #1 << 20
 277         str     r3, [r0, #4]                    @ KERNEL + 3MB
 278
 279         /*
 280          * Then map first 1MB of ram in case it contains our boot params.
 281          */
 282         add     r0, r4, #VIRT_OFFSET >> 18
 283         orr     r6, r5, r7
 284         str     r6, [r0]
 285
 286 #ifdef CONFIG_XIP_KERNEL
 287         /*
 288          * Map some ram to cover our .data and .bss areas.
 289          * Mapping 3MB should be plenty.
 290          */
 291         sub     r3, r4, r5
 292         mov     r3, r3, lsr #20
 293         add     r0, r0, r3, lsl #2
 294         add     r6, r6, r3, lsl #20
 295         str     r6, [r0], #4
 296         add     r6, r6, #(1 << 20)
 297         str     r6, [r0], #4
 298         add     r6, r6, #(1 << 20)
 299         str     r6, [r0]
 300 #endif
 301
 302         bic     r7, r7, #0x0c                   @ turn off cacheable
 303                                                 @ and bufferable bits
 304 #ifdef CONFIG_DEBUG_LL
 305         /*
 306          * Map in IO space for serial debugging.
 307          * This allows debug messages to be output
 308          * via a serial console before paging_init.
 309          */
 310         ldr     r3, [r8, #MACHINFO_PGOFFIO]
 311         add     r0, r4, r3
 312         rsb     r3, r3, #0x4000                 @ PTRS_PER_PGD*sizeof(long)
 313         cmp     r3, #0x0800                     @ limit to 512MB
 314         movhi   r3, #0x0800
 315         add     r6, r0, r3
 316         ldr     r3, [r8, #MACHINFO_PHYSIO]
 317         orr     r3, r3, r7
 318 1:      str     r3, [r0], #4
 319         add     r3, r3, #1 << 20
 320         teq     r0, r6
 321         bne     1b
 322 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
 323         /*
 324          * If we're using the NetWinder, we need to map in
 325          * the 16550-type serial port for the debug messages
 326          */
 327         teq     r1, #MACH_TYPE_NETWINDER
 328         teqne   r1, #MACH_TYPE_CATS
 329         bne     1f
 330         add     r0, r4, #0x3fc0                 @ ff000000
 331         mov     r3, #0x7c000000
 332         orr     r3, r3, r7
 333         str     r3, [r0], #4
 334         add     r3, r3, #1 << 20
 335         str     r3, [r0], #4
 336 1:
 337 #endif
 338 #endif
 339 #ifdef CONFIG_ARCH_RPC
 340         /*
 341          * Map in screen at 0x02000000 & SCREEN2_BASE
 342          * Similar reasons here - for debug.  This is
 343          * only for Acorn RiscPC architectures.
 344          */
 345         add     r0, r4, #0x80                   @ 02000000
 346         mov     r3, #0x02000000
 347         orr     r3, r3, r7
 348         str     r3, [r0]
 349         add     r0, r4, #0x3600                 @ d8000000
 350         str     r3, [r0]
 351 #endif
 352         mov     pc, lr
 353         .ltorg
 354
 355
 356
 357 /*
 358  * Exception handling.  Something went wrong and we can't proceed.  We
 359  * ought to tell the user, but since we don't have any guarantee that
 360  * we're even running on the right architecture, we do virtually nothing.
 361  *
 362  * r0 = ascii error character:
 363  *      a = invalid architecture
 364  *      p = invalid processor
 365  *      i = invalid calling convention
 366  *
 367  * Generally, only serious errors cause this.
 368  */
 369         .type   __error, %function
 370 __error:
 371 #ifdef CONFIG_DEBUG_LL
 372         mov     r8, r0                          @ preserve r0
 373         adr     r0, err_str
 374         bl      printascii
 375         mov     r0, r8
 376         bl      printch
 377 #endif
 378 #ifdef CONFIG_ARCH_RPC
 379 /*
 380  * Turn the screen red on a error - RiscPC only.
 381  */
 382         mov     r0, #0x02000000
 383         mov     r3, #0x11
 384         orr     r3, r3, r3, lsl #8
 385         orr     r3, r3, r3, lsl #16
 386         str     r3, [r0], #4
 387         str     r3, [r0], #4
 388         str     r3, [r0], #4
 389         str     r3, [r0], #4
 390 #endif
 391 1:      mov     r0, r0
 392         b       1b
 393
 394 #ifdef CONFIG_DEBUG_LL
 395         .type   err_str, %object
 396 err_str:
 397         .asciz  "\nError: "
 398         .align
 399 #endif
 400
 401 /*
 402  * Read processor ID register (CP#15, CR0), and look up in the linker-built
 403  * supported processor list.  Note that we can't use the absolute addresses
 404  * for the __proc_info lists since we aren't running with the MMU on
 405  * (and therefore, we are not in the correct address space).  We have to
 406  * calculate the offset.
 407  *
 408  * Returns:
 409  *      r3, r4, r6 corrupted
 410  *      r5 = proc_info pointer in physical address space
 411  *      r9 = cpuid
 412  */
 413         .type   __lookup_processor_type, %function
 414 __lookup_processor_type:
 415         adr     r3, 3f
 416         ldmda   r3, {r5, r6, r9}
 417         sub     r3, r3, r9                      @ get offset between virt&phys
 418         add     r5, r5, r3                      @ convert virt addresses to
 419         add     r6, r6, r3                      @ physical address space
 420         mrc     p15, 0, r9, c0, c0              @ get processor id
 421 1:      ldmia   r5, {r3, r4}                    @ value, mask
 422         and     r4, r4, r9                      @ mask wanted bits
 423         teq     r3, r4
 424         beq     2f
 425         add     r5, r5, #PROC_INFO_SZ           @ sizeof(proc_info_list)
 426         cmp     r5, r6
 427         blt     1b
 428         mov     r5, #0                          @ unknown processor
 429 2:      mov     pc, lr
 430
 431 /*
 432  * This provides a C-API version of the above function.
 433  */
 434 ENTRY(lookup_processor_type)
 435         stmfd   sp!, {r4 - r6, r9, lr}
 436         bl      __lookup_processor_type
 437         mov     r0, r5
 438         ldmfd   sp!, {r4 - r6, r9, pc}
 439
 440 /*
 441  * Look in include/asm-arm/procinfo.h and arch/arm/kernel/arch.[ch] for
 442  * more information about the __proc_info and __arch_info structures.
 443  */
 444         .long   __proc_info_begin
 445         .long   __proc_info_end
 446 3:      .long   .
 447         .long   __arch_info_begin
 448         .long   __arch_info_end
 449
 450 /*
 451  * Lookup machine architecture in the linker-build list of architectures.
 452  * Note that we can't use the absolute addresses for the __arch_info
 453  * lists since we aren't running with the MMU on (and therefore, we are
 454  * not in the correct address space).  We have to calculate the offset.
 455  *
 456  *  r1 = machine architecture number
 457  * Returns:
 458  *  r3, r4, r6 corrupted
 459  *  r5 = mach_info pointer in physical address space
 460  */
 461         .type   __lookup_machine_type, %function
 462 __lookup_machine_type:
 463         adr     r3, 3b
 464         ldmia   r3, {r4, r5, r6}
 465         sub     r3, r3, r4                      @ get offset between virt&phys
 466         add     r5, r5, r3                      @ convert virt addresses to
 467         add     r6, r6, r3                      @ physical address space
 468 1:      ldr     r3, [r5]                        @ get machine type
 469         teq     r3, r1                          @ matches loader number?
 470         beq     2f                              @ found
 471         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 472         cmp     r5, r6
 473         blt     1b
 474         mov     r5, #0                          @ unknown machine
 475 2:      mov     pc, lr
 476
 477 /*
 478  * This provides a C-API version of the above function.
 479  */
 480 ENTRY(lookup_machine_type)
 481         stmfd   sp!, {r4 - r6, lr}
 482         mov     r1, r0
 483         bl      __lookup_machine_type
 484         mov     r0, r5
 485         ldmfd   sp!, {r4 - r6, pc}