arch/cris/arch-v10/boot/rescue/head.S

   1 /* $Id: head.S,v 1.7 2005/03/07 12:11:06 starvik Exp $
   2  *
   3  * Rescue code, made to reside at the beginning of the
   4  * flash-memory. when it starts, it checks a partition
   5  * table at the first sector after the rescue sector.
   6  * the partition table was generated by the product builder
   7  * script and contains offsets, lengths, types and checksums
   8  * for each partition that this code should check.
   9  *
  10  * If any of the checksums fail, we assume the flash is so
  11  * corrupt that we cant use it to boot into the ftp flash
  12  * loader, and instead we initialize the serial port to
  13  * receive a flash-loader and new flash image. we dont include
  14  * any flash code here, but just accept a certain amount of
  15  * bytes from the serial port and jump into it. the downloaded
  16  * code is put in the cache.
  17  *
  18  * The partitiontable is designed so that it is transparent to
  19  * code execution - it has a relative branch opcode in the
  20  * beginning that jumps over it. each entry contains extra
  21  * data so we can add stuff later.
  22  *
  23  * Partition table format:
  24  *
  25  *     Code transparency:
  26  *
  27  *     2 bytes    [opcode 'nop']
  28  *     2 bytes    [opcode 'di']
  29  *     4 bytes    [opcode 'ba <offset>', 8-bit or 16-bit version]
  30  *     2 bytes    [opcode 'nop', delay slot]
  31  *
  32  *     Table validation (at +10):
  33  *
  34  *     2 bytes    [magic/version word for partitiontable - 0xef, 0xbe]
  35  *     2 bytes    [length of all entries plus the end marker]
  36  *     4 bytes    [checksum for the partitiontable itself]
  37  *
  38  *     Entries, each with the following format, last has offset -1:
  39  *
  40  *        4 bytes    [offset in bytes, from start of flash]
  41  *        4 bytes    [length in bytes of partition]
  42  *        4 bytes    [checksum, simple longword sum]
  43  *        2 bytes    [partition type]
  44  *        2 bytes    [flags, only bit 0 used, ro/rw = 1/0]
  45  *        16 bytes   [reserved for future use]
  46  *
  47  *     End marker
  48  *
  49  *        4 bytes    [-1]
  50  *
  51  *       10 bytes    [0, padding]
  52  *
  53  * Bit 0 in flags signifies RW or RO. The rescue code only bothers
  54  * to check the checksum for RO partitions, since the others will
  55  * change their data without updating the checksums. A 1 in bit 0
  56  * means RO, 0 means RW. That way, it is possible to set a partition
  57  * in RO mode initially, and later mark it as RW, since you can always
  58  * write 0's to the flash.
  59  *
  60  * During the wait for serial input, the status LED will flash so the
  61  * user knows something went wrong.
  62  *
  63  * Copyright (C) 1999, 2000, 2001, 2002, 2003 Axis Communications AB
  64  */
  65
  66 #include <linux/config.h>
  67 #define ASSEMBLER_MACROS_ONLY
  68 #include <asm/arch/sv_addr_ag.h>
  69
  70         ;; The partitiontable is looked for at the first sector after the boot
  71         ;; sector. Sector size is 65536 bytes in all flashes we use.
  72
  73 #define PTABLE_START CONFIG_ETRAX_PTABLE_SECTOR
  74 #define PTABLE_MAGIC 0xbeef
  75
  76         ;; The normal Etrax100 on-chip boot ROM does serial boot at 0x380000f0.
  77         ;; That is not where we put our downloaded serial boot-code. The length is
  78         ;; enough for downloading code that loads the rest of itself (after
  79         ;; having setup the DRAM etc). It is the same length as the on-chip
  80         ;; ROM loads, so the same host loader can be used to load a rescued
  81         ;; product as well as one booted through the Etrax serial boot code.
  82
  83 #define CODE_START 0x40000000
  84 #define CODE_LENGTH 784
  85
  86 #ifdef CONFIG_ETRAX_RESCUE_SER0
  87 #define SERXOFF R_SERIAL0_XOFF
  88 #define SERBAUD R_SERIAL0_BAUD
  89 #define SERRECC R_SERIAL0_REC_CTRL
  90 #define SERRDAT R_SERIAL0_REC_DATA
  91 #define SERSTAT R_SERIAL0_STATUS
  92 #endif
  93 #ifdef CONFIG_ETRAX_RESCUE_SER1
  94 #define SERXOFF R_SERIAL1_XOFF
  95 #define SERBAUD R_SERIAL1_BAUD
  96 #define SERRECC R_SERIAL1_REC_CTRL
  97 #define SERRDAT R_SERIAL1_REC_DATA
  98 #define SERSTAT R_SERIAL1_STATUS
  99 #endif
 100 #ifdef CONFIG_ETRAX_RESCUE_SER2
 101 #define SERXOFF R_SERIAL2_XOFF
 102 #define SERBAUD R_SERIAL2_BAUD
 103 #define SERRECC R_SERIAL2_REC_CTRL
 104 #define SERRDAT R_SERIAL2_REC_DATA
 105 #define SERSTAT R_SERIAL2_STATUS
 106 #endif
 107 #ifdef CONFIG_ETRAX_RESCUE_SER3
 108 #define SERXOFF R_SERIAL3_XOFF
 109 #define SERBAUD R_SERIAL3_BAUD
 110 #define SERRECC R_SERIAL3_REC_CTRL
 111 #define SERRDAT R_SERIAL3_REC_DATA
 112 #define SERSTAT R_SERIAL3_STATUS
 113 #endif
 114
 115 #define NOP_DI 0xf025050f
 116 #define RAM_INIT_MAGIC 0x56902387
 117
 118         .text
 119
 120         ;; This is the entry point of the rescue code
 121         ;; 0x80000000 if loaded in flash (as it should be)
 122         ;; since etrax actually starts at address 2 when booting from flash, we
 123         ;; put a nop (2 bytes) here first so we dont accidentally skip the di
 124
 125         nop
 126         di
 127
 128         jump    in_cache        ; enter cached area instead
 129 in_cache:
 130
 131
 132         ;; first put a jump test to give a possibility of upgrading the rescue code
 133         ;; without erasing/reflashing the sector. we put a longword of -1 here and if
 134         ;; it is not -1, we jump using the value as jump target. since we can always
 135         ;; change 1's to 0's without erasing the sector, it is possible to add new
 136         ;; code after this and altering the jumptarget in an upgrade.
 137
 138 jtcd:   move.d  [jumptarget], $r0
 139         cmp.d   0xffffffff, $r0
 140         beq     no_newjump
 141         nop
 142
 143         jump    [$r0]
 144
 145 jumptarget:
 146         .dword  0xffffffff      ; can be overwritten later to insert new code
 147
 148 no_newjump:
 149 #ifdef CONFIG_ETRAX_ETHERNET
 150         ;; Start MII clock to make sure it is running when tranceiver is reset
 151         move.d 0x3, $r0    ; enable = on, phy = mii_clk
 152         move.d $r0, [R_NETWORK_GEN_CONFIG]
 153 #endif
 154
 155         ;; We need to setup the bus registers before we start using the DRAM
 156 #include "../../lib/dram_init.S"
 157
 158         ;; we now should go through the checksum-table and check the listed
 159         ;; partitions for errors.
 160
 161         move.d  PTABLE_START, $r3
 162         move.d  [$r3], $r0
 163         cmp.d   NOP_DI, $r0     ; make sure the nop/di is there...
 164         bne     do_rescue
 165         nop
 166
 167         ;; skip the code transparency block (10 bytes).
 168
 169         addq    10, $r3
 170
 171         ;; check for correct magic
 172
 173         move.w  [$r3+], $r0
 174         cmp.w   PTABLE_MAGIC, $r0
 175         bne     do_rescue       ; didn't recognize - trig rescue
 176         nop
 177
 178         ;; check for correct ptable checksum
 179
 180         movu.w  [$r3+], $r2     ; ptable length
 181         move.d  $r2, $r8        ; save for later, length of total ptable
 182         addq    28, $r8         ; account for the rest
 183         move.d  [$r3+], $r4     ; ptable checksum
 184         move.d  $r3, $r1
 185         jsr     checksum        ; r1 source, r2 length, returns in r0
 186
 187         cmp.d   $r0, $r4
 188         bne     do_rescue       ; didn't match - trig rescue
 189         nop
 190
 191         ;; ptable is ok. validate each entry.
 192
 193         moveq   -1, $r7
 194
 195 ploop:  move.d  [$r3+], $r1     ; partition offset (from ptable start)
 196         bne     notfirst        ; check if it is the partition containing ptable
 197         nop                     ; yes..
 198         move.d  $r8, $r1        ; for its checksum check, skip the ptable
 199         move.d  [$r3+], $r2     ; partition length
 200         sub.d   $r8, $r2        ; minus the ptable length
 201         ba      bosse
 202         nop
 203 notfirst:
 204         cmp.d   -1, $r1         ; the end of the ptable ?
 205         beq     flash_ok        ;   if so, the flash is validated
 206         move.d  [$r3+], $r2     ; partition length
 207 bosse:  move.d  [$r3+], $r5     ; checksum
 208         move.d  [$r3+], $r4     ; type and flags
 209         addq    16, $r3         ; skip the reserved bytes
 210         btstq   16, $r4         ; check ro flag
 211         bpl     ploop           ;   rw partition, skip validation
 212         nop
 213         btstq   17, $r4         ; check bootable flag
 214         bpl     1f
 215         nop
 216         move.d  $r1, $r7        ; remember boot partition offset
 217 1:
 218
 219         add.d   PTABLE_START, $r1
 220
 221         jsr     checksum        ; checksum the partition
 222
 223         cmp.d   $r0, $r5
 224         beq     ploop           ; checksums matched, go to next entry
 225         nop
 226
 227         ;; otherwise fall through to the rescue code.
 228
 229 do_rescue:
 230         ;; setup port PA and PB default initial directions and data
 231         ;; (so we can flash LEDs, and so that DTR and others are set)
 232
 233         move.b  CONFIG_ETRAX_DEF_R_PORT_PA_DIR, $r0
 234         move.b  $r0, [R_PORT_PA_DIR]
 235         move.b  CONFIG_ETRAX_DEF_R_PORT_PA_DATA, $r0
 236         move.b  $r0, [R_PORT_PA_DATA]
 237
 238         move.b  CONFIG_ETRAX_DEF_R_PORT_PB_DIR, $r0
 239         move.b  $r0, [R_PORT_PB_DIR]
 240         move.b  CONFIG_ETRAX_DEF_R_PORT_PB_DATA, $r0
 241         move.b  $r0, [R_PORT_PB_DATA]
 242
 243         ;; setup the serial port at 115200 baud
 244
 245         moveq   0, $r0
 246         move.d  $r0, [SERXOFF]
 247
 248         move.b  0x99, $r0
 249         move.b  $r0, [SERBAUD]          ; 115.2kbaud for both transmit and receive
 250
 251         move.b  0x40, $r0               ; rec enable
 252         move.b  $r0, [SERRECC]
 253
 254         moveq   0, $r1          ; "timer" to clock out a LED red flash
 255         move.d  CODE_START, $r3 ; destination counter
 256         movu.w  CODE_LENGTH, $r4; length
 257
 258 wait_ser:
 259         addq    1, $r1
 260 #ifndef CONFIG_ETRAX_NO_LEDS
 261 #ifdef CONFIG_ETRAX_PA_LEDS
 262         move.b  CONFIG_ETRAX_DEF_R_PORT_PA_DATA, $r2
 263 #endif
 264 #ifdef CONFIG_ETRAX_PB_LEDS
 265         move.b  CONFIG_ETRAX_DEF_R_PORT_PB_DATA, $r2
 266 #endif
 267         move.d  (1 << CONFIG_ETRAX_LED1R) | (1 << CONFIG_ETRAX_LED2R), $r0
 268         btstq   16, $r1
 269         bpl     1f
 270         nop
 271         or.d    $r0, $r2        ; set bit
 272         ba      2f
 273         nop
 274 1:      not     $r0             ; clear bit
 275         and.d   $r0, $r2
 276 2:
 277 #ifdef CONFIG_ETRAX_PA_LEDS
 278         move.b  $r2, [R_PORT_PA_DATA]
 279 #endif
 280 #ifdef CONFIG_ETRAX_PB_LEDS
 281         move.b  $r2, [R_PORT_PB_DATA]
 282 #endif
 283 #ifdef CONFIG_ETRAX_90000000_LEDS
 284         move.b  $r2, [0x90000000]
 285 #endif
 286 #endif
 287
 288         ;; check if we got something on the serial port
 289
 290         move.b  [SERSTAT], $r0
 291         btstq   0, $r0          ; data_avail
 292         bpl     wait_ser
 293         nop
 294
 295         ;; got something - copy the byte and loop
 296
 297         move.b  [SERRDAT], $r0
 298         move.b  $r0, [$r3+]
 299
 300         subq    1, $r4          ; decrease length
 301         bne     wait_ser
 302         nop
 303
 304         ;; jump into downloaded code
 305
 306         move.d  RAM_INIT_MAGIC, $r8     ; Tell next product that DRAM is initialized
 307         jump    CODE_START
 308
 309 flash_ok:
 310         ;; check r7, which contains either -1 or the partition to boot from
 311
 312         cmp.d   -1, $r7
 313         bne     1f
 314         nop
 315         move.d  PTABLE_START, $r7; otherwise use the ptable start
 316 1:
 317         move.d  RAM_INIT_MAGIC, $r8     ; Tell next product that DRAM is initialized
 318         jump    $r7             ; boot!
 319
 320
 321         ;; Helper subroutines
 322
 323         ;; Will checksum by simple addition
 324         ;; r1 - source
 325         ;; r2 - length in bytes
 326         ;; result will be in r0
 327 checksum:
 328         moveq   0, $r0
 329         moveq   CONFIG_ETRAX_FLASH1_SIZE, $r6
 330
 331         ;; If the first physical flash memory is exceeded wrap to the second one.
 332         btstq   26, $r1         ; Are we addressing first flash?
 333         bpl     1f
 334         nop
 335         clear.d $r6
 336
 337 1:      test.d  $r6             ; 0 = no wrapping
 338         beq     2f
 339         nop
 340         lslq    20, $r6         ; Convert MB to bytes
 341         sub.d   $r1, $r6
 342
 343 2:      addu.b  [$r1+], $r0
 344         subq    1, $r6          ; Flash memory left
 345         beq     3f
 346         subq    1, $r2          ; Length left
 347         bne     2b
 348         nop
 349         ret
 350         nop
 351
 352 3:      move.d  MEM_CSE1_START, $r1 ; wrap to second flash
 353         ba      2b
 354         nop