arch/ia64/kernel/entry.S

   1 /*
   2  * ia64/kernel/entry.S
   3  *
   4  * Kernel entry points.
   5  *
   6  * Copyright (C) 1998-2003 Hewlett-Packard Co
   7  *      David Mosberger-Tang <davidm@hpl.hp.com>
   8  * Copyright (C) 1999, 2002-2003
   9  *      Asit Mallick <Asit.K.Mallick@intel.com>
  10  *      Don Dugger <Don.Dugger@intel.com>
  11  *      Suresh Siddha <suresh.b.siddha@intel.com>
  12  *      Fenghua Yu <fenghua.yu@intel.com>
  13  * Copyright (C) 1999 VA Linux Systems
  14  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  15  */
  16 /*
  17  * ia64_switch_to now places correct virtual mapping in in TR2 for
  18  * kernel stack. This allows us to handle interrupts without changing
  19  * to physical mode.
  20  *
  21  * Jonathan Nicklin     <nicklin@missioncriticallinux.com>
  22  * Patrick O'Rourke     <orourke@missioncriticallinux.com>
  23  * 11/07/2000
  24  */
  25 /*
  26  * Global (preserved) predicate usage on syscall entry/exit path:
  27  *
  28  *      pKStk:          See entry.h.
  29  *      pUStk:          See entry.h.
  30  *      pSys:           See entry.h.
  31  *      pNonSys:        !pSys
  32  */
  33
  34 #include <linux/config.h>
  35
  36 #include <asm/asmmacro.h>
  37 #include <asm/cache.h>
  38 #include <asm/errno.h>
  39 #include <asm/kregs.h>
  40 #include <asm/offsets.h>
  41 #include <asm/pgtable.h>
  42 #include <asm/percpu.h>
  43 #include <asm/processor.h>
  44 #include <asm/thread_info.h>
  45 #include <asm/unistd.h>
  46
  47 #include "minstate.h"
  48
  49         /*
  50          * execve() is special because in case of success, we need to
  51          * setup a null register window frame.
  52          */
  53 ENTRY(ia64_execve)
  54         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(3)
  55         alloc loc1=ar.pfs,3,2,4,0
  56         mov loc0=rp
  57         .body
  58         mov out0=in0                    // filename
  59         ;;                              // stop bit between alloc and call
  60         mov out1=in1                    // argv
  61         mov out2=in2                    // envp
  62         add out3=16,sp                  // regs
  63         br.call.sptk.many rp=sys_execve
  64 .ret0:
  65 #ifdef CONFIG_IA32_SUPPORT
  66         /*
  67          * Check if we're returning to ia32 mode. If so, we need to restore ia32 registers
  68          * from pt_regs.
  69          */
  70         adds r16=PT(CR_IPSR)+16,sp
  71         ;;
  72         ld8 r16=[r16]
  73 #endif
  74         cmp4.ge p6,p7=r8,r0
  75         mov ar.pfs=loc1                 // restore ar.pfs
  76         sxt4 r8=r8                      // return 64-bit result
  77         ;;
  78         stf.spill [sp]=f0
  79 (p6)    cmp.ne pKStk,pUStk=r0,r0        // a successful execve() lands us in user-mode...
  80         mov rp=loc0
  81 (p6)    mov ar.pfs=r0                   // clear ar.pfs on success
  82 (p7)    br.ret.sptk.many rp
  83
  84         /*
  85          * In theory, we'd have to zap this state only to prevent leaking of
  86          * security sensitive state (e.g., if current->mm->dumpable is zero).  However,
  87          * this executes in less than 20 cycles even on Itanium, so it's not worth
  88          * optimizing for...).
  89          */
  90         mov ar.unat=0;          mov ar.lc=0
  91         mov r4=0;               mov f2=f0;              mov b1=r0
  92         mov r5=0;               mov f3=f0;              mov b2=r0
  93         mov r6=0;               mov f4=f0;              mov b3=r0
  94         mov r7=0;               mov f5=f0;              mov b4=r0
  95         ldf.fill f12=[sp];      mov f13=f0;             mov b5=r0
  96         ldf.fill f14=[sp];      ldf.fill f15=[sp];      mov f16=f0
  97         ldf.fill f17=[sp];      ldf.fill f18=[sp];      mov f19=f0
  98         ldf.fill f20=[sp];      ldf.fill f21=[sp];      mov f22=f0
  99         ldf.fill f23=[sp];      ldf.fill f24=[sp];      mov f25=f0
 100         ldf.fill f26=[sp];      ldf.fill f27=[sp];      mov f28=f0
 101         ldf.fill f29=[sp];      ldf.fill f30=[sp];      mov f31=f0
 102 #ifdef CONFIG_IA32_SUPPORT
 103         tbit.nz p6,p0=r16, IA64_PSR_IS_BIT
 104         movl loc0=ia64_ret_from_ia32_execve
 105         ;;
 106 (p6)    mov rp=loc0
 107 #endif
 108         br.ret.sptk.many rp
 109 END(ia64_execve)
 110
 111 /*
 112  * sys_clone2(u64 flags, u64 ustack_base, u64 ustack_size, u64 parent_tidptr, u64 child_tidptr,
 113  *            u64 tls)
 114  */
 115 GLOBAL_ENTRY(sys_clone2)
 116         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(6)
 117         alloc r16=ar.pfs,6,2,6,0
 118         DO_SAVE_SWITCH_STACK
 119         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 120         mov loc0=rp
 121         mov loc1=r16                            // save ar.pfs across do_fork
 122         .body
 123         mov out1=in1
 124         mov out3=in2
 125         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 126         mov out4=in3    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 127         ;;
 128 (p6)    st8 [r2]=in5                            // store TLS in r16 for copy_thread()
 129         mov out5=in4    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 130         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 131         mov out0=in0                            // out0 = clone_flags
 132         br.call.sptk.many rp=do_fork
 133 .ret1:  .restore sp
 134         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 135         mov ar.pfs=loc1
 136         mov rp=loc0
 137         br.ret.sptk.many rp
 138 END(sys_clone2)
 139
 140 /*
 141  * sys_clone(u64 flags, u64 ustack_base, u64 parent_tidptr, u64 child_tidptr, u64 tls)
 142  *      Deprecated.  Use sys_clone2() instead.
 143  */
 144 GLOBAL_ENTRY(sys_clone)
 145         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(5)
 146         alloc r16=ar.pfs,5,2,6,0
 147         DO_SAVE_SWITCH_STACK
 148         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 149         mov loc0=rp
 150         mov loc1=r16                            // save ar.pfs across do_fork
 151         .body
 152         mov out1=in1
 153         mov out3=16                             // stacksize (compensates for 16-byte scratch area)
 154         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 155         mov out4=in2    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 156         ;;
 157 (p6)    st8 [r2]=in4                            // store TLS in r13 (tp)
 158         mov out5=in3    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 159         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 160         mov out0=in0                            // out0 = clone_flags
 161         br.call.sptk.many rp=do_fork
 162 .ret2:  .restore sp
 163         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 164         mov ar.pfs=loc1
 165         mov rp=loc0
 166         br.ret.sptk.many rp
 167 END(sys_clone)
 168
 169 /*
 170  * prev_task <- ia64_switch_to(struct task_struct *next)
 171  *      With Ingo's new scheduler, interrupts are disabled when this routine gets
 172  *      called.  The code starting at .map relies on this.  The rest of the code
 173  *      doesn't care about the interrupt masking status.
 174  */
 175 GLOBAL_ENTRY(ia64_switch_to)
 176         .prologue
 177         alloc r16=ar.pfs,1,0,0,0
 178         DO_SAVE_SWITCH_STACK
 179         .body
 180
 181         adds r22=IA64_TASK_THREAD_KSP_OFFSET,r13
 182         movl r25=init_task
 183         mov r27=IA64_KR(CURRENT_STACK)
 184         adds r21=IA64_TASK_THREAD_KSP_OFFSET,in0
 185         dep r20=0,in0,61,3              // physical address of "next"
 186         ;;
 187         st8 [r22]=sp                    // save kernel stack pointer of old task
 188         shr.u r26=r20,IA64_GRANULE_SHIFT
 189         cmp.eq p7,p6=r25,in0
 190         ;;
 191         /*
 192          * If we've already mapped this task's page, we can skip doing it again.
 193          */
 194 (p6)    cmp.eq p7,p6=r26,r27
 195 (p6)    br.cond.dpnt .map
 196         ;;
 197 .done:
 198 (p6)    ssm psr.ic                      // if we had to map, reenable the psr.ic bit FIRST!!!
 199         ;;
 200 (p6)    srlz.d
 201         ld8 sp=[r21]                    // load kernel stack pointer of new task
 202         mov IA64_KR(CURRENT)=in0        // update "current" application register
 203         mov r8=r13                      // return pointer to previously running task
 204         mov r13=in0                     // set "current" pointer
 205         ;;
 206         DO_LOAD_SWITCH_STACK
 207
 208 #ifdef CONFIG_SMP
 209         sync.i                          // ensure "fc"s done by this CPU are visible on other CPUs
 210 #endif
 211         br.ret.sptk.many rp             // boogie on out in new context
 212
 213 .map:
 214         rsm psr.ic                      // interrupts (psr.i) are already disabled here
 215         movl r25=PAGE_KERNEL
 216         ;;
 217         srlz.d
 218         or r23=r25,r20                  // construct PA | page properties
 219         mov r25=IA64_GRANULE_SHIFT<<2
 220         ;;
 221         mov cr.itir=r25
 222         mov cr.ifa=in0                  // VA of next task...
 223         ;;
 224         mov r25=IA64_TR_CURRENT_STACK
 225         mov IA64_KR(CURRENT_STACK)=r26  // remember last page we mapped...
 226         ;;
 227         itr.d dtr[r25]=r23              // wire in new mapping...
 228         br.cond.sptk .done
 229 END(ia64_switch_to)
 230
 231 /*
 232  * Note that interrupts are enabled during save_switch_stack and load_switch_stack.  This
 233  * means that we may get an interrupt with "sp" pointing to the new kernel stack while
 234  * ar.bspstore is still pointing to the old kernel backing store area.  Since ar.rsc,
 235  * ar.rnat, ar.bsp, and ar.bspstore are all preserved by interrupts, this is not a
 236  * problem.  Also, we don't need to specify unwind information for preserved registers
 237  * that are not modified in save_switch_stack as the right unwind information is already
 238  * specified at the call-site of save_switch_stack.
 239  */
 240
 241 /*
 242  * save_switch_stack:
 243  *      - r16 holds ar.pfs
 244  *      - b7 holds address to return to
 245  *      - rp (b0) holds return address to save
 246  */
 247 GLOBAL_ENTRY(save_switch_stack)
 248         .prologue
 249         .altrp b7
 250         flushrs                 // flush dirty regs to backing store (must be first in insn group)
 251         .save @priunat,r17
 252         mov r17=ar.unat         // preserve caller's
 253         .body
 254 #ifdef CONFIG_ITANIUM
 255         adds r2=16+128,sp
 256         adds r3=16+64,sp
 257         adds r14=SW(R4)+16,sp
 258         ;;
 259         st8.spill [r14]=r4,16           // spill r4
 260         lfetch.fault.excl.nt1 [r3],128
 261         ;;
 262         lfetch.fault.excl.nt1 [r2],128
 263         lfetch.fault.excl.nt1 [r3],128
 264         ;;
 265         lfetch.fault.excl [r2]
 266         lfetch.fault.excl [r3]
 267         adds r15=SW(R5)+16,sp
 268 #else
 269         add r2=16+3*128,sp
 270         add r3=16,sp
 271         add r14=SW(R4)+16,sp
 272         ;;
 273         st8.spill [r14]=r4,SW(R6)-SW(R4)        // spill r4 and prefetch offset 0x1c0
 274         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x010
 275         ;;
 276         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x090
 277         lfetch.fault.excl.nt1 [r2],128  //              prefetch offset 0x190
 278         ;;
 279         lfetch.fault.excl.nt1 [r3]      //              prefetch offset 0x110
 280         lfetch.fault.excl.nt1 [r2]      //              prefetch offset 0x210
 281         adds r15=SW(R5)+16,sp
 282 #endif
 283         ;;
 284         st8.spill [r15]=r5,SW(R7)-SW(R5)        // spill r5
 285         mov.m ar.rsc=0                  // put RSE in mode: enforced lazy, little endian, pl 0
 286         add r2=SW(F2)+16,sp             // r2 = &sw->f2
 287         ;;
 288         st8.spill [r14]=r6,SW(B0)-SW(R6)        // spill r6
 289         mov.m r18=ar.fpsr               // preserve fpsr
 290         add r3=SW(F3)+16,sp             // r3 = &sw->f3
 291         ;;
 292         stf.spill [r2]=f2,32
 293         mov.m r19=ar.rnat
 294         mov r21=b0
 295
 296         stf.spill [r3]=f3,32
 297         st8.spill [r15]=r7,SW(B2)-SW(R7)        // spill r7
 298         mov r22=b1
 299         ;;
 300         // since we're done with the spills, read and save ar.unat:
 301         mov.m r29=ar.unat
 302         mov.m r20=ar.bspstore
 303         mov r23=b2
 304         stf.spill [r2]=f4,32
 305         stf.spill [r3]=f5,32
 306         mov r24=b3
 307         ;;
 308         st8 [r14]=r21,SW(B1)-SW(B0)             // save b0
 309         st8 [r15]=r23,SW(B3)-SW(B2)             // save b2
 310         mov r25=b4
 311         mov r26=b5
 312         ;;
 313         st8 [r14]=r22,SW(B4)-SW(B1)             // save b1
 314         st8 [r15]=r24,SW(AR_PFS)-SW(B3)         // save b3
 315         mov r21=ar.lc           // I-unit
 316         stf.spill [r2]=f12,32
 317         stf.spill [r3]=f13,32
 318         ;;
 319         st8 [r14]=r25,SW(B5)-SW(B4)             // save b4
 320         st8 [r15]=r16,SW(AR_LC)-SW(AR_PFS)      // save ar.pfs
 321         stf.spill [r2]=f14,32
 322         stf.spill [r3]=f15,32
 323         ;;
 324         st8 [r14]=r26                           // save b5
 325         st8 [r15]=r21                           // save ar.lc
 326         stf.spill [r2]=f16,32
 327         stf.spill [r3]=f17,32
 328         ;;
 329         stf.spill [r2]=f18,32
 330         stf.spill [r3]=f19,32
 331         ;;
 332         stf.spill [r2]=f20,32
 333         stf.spill [r3]=f21,32
 334         ;;
 335         stf.spill [r2]=f22,32
 336         stf.spill [r3]=f23,32
 337         ;;
 338         stf.spill [r2]=f24,32
 339         stf.spill [r3]=f25,32
 340         ;;
 341         stf.spill [r2]=f26,32
 342         stf.spill [r3]=f27,32
 343         ;;
 344         stf.spill [r2]=f28,32
 345         stf.spill [r3]=f29,32
 346         ;;
 347         stf.spill [r2]=f30,SW(AR_UNAT)-SW(F30)
 348         stf.spill [r3]=f31,SW(PR)-SW(F31)
 349         add r14=SW(CALLER_UNAT)+16,sp
 350         ;;
 351         st8 [r2]=r29,SW(AR_RNAT)-SW(AR_UNAT)    // save ar.unat
 352         st8 [r14]=r17,SW(AR_FPSR)-SW(CALLER_UNAT) // save caller_unat
 353         mov r21=pr
 354         ;;
 355         st8 [r2]=r19,SW(AR_BSPSTORE)-SW(AR_RNAT) // save ar.rnat
 356         st8 [r3]=r21                            // save predicate registers
 357         ;;
 358         st8 [r2]=r20                            // save ar.bspstore
 359         st8 [r14]=r18                           // save fpsr
 360         mov ar.rsc=3            // put RSE back into eager mode, pl 0
 361         br.cond.sptk.many b7
 362 END(save_switch_stack)
 363
 364 /*
 365  * load_switch_stack:
 366  *      - "invala" MUST be done at call site (normally in DO_LOAD_SWITCH_STACK)
 367  *      - b7 holds address to return to
 368  *      - must not touch r8-r11
 369  */
 370 ENTRY(load_switch_stack)
 371         .prologue
 372         .altrp b7
 373
 374         .body
 375         lfetch.fault.nt1 [sp]
 376         adds r2=SW(AR_BSPSTORE)+16,sp
 377         adds r3=SW(AR_UNAT)+16,sp
 378         mov ar.rsc=0                                            // put RSE into enforced lazy mode
 379         adds r14=SW(CALLER_UNAT)+16,sp
 380         adds r15=SW(AR_FPSR)+16,sp
 381         ;;
 382         ld8 r27=[r2],(SW(B0)-SW(AR_BSPSTORE))   // bspstore
 383         ld8 r29=[r3],(SW(B1)-SW(AR_UNAT))       // unat
 384         ;;
 385         ld8 r21=[r2],16         // restore b0
 386         ld8 r22=[r3],16         // restore b1
 387         ;;
 388         ld8 r23=[r2],16         // restore b2
 389         ld8 r24=[r3],16         // restore b3
 390         ;;
 391         ld8 r25=[r2],16         // restore b4
 392         ld8 r26=[r3],16         // restore b5
 393         ;;
 394         ld8 r16=[r2],(SW(PR)-SW(AR_PFS))        // ar.pfs
 395         ld8 r17=[r3],(SW(AR_RNAT)-SW(AR_LC))    // ar.lc
 396         ;;
 397         ld8 r28=[r2]            // restore pr
 398         ld8 r30=[r3]            // restore rnat
 399         ;;
 400         ld8 r18=[r14],16        // restore caller's unat
 401         ld8 r19=[r15],24        // restore fpsr
 402         ;;
 403         ldf.fill f2=[r14],32
 404         ldf.fill f3=[r15],32
 405         ;;
 406         ldf.fill f4=[r14],32
 407         ldf.fill f5=[r15],32
 408         ;;
 409         ldf.fill f12=[r14],32
 410         ldf.fill f13=[r15],32
 411         ;;
 412         ldf.fill f14=[r14],32
 413         ldf.fill f15=[r15],32
 414         ;;
 415         ldf.fill f16=[r14],32
 416         ldf.fill f17=[r15],32
 417         ;;
 418         ldf.fill f18=[r14],32
 419         ldf.fill f19=[r15],32
 420         mov b0=r21
 421         ;;
 422         ldf.fill f20=[r14],32
 423         ldf.fill f21=[r15],32
 424         mov b1=r22
 425         ;;
 426         ldf.fill f22=[r14],32
 427         ldf.fill f23=[r15],32
 428         mov b2=r23
 429         ;;
 430         mov ar.bspstore=r27
 431         mov ar.unat=r29         // establish unat holding the NaT bits for r4-r7
 432         mov b3=r24
 433         ;;
 434         ldf.fill f24=[r14],32
 435         ldf.fill f25=[r15],32
 436         mov b4=r25
 437         ;;
 438         ldf.fill f26=[r14],32
 439         ldf.fill f27=[r15],32
 440         mov b5=r26
 441         ;;
 442         ldf.fill f28=[r14],32
 443         ldf.fill f29=[r15],32
 444         mov ar.pfs=r16
 445         ;;
 446         ldf.fill f30=[r14],32
 447         ldf.fill f31=[r15],24
 448         mov ar.lc=r17
 449         ;;
 450         ld8.fill r4=[r14],16
 451         ld8.fill r5=[r15],16
 452         mov pr=r28,-1
 453         ;;
 454         ld8.fill r6=[r14],16
 455         ld8.fill r7=[r15],16
 456
 457         mov ar.unat=r18                         // restore caller's unat
 458         mov ar.rnat=r30                         // must restore after bspstore but before rsc!
 459         mov ar.fpsr=r19                         // restore fpsr
 460         mov ar.rsc=3                            // put RSE back into eager mode, pl 0
 461         br.cond.sptk.many b7
 462 END(load_switch_stack)
 463
 464 GLOBAL_ENTRY(__ia64_syscall)
 465         .regstk 6,0,0,0
 466         mov r15=in5                             // put syscall number in place
 467         break __BREAK_SYSCALL
 468         movl r2=errno
 469         cmp.eq p6,p7=-1,r10
 470         ;;
 471 (p6)    st4 [r2]=r8
 472 (p6)    mov r8=-1
 473         br.ret.sptk.many rp
 474 END(__ia64_syscall)
 475
 476 GLOBAL_ENTRY(execve)
 477         mov r15=__NR_execve                     // put syscall number in place
 478         break __BREAK_SYSCALL
 479         br.ret.sptk.many rp
 480 END(execve)
 481
 482 GLOBAL_ENTRY(clone)
 483         mov r15=__NR_clone                      // put syscall number in place
 484         break __BREAK_SYSCALL
 485         br.ret.sptk.many rp
 486 END(clone)
 487
 488         /*
 489          * Invoke a system call, but do some tracing before and after the call.
 490          * We MUST preserve the current register frame throughout this routine
 491          * because some system calls (such as ia64_execve) directly
 492          * manipulate ar.pfs.
 493          */
 494 GLOBAL_ENTRY(ia64_trace_syscall)
 495         PT_REGS_UNWIND_INFO(0)
 496         /*
 497          * We need to preserve the scratch registers f6-f11 in case the system
 498          * call is sigreturn.
 499          */
 500         adds r16=PT(F6)+16,sp
 501         adds r17=PT(F7)+16,sp
 502         ;;
 503         stf.spill [r16]=f6,32
 504         stf.spill [r17]=f7,32
 505         ;;
 506         stf.spill [r16]=f8,32
 507         stf.spill [r17]=f9,32
 508         ;;
 509         stf.spill [r16]=f10
 510         stf.spill [r17]=f11
 511         br.call.sptk.many rp=syscall_trace_enter // give parent a chance to catch syscall args
 512         adds r16=PT(F6)+16,sp
 513         adds r17=PT(F7)+16,sp
 514         ;;
 515         ldf.fill f6=[r16],32
 516         ldf.fill f7=[r17],32
 517         ;;
 518         ldf.fill f8=[r16],32
 519         ldf.fill f9=[r17],32
 520         ;;
 521         ldf.fill f10=[r16]
 522         ldf.fill f11=[r17]
 523         // the syscall number may have changed, so re-load it and re-calculate the
 524         // syscall entry-point:
 525         adds r15=PT(R15)+16,sp                  // r15 = &pt_regs.r15 (syscall #)
 526         ;;
 527         ld8 r15=[r15]
 528         mov r3=NR_syscalls - 1
 529         ;;
 530         adds r15=-1024,r15
 531         movl r16=sys_call_table
 532         ;;
 533         shladd r20=r15,3,r16                    // r20 = sys_call_table + 8*(syscall-1024)
 534         cmp.leu p6,p7=r15,r3
 535         ;;
 536 (p6)    ld8 r20=[r20]                           // load address of syscall entry point
 537 (p7)    movl r20=sys_ni_syscall
 538         ;;
 539         mov b6=r20
 540         br.call.sptk.many rp=b6                 // do the syscall
 541 .strace_check_retval:
 542         cmp.lt p6,p0=r8,r0                      // syscall failed?
 543         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 544         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 545         mov r10=0
 546 (p6)    br.cond.sptk strace_error               // syscall failed ->
 547         ;;                                      // avoid RAW on r10
 548 .strace_save_retval:
 549 .mem.offset 0,0; st8.spill [r2]=r8              // store return value in slot for r8
 550 .mem.offset 8,0; st8.spill [r3]=r10             // clear error indication in slot for r10
 551         br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
 552 .ret3:  br.cond.sptk ia64_leave_syscall
 553
 554 strace_error:
 555         ld8 r3=[r2]                             // load pt_regs.r8
 556         sub r9=0,r8                             // negate return value to get errno value
 557         ;;
 558         cmp.ne p6,p0=r3,r0                      // is pt_regs.r8!=0?
 559         adds r3=16,r2                           // r3=&pt_regs.r10
 560         ;;
 561 (p6)    mov r10=-1
 562 (p6)    mov r8=r9
 563         br.cond.sptk .strace_save_retval
 564 END(ia64_trace_syscall)
 565
 566         /*
 567          * When traced and returning from sigreturn, we invoke syscall_trace but then
 568          * go straight to ia64_leave_kernel rather than ia64_leave_syscall.
 569          */
 570 GLOBAL_ENTRY(ia64_strace_leave_kernel)
 571         PT_REGS_UNWIND_INFO(0)
 572 {       /*
 573          * Some versions of gas generate bad unwind info if the first instruction of a
 574          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 575          */
 576         nop.m 0
 577         nop.i 0
 578         br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
 579 }
 580 .ret4:  br.cond.sptk ia64_leave_kernel
 581 END(ia64_strace_leave_kernel)
 582
 583 GLOBAL_ENTRY(ia64_ret_from_clone)
 584         PT_REGS_UNWIND_INFO(0)
 585 {       /*
 586          * Some versions of gas generate bad unwind info if the first instruction of a
 587          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 588          */
 589         nop.m 0
 590         nop.i 0
 591         /*
 592          * We need to call schedule_tail() to complete the scheduling process.
 593          * Called by ia64_switch_to() after do_fork()->copy_thread().  r8 contains the
 594          * address of the previously executing task.
 595          */
 596         br.call.sptk.many rp=ia64_invoke_schedule_tail
 597 }
 598 .ret8:
 599         adds r2=TI_FLAGS+IA64_TASK_SIZE,r13
 600         ;;
 601         ld4 r2=[r2]
 602         ;;
 603         mov r8=0
 604         and r2=_TIF_SYSCALL_TRACEAUDIT,r2
 605         ;;
 606         cmp.ne p6,p0=r2,r0
 607 (p6)    br.cond.spnt .strace_check_retval
 608         ;;                                      // added stop bits to prevent r8 dependency
 609 END(ia64_ret_from_clone)
 610         // fall through
 611 GLOBAL_ENTRY(ia64_ret_from_syscall)
 612         PT_REGS_UNWIND_INFO(0)
 613         cmp.ge p6,p7=r8,r0                      // syscall executed successfully?
 614         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 615         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 616         ;;
 617 .mem.offset 0,0; (p6) st8.spill [r2]=r8 // store return value in slot for r8 and set unat bit
 618 .mem.offset 8,0; (p6) st8.spill [r3]=r0 // clear error indication in slot for r10 and set unat bit
 619 (p7)    br.cond.spnt handle_syscall_error       // handle potential syscall failure
 620 END(ia64_ret_from_syscall)
 621         // fall through
 622 /*
 623  * ia64_leave_syscall(): Same as ia64_leave_kernel, except that it doesn't
 624  *      need to switch to bank 0 and doesn't restore the scratch registers.
 625  *      To avoid leaking kernel bits, the scratch registers are set to
 626  *      the following known-to-be-safe values:
 627  *
 628  *                r1: restored (global pointer)
 629  *                r2: cleared
 630  *                r3: 1 (when returning to user-level)
 631  *            r8-r11: restored (syscall return value(s))
 632  *               r12: restored (user-level stack pointer)
 633  *               r13: restored (user-level thread pointer)
 634  *               r14: cleared
 635  *               r15: restored (syscall #)
 636  *           r16-r19: cleared
 637  *               r20: user-level ar.fpsr
 638  *               r21: user-level b0
 639  *               r22: user-level b6
 640  *               r23: user-level ar.bspstore
 641  *               r24: user-level ar.rnat
 642  *               r25: user-level ar.unat
 643  *               r26: user-level ar.pfs
 644  *               r27: user-level ar.rsc
 645  *               r28: user-level ip
 646  *               r29: user-level psr
 647  *               r30: user-level cfm
 648  *               r31: user-level pr
 649  *            f6-f11: cleared
 650  *                pr: restored (user-level pr)
 651  *                b0: restored (user-level rp)
 652  *                b6: restored
 653  *                b7: cleared
 654  *           ar.unat: restored (user-level ar.unat)
 655  *            ar.pfs: restored (user-level ar.pfs)
 656  *            ar.rsc: restored (user-level ar.rsc)
 657  *           ar.rnat: restored (user-level ar.rnat)
 658  *       ar.bspstore: restored (user-level ar.bspstore)
 659  *           ar.fpsr: restored (user-level ar.fpsr)
 660  *            ar.ccv: cleared
 661  *            ar.csd: cleared
 662  *            ar.ssd: cleared
 663  */
 664 GLOBAL_ENTRY(ia64_leave_syscall)
 665         PT_REGS_UNWIND_INFO(0)
 666         /*
 667          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 668          * user- or fsys-mode, hence we disable interrupts early on.
 669          *
 670          * p6 controls whether current_thread_info()->flags needs to be check for
 671          * extra work.  We always check for extra work when returning to user-level.
 672          * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
 673          * is 0.  After extra work processing has been completed, execution
 674          * resumes at .work_processed_syscall with p6 set to 1 if the extra-work-check
 675          * needs to be redone.
 676          */
 677 #ifdef CONFIG_PREEMPT
 678         rsm psr.i                               // disable interrupts
 679         cmp.eq pLvSys,p0=r0,r0                  // pLvSys=1: leave from syscall
 680 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 681         ;;
 682         .pred.rel.mutex pUStk,pKStk
 683 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 684 (pUStk) mov r21=0                       // r21 <- 0
 685         ;;
 686         cmp.eq p6,p0=r21,r0             // p6 <- pUStk || (preempt_count == 0)
 687 #else /* !CONFIG_PREEMPT */
 688 (pUStk) rsm psr.i
 689         cmp.eq pLvSys,p0=r0,r0          // pLvSys=1: leave from syscall
 690 (pUStk) cmp.eq.unc p6,p0=r0,r0          // p6 <- pUStk
 691 #endif
 692 .work_processed_syscall:
 693         adds r16=PT(LOADRS)+16,r12
 694         adds r17=PT(AR_BSPSTORE)+16,r12
 695         adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
 696         ;;
 697 (p6)    ld4 r31=[r18]                           // load current_thread_info()->flags
 698         ld8 r19=[r16],PT(B6)-PT(LOADRS)         // load ar.rsc value for "loadrs"
 699         nop.i 0
 700         ;;
 701         ld8 r23=[r17],PT(R9)-PT(AR_BSPSTORE)    // load ar.bspstore (may be garbage)
 702         ld8 r22=[r16],PT(R8)-PT(B6)             // load b6
 703 (p6)    and r15=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 704         ;;
 705
 706         mov.m ar.ccv=r0         // clear ar.ccv
 707 (p6)    cmp4.ne.unc p6,p0=r15, r0               // any special work pending?
 708 (p6)    br.cond.spnt .work_pending
 709         ;;
 710         // start restoring the state saved on the kernel stack (struct pt_regs):
 711         ld8.fill r8=[r16],16
 712         ld8.fill r9=[r17],16
 713         mov f6=f0               // clear f6
 714         ;;
 715         ld8.fill r10=[r16],16
 716         ld8.fill r11=[r17],16
 717         mov f7=f0               // clear f7
 718         ;;
 719         ld8 r29=[r16],16        // load cr.ipsr
 720         ld8 r28=[r17],16        // load cr.iip
 721         mov f8=f0               // clear f8
 722         ;;
 723         ld8 r30=[r16],16        // load cr.ifs
 724         ld8 r25=[r17],16        // load ar.unat
 725         cmp.eq p9,p0=r0,r0      // set p9 to indicate that we should restore cr.ifs
 726         ;;
 727         rsm psr.i | psr.ic      // initiate turning off of interrupt and interruption collection
 728         invala                  // invalidate ALAT
 729         mov f9=f0               // clear f9
 730
 731         mov.m ar.ssd=r0         // clear ar.ssd
 732         mov.m ar.csd=r0         // clear ar.csd
 733         mov f10=f0              // clear f10
 734         ;;
 735         ld8 r26=[r16],16        // load ar.pfs
 736         ld8 r27=[r17],PT(PR)-PT(AR_RSC) // load ar.rsc
 737         mov f11=f0              // clear f11
 738         ;;
 739         ld8 r24=[r16],PT(B0)-PT(AR_RNAT)        // load ar.rnat (may be garbage)
 740         ld8 r31=[r17],PT(R1)-PT(PR)             // load predicates
 741 (pUStk) add r14=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
 742         ;;
 743         ld8 r21=[r16],PT(R12)-PT(B0) // load b0
 744         ld8.fill r1=[r17],16    // load r1
 745 (pUStk) mov r3=1
 746         ;;
 747         ld8.fill r12=[r16],16
 748         ld8.fill r13=[r17],16
 749         mov r2=r0               // clear r2
 750         ;;
 751         ld8 r20=[r16]           // load ar.fpsr
 752         ld8.fill r15=[r17]      // load r15
 753         mov b7=r0               // clear b7
 754         ;;
 755 (pUStk) st1 [r14]=r3
 756         addl r17=THIS_CPU(ia64_phys_stacked_size_p8),r0
 757         ;;
 758         mov r16=ar.bsp          // get existing backing store pointer
 759         srlz.i                  // ensure interruption collection is off
 760         mov r14=r0              // clear r14
 761         ;;
 762         ld4 r17=[r17]           // r17 = cpu_data->phys_stacked_size_p8
 763         mov b6=r22                              // restore b6
 764         shr.u r18=r19,16        // get byte size of existing "dirty" partition
 765 (pKStk) br.cond.dpnt.many skip_rbs_switch
 766 (pNonSys) br.cond.dpnt.many dont_preserve_current_frame
 767         br.cond.sptk.many rbs_switch
 768 END(ia64_leave_syscall)
 769
 770 #ifdef CONFIG_IA32_SUPPORT
 771 GLOBAL_ENTRY(ia64_ret_from_ia32_execve)
 772         PT_REGS_UNWIND_INFO(0)
 773         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 774         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 775         ;;
 776         .mem.offset 0,0
 777         st8.spill [r2]=r8       // store return value in slot for r8 and set unat bit
 778         .mem.offset 8,0
 779         st8.spill [r3]=r0       // clear error indication in slot for r10 and set unat bit
 780 END(ia64_ret_from_ia32_execve_syscall)
 781         // fall through
 782 #endif /* CONFIG_IA32_SUPPORT */
 783 GLOBAL_ENTRY(ia64_leave_kernel)
 784         PT_REGS_UNWIND_INFO(0)
 785         /*
 786          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 787          * user- or fsys-mode, hence we disable interrupts early on.
 788          *
 789          * p6 controls whether current_thread_info()->flags needs to be check for
 790          * extra work.  We always check for extra work when returning to user-level.
 791          * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
 792          * is 0.  After extra work processing has been completed, execution
 793          * resumes at .work_processed_syscall with p6 set to 1 if the extra-work-check
 794          * needs to be redone.
 795          */
 796 #ifdef CONFIG_PREEMPT
 797         rsm psr.i                               // disable interrupts
 798         cmp.eq p0,pLvSys=r0,r0                  // pLvSys=0: leave from kernel
 799 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 800         ;;
 801         .pred.rel.mutex pUStk,pKStk
 802 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 803 (pUStk) mov r21=0                       // r21 <- 0
 804         ;;
 805         cmp.eq p6,p0=r21,r0             // p6 <- pUStk || (preempt_count == 0)
 806 #else
 807 (pUStk) rsm psr.i
 808         cmp.eq p0,pLvSys=r0,r0          // pLvSys=0: leave from kernel
 809 (pUStk) cmp.eq.unc p6,p0=r0,r0          // p6 <- pUStk
 810 #endif
 811 .work_processed_kernel:
 812         adds r17=TI_FLAGS+IA64_TASK_SIZE,r13
 813         ;;
 814 (p6)    ld4 r31=[r17]                           // load current_thread_info()->flags
 815         adds r21=PT(PR)+16,r12
 816         ;;
 817
 818         lfetch [r21],PT(CR_IPSR)-PT(PR)
 819         adds r2=PT(B6)+16,r12
 820         adds r3=PT(R16)+16,r12
 821         ;;
 822         lfetch [r21]
 823         ld8 r28=[r2],8          // load b6
 824         adds r29=PT(R24)+16,r12
 825
 826         ld8.fill r16=[r3],PT(AR_CSD)-PT(R16)
 827         adds r30=PT(AR_CCV)+16,r12
 828 (p6)    and r19=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 829         ;;
 830         ld8.fill r24=[r29]
 831         ld8 r15=[r30]           // load ar.ccv
 832 (p6)    cmp4.ne.unc p6,p0=r19, r0               // any special work pending?
 833         ;;
 834         ld8 r29=[r2],16         // load b7
 835         ld8 r30=[r3],16         // load ar.csd
 836 (p6)    br.cond.spnt .work_pending
 837         ;;
 838         ld8 r31=[r2],16         // load ar.ssd
 839         ld8.fill r8=[r3],16
 840         ;;
 841         ld8.fill r9=[r2],16
 842         ld8.fill r10=[r3],PT(R17)-PT(R10)
 843         ;;
 844         ld8.fill r11=[r2],PT(R18)-PT(R11)
 845         ld8.fill r17=[r3],16
 846         ;;
 847         ld8.fill r18=[r2],16
 848         ld8.fill r19=[r3],16
 849         ;;
 850         ld8.fill r20=[r2],16
 851         ld8.fill r21=[r3],16
 852         mov ar.csd=r30
 853         mov ar.ssd=r31
 854         ;;
 855         rsm psr.i | psr.ic      // initiate turning off of interrupt and interruption collection
 856         invala                  // invalidate ALAT
 857         ;;
 858         ld8.fill r22=[r2],24
 859         ld8.fill r23=[r3],24
 860         mov b6=r28
 861         ;;
 862         ld8.fill r25=[r2],16
 863         ld8.fill r26=[r3],16
 864         mov b7=r29
 865         ;;
 866         ld8.fill r27=[r2],16
 867         ld8.fill r28=[r3],16
 868         ;;
 869         ld8.fill r29=[r2],16
 870         ld8.fill r30=[r3],24
 871         ;;
 872         ld8.fill r31=[r2],PT(F9)-PT(R31)
 873         adds r3=PT(F10)-PT(F6),r3
 874         ;;
 875         ldf.fill f9=[r2],PT(F6)-PT(F9)
 876         ldf.fill f10=[r3],PT(F8)-PT(F10)
 877         ;;
 878         ldf.fill f6=[r2],PT(F7)-PT(F6)
 879         ;;
 880         ldf.fill f7=[r2],PT(F11)-PT(F7)
 881         ldf.fill f8=[r3],32
 882         ;;
 883         srlz.i                  // ensure interruption collection is off
 884         mov ar.ccv=r15
 885         ;;
 886         bsw.0                   // switch back to bank 0 (no stop bit required beforehand...)
 887         ;;
 888         ldf.fill f11=[r2]
 889 (pUStk) mov r18=IA64_KR(CURRENT)        // Itanium 2: 12 cycle read latency
 890         adds r16=PT(CR_IPSR)+16,r12
 891         adds r17=PT(CR_IIP)+16,r12
 892         ;;
 893         ld8 r29=[r16],16        // load cr.ipsr
 894         ld8 r28=[r17],16        // load cr.iip
 895         ;;
 896         ld8 r30=[r16],16        // load cr.ifs
 897         ld8 r25=[r17],16        // load ar.unat
 898         ;;
 899         ld8 r26=[r16],16        // load ar.pfs
 900         ld8 r27=[r17],16        // load ar.rsc
 901         cmp.eq p9,p0=r0,r0      // set p9 to indicate that we should restore cr.ifs
 902         ;;
 903         ld8 r24=[r16],16        // load ar.rnat (may be garbage)
 904         ld8 r23=[r17],16// load ar.bspstore (may be garbage)
 905         ;;
 906         ld8 r31=[r16],16        // load predicates
 907         ld8 r21=[r17],16        // load b0
 908         ;;
 909         ld8 r19=[r16],16        // load ar.rsc value for "loadrs"
 910         ld8.fill r1=[r17],16    // load r1
 911         ;;
 912         ld8.fill r12=[r16],16
 913         ld8.fill r13=[r17],16
 914 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18
 915         ;;
 916         ld8 r20=[r16],16        // ar.fpsr
 917         ld8.fill r15=[r17],16
 918         ;;
 919         ld8.fill r14=[r16],16
 920         ld8.fill r2=[r17]
 921 (pUStk) mov r17=1
 922         ;;
 923         ld8.fill r3=[r16]
 924 (pUStk) st1 [r18]=r17           // restore current->thread.on_ustack
 925         shr.u r18=r19,16        // get byte size of existing "dirty" partition
 926         ;;
 927         mov r16=ar.bsp          // get existing backing store pointer
 928         addl r17=THIS_CPU(ia64_phys_stacked_size_p8),r0
 929         ;;
 930         ld4 r17=[r17]           // r17 = cpu_data->phys_stacked_size_p8
 931 (pKStk) br.cond.dpnt skip_rbs_switch
 932
 933         /*
 934          * Restore user backing store.
 935          *
 936          * NOTE: alloc, loadrs, and cover can't be predicated.
 937          */
 938 (pNonSys) br.cond.dpnt dont_preserve_current_frame
 939
 940 rbs_switch:
 941         cover                           // add current frame into dirty partition and set cr.ifs
 942         ;;
 943         mov r19=ar.bsp                  // get new backing store pointer
 944         sub r16=r16,r18                 // krbs = old bsp - size of dirty partition
 945         cmp.ne p9,p0=r0,r0              // clear p9 to skip restore of cr.ifs
 946         ;;
 947         sub r19=r19,r16                 // calculate total byte size of dirty partition
 948         add r18=64,r18                  // don't force in0-in7 into memory...
 949         ;;
 950         shl r19=r19,16                  // shift size of dirty partition into loadrs position
 951         ;;
 952 dont_preserve_current_frame:
 953         /*
 954          * To prevent leaking bits between the kernel and user-space,
 955          * we must clear the stacked registers in the "invalid" partition here.
 956          * Not pretty, but at least it's fast (3.34 registers/cycle on Itanium,
 957          * 5 registers/cycle on McKinley).
 958          */
 959 #       define pRecurse p6
 960 #       define pReturn  p7
 961 #ifdef CONFIG_ITANIUM
 962 #       define Nregs    10
 963 #else
 964 #       define Nregs    14
 965 #endif
 966         alloc loc0=ar.pfs,2,Nregs-2,2,0
 967         shr.u loc1=r18,9                // RNaTslots <= floor(dirtySize / (64*8))
 968         sub r17=r17,r18                 // r17 = (physStackedSize + 8) - dirtySize
 969         ;;
 970         mov ar.rsc=r19                  // load ar.rsc to be used for "loadrs"
 971         shladd in0=loc1,3,r17
 972         mov in1=0
 973         ;;
 974 rse_clear_invalid:
 975 #ifdef CONFIG_ITANIUM
 976         // cycle 0
 977  { .mii
 978         alloc loc0=ar.pfs,2,Nregs-2,2,0
 979         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
 980         add out0=-Nregs*8,in0
 981 }{ .mfb
 982         add out1=1,in1                  // increment recursion count
 983         nop.f 0
 984         nop.b 0                         // can't do br.call here because of alloc (WAW on CFM)
 985         ;;
 986 }{ .mfi // cycle 1
 987         mov loc1=0
 988         nop.f 0
 989         mov loc2=0
 990 }{ .mib
 991         mov loc3=0
 992         mov loc4=0
 993 (pRecurse) br.call.sptk.many b0=rse_clear_invalid
 994
 995 }{ .mfi // cycle 2
 996         mov loc5=0
 997         nop.f 0
 998         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
 999 }{ .mib
1000         mov loc6=0
1001         mov loc7=0
1002 (pReturn) br.ret.sptk.many b0
1003 }
1004 #else /* !CONFIG_ITANIUM */
1005         alloc loc0=ar.pfs,2,Nregs-2,2,0
1006         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
1007         add out0=-Nregs*8,in0
1008         add out1=1,in1                  // increment recursion count
1009         mov loc1=0
1010         mov loc2=0
1011         ;;
1012         mov loc3=0
1013         mov loc4=0
1014         mov loc5=0
1015         mov loc6=0
1016         mov loc7=0
1017 (pRecurse) br.call.sptk.few b0=rse_clear_invalid
1018         ;;
1019         mov loc8=0
1020         mov loc9=0
1021         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
1022         mov loc10=0
1023         mov loc11=0
1024 (pReturn) br.ret.sptk.many b0
1025 #endif /* !CONFIG_ITANIUM */
1026 #       undef pRecurse
1027 #       undef pReturn
1028         ;;
1029         alloc r17=ar.pfs,0,0,0,0        // drop current register frame
1030         ;;
1031         loadrs
1032         ;;
1033 skip_rbs_switch:
1034 (pLvSys)        mov r19=r0              // clear r19 for leave_syscall, no-op otherwise
1035         mov b0=r21
1036         mov ar.pfs=r26
1037 (pUStk) mov ar.bspstore=r23
1038 (p9)    mov cr.ifs=r30
1039 (pLvSys)mov r16=r0              // clear r16 for leave_syscall, no-op otherwise
1040         mov cr.ipsr=r29
1041         mov ar.fpsr=r20
1042 (pLvSys)mov r17=r0              // clear r17 for leave_syscall, no-op otherwise
1043         mov cr.iip=r28
1044         ;;
1045 (pUStk) mov ar.rnat=r24         // must happen with RSE in lazy mode
1046 (pLvSys)mov r18=r0              // clear r18 for leave_syscall, no-op otherwise
1047         mov ar.rsc=r27
1048         mov ar.unat=r25
1049         mov pr=r31,-1
1050         rfi
1051
1052         /*
1053          * On entry:
1054          *      r20 = &current->thread_info->pre_count (if CONFIG_PREEMPT)
1055          *      r31 = current->thread_info->flags
1056          * On exit:
1057          *      p6 = TRUE if work-pending-check needs to be redone
1058          */
1059 .work_pending:
1060         tbit.z p6,p0=r31,TIF_NEED_RESCHED               // current_thread_info()->need_resched==0?
1061 (p6)    br.cond.sptk.few .notify
1062 #ifdef CONFIG_PREEMPT
1063 (pKStk) dep r21=-1,r0,PREEMPT_ACTIVE_BIT,1
1064         ;;
1065 (pKStk) st4 [r20]=r21
1066         ssm psr.i               // enable interrupts
1067 #endif
1068         br.call.spnt.many rp=schedule
1069 .ret9:  cmp.eq p6,p0=r0,r0                              // p6 <- 1
1070         rsm psr.i               // disable interrupts
1071         ;;
1072 #ifdef CONFIG_PREEMPT
1073 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
1074         ;;
1075 (pKStk) st4 [r20]=r0            // preempt_count() <- 0
1076 #endif
1077 (pLvSys)br.cond.sptk.many .work_processed_syscall       // re-check
1078         br.cond.sptk.many .work_processed_kernel        // re-check
1079
1080 .notify:
1081 (pUStk) br.call.spnt.many rp=notify_resume_user
1082 .ret10: cmp.ne p6,p0=r0,r0                              // p6 <- 0
1083 (pLvSys)br.cond.sptk.many .work_processed_syscall       // don't re-check
1084         br.cond.sptk.many .work_processed_kernel        // don't re-check
1085 END(ia64_leave_kernel)
1086
1087 ENTRY(handle_syscall_error)
1088         /*
1089          * Some system calls (e.g., ptrace, mmap) can return arbitrary values which could
1090          * lead us to mistake a negative return value as a failed syscall.  Those syscall
1091          * must deposit a non-zero value in pt_regs.r8 to indicate an error.  If
1092          * pt_regs.r8 is zero, we assume that the call completed successfully.
1093          */
1094         PT_REGS_UNWIND_INFO(0)
1095         ld8 r3=[r2]             // load pt_regs.r8
1096         sub r9=0,r8             // negate return value to get errno
1097         ;;
1098         mov r10=-1              // return -1 in pt_regs.r10 to indicate error
1099         cmp.eq p6,p7=r3,r0      // is pt_regs.r8==0?
1100         adds r3=16,r2           // r3=&pt_regs.r10
1101         ;;
1102 (p6)    mov r9=r8
1103 (p6)    mov r10=0
1104         ;;
1105 .mem.offset 0,0; st8.spill [r2]=r9      // store errno in pt_regs.r8 and set unat bit
1106 .mem.offset 8,0; st8.spill [r3]=r10     // store error indication in pt_regs.r10 and set unat bit
1107         br.cond.sptk ia64_leave_syscall
1108 END(handle_syscall_error)
1109
1110         /*
1111          * Invoke schedule_tail(task) while preserving in0-in7, which may be needed
1112          * in case a system call gets restarted.
1113          */
1114 GLOBAL_ENTRY(ia64_invoke_schedule_tail)
1115         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1116         alloc loc1=ar.pfs,8,2,1,0
1117         mov loc0=rp
1118         mov out0=r8                             // Address of previous task
1119         ;;
1120         br.call.sptk.many rp=schedule_tail
1121 .ret11: mov ar.pfs=loc1
1122         mov rp=loc0
1123         br.ret.sptk.many rp
1124 END(ia64_invoke_schedule_tail)
1125
1126         /*
1127          * Setup stack and call do_notify_resume_user().  Note that pSys and pNonSys need to
1128          * be set up by the caller.  We declare 8 input registers so the system call
1129          * args get preserved, in case we need to restart a system call.
1130          */
1131 ENTRY(notify_resume_user)
1132         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1133         alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1134         mov r9=ar.unat
1135         mov loc0=rp                             // save return address
1136         mov out0=0                              // there is no "oldset"
1137         adds out1=8,sp                          // out1=&sigscratch->ar_pfs
1138 (pSys)  mov out2=1                              // out2==1 => we're in a syscall
1139         ;;
1140 (pNonSys) mov out2=0                            // out2==0 => not a syscall
1141         .fframe 16
1142         .spillpsp ar.unat, 16                   // (note that offset is relative to psp+0x10!)
1143         st8 [sp]=r9,-16                         // allocate space for ar.unat and save it
1144         st8 [out1]=loc1,-8                      // save ar.pfs, out1=&sigscratch
1145         .body
1146         br.call.sptk.many rp=do_notify_resume_user
1147 .ret15: .restore sp
1148         adds sp=16,sp                           // pop scratch stack space
1149         ;;
1150         ld8 r9=[sp]                             // load new unat from sigscratch->scratch_unat
1151         mov rp=loc0
1152         ;;
1153         mov ar.unat=r9
1154         mov ar.pfs=loc1
1155         br.ret.sptk.many rp
1156 END(notify_resume_user)
1157
1158 GLOBAL_ENTRY(sys_rt_sigsuspend)
1159         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1160         alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1161         mov r9=ar.unat
1162         mov loc0=rp                             // save return address
1163         mov out0=in0                            // mask
1164         mov out1=in1                            // sigsetsize
1165         adds out2=8,sp                          // out2=&sigscratch->ar_pfs
1166         ;;
1167         .fframe 16
1168         .spillpsp ar.unat, 16                   // (note that offset is relative to psp+0x10!)
1169         st8 [sp]=r9,-16                         // allocate space for ar.unat and save it
1170         st8 [out2]=loc1,-8                      // save ar.pfs, out2=&sigscratch
1171         .body
1172         br.call.sptk.many rp=ia64_rt_sigsuspend
1173 .ret17: .restore sp
1174         adds sp=16,sp                           // pop scratch stack space
1175         ;;
1176         ld8 r9=[sp]                             // load new unat from sw->caller_unat
1177         mov rp=loc0
1178         ;;
1179         mov ar.unat=r9
1180         mov ar.pfs=loc1
1181         br.ret.sptk.many rp
1182 END(sys_rt_sigsuspend)
1183
1184 ENTRY(sys_rt_sigreturn)
1185         PT_REGS_UNWIND_INFO(0)
1186         alloc r2=ar.pfs,0,0,1,0
1187         .prologue
1188         PT_REGS_SAVES(16)
1189         adds sp=-16,sp
1190         .body
1191         cmp.eq pNonSys,pSys=r0,r0               // sigreturn isn't a normal syscall...
1192         ;;
1193         /*
1194          * leave_kernel() restores f6-f11 from pt_regs, but since the streamlined
1195          * syscall-entry path does not save them we save them here instead.  Note: we
1196          * don't need to save any other registers that are not saved by the stream-lined
1197          * syscall path, because restore_sigcontext() restores them.
1198          */
1199         adds r16=PT(F6)+32,sp
1200         adds r17=PT(F7)+32,sp
1201         ;;
1202         stf.spill [r16]=f6,32
1203         stf.spill [r17]=f7,32
1204         ;;
1205         stf.spill [r16]=f8,32
1206         stf.spill [r17]=f9,32
1207         ;;
1208         stf.spill [r16]=f10
1209         stf.spill [r17]=f11
1210         adds out0=16,sp                         // out0 = &sigscratch
1211         br.call.sptk.many rp=ia64_rt_sigreturn
1212 .ret19: .restore sp 0
1213         adds sp=16,sp
1214         ;;
1215         ld8 r9=[sp]                             // load new ar.unat
1216         mov.sptk b7=r8,ia64_leave_kernel
1217         ;;
1218         mov ar.unat=r9
1219         br.many b7
1220 END(sys_rt_sigreturn)
1221
1222 GLOBAL_ENTRY(ia64_prepare_handle_unaligned)
1223         .prologue
1224         /*
1225          * r16 = fake ar.pfs, we simply need to make sure privilege is still 0
1226          */
1227         mov r16=r0
1228         DO_SAVE_SWITCH_STACK
1229         br.call.sptk.many rp=ia64_handle_unaligned      // stack frame setup in ivt
1230 .ret21: .body
1231         DO_LOAD_SWITCH_STACK
1232         br.cond.sptk.many rp                            // goes to ia64_leave_kernel
1233 END(ia64_prepare_handle_unaligned)
1234
1235         //
1236         // unw_init_running(void (*callback)(info, arg), void *arg)
1237         //
1238 #       define EXTRA_FRAME_SIZE ((UNW_FRAME_INFO_SIZE+15)&~15)
1239
1240 GLOBAL_ENTRY(unw_init_running)
1241         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1242         alloc loc1=ar.pfs,2,3,3,0
1243         ;;
1244         ld8 loc2=[in0],8
1245         mov loc0=rp
1246         mov r16=loc1
1247         DO_SAVE_SWITCH_STACK
1248         .body
1249
1250         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1251         .fframe IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE
1252         SWITCH_STACK_SAVES(EXTRA_FRAME_SIZE)
1253         adds sp=-EXTRA_FRAME_SIZE,sp
1254         .body
1255         ;;
1256         adds out0=16,sp                         // &info
1257         mov out1=r13                            // current
1258         adds out2=16+EXTRA_FRAME_SIZE,sp        // &switch_stack
1259         br.call.sptk.many rp=unw_init_frame_info
1260 1:      adds out0=16,sp                         // &info
1261         mov b6=loc2
1262         mov loc2=gp                             // save gp across indirect function call
1263         ;;
1264         ld8 gp=[in0]
1265         mov out1=in1                            // arg
1266         br.call.sptk.many rp=b6                 // invoke the callback function
1267 1:      mov gp=loc2                             // restore gp
1268
1269         // For now, we don't allow changing registers from within
1270         // unw_init_running; if we ever want to allow that, we'd
1271         // have to do a load_switch_stack here:
1272         .restore sp
1273         adds sp=IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE,sp
1274
1275         mov ar.pfs=loc1
1276         mov rp=loc0
1277         br.ret.sptk.many rp
1278 END(unw_init_running)
1279
1280         .rodata
1281         .align 8
1282         .globl sys_call_table
1283 sys_call_table:
1284         data8 sys_ni_syscall            //  This must be sys_ni_syscall!  See ivt.S.
1285         data8 sys_exit                          // 1025
1286         data8 sys_read
1287         data8 sys_write
1288         data8 sys_open
1289         data8 sys_close
1290         data8 sys_creat                         // 1030
1291         data8 sys_link
1292         data8 sys_unlink
1293         data8 ia64_execve
1294         data8 sys_chdir
1295         data8 sys_fchdir                        // 1035
1296         data8 sys_utimes
1297         data8 sys_mknod
1298         data8 sys_chmod
1299         data8 sys_chown
1300         data8 sys_lseek                         // 1040
1301         data8 sys_getpid
1302         data8 sys_getppid
1303         data8 sys_mount
1304         data8 sys_umount
1305         data8 sys_setuid                        // 1045
1306         data8 sys_getuid
1307         data8 sys_geteuid
1308         data8 sys_ptrace
1309         data8 sys_access
1310         data8 sys_sync                          // 1050
1311         data8 sys_fsync
1312         data8 sys_fdatasync
1313         data8 sys_kill
1314         data8 sys_rename
1315         data8 sys_mkdir                         // 1055
1316         data8 sys_rmdir
1317         data8 sys_dup
1318         data8 sys_pipe
1319         data8 sys_times
1320         data8 ia64_brk                          // 1060
1321         data8 sys_setgid
1322         data8 sys_getgid
1323         data8 sys_getegid
1324         data8 sys_acct
1325         data8 sys_ioctl                         // 1065
1326         data8 sys_fcntl
1327         data8 sys_umask
1328         data8 sys_chroot
1329         data8 sys_ustat
1330         data8 sys_dup2                          // 1070
1331         data8 sys_setreuid
1332         data8 sys_setregid
1333         data8 sys_getresuid
1334         data8 sys_setresuid
1335         data8 sys_getresgid                     // 1075
1336         data8 sys_setresgid
1337         data8 sys_getgroups
1338         data8 sys_setgroups
1339         data8 sys_getpgid
1340         data8 sys_setpgid                       // 1080
1341         data8 sys_setsid
1342         data8 sys_getsid
1343         data8 sys_sethostname
1344         data8 sys_setrlimit
1345         data8 sys_getrlimit                     // 1085
1346         data8 sys_getrusage
1347         data8 sys_gettimeofday
1348         data8 sys_settimeofday
1349         data8 sys_select
1350         data8 sys_poll                          // 1090
1351         data8 sys_symlink
1352         data8 sys_readlink
1353         data8 sys_uselib
1354         data8 sys_swapon
1355         data8 sys_swapoff                       // 1095
1356         data8 sys_reboot
1357         data8 sys_truncate
1358         data8 sys_ftruncate
1359         data8 sys_fchmod
1360         data8 sys_fchown                        // 1100
1361         data8 ia64_getpriority
1362         data8 sys_setpriority
1363         data8 sys_statfs
1364         data8 sys_fstatfs
1365         data8 sys_gettid                        // 1105
1366         data8 sys_semget
1367         data8 sys_semop
1368         data8 sys_semctl
1369         data8 sys_msgget
1370         data8 sys_msgsnd                        // 1110
1371         data8 sys_msgrcv
1372         data8 sys_msgctl
1373         data8 sys_shmget
1374         data8 ia64_shmat
1375         data8 sys_shmdt                         // 1115
1376         data8 sys_shmctl
1377         data8 sys_syslog
1378         data8 sys_setitimer
1379         data8 sys_getitimer
1380         data8 sys_ni_syscall                    // 1120         /* was: ia64_oldstat */
1381         data8 sys_ni_syscall                                    /* was: ia64_oldlstat */
1382         data8 sys_ni_syscall                                    /* was: ia64_oldfstat */
1383         data8 sys_vhangup
1384         data8 sys_lchown
1385         data8 sys_remap_file_pages              // 1125
1386         data8 sys_wait4
1387         data8 sys_sysinfo
1388         data8 sys_clone
1389         data8 sys_setdomainname
1390         data8 sys_newuname                      // 1130
1391         data8 sys_adjtimex
1392         data8 sys_ni_syscall                                    /* was: ia64_create_module */
1393         data8 sys_init_module
1394         data8 sys_delete_module
1395         data8 sys_ni_syscall                    // 1135         /* was: sys_get_kernel_syms */
1396         data8 sys_ni_syscall                                    /* was: sys_query_module */
1397         data8 sys_quotactl
1398         data8 sys_bdflush
1399         data8 sys_sysfs
1400         data8 sys_personality                   // 1140
1401         data8 sys_ni_syscall            // sys_afs_syscall
1402         data8 sys_setfsuid
1403         data8 sys_setfsgid
1404         data8 sys_getdents
1405         data8 sys_flock                         // 1145
1406         data8 sys_readv
1407         data8 sys_writev
1408         data8 sys_pread64
1409         data8 sys_pwrite64
1410         data8 sys_sysctl                        // 1150
1411         data8 sys_mmap
1412         data8 sys_munmap
1413         data8 sys_mlock
1414         data8 sys_mlockall
1415         data8 sys_mprotect                      // 1155
1416         data8 ia64_mremap
1417         data8 sys_msync
1418         data8 sys_munlock
1419         data8 sys_munlockall
1420         data8 sys_sched_getparam                // 1160
1421         data8 sys_sched_setparam
1422         data8 sys_sched_getscheduler
1423         data8 sys_sched_setscheduler
1424         data8 sys_sched_yield
1425         data8 sys_sched_get_priority_max        // 1165
1426         data8 sys_sched_get_priority_min
1427         data8 sys_sched_rr_get_interval
1428         data8 sys_nanosleep
1429         data8 sys_nfsservctl
1430         data8 sys_prctl                         // 1170
1431         data8 sys_getpagesize
1432         data8 sys_mmap2
1433         data8 sys_pciconfig_read
1434         data8 sys_pciconfig_write
1435         data8 sys_perfmonctl                    // 1175
1436         data8 sys_sigaltstack
1437         data8 sys_rt_sigaction
1438         data8 sys_rt_sigpending
1439         data8 sys_rt_sigprocmask
1440         data8 sys_rt_sigqueueinfo               // 1180
1441         data8 sys_rt_sigreturn
1442         data8 sys_rt_sigsuspend
1443         data8 sys_rt_sigtimedwait
1444         data8 sys_getcwd
1445         data8 sys_capget                        // 1185
1446         data8 sys_capset
1447         data8 sys_sendfile64
1448         data8 sys_ni_syscall            // sys_getpmsg (STREAMS)
1449         data8 sys_ni_syscall            // sys_putpmsg (STREAMS)
1450         data8 sys_socket                        // 1190
1451         data8 sys_bind
1452         data8 sys_connect
1453         data8 sys_listen
1454         data8 sys_accept
1455         data8 sys_getsockname                   // 1195
1456         data8 sys_getpeername
1457         data8 sys_socketpair
1458         data8 sys_send
1459         data8 sys_sendto
1460         data8 sys_recv                          // 1200
1461         data8 sys_recvfrom
1462         data8 sys_shutdown
1463         data8 sys_setsockopt
1464         data8 sys_getsockopt
1465         data8 sys_sendmsg                       // 1205
1466         data8 sys_recvmsg
1467         data8 sys_pivot_root
1468         data8 sys_mincore
1469         data8 sys_madvise
1470         data8 sys_newstat                       // 1210
1471         data8 sys_newlstat
1472         data8 sys_newfstat
1473         data8 sys_clone2
1474         data8 sys_getdents64
1475         data8 sys_getunwind                     // 1215
1476         data8 sys_readahead
1477         data8 sys_setxattr
1478         data8 sys_lsetxattr
1479         data8 sys_fsetxattr
1480         data8 sys_getxattr                      // 1220
1481         data8 sys_lgetxattr
1482         data8 sys_fgetxattr
1483         data8 sys_listxattr
1484         data8 sys_llistxattr
1485         data8 sys_flistxattr                    // 1225
1486         data8 sys_removexattr
1487         data8 sys_lremovexattr
1488         data8 sys_fremovexattr
1489         data8 sys_tkill
1490         data8 sys_futex                         // 1230
1491         data8 sys_sched_setaffinity
1492         data8 sys_sched_getaffinity
1493         data8 sys_set_tid_address
1494         data8 sys_fadvise64_64
1495         data8 sys_tgkill                        // 1235
1496         data8 sys_exit_group
1497         data8 sys_lookup_dcookie
1498         data8 sys_io_setup
1499         data8 sys_io_destroy
1500         data8 sys_io_getevents                  // 1240
1501         data8 sys_io_submit
1502         data8 sys_io_cancel
1503         data8 sys_epoll_create
1504         data8 sys_epoll_ctl
1505         data8 sys_epoll_wait                    // 1245
1506         data8 sys_restart_syscall
1507         data8 sys_semtimedop
1508         data8 sys_timer_create
1509         data8 sys_timer_settime
1510         data8 sys_timer_gettime                 // 1250
1511         data8 sys_timer_getoverrun
1512         data8 sys_timer_delete
1513         data8 sys_clock_settime
1514         data8 sys_clock_gettime
1515         data8 sys_clock_getres                  // 1255
1516         data8 sys_clock_nanosleep
1517         data8 sys_fstatfs64
1518         data8 sys_statfs64
1519         data8 sys_mbind
1520         data8 sys_get_mempolicy                 // 1260
1521         data8 sys_set_mempolicy
1522         data8 sys_mq_open
1523         data8 sys_mq_unlink
1524         data8 sys_mq_timedsend
1525         data8 sys_mq_timedreceive               // 1265
1526         data8 sys_mq_notify
1527         data8 sys_mq_getsetattr
1528         data8 sys_ni_syscall                    // reserved for kexec_load
1529         data8 sys_vserver
1530         data8 sys_ni_syscall                    // 1270
1531         data8 sys_ni_syscall
1532         data8 sys_ni_syscall
1533         data8 sys_ni_syscall
1534         data8 sys_ni_syscall
1535         data8 sys_ni_syscall                    // 1275
1536         data8 sys_ni_syscall
1537         data8 sys_ni_syscall
1538         data8 sys_ni_syscall
1539         data8 sys_ni_syscall
1540
1541         .org sys_call_table + 8*NR_syscalls     // guard against failures to increase NR_syscalls