arch/h8300/platform/h8300h/entry.S

   1 /* -*- mode: asm -*-
   2  *
   3  *  linux/arch/h8300/platform/h8300h/entry.S
   4  *
   5  *  Yoshinori Sato <ysato@users.sourceforge.jp>
   6  *  David McCullough <davidm@snapgear.com>
   7  *
   8  */
   9
  10 /*
  11  *  entry.S
  12  *  include exception/interrupt gateway
  13  *          system call entry
  14  */
  15
  16 #include <linux/sys.h>
  17 #include <linux/config.h>
  18 #include <asm/unistd.h>
  19 #include <asm/setup.h>
  20 #include <asm/segment.h>
  21 #include <asm/linkage.h>
  22 #include <asm/asm-offsets.h>
  23 #include <asm/thread_info.h>
  24 #include <asm/errno.h>
  25
  26         .h8300h
  27
  28 /* CPU context save/restore macros. */
  29
  30         .macro  SAVE_ALL
  31         mov.l   er0,@-sp
  32
  33         stc     ccr,r0l                         /* check kernel mode */
  34         orc     #0x10,ccr
  35         btst    #4,r0l
  36         bne     5f
  37
  38         mov.l   sp,@SYMBOL_NAME(sw_usp)         /* user mode */
  39         mov.l   @sp,er0
  40         mov.l   @SYMBOL_NAME(sw_ksp),sp
  41         sub.l   #(LRET-LORIG),sp                /* allocate LORIG - LRET */
  42         mov.l   er0,@-sp
  43         mov.l   er1,@-sp
  44         mov.l   @SYMBOL_NAME(sw_usp),er0
  45         mov.l   @(8:16,er0),er1                 /* copy the RET addr */
  46         mov.l   er1,@(LRET-LER1:16,sp)
  47
  48         mov.w   e1,r1                           /* e1 highbyte = ccr */
  49         and     #0xef,r1h                       /* mask mode? flag */
  50         sub.w   r0,r0
  51         mov.b   r1h,r0l
  52         mov.w   r0,@(LCCR-LER1:16,sp)           /* copy ccr */
  53         mov.l   @(LORIG-LER1:16,sp),er0
  54         mov.l   er0,@(LER0-LER1:16,sp)          /* copy ER0 */
  55         bra     6f
  56 5:
  57         mov.l   @sp,er0                         /* kernel mode */
  58         subs    #2,sp                           /* dummy ccr */
  59         mov.l   er0,@-sp
  60         mov.l   er1,@-sp
  61         mov.w   @(LRET-LER1:16,sp),r1           /* copy old ccr */
  62         mov.b   r1h,r1l
  63         mov.b   #0,r1h
  64         mov.w   r1,@(LCCR-LER1:16,sp)           /* set ccr */
  65 6:
  66         mov.l   er2,@-sp
  67         mov.l   er3,@-sp
  68         mov.l   er6,@-sp                        /* syscall arg #6 */
  69         mov.l   er5,@-sp                        /* syscall arg #5 */
  70         mov.l   er4,@-sp                        /* syscall arg #4 */
  71         .endm
  72
  73         .macro  RESTORE_ALL
  74         mov.l   @sp+,er4
  75         mov.l   @sp+,er5
  76         mov.l   @sp+,er6
  77         mov.l   @sp+,er3
  78         mov.l   @sp+,er2
  79         mov.w   @(LCCR-LER1:16,sp),r0           /* check kernel mode */
  80         btst    #4,r0l
  81         bne     7f
  82
  83         orc     #0x80,ccr
  84         mov.l   @SYMBOL_NAME(sw_usp),er0
  85         mov.l   @(LER0-LER1:16,sp),er1          /* restore ER0 */
  86         mov.l   er1,@er0
  87         mov.w   @(LCCR-LER1:16,sp),r1           /* restore the RET addr */
  88         mov.b   r1l,r1h
  89         mov.b   @(LRET+1-LER1:16,sp),r1l
  90         mov.w   r1,e1
  91         mov.w   @(LRET+2-LER1:16,sp),r1
  92         mov.l   er1,@(8:16,er0)
  93
  94         mov.l   @sp+,er1
  95         add.l   #(LRET-LER1),sp                 /* remove LORIG - LRET */
  96         mov.l   sp,@SYMBOL_NAME(sw_ksp)
  97         mov.l   er0,sp
  98         bra     8f
  99 7:
 100         mov.l   @sp+,er1
 101         adds    #4,sp
 102         adds    #2,sp
 103 8:
 104         mov.l   @sp+,er0
 105         adds    #4,sp                           /* remove the sw created LVEC */
 106         rte
 107         .endm
 108
 109 .globl SYMBOL_NAME(system_call)
 110 .globl SYMBOL_NAME(ret_from_exception)
 111 .globl SYMBOL_NAME(ret_from_fork)
 112 .globl SYMBOL_NAME(ret_from_signal)
 113 .globl SYMBOL_NAME(ret_from_interrupt)
 114 .globl SYMBOL_NAME(interrupt_redirect_table)
 115 .globl SYMBOL_NAME(sw_ksp),SYMBOL_NAME(sw_usp)
 116 .globl SYMBOL_NAME(resume)
 117 .globl SYMBOL_NAME(syscall_trampoline)
 118 .globl SYMBOL_NAME(interrupt_redirect_table)
 119 .globl SYMBOL_NAME(interrupt_entry)
 120 .globl SYMBOL_NAME(system_call)
 121 .globl SYMBOL_NAME(trace_break)
 122
 123 #if defined(CONFIG_ROMKERNEL)
 124 INTERRUPTS = 64
 125         .section .int_redirect,"ax"
 126 SYMBOL_NAME_LABEL(interrupt_redirect_table)
 127         .rept   7
 128         .long   0
 129         .endr
 130         jsr     @SYMBOL_NAME(interrupt_entry)   /* NMI */
 131         jmp     @SYMBOL_NAME(system_call)       /* TRAPA #0 (System call) */
 132         .long   0
 133         .long   0
 134         jmp     @SYMBOL_NAME(trace_break)       /* TRAPA #3 (breakpoint) */
 135         .rept   INTERRUPTS-12
 136         jsr     @SYMBOL_NAME(interrupt_entry)
 137         .endr
 138 #endif
 139 #if defined(CONFIG_RAMKERNEL)
 140 .globl SYMBOL_NAME(interrupt_redirect_table)
 141         .section .bss
 142 SYMBOL_NAME_LABEL(interrupt_redirect_table)
 143         .space  4
 144 #endif
 145
 146         .section .text
 147         .align  2
 148 SYMBOL_NAME_LABEL(interrupt_entry)
 149         SAVE_ALL
 150         mov.w   @(LCCR,sp),r0
 151         btst    #4,r0l
 152         bne     1f
 153         mov.l   @SYMBOL_NAME(sw_usp),er0
 154         mov.l   @(4:16,er0),er0
 155         bra     2f
 156 1:
 157         mov.l   @(LVEC,sp),er0
 158 2:
 159 #if defined(CONFIG_ROMKERNEL)
 160         sub.l   #SYMBOL_NAME(interrupt_redirect_table),er0
 161 #endif
 162 #if defined(CONFIG_RAMKERNEL)
 163         mov.l   @SYMBOL_NAME(interrupt_redirect_table),er1
 164         sub.l   er1,er0
 165 #endif
 166         shlr.l  er0
 167         shlr.l  er0
 168         dec.l   #1,er0
 169         mov.l   sp,er1
 170         subs    #4,er1                          /* adjust ret_pc */
 171         jsr     @SYMBOL_NAME(process_int)
 172         mov.l   @SYMBOL_NAME(irq_stat)+CPUSTAT_SOFTIRQ_PENDING,er0
 173         beq     1f
 174         jsr     @SYMBOL_NAME(do_softirq)
 175 1:
 176         jmp     @SYMBOL_NAME(ret_from_exception)
 177
 178 SYMBOL_NAME_LABEL(system_call)
 179         subs    #4,sp                           /* dummy LVEC */
 180         SAVE_ALL
 181         mov.w   @(LCCR:16,sp),r1
 182         bset    #4,r1l
 183         ldc     r1l,ccr
 184         mov.l   er0,er4
 185         mov.l   #-ENOSYS,er0
 186         mov.l   er0,@(LER0:16,sp)
 187
 188         /* save top of frame */
 189         mov.l   sp,er0
 190         jsr     @SYMBOL_NAME(set_esp0)
 191         cmp.l   #NR_syscalls,er4
 192         bcc     SYMBOL_NAME(ret_from_exception):16
 193         shll.l  er4
 194         shll.l  er4
 195         mov.l   #SYMBOL_NAME(sys_call_table),er0
 196         add.l   er4,er0
 197         mov.l   @er0,er4
 198         beq     SYMBOL_NAME(ret_from_exception):16
 199         mov.l   sp,er2
 200         and.w   #0xe000,r2
 201         mov.b   @((TASK_FLAGS+3-(TIF_SYSCALL_TRACE >> 3)):16,er2),r2l
 202         btst    #(TIF_SYSCALL_TRACE & 7),r2l
 203         bne     1f
 204         mov.l   @(LER1:16,sp),er0
 205         mov.l   @(LER2:16,sp),er1
 206         mov.l   @(LER3:16,sp),er2
 207         jsr     @er4
 208         mov.l   er0,@(LER0,sp)                  /* save the return value */
 209 #if defined(CONFIG_SYSCALL_PRINT)
 210         jsr     @SYMBOL_NAME(syscall_print)
 211 #endif
 212         jmp     @SYMBOL_NAME(ret_from_exception)
 213 1:
 214         jsr     SYMBOL_NAME(syscall_trace)
 215         mov.l   @(LER1:16,sp),er0
 216         mov.l   @(LER2:16,sp),er1
 217         mov.l   @(LER3:16,sp),er2
 218         jsr     @er4
 219         mov.l   er0,@(LER0:16,sp)               /* save the return value */
 220         jsr     @SYMBOL_NAME(syscall_trace)
 221
 222 SYMBOL_NAME_LABEL(ret_from_signal)
 223
 224 SYMBOL_NAME_LABEL(ret_from_exception)
 225         mov.b   @(LCCR+1:16,sp),r0l
 226         btst    #4,r0l                  /* check if returning to kernel */
 227         bne     3f                      /* if so, skip resched, signals */
 228         andc    #0x7f,ccr
 229         mov.l   sp,er2
 230         and.w   #0xe000,r2
 231         mov.l   @(TI_FLAGS:16,er2),er1
 232         and.l   #_TIF_WORK_MASK,er1
 233         beq     3f
 234 1:
 235         mov.l   @(TI_FLAGS:16,er2),er1
 236         btst    #TIF_NEED_RESCHED,r1l
 237         bne     SYMBOL_NAME(reschedule):16
 238         mov.l   sp,er1
 239         subs    #4,er1                  /* adjust retpc */
 240         mov.l   er2,er0
 241         jsr     @SYMBOL_NAME(do_signal)
 242 3:
 243         RESTORE_ALL                     /* Does RTE */
 244
 245 SYMBOL_NAME_LABEL(reschedule)
 246         /* save top of frame */
 247         mov.l   sp,er0
 248         jsr     @SYMBOL_NAME(set_esp0)
 249
 250         mov.l   #SYMBOL_NAME(ret_from_exception),er0
 251         mov.l   er0,@-sp
 252         jmp     @SYMBOL_NAME(schedule)
 253
 254 SYMBOL_NAME_LABEL(ret_from_fork)
 255         mov.l   er2,er0
 256         jsr     @SYMBOL_NAME(schedule_tail)
 257         jmp     @SYMBOL_NAME(ret_from_exception)
 258
 259 SYMBOL_NAME_LABEL(resume)
 260         /*
 261          * Beware - when entering resume, offset of tss is in d1,
 262          * prev (the current task) is in a0, next (the new task)
 263          * is in a1 and d2.b is non-zero if the mm structure is
 264          * shared between the tasks, so don't change these
 265          * registers until their contents are no longer needed.
 266          */
 267
 268         /* save sr */
 269         sub.w   r3,r3
 270         stc     ccr,r3l
 271         mov.w   r3,@(THREAD_CCR+2:16,er0)
 272
 273         /* disable interrupts */
 274         orc     #0x80,ccr
 275         mov.l   @SYMBOL_NAME(sw_usp),er3
 276         mov.l   er3,@(THREAD_USP:16,er0)
 277         mov.l   sp,@(THREAD_KSP:16,er0)
 278
 279         /* Skip address space switching if they are the same. */
 280         /* FIXME: what did we hack out of here, this does nothing! */
 281
 282         mov.l   @(THREAD_USP:16,er1),er0
 283         mov.l   er0,@SYMBOL_NAME(sw_usp)
 284         mov.l   @(THREAD_KSP:16,er1),sp
 285
 286         /* restore status register */
 287         mov.w   @(THREAD_CCR+2:16,er1),r3
 288
 289         ldc     r3l,ccr
 290         rts
 291
 292 SYMBOL_NAME_LABEL(trace_break)
 293         subs    #4,sp
 294         SAVE_ALL
 295         sub.l   er1,er1
 296         dec.l   #1,er1
 297         mov.l   er1,@(LORIG,sp)
 298         mov.l   sp,er0
 299         jsr     @SYMBOL_NAME(set_esp0)
 300         mov.l   @SYMBOL_NAME(sw_usp),er0
 301         mov.l   @er0,er1
 302         subs    #2,er1
 303         mov.l   er1,@er0
 304         and.w   #0xff,e1
 305         mov.l   er1,er0
 306         jsr     @SYMBOL_NAME(trace_trap)
 307         jmp     @SYMBOL_NAME(ret_from_exception)
 308
 309 SYMBOL_NAME_LABEL(syscall_trampoline)
 310         mov.l   er0,er6
 311         mov.l   sp,er0
 312         jmp     @er6
 313
 314         .section        .bss
 315 SYMBOL_NAME_LABEL(sw_ksp)
 316         .space  4
 317 SYMBOL_NAME_LABEL(sw_usp)
 318         .space  4