arch/i386/kernel/vsyscall.lds

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address, and with only one read-only
   4  * segment (that fits in one page).  This script controls its layout.
   5  */
   6
   7 /* This must match <asm/fixmap.h>.  */
   8 VSYSCALL_BASE = 0xffffe000;
   9
  10 SECTIONS
  11 {
  12   . = VSYSCALL_BASE + SIZEOF_HEADERS;
  13
  14   .hash           : { *(.hash) }                :text
  15   .dynsym         : { *(.dynsym) }
  16   .dynstr         : { *(.dynstr) }
  17   .gnu.version    : { *(.gnu.version) }
  18   .gnu.version_d  : { *(.gnu.version_d) }
  19   .gnu.version_r  : { *(.gnu.version_r) }
  20
  21   /* This linker script is used both with -r and with -shared.
  22      For the layouts to match, we need to skip more than enough
  23      space for the dynamic symbol table et al.  If this amount
  24      is insufficient, ld -shared will barf.  Just increase it here.  */
  25   . = VSYSCALL_BASE + 0x400;
  26
  27   .text           : { *(.text) }                :text =0x90909090
  28
  29   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  30   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  31   .dynamic        : { *(.dynamic) }             :text :dynamic
  32   .useless        : {
  33         *(.got.plt) *(.got)
  34         *(.data .data.* .gnu.linkonce.d.*)
  35         *(.dynbss)
  36         *(.bss .bss.* .gnu.linkonce.b.*)
  37   }                                             :text
  38 }
  39
  40 /*
  41  * We must supply the ELF program headers explicitly to get just one
  42  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  43  */
  44 PHDRS
  45 {
  46   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  47   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  48   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  49 }
  50
  51 /*
  52  * This controls what symbols we export from the DSO.
  53  */
  54 VERSION
  55 {
  56   LINUX_2.5 {
  57     global:
  58         __kernel_vsyscall;
  59         __kernel_sigreturn;
  60         __kernel_rt_sigreturn;
  61
  62     local: *;
  63   };
  64 }
  65
  66 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  67 ENTRY(__kernel_vsyscall);