arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %gs
  34  *      28(%esp) - orig_eax
  35  *      2C(%esp) - %eip
  36  *      30(%esp) - %cs
  37  *      34(%esp) - %eflags
  38  *      38(%esp) - %oldesp
  39  *      3C(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include "irq_vectors.h"
  55
  56 /*
  57  * We use macros for low-level operations which need to be overridden
  58  * for paravirtualization.  The following will never clobber any registers:
  59  *   INTERRUPT_RETURN (aka. "iret")
  60  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  61  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  62  *
  63  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  64  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  65  * Allowing a register to be clobbered can shrink the paravirt replacement
  66  * enough to patch inline, increasing performance.
  67  */
  68
  69 #define nr_syscalls ((syscall_table_size)/4)
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  80 #else
  81 #define preempt_stop(clobbers)
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 .macro TRACE_IRQS_IRET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
  88         jz 1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 #ifdef CONFIG_VM86
  95 #define resume_userspace_sig    check_userspace
  96 #else
  97 #define resume_userspace_sig    resume_userspace
  98 #endif
  99
 100 #define SAVE_ALL \
 101         cld; \
 102         pushl %gs; \
 103         CFI_ADJUST_CFA_OFFSET 4;\
 104         /*CFI_REL_OFFSET gs, 0;*/\
 105         pushl %es; \
 106         CFI_ADJUST_CFA_OFFSET 4;\
 107         /*CFI_REL_OFFSET es, 0;*/\
 108         pushl %ds; \
 109         CFI_ADJUST_CFA_OFFSET 4;\
 110         /*CFI_REL_OFFSET ds, 0;*/\
 111         pushl %eax; \
 112         CFI_ADJUST_CFA_OFFSET 4;\
 113         CFI_REL_OFFSET eax, 0;\
 114         pushl %ebp; \
 115         CFI_ADJUST_CFA_OFFSET 4;\
 116         CFI_REL_OFFSET ebp, 0;\
 117         pushl %edi; \
 118         CFI_ADJUST_CFA_OFFSET 4;\
 119         CFI_REL_OFFSET edi, 0;\
 120         pushl %esi; \
 121         CFI_ADJUST_CFA_OFFSET 4;\
 122         CFI_REL_OFFSET esi, 0;\
 123         pushl %edx; \
 124         CFI_ADJUST_CFA_OFFSET 4;\
 125         CFI_REL_OFFSET edx, 0;\
 126         pushl %ecx; \
 127         CFI_ADJUST_CFA_OFFSET 4;\
 128         CFI_REL_OFFSET ecx, 0;\
 129         pushl %ebx; \
 130         CFI_ADJUST_CFA_OFFSET 4;\
 131         CFI_REL_OFFSET ebx, 0;\
 132         movl $(__USER_DS), %edx; \
 133         movl %edx, %ds; \
 134         movl %edx, %es; \
 135         movl $(__KERNEL_PDA), %edx; \
 136         movl %edx, %gs
 137
 138 #define RESTORE_INT_REGS \
 139         popl %ebx;      \
 140         CFI_ADJUST_CFA_OFFSET -4;\
 141         CFI_RESTORE ebx;\
 142         popl %ecx;      \
 143         CFI_ADJUST_CFA_OFFSET -4;\
 144         CFI_RESTORE ecx;\
 145         popl %edx;      \
 146         CFI_ADJUST_CFA_OFFSET -4;\
 147         CFI_RESTORE edx;\
 148         popl %esi;      \
 149         CFI_ADJUST_CFA_OFFSET -4;\
 150         CFI_RESTORE esi;\
 151         popl %edi;      \
 152         CFI_ADJUST_CFA_OFFSET -4;\
 153         CFI_RESTORE edi;\
 154         popl %ebp;      \
 155         CFI_ADJUST_CFA_OFFSET -4;\
 156         CFI_RESTORE ebp;\
 157         popl %eax;      \
 158         CFI_ADJUST_CFA_OFFSET -4;\
 159         CFI_RESTORE eax
 160
 161 #define RESTORE_REGS    \
 162         RESTORE_INT_REGS; \
 163 1:      popl %ds;       \
 164         CFI_ADJUST_CFA_OFFSET -4;\
 165         /*CFI_RESTORE ds;*/\
 166 2:      popl %es;       \
 167         CFI_ADJUST_CFA_OFFSET -4;\
 168         /*CFI_RESTORE es;*/\
 169 3:      popl %gs;       \
 170         CFI_ADJUST_CFA_OFFSET -4;\
 171         /*CFI_RESTORE gs;*/\
 172 .pushsection .fixup,"ax";       \
 173 4:      movl $0,(%esp); \
 174         jmp 1b;         \
 175 5:      movl $0,(%esp); \
 176         jmp 2b;         \
 177 6:      movl $0,(%esp); \
 178         jmp 3b;         \
 179 .section __ex_table,"a";\
 180         .align 4;       \
 181         .long 1b,4b;    \
 182         .long 2b,5b;    \
 183         .long 3b,6b;    \
 184 .popsection
 185
 186 #define RING0_INT_FRAME \
 187         CFI_STARTPROC simple;\
 188         CFI_SIGNAL_FRAME;\
 189         CFI_DEF_CFA esp, 3*4;\
 190         /*CFI_OFFSET cs, -2*4;*/\
 191         CFI_OFFSET eip, -3*4
 192
 193 #define RING0_EC_FRAME \
 194         CFI_STARTPROC simple;\
 195         CFI_SIGNAL_FRAME;\
 196         CFI_DEF_CFA esp, 4*4;\
 197         /*CFI_OFFSET cs, -2*4;*/\
 198         CFI_OFFSET eip, -3*4
 199
 200 #define RING0_PTREGS_FRAME \
 201         CFI_STARTPROC simple;\
 202         CFI_SIGNAL_FRAME;\
 203         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 204         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 205         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 206         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 207         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 208         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 209         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 210         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 211         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 212         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 213         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 214         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 215
 216 ENTRY(ret_from_fork)
 217         CFI_STARTPROC
 218         pushl %eax
 219         CFI_ADJUST_CFA_OFFSET 4
 220         call schedule_tail
 221         GET_THREAD_INFO(%ebp)
 222         popl %eax
 223         CFI_ADJUST_CFA_OFFSET -4
 224         pushl $0x0202                   # Reset kernel eflags
 225         CFI_ADJUST_CFA_OFFSET 4
 226         popfl
 227         CFI_ADJUST_CFA_OFFSET -4
 228         jmp syscall_exit
 229         CFI_ENDPROC
 230
 231 /*
 232  * Return to user mode is not as complex as all this looks,
 233  * but we want the default path for a system call return to
 234  * go as quickly as possible which is why some of this is
 235  * less clear than it otherwise should be.
 236  */
 237
 238         # userspace resumption stub bypassing syscall exit tracing
 239         ALIGN
 240         RING0_PTREGS_FRAME
 241 ret_from_exception:
 242         preempt_stop(CLBR_ANY)
 243 ret_from_intr:
 244         GET_THREAD_INFO(%ebp)
 245 check_userspace:
 246         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 247         movb PT_CS(%esp), %al
 248         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
 249         cmpl $USER_RPL, %eax
 250         jb resume_kernel                # not returning to v8086 or userspace
 251
 252 ENTRY(resume_userspace)
 253         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 254                                         # setting need_resched or sigpending
 255                                         # between sampling and the iret
 256         movl TI_flags(%ebp), %ecx
 257         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 258                                         # int/exception return?
 259         jne work_pending
 260         jmp restore_all
 261
 262 #ifdef CONFIG_PREEMPT
 263 ENTRY(resume_kernel)
 264         DISABLE_INTERRUPTS(CLBR_ANY)
 265         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 266         jnz restore_nocheck
 267 need_resched:
 268         movl TI_flags(%ebp), %ecx       # need_resched set ?
 269         testb $_TIF_NEED_RESCHED, %cl
 270         jz restore_all
 271         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
 272         jz restore_all
 273         call preempt_schedule_irq
 274         jmp need_resched
 275 #endif
 276         CFI_ENDPROC
 277
 278 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 279    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 280
 281         # sysenter call handler stub
 282 ENTRY(sysenter_entry)
 283         CFI_STARTPROC simple
 284         CFI_SIGNAL_FRAME
 285         CFI_DEF_CFA esp, 0
 286         CFI_REGISTER esp, ebp
 287         movl SYSENTER_stack_esp0(%esp),%esp
 288 sysenter_past_esp:
 289         /*
 290          * No need to follow this irqs on/off section: the syscall
 291          * disabled irqs and here we enable it straight after entry:
 292          */
 293         ENABLE_INTERRUPTS(CLBR_NONE)
 294         pushl $(__USER_DS)
 295         CFI_ADJUST_CFA_OFFSET 4
 296         /*CFI_REL_OFFSET ss, 0*/
 297         pushl %ebp
 298         CFI_ADJUST_CFA_OFFSET 4
 299         CFI_REL_OFFSET esp, 0
 300         pushfl
 301         CFI_ADJUST_CFA_OFFSET 4
 302         pushl $(__USER_CS)
 303         CFI_ADJUST_CFA_OFFSET 4
 304         /*CFI_REL_OFFSET cs, 0*/
 305 #ifndef CONFIG_COMPAT_VDSO
 306         /*
 307          * Push current_thread_info()->sysenter_return to the stack.
 308          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 309          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 310          */
 311         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 312 #else
 313         pushl $SYSENTER_RETURN
 314 #endif
 315         CFI_ADJUST_CFA_OFFSET 4
 316         CFI_REL_OFFSET eip, 0
 317
 318 /*
 319  * Load the potential sixth argument from user stack.
 320  * Careful about security.
 321  */
 322         cmpl $__PAGE_OFFSET-3,%ebp
 323         jae syscall_fault
 324 1:      movl (%ebp),%ebp
 325 .section __ex_table,"a"
 326         .align 4
 327         .long 1b,syscall_fault
 328 .previous
 329
 330         pushl %eax
 331         CFI_ADJUST_CFA_OFFSET 4
 332         SAVE_ALL
 333         GET_THREAD_INFO(%ebp)
 334
 335         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 336         testw $(_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 337         jnz syscall_trace_entry
 338         cmpl $(nr_syscalls), %eax
 339         jae syscall_badsys
 340         call *sys_call_table(,%eax,4)
 341         movl %eax,PT_EAX(%esp)
 342         DISABLE_INTERRUPTS(CLBR_ECX|CLBR_EDX)
 343         TRACE_IRQS_OFF
 344         movl TI_flags(%ebp), %ecx
 345         testw $_TIF_ALLWORK_MASK, %cx
 346         jne syscall_exit_work
 347 /* if something modifies registers it must also disable sysexit */
 348         movl PT_EIP(%esp), %edx
 349         movl PT_OLDESP(%esp), %ecx
 350         xorl %ebp,%ebp
 351         TRACE_IRQS_ON
 352 1:      mov  PT_GS(%esp), %gs
 353         ENABLE_INTERRUPTS_SYSEXIT
 354         CFI_ENDPROC
 355 .pushsection .fixup,"ax"
 356 2:      movl $0,PT_GS(%esp)
 357         jmp 1b
 358 .section __ex_table,"a"
 359         .align 4
 360         .long 1b,2b
 361 .popsection
 362
 363         # system call handler stub
 364 ENTRY(system_call)
 365         RING0_INT_FRAME                 # can't unwind into user space anyway
 366         pushl %eax                      # save orig_eax
 367         CFI_ADJUST_CFA_OFFSET 4
 368         SAVE_ALL
 369         GET_THREAD_INFO(%ebp)
 370         testl $TF_MASK,PT_EFLAGS(%esp)
 371         jz no_singlestep
 372         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
 373 no_singlestep:
 374                                         # system call tracing in operation / emulation
 375         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 376         testw $(_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 377         jnz syscall_trace_entry
 378         cmpl $(nr_syscalls), %eax
 379         jae syscall_badsys
 380 syscall_call:
 381         call *sys_call_table(,%eax,4)
 382         movl %eax,PT_EAX(%esp)          # store the return value
 383 syscall_exit:
 384         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 385                                         # setting need_resched or sigpending
 386                                         # between sampling and the iret
 387         TRACE_IRQS_OFF
 388         movl TI_flags(%ebp), %ecx
 389         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 390         jne syscall_exit_work
 391
 392 restore_all:
 393         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 394         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 395         # are returning to the kernel.
 396         # See comments in process.c:copy_thread() for details.
 397         movb PT_OLDSS(%esp), %ah
 398         movb PT_CS(%esp), %al
 399         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 400         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 401         CFI_REMEMBER_STATE
 402         je ldt_ss                       # returning to user-space with LDT SS
 403 restore_nocheck:
 404         TRACE_IRQS_IRET
 405 restore_nocheck_notrace:
 406         RESTORE_REGS
 407         addl $4, %esp                   # skip orig_eax/error_code
 408         CFI_ADJUST_CFA_OFFSET -4
 409 1:      INTERRUPT_RETURN
 410 .section .fixup,"ax"
 411 iret_exc:
 412         TRACE_IRQS_ON
 413         ENABLE_INTERRUPTS(CLBR_NONE)
 414         pushl $0                        # no error code
 415         pushl $do_iret_error
 416         jmp error_code
 417 .previous
 418 .section __ex_table,"a"
 419         .align 4
 420         .long 1b,iret_exc
 421 .previous
 422
 423         CFI_RESTORE_STATE
 424 ldt_ss:
 425         larl PT_OLDSS(%esp), %eax
 426         jnz restore_nocheck
 427         testl $0x00400000, %eax         # returning to 32bit stack?
 428         jnz restore_nocheck             # allright, normal return
 429
 430 #ifdef CONFIG_PARAVIRT
 431         /*
 432          * The kernel can't run on a non-flat stack if paravirt mode
 433          * is active.  Rather than try to fixup the high bits of
 434          * ESP, bypass this code entirely.  This may break DOSemu
 435          * and/or Wine support in a paravirt VM, although the option
 436          * is still available to implement the setting of the high
 437          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 438          */
 439         cmpl $0, paravirt_ops+PARAVIRT_enabled
 440         jne restore_nocheck
 441 #endif
 442
 443         /* If returning to userspace with 16bit stack,
 444          * try to fix the higher word of ESP, as the CPU
 445          * won't restore it.
 446          * This is an "official" bug of all the x86-compatible
 447          * CPUs, which we can try to work around to make
 448          * dosemu and wine happy. */
 449         movl PT_OLDESP(%esp), %eax
 450         movl %esp, %edx
 451         call patch_espfix_desc
 452         pushl $__ESPFIX_SS
 453         CFI_ADJUST_CFA_OFFSET 4
 454         pushl %eax
 455         CFI_ADJUST_CFA_OFFSET 4
 456         DISABLE_INTERRUPTS(CLBR_EAX)
 457         TRACE_IRQS_OFF
 458         lss (%esp), %esp
 459         CFI_ADJUST_CFA_OFFSET -8
 460         jmp restore_nocheck
 461         CFI_ENDPROC
 462
 463         # perform work that needs to be done immediately before resumption
 464         ALIGN
 465         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 466 work_pending:
 467         testb $_TIF_NEED_RESCHED, %cl
 468         jz work_notifysig
 469 work_resched:
 470         call schedule
 471         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 472                                         # setting need_resched or sigpending
 473                                         # between sampling and the iret
 474         TRACE_IRQS_OFF
 475         movl TI_flags(%ebp), %ecx
 476         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 477                                         # than syscall tracing?
 478         jz restore_all
 479         testb $_TIF_NEED_RESCHED, %cl
 480         jnz work_resched
 481
 482 work_notifysig:                         # deal with pending signals and
 483                                         # notify-resume requests
 484 #ifdef CONFIG_VM86
 485         testl $VM_MASK, PT_EFLAGS(%esp)
 486         movl %esp, %eax
 487         jne work_notifysig_v86          # returning to kernel-space or
 488                                         # vm86-space
 489         xorl %edx, %edx
 490         call do_notify_resume
 491         jmp resume_userspace_sig
 492
 493         ALIGN
 494 work_notifysig_v86:
 495         pushl %ecx                      # save ti_flags for do_notify_resume
 496         CFI_ADJUST_CFA_OFFSET 4
 497         call save_v86_state             # %eax contains pt_regs pointer
 498         popl %ecx
 499         CFI_ADJUST_CFA_OFFSET -4
 500         movl %eax, %esp
 501 #else
 502         movl %esp, %eax
 503 #endif
 504         xorl %edx, %edx
 505         call do_notify_resume
 506         jmp resume_userspace_sig
 507
 508         # perform syscall exit tracing
 509         ALIGN
 510 syscall_trace_entry:
 511         movl $-ENOSYS,PT_EAX(%esp)
 512         movl %esp, %eax
 513         xorl %edx,%edx
 514         call do_syscall_trace
 515         movl PT_ORIG_EAX(%esp), %eax
 516         cmpl $(nr_syscalls), %eax
 517         jnae syscall_call
 518         jmp syscall_exit
 519
 520         # perform syscall exit tracing
 521         ALIGN
 522 syscall_exit_work:
 523         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 524         jz work_pending
 525         TRACE_IRQS_ON
 526         ENABLE_INTERRUPTS(CLBR_ANY)     # could let do_syscall_trace() call
 527                                         # schedule() instead
 528         movl %esp, %eax
 529         movl $1, %edx
 530         call do_syscall_trace
 531         jmp resume_userspace
 532         CFI_ENDPROC
 533
 534         RING0_INT_FRAME                 # can't unwind into user space anyway
 535 syscall_fault:
 536         pushl %eax                      # save orig_eax
 537         CFI_ADJUST_CFA_OFFSET 4
 538         SAVE_ALL
 539         GET_THREAD_INFO(%ebp)
 540         movl $-EFAULT,PT_EAX(%esp)
 541         jmp resume_userspace
 542
 543 syscall_badsys:
 544         movl $-ENOSYS,PT_EAX(%esp)
 545         jmp resume_userspace
 546         CFI_ENDPROC
 547
 548 #define FIXUP_ESPFIX_STACK \
 549         /* since we are on a wrong stack, we cant make it a C code :( */ \
 550         movl %gs:PDA_cpu, %ebx; \
 551         PER_CPU(cpu_gdt_descr, %ebx); \
 552         movl GDS_address(%ebx), %ebx; \
 553         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 554         addl %esp, %eax; \
 555         pushl $__KERNEL_DS; \
 556         CFI_ADJUST_CFA_OFFSET 4; \
 557         pushl %eax; \
 558         CFI_ADJUST_CFA_OFFSET 4; \
 559         lss (%esp), %esp; \
 560         CFI_ADJUST_CFA_OFFSET -8;
 561 #define UNWIND_ESPFIX_STACK \
 562         movl %ss, %eax; \
 563         /* see if on espfix stack */ \
 564         cmpw $__ESPFIX_SS, %ax; \
 565         jne 27f; \
 566         movl $__KERNEL_DS, %eax; \
 567         movl %eax, %ds; \
 568         movl %eax, %es; \
 569         /* switch to normal stack */ \
 570         FIXUP_ESPFIX_STACK; \
 571 27:;
 572
 573 /*
 574  * Build the entry stubs and pointer table with
 575  * some assembler magic.
 576  */
 577 .data
 578 ENTRY(interrupt)
 579 .text
 580
 581 vector=0
 582 ENTRY(irq_entries_start)
 583         RING0_INT_FRAME
 584 .rept NR_IRQS
 585         ALIGN
 586  .if vector
 587         CFI_ADJUST_CFA_OFFSET -4
 588  .endif
 589 1:      pushl $~(vector)
 590         CFI_ADJUST_CFA_OFFSET 4
 591         jmp common_interrupt
 592 .data
 593         .long 1b
 594 .text
 595 vector=vector+1
 596 .endr
 597
 598 /*
 599  * the CPU automatically disables interrupts when executing an IRQ vector,
 600  * so IRQ-flags tracing has to follow that:
 601  */
 602         ALIGN
 603 common_interrupt:
 604         SAVE_ALL
 605         TRACE_IRQS_OFF
 606         movl %esp,%eax
 607         call do_IRQ
 608         jmp ret_from_intr
 609         CFI_ENDPROC
 610
 611 #define BUILD_INTERRUPT(name, nr)       \
 612 ENTRY(name)                             \
 613         RING0_INT_FRAME;                \
 614         pushl $~(nr);                   \
 615         CFI_ADJUST_CFA_OFFSET 4;        \
 616         SAVE_ALL;                       \
 617         TRACE_IRQS_OFF                  \
 618         movl %esp,%eax;                 \
 619         call smp_/**/name;              \
 620         jmp ret_from_intr;              \
 621         CFI_ENDPROC
 622
 623 /* The include is where all of the SMP etc. interrupts come from */
 624 #include "entry_arch.h"
 625
 626 KPROBE_ENTRY(page_fault)
 627         RING0_EC_FRAME
 628         pushl $do_page_fault
 629         CFI_ADJUST_CFA_OFFSET 4
 630         ALIGN
 631 error_code:
 632         /* the function address is in %gs's slot on the stack */
 633         pushl %es
 634         CFI_ADJUST_CFA_OFFSET 4
 635         /*CFI_REL_OFFSET es, 0*/
 636         pushl %ds
 637         CFI_ADJUST_CFA_OFFSET 4
 638         /*CFI_REL_OFFSET ds, 0*/
 639         pushl %eax
 640         CFI_ADJUST_CFA_OFFSET 4
 641         CFI_REL_OFFSET eax, 0
 642         pushl %ebp
 643         CFI_ADJUST_CFA_OFFSET 4
 644         CFI_REL_OFFSET ebp, 0
 645         pushl %edi
 646         CFI_ADJUST_CFA_OFFSET 4
 647         CFI_REL_OFFSET edi, 0
 648         pushl %esi
 649         CFI_ADJUST_CFA_OFFSET 4
 650         CFI_REL_OFFSET esi, 0
 651         pushl %edx
 652         CFI_ADJUST_CFA_OFFSET 4
 653         CFI_REL_OFFSET edx, 0
 654         pushl %ecx
 655         CFI_ADJUST_CFA_OFFSET 4
 656         CFI_REL_OFFSET ecx, 0
 657         pushl %ebx
 658         CFI_ADJUST_CFA_OFFSET 4
 659         CFI_REL_OFFSET ebx, 0
 660         cld
 661         pushl %gs
 662         CFI_ADJUST_CFA_OFFSET 4
 663         /*CFI_REL_OFFSET gs, 0*/
 664         movl $(__KERNEL_PDA), %ecx
 665         movl %ecx, %gs
 666         UNWIND_ESPFIX_STACK
 667         popl %ecx
 668         CFI_ADJUST_CFA_OFFSET -4
 669         /*CFI_REGISTER es, ecx*/
 670         movl PT_GS(%esp), %edi          # get the function address
 671         movl PT_ORIG_EAX(%esp), %edx    # get the error code
 672         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
 673         mov  %ecx, PT_GS(%esp)
 674         /*CFI_REL_OFFSET gs, ES*/
 675         movl $(__USER_DS), %ecx
 676         movl %ecx, %ds
 677         movl %ecx, %es
 678         movl %esp,%eax                  # pt_regs pointer
 679         call *%edi
 680         jmp ret_from_exception
 681         CFI_ENDPROC
 682 KPROBE_END(page_fault)
 683
 684 ENTRY(coprocessor_error)
 685         RING0_INT_FRAME
 686         pushl $0
 687         CFI_ADJUST_CFA_OFFSET 4
 688         pushl $do_coprocessor_error
 689         CFI_ADJUST_CFA_OFFSET 4
 690         jmp error_code
 691         CFI_ENDPROC
 692
 693 ENTRY(simd_coprocessor_error)
 694         RING0_INT_FRAME
 695         pushl $0
 696         CFI_ADJUST_CFA_OFFSET 4
 697         pushl $do_simd_coprocessor_error
 698         CFI_ADJUST_CFA_OFFSET 4
 699         jmp error_code
 700         CFI_ENDPROC
 701
 702 ENTRY(device_not_available)
 703         RING0_INT_FRAME
 704         pushl $-1                       # mark this as an int
 705         CFI_ADJUST_CFA_OFFSET 4
 706         SAVE_ALL
 707         GET_CR0_INTO_EAX
 708         testl $0x4, %eax                # EM (math emulation bit)
 709         jne device_not_available_emulate
 710         preempt_stop(CLBR_ANY)
 711         call math_state_restore
 712         jmp ret_from_exception
 713 device_not_available_emulate:
 714         pushl $0                        # temporary storage for ORIG_EIP
 715         CFI_ADJUST_CFA_OFFSET 4
 716         call math_emulate
 717         addl $4, %esp
 718         CFI_ADJUST_CFA_OFFSET -4
 719         jmp ret_from_exception
 720         CFI_ENDPROC
 721
 722 /*
 723  * Debug traps and NMI can happen at the one SYSENTER instruction
 724  * that sets up the real kernel stack. Check here, since we can't
 725  * allow the wrong stack to be used.
 726  *
 727  * "SYSENTER_stack_esp0+12" is because the NMI/debug handler will have
 728  * already pushed 3 words if it hits on the sysenter instruction:
 729  * eflags, cs and eip.
 730  *
 731  * We just load the right stack, and push the three (known) values
 732  * by hand onto the new stack - while updating the return eip past
 733  * the instruction that would have done it for sysenter.
 734  */
 735 #define FIX_STACK(offset, ok, label)            \
 736         cmpw $__KERNEL_CS,4(%esp);              \
 737         jne ok;                                 \
 738 label:                                          \
 739         movl SYSENTER_stack_esp0+offset(%esp),%esp;     \
 740         CFI_DEF_CFA esp, 0;                     \
 741         CFI_UNDEFINED eip;                      \
 742         pushfl;                                 \
 743         CFI_ADJUST_CFA_OFFSET 4;                \
 744         pushl $__KERNEL_CS;                     \
 745         CFI_ADJUST_CFA_OFFSET 4;                \
 746         pushl $sysenter_past_esp;               \
 747         CFI_ADJUST_CFA_OFFSET 4;                \
 748         CFI_REL_OFFSET eip, 0
 749
 750 KPROBE_ENTRY(debug)
 751         RING0_INT_FRAME
 752         cmpl $sysenter_entry,(%esp)
 753         jne debug_stack_correct
 754         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 755 debug_stack_correct:
 756         pushl $-1                       # mark this as an int
 757         CFI_ADJUST_CFA_OFFSET 4
 758         SAVE_ALL
 759         xorl %edx,%edx                  # error code 0
 760         movl %esp,%eax                  # pt_regs pointer
 761         call do_debug
 762         jmp ret_from_exception
 763         CFI_ENDPROC
 764 KPROBE_END(debug)
 765
 766 /*
 767  * NMI is doubly nasty. It can happen _while_ we're handling
 768  * a debug fault, and the debug fault hasn't yet been able to
 769  * clear up the stack. So we first check whether we got  an
 770  * NMI on the sysenter entry path, but after that we need to
 771  * check whether we got an NMI on the debug path where the debug
 772  * fault happened on the sysenter path.
 773  */
 774 KPROBE_ENTRY(nmi)
 775         RING0_INT_FRAME
 776         pushl %eax
 777         CFI_ADJUST_CFA_OFFSET 4
 778         movl %ss, %eax
 779         cmpw $__ESPFIX_SS, %ax
 780         popl %eax
 781         CFI_ADJUST_CFA_OFFSET -4
 782         je nmi_espfix_stack
 783         cmpl $sysenter_entry,(%esp)
 784         je nmi_stack_fixup
 785         pushl %eax
 786         CFI_ADJUST_CFA_OFFSET 4
 787         movl %esp,%eax
 788         /* Do not access memory above the end of our stack page,
 789          * it might not exist.
 790          */
 791         andl $(THREAD_SIZE-1),%eax
 792         cmpl $(THREAD_SIZE-20),%eax
 793         popl %eax
 794         CFI_ADJUST_CFA_OFFSET -4
 795         jae nmi_stack_correct
 796         cmpl $sysenter_entry,12(%esp)
 797         je nmi_debug_stack_check
 798 nmi_stack_correct:
 799         /* We have a RING0_INT_FRAME here */
 800         pushl %eax
 801         CFI_ADJUST_CFA_OFFSET 4
 802         SAVE_ALL
 803         xorl %edx,%edx          # zero error code
 804         movl %esp,%eax          # pt_regs pointer
 805         call do_nmi
 806         jmp restore_nocheck_notrace
 807         CFI_ENDPROC
 808
 809 nmi_stack_fixup:
 810         RING0_INT_FRAME
 811         FIX_STACK(12,nmi_stack_correct, 1)
 812         jmp nmi_stack_correct
 813
 814 nmi_debug_stack_check:
 815         /* We have a RING0_INT_FRAME here */
 816         cmpw $__KERNEL_CS,16(%esp)
 817         jne nmi_stack_correct
 818         cmpl $debug,(%esp)
 819         jb nmi_stack_correct
 820         cmpl $debug_esp_fix_insn,(%esp)
 821         ja nmi_stack_correct
 822         FIX_STACK(24,nmi_stack_correct, 1)
 823         jmp nmi_stack_correct
 824
 825 nmi_espfix_stack:
 826         /* We have a RING0_INT_FRAME here.
 827          *
 828          * create the pointer to lss back
 829          */
 830         pushl %ss
 831         CFI_ADJUST_CFA_OFFSET 4
 832         pushl %esp
 833         CFI_ADJUST_CFA_OFFSET 4
 834         addw $4, (%esp)
 835         /* copy the iret frame of 12 bytes */
 836         .rept 3
 837         pushl 16(%esp)
 838         CFI_ADJUST_CFA_OFFSET 4
 839         .endr
 840         pushl %eax
 841         CFI_ADJUST_CFA_OFFSET 4
 842         SAVE_ALL
 843         FIXUP_ESPFIX_STACK              # %eax == %esp
 844         xorl %edx,%edx                  # zero error code
 845         call do_nmi
 846         RESTORE_REGS
 847         lss 12+4(%esp), %esp            # back to espfix stack
 848         CFI_ADJUST_CFA_OFFSET -24
 849 1:      INTERRUPT_RETURN
 850         CFI_ENDPROC
 851 .section __ex_table,"a"
 852         .align 4
 853         .long 1b,iret_exc
 854 .previous
 855 KPROBE_END(nmi)
 856
 857 #ifdef CONFIG_PARAVIRT
 858 ENTRY(native_iret)
 859 1:      iret
 860 .section __ex_table,"a"
 861         .align 4
 862         .long 1b,iret_exc
 863 .previous
 864
 865 ENTRY(native_irq_enable_sysexit)
 866         sti
 867         sysexit
 868 #endif
 869
 870 KPROBE_ENTRY(int3)
 871         RING0_INT_FRAME
 872         pushl $-1                       # mark this as an int
 873         CFI_ADJUST_CFA_OFFSET 4
 874         SAVE_ALL
 875         xorl %edx,%edx          # zero error code
 876         movl %esp,%eax          # pt_regs pointer
 877         call do_int3
 878         jmp ret_from_exception
 879         CFI_ENDPROC
 880 KPROBE_END(int3)
 881
 882 ENTRY(overflow)
 883         RING0_INT_FRAME
 884         pushl $0
 885         CFI_ADJUST_CFA_OFFSET 4
 886         pushl $do_overflow
 887         CFI_ADJUST_CFA_OFFSET 4
 888         jmp error_code
 889         CFI_ENDPROC
 890
 891 ENTRY(bounds)
 892         RING0_INT_FRAME
 893         pushl $0
 894         CFI_ADJUST_CFA_OFFSET 4
 895         pushl $do_bounds
 896         CFI_ADJUST_CFA_OFFSET 4
 897         jmp error_code
 898         CFI_ENDPROC
 899
 900 ENTRY(invalid_op)
 901         RING0_INT_FRAME
 902         pushl $0
 903         CFI_ADJUST_CFA_OFFSET 4
 904         pushl $do_invalid_op
 905         CFI_ADJUST_CFA_OFFSET 4
 906         jmp error_code
 907         CFI_ENDPROC
 908
 909 ENTRY(coprocessor_segment_overrun)
 910         RING0_INT_FRAME
 911         pushl $0
 912         CFI_ADJUST_CFA_OFFSET 4
 913         pushl $do_coprocessor_segment_overrun
 914         CFI_ADJUST_CFA_OFFSET 4
 915         jmp error_code
 916         CFI_ENDPROC
 917
 918 ENTRY(invalid_TSS)
 919         RING0_EC_FRAME
 920         pushl $do_invalid_TSS
 921         CFI_ADJUST_CFA_OFFSET 4
 922         jmp error_code
 923         CFI_ENDPROC
 924
 925 ENTRY(segment_not_present)
 926         RING0_EC_FRAME
 927         pushl $do_segment_not_present
 928         CFI_ADJUST_CFA_OFFSET 4
 929         jmp error_code
 930         CFI_ENDPROC
 931
 932 ENTRY(stack_segment)
 933         RING0_EC_FRAME
 934         pushl $do_stack_segment
 935         CFI_ADJUST_CFA_OFFSET 4
 936         jmp error_code
 937         CFI_ENDPROC
 938
 939 KPROBE_ENTRY(general_protection)
 940         RING0_EC_FRAME
 941         pushl $do_general_protection
 942         CFI_ADJUST_CFA_OFFSET 4
 943         jmp error_code
 944         CFI_ENDPROC
 945 KPROBE_END(general_protection)
 946
 947 ENTRY(alignment_check)
 948         RING0_EC_FRAME
 949         pushl $do_alignment_check
 950         CFI_ADJUST_CFA_OFFSET 4
 951         jmp error_code
 952         CFI_ENDPROC
 953
 954 ENTRY(divide_error)
 955         RING0_INT_FRAME
 956         pushl $0                        # no error code
 957         CFI_ADJUST_CFA_OFFSET 4
 958         pushl $do_divide_error
 959         CFI_ADJUST_CFA_OFFSET 4
 960         jmp error_code
 961         CFI_ENDPROC
 962
 963 #ifdef CONFIG_X86_MCE
 964 ENTRY(machine_check)
 965         RING0_INT_FRAME
 966         pushl $0
 967         CFI_ADJUST_CFA_OFFSET 4
 968         pushl machine_check_vector
 969         CFI_ADJUST_CFA_OFFSET 4
 970         jmp error_code
 971         CFI_ENDPROC
 972 #endif
 973
 974 ENTRY(spurious_interrupt_bug)
 975         RING0_INT_FRAME
 976         pushl $0
 977         CFI_ADJUST_CFA_OFFSET 4
 978         pushl $do_spurious_interrupt_bug
 979         CFI_ADJUST_CFA_OFFSET 4
 980         jmp error_code
 981         CFI_ENDPROC
 982
 983 ENTRY(kernel_thread_helper)
 984         pushl $0                # fake return address for unwinder
 985         CFI_STARTPROC
 986         movl %edx,%eax
 987         push %edx
 988         CFI_ADJUST_CFA_OFFSET 4
 989         call *%ebx
 990         push %eax
 991         CFI_ADJUST_CFA_OFFSET 4
 992         call do_exit
 993         CFI_ENDPROC
 994 ENDPROC(kernel_thread_helper)
 995
 996 .section .rodata,"a"
 997 #include "syscall_table.S"
 998
 999 syscall_table_size=(.-sys_call_table)