arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7
   8 OUTPUT_ARCH(arm)
   9 ENTRY(stext)
  10 #ifndef __ARMEB__
  11 jiffies = jiffies_64;
  12 #else
  13 jiffies = jiffies_64 + 4;
  14 #endif
  15 SECTIONS
  16 {
  17         . = TEXTADDR;
  18         .init : {                       /* Init code and data           */
  19                 _stext = .;
  20                 __init_begin = .;
  21                         _sinittext = .;
  22                         *(.init.text)
  23                         _einittext = .;
  24                 __proc_info_begin = .;
  25                         *(.proc.info)
  26                 __proc_info_end = .;
  27                 __arch_info_begin = .;
  28                         *(.arch.info)
  29                 __arch_info_end = .;
  30                 __tagtable_begin = .;
  31                         *(.taglist)
  32                 __tagtable_end = .;
  33                         *(.init.data)
  34                 . = ALIGN(16);
  35                 __setup_start = .;
  36                         *(.init.setup)
  37                 __setup_end = .;
  38                 __early_begin = .;
  39                         *(__early_param)
  40                 __early_end = .;
  41                 __initcall_start = .;
  42                         *(.initcall1.init)
  43                         *(.initcall2.init)
  44                         *(.initcall3.init)
  45                         *(.initcall4.init)
  46                         *(.initcall5.init)
  47                         *(.initcall6.init)
  48                         *(.initcall7.init)
  49                 __initcall_end = .;
  50                 __con_initcall_start = .;
  51                         *(.con_initcall.init)
  52                 __con_initcall_end = .;
  53                 __security_initcall_start = .;
  54                         *(.security_initcall.init)
  55                 __security_initcall_end = .;
  56                 . = ALIGN(32);
  57                 __initramfs_start = .;
  58                         usr/built-in.o(.init.ramfs)
  59                 __initramfs_end = .;
  60                 . = ALIGN(4096);
  61                 __init_end = .;
  62         }
  63
  64         /DISCARD/ : {                   /* Exit code and data           */
  65                 *(.exit.text)
  66                 *(.exit.data)
  67                 *(.exitcall.exit)
  68         }
  69
  70         .text : {                       /* Real text segment            */
  71                 _text = .;              /* Text and read-only data      */
  72                         *(.text)
  73                         SCHED_TEXT
  74                         LOCK_TEXT
  75                         *(.fixup)
  76                         *(.gnu.warning)
  77                         *(.rodata)
  78                         *(.rodata.*)
  79                         *(.glue_7)
  80                         *(.glue_7t)
  81                 *(.got)                 /* Global offset table          */
  82
  83                 _etext = .;             /* End of text section          */
  84         }
  85
  86         . = ALIGN(16);
  87         __ex_table : {                  /* Exception table              */
  88                 __start___ex_table = .;
  89                         *(__ex_table)
  90                 __stop___ex_table = .;
  91         }
  92
  93         RODATA
  94
  95         . = ALIGN(8192);
  96
  97         .data : {
  98                 /*
  99                  * first, the init task union, aligned
 100                  * to an 8192 byte boundary.
 101                  */
 102                 *(.init.task)
 103
 104                 . = ALIGN(4096);
 105                 __nosave_begin = .;
 106                 *(.data.nosave)
 107                 . = ALIGN(4096);
 108                 __nosave_end = .;
 109
 110                 /*
 111                  * then the cacheline aligned data
 112                  */
 113                 . = ALIGN(32);
 114                 *(.data.cacheline_aligned)
 115
 116                 /*
 117                  * and the usual data section
 118                  */
 119                 *(.data)
 120                 CONSTRUCTORS
 121
 122                 _edata = .;
 123         }
 124
 125         .bss : {
 126                 __bss_start = .;        /* BSS                          */
 127                 *(.bss)
 128                 *(COMMON)
 129                 _end = . ;
 130         }
 131                                         /* Stabs debugging sections.    */
 132         .stab 0 : { *(.stab) }
 133         .stabstr 0 : { *(.stabstr) }
 134         .stab.excl 0 : { *(.stab.excl) }
 135         .stab.exclstr 0 : { *(.stab.exclstr) }
 136         .stab.index 0 : { *(.stab.index) }
 137         .stab.indexstr 0 : { *(.stab.indexstr) }
 138         .comment 0 : { *(.comment) }
 139 }