arch/i386/kernel/vsyscall.lds

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object with only one read-only segment (that fits in one page).
   4  * This script controls its layout.
   5  */
   6
   7 SECTIONS
   8 {
   9   . = SIZEOF_HEADERS;
  10
  11   .hash           : { *(.hash) }                :text
  12   .dynsym         : { *(.dynsym) }
  13   .dynstr         : { *(.dynstr) }
  14   .gnu.version    : { *(.gnu.version) }
  15   .gnu.version_d  : { *(.gnu.version_d) }
  16   .gnu.version_r  : { *(.gnu.version_r) }
  17
  18   /* This linker script is used both with -r and with -shared.
  19      For the layouts to match, we need to skip more than enough
  20      space for the dynamic symbol table et al.  If this amount
  21      is insufficient, ld -shared will barf.  Just increase it here.  */
  22   . = 0x400;
  23
  24   .text           : { *(.text) }                :text =0x90909090
  25
  26   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  27   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  28   .dynamic        : { *(.dynamic) }             :text :dynamic
  29   .useless        : {
  30         *(.got.plt) *(.got)
  31         *(.data .data.* .gnu.linkonce.d.*)
  32         *(.dynbss)
  33         *(.bss .bss.* .gnu.linkonce.b.*)
  34   }                                             :text
  35 }
  36
  37 /*
  38  * We must supply the ELF program headers explicitly to get just one
  39  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  40  */
  41 PHDRS
  42 {
  43   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  44   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  45   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  46 }
  47
  48 /*
  49  * This controls what symbols we export from the DSO.
  50  */
  51 VERSION
  52 {
  53   LINUX_2.5 {
  54     global:
  55         __kernel_vsyscall;
  56         __kernel_sigreturn;
  57         __kernel_rt_sigreturn;
  58
  59     local: *;
  60   };
  61 }
  62
  63 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  64 ENTRY(__kernel_vsyscall);