arch/ia64/kernel/entry.S

   1 /*
   2  * ia64/kernel/entry.S
   3  *
   4  * Kernel entry points.
   5  *
   6  * Copyright (C) 1998-2003 Hewlett-Packard Co
   7  *      David Mosberger-Tang <davidm@hpl.hp.com>
   8  * Copyright (C) 1999, 2002-2003
   9  *      Asit Mallick <Asit.K.Mallick@intel.com>
  10  *      Don Dugger <Don.Dugger@intel.com>
  11  *      Suresh Siddha <suresh.b.siddha@intel.com>
  12  *      Fenghua Yu <fenghua.yu@intel.com>
  13  * Copyright (C) 1999 VA Linux Systems
  14  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  15  */
  16 /*
  17  * ia64_switch_to now places correct virtual mapping in in TR2 for
  18  * kernel stack. This allows us to handle interrupts without changing
  19  * to physical mode.
  20  *
  21  * Jonathan Nicklin     <nicklin@missioncriticallinux.com>
  22  * Patrick O'Rourke     <orourke@missioncriticallinux.com>
  23  * 11/07/2000
  24  */
  25 /*
  26  * Global (preserved) predicate usage on syscall entry/exit path:
  27  *
  28  *      pKStk:          See entry.h.
  29  *      pUStk:          See entry.h.
  30  *      pSys:           See entry.h.
  31  *      pNonSys:        !pSys
  32  */
  33
  34 #include <linux/config.h>
  35
  36 #include <asm/asmmacro.h>
  37 #include <asm/cache.h>
  38 #include <asm/errno.h>
  39 #include <asm/kregs.h>
  40 #include <asm/offsets.h>
  41 #include <asm/pgtable.h>
  42 #include <asm/percpu.h>
  43 #include <asm/processor.h>
  44 #include <asm/thread_info.h>
  45 #include <asm/unistd.h>
  46
  47 #include "minstate.h"
  48
  49         /*
  50          * execve() is special because in case of success, we need to
  51          * setup a null register window frame.
  52          */
  53 ENTRY(ia64_execve)
  54         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(3)
  55         alloc loc1=ar.pfs,3,2,4,0
  56         mov loc0=rp
  57         .body
  58         mov out0=in0                    // filename
  59         ;;                              // stop bit between alloc and call
  60         mov out1=in1                    // argv
  61         mov out2=in2                    // envp
  62         add out3=16,sp                  // regs
  63         br.call.sptk.many rp=sys_execve
  64 .ret0:
  65 #ifdef CONFIG_IA32_SUPPORT
  66         /*
  67          * Check if we're returning to ia32 mode. If so, we need to restore ia32 registers
  68          * from pt_regs.
  69          */
  70         adds r16=PT(CR_IPSR)+16,sp
  71         ;;
  72         ld8 r16=[r16]
  73 #endif
  74         cmp4.ge p6,p7=r8,r0
  75         mov ar.pfs=loc1                 // restore ar.pfs
  76         sxt4 r8=r8                      // return 64-bit result
  77         ;;
  78         stf.spill [sp]=f0
  79 (p6)    cmp.ne pKStk,pUStk=r0,r0        // a successful execve() lands us in user-mode...
  80         mov rp=loc0
  81 (p6)    mov ar.pfs=r0                   // clear ar.pfs on success
  82 (p7)    br.ret.sptk.many rp
  83
  84         /*
  85          * In theory, we'd have to zap this state only to prevent leaking of
  86          * security sensitive state (e.g., if current->mm->dumpable is zero).  However,
  87          * this executes in less than 20 cycles even on Itanium, so it's not worth
  88          * optimizing for...).
  89          */
  90         mov ar.unat=0;          mov ar.lc=0
  91         mov r4=0;               mov f2=f0;              mov b1=r0
  92         mov r5=0;               mov f3=f0;              mov b2=r0
  93         mov r6=0;               mov f4=f0;              mov b3=r0
  94         mov r7=0;               mov f5=f0;              mov b4=r0
  95         ldf.fill f12=[sp];      mov f13=f0;             mov b5=r0
  96         ldf.fill f14=[sp];      ldf.fill f15=[sp];      mov f16=f0
  97         ldf.fill f17=[sp];      ldf.fill f18=[sp];      mov f19=f0
  98         ldf.fill f20=[sp];      ldf.fill f21=[sp];      mov f22=f0
  99         ldf.fill f23=[sp];      ldf.fill f24=[sp];      mov f25=f0
 100         ldf.fill f26=[sp];      ldf.fill f27=[sp];      mov f28=f0
 101         ldf.fill f29=[sp];      ldf.fill f30=[sp];      mov f31=f0
 102 #ifdef CONFIG_IA32_SUPPORT
 103         tbit.nz p6,p0=r16, IA64_PSR_IS_BIT
 104         movl loc0=ia64_ret_from_ia32_execve
 105         ;;
 106 (p6)    mov rp=loc0
 107 #endif
 108         br.ret.sptk.many rp
 109 END(ia64_execve)
 110
 111 /*
 112  * sys_clone2(u64 flags, u64 ustack_base, u64 ustack_size, u64 parent_tidptr, u64 child_tidptr,
 113  *            u64 tls)
 114  */
 115 GLOBAL_ENTRY(sys_clone2)
 116         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(6)
 117         alloc r16=ar.pfs,6,2,6,0
 118         DO_SAVE_SWITCH_STACK
 119         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 120         mov loc0=rp
 121         mov loc1=r16                            // save ar.pfs across do_fork
 122         .body
 123         mov out1=in1
 124         mov out3=in2
 125         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 126         mov out4=in3    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 127         ;;
 128 (p6)    st8 [r2]=in5                            // store TLS in r16 for copy_thread()
 129         mov out5=in4    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 130         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 131         dep out0=0,in0,CLONE_IDLETASK_BIT,1     // out0 = clone_flags & ~CLONE_IDLETASK
 132         br.call.sptk.many rp=do_fork
 133 .ret1:  .restore sp
 134         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 135         mov ar.pfs=loc1
 136         mov rp=loc0
 137         br.ret.sptk.many rp
 138 END(sys_clone2)
 139
 140 /*
 141  * sys_clone(u64 flags, u64 ustack_base, u64 parent_tidptr, u64 child_tidptr, u64 tls)
 142  *      Deprecated.  Use sys_clone2() instead.
 143  */
 144 GLOBAL_ENTRY(sys_clone)
 145         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(5)
 146         alloc r16=ar.pfs,5,2,6,0
 147         DO_SAVE_SWITCH_STACK
 148         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 149         mov loc0=rp
 150         mov loc1=r16                            // save ar.pfs across do_fork
 151         .body
 152         mov out1=in1
 153         mov out3=16                             // stacksize (compensates for 16-byte scratch area)
 154         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 155         mov out4=in2    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 156         ;;
 157 (p6)    st8 [r2]=in4                            // store TLS in r13 (tp)
 158         mov out5=in3    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 159         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 160         dep out0=0,in0,CLONE_IDLETASK_BIT,1     // out0 = clone_flags & ~CLONE_IDLETASK
 161         br.call.sptk.many rp=do_fork
 162 .ret2:  .restore sp
 163         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 164         mov ar.pfs=loc1
 165         mov rp=loc0
 166         br.ret.sptk.many rp
 167 END(sys_clone)
 168
 169 /*
 170  * prev_task <- ia64_switch_to(struct task_struct *next)
 171  *      With Ingo's new scheduler, interrupts are disabled when this routine gets
 172  *      called.  The code starting at .map relies on this.  The rest of the code
 173  *      doesn't care about the interrupt masking status.
 174  */
 175 GLOBAL_ENTRY(ia64_switch_to)
 176         .prologue
 177         alloc r16=ar.pfs,1,0,0,0
 178         DO_SAVE_SWITCH_STACK
 179         .body
 180
 181         adds r22=IA64_TASK_THREAD_KSP_OFFSET,r13
 182         mov r27=IA64_KR(CURRENT_STACK)
 183         dep r20=0,in0,61,3              // physical address of "current"
 184         ;;
 185         st8 [r22]=sp                    // save kernel stack pointer of old task
 186         shr.u r26=r20,IA64_GRANULE_SHIFT
 187         adds r21=IA64_TASK_THREAD_KSP_OFFSET,in0
 188         ;;
 189         /*
 190          * If we've already mapped this task's page, we can skip doing it again.
 191          */
 192         cmp.eq p7,p6=r26,r27
 193 (p6)    br.cond.dpnt .map
 194         ;;
 195 .done:
 196 (p6)    ssm psr.ic                      // if we we had to map, renable the psr.ic bit FIRST!!!
 197         ;;
 198 (p6)    srlz.d
 199         ld8 sp=[r21]                    // load kernel stack pointer of new task
 200         mov IA64_KR(CURRENT)=in0        // update "current" application register
 201         mov r8=r13                      // return pointer to previously running task
 202         mov r13=in0                     // set "current" pointer
 203         ;;
 204         DO_LOAD_SWITCH_STACK
 205
 206 #ifdef CONFIG_SMP
 207         sync.i                          // ensure "fc"s done by this CPU are visible on other CPUs
 208 #endif
 209         br.ret.sptk.many rp             // boogie on out in new context
 210
 211 .map:
 212         rsm psr.ic                      // interrupts (psr.i) are already disabled here
 213         movl r25=PAGE_KERNEL
 214         ;;
 215         srlz.d
 216         or r23=r25,r20                  // construct PA | page properties
 217         mov r25=IA64_GRANULE_SHIFT<<2
 218         ;;
 219         mov cr.itir=r25
 220         mov cr.ifa=in0                  // VA of next task...
 221         ;;
 222         mov r25=IA64_TR_CURRENT_STACK
 223         mov IA64_KR(CURRENT_STACK)=r26  // remember last page we mapped...
 224         ;;
 225         itr.d dtr[r25]=r23              // wire in new mapping...
 226         br.cond.sptk .done
 227 END(ia64_switch_to)
 228
 229 /*
 230  * Note that interrupts are enabled during save_switch_stack and load_switch_stack.  This
 231  * means that we may get an interrupt with "sp" pointing to the new kernel stack while
 232  * ar.bspstore is still pointing to the old kernel backing store area.  Since ar.rsc,
 233  * ar.rnat, ar.bsp, and ar.bspstore are all preserved by interrupts, this is not a
 234  * problem.  Also, we don't need to specify unwind information for preserved registers
 235  * that are not modified in save_switch_stack as the right unwind information is already
 236  * specified at the call-site of save_switch_stack.
 237  */
 238
 239 /*
 240  * save_switch_stack:
 241  *      - r16 holds ar.pfs
 242  *      - b7 holds address to return to
 243  *      - rp (b0) holds return address to save
 244  */
 245 GLOBAL_ENTRY(save_switch_stack)
 246         .prologue
 247         .altrp b7
 248         flushrs                 // flush dirty regs to backing store (must be first in insn group)
 249         .save @priunat,r17
 250         mov r17=ar.unat         // preserve caller's
 251         .body
 252 #ifdef CONFIG_ITANIUM
 253         adds r2=16+128,sp
 254         adds r3=16+64,sp
 255         adds r14=SW(R4)+16,sp
 256         ;;
 257         st8.spill [r14]=r4,16           // spill r4
 258         lfetch.fault.excl.nt1 [r3],128
 259         ;;
 260         lfetch.fault.excl.nt1 [r2],128
 261         lfetch.fault.excl.nt1 [r3],128
 262         ;;
 263         lfetch.fault.excl [r2]
 264         lfetch.fault.excl [r3]
 265         adds r15=SW(R5)+16,sp
 266 #else
 267         add r2=16+3*128,sp
 268         add r3=16,sp
 269         add r14=SW(R4)+16,sp
 270         ;;
 271         st8.spill [r14]=r4,SW(R6)-SW(R4)        // spill r4 and prefetch offset 0x1c0
 272         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x010
 273         ;;
 274         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x090
 275         lfetch.fault.excl.nt1 [r2],128  //              prefetch offset 0x190
 276         ;;
 277         lfetch.fault.excl.nt1 [r3]      //              prefetch offset 0x110
 278         lfetch.fault.excl.nt1 [r2]      //              prefetch offset 0x210
 279         adds r15=SW(R5)+16,sp
 280 #endif
 281         ;;
 282         st8.spill [r15]=r5,SW(R7)-SW(R5)        // spill r5
 283         mov.m ar.rsc=0                  // put RSE in mode: enforced lazy, little endian, pl 0
 284         add r2=SW(F2)+16,sp             // r2 = &sw->f2
 285         ;;
 286         st8.spill [r14]=r6,SW(B0)-SW(R6)        // spill r6
 287         mov.m r18=ar.fpsr               // preserve fpsr
 288         add r3=SW(F3)+16,sp             // r3 = &sw->f3
 289         ;;
 290         stf.spill [r2]=f2,32
 291         mov.m r19=ar.rnat
 292         mov r21=b0
 293
 294         stf.spill [r3]=f3,32
 295         st8.spill [r15]=r7,SW(B2)-SW(R7)        // spill r7
 296         mov r22=b1
 297         ;;
 298         // since we're done with the spills, read and save ar.unat:
 299         mov.m r29=ar.unat
 300         mov.m r20=ar.bspstore
 301         mov r23=b2
 302         stf.spill [r2]=f4,32
 303         stf.spill [r3]=f5,32
 304         mov r24=b3
 305         ;;
 306         st8 [r14]=r21,SW(B1)-SW(B0)             // save b0
 307         st8 [r15]=r23,SW(B3)-SW(B2)             // save b2
 308         mov r25=b4
 309         mov r26=b5
 310         ;;
 311         st8 [r14]=r22,SW(B4)-SW(B1)             // save b1
 312         st8 [r15]=r24,SW(AR_PFS)-SW(B3)         // save b3
 313         mov r21=ar.lc           // I-unit
 314         stf.spill [r2]=f12,32
 315         stf.spill [r3]=f13,32
 316         ;;
 317         st8 [r14]=r25,SW(B5)-SW(B4)             // save b4
 318         st8 [r15]=r16,SW(AR_LC)-SW(AR_PFS)      // save ar.pfs
 319         stf.spill [r2]=f14,32
 320         stf.spill [r3]=f15,32
 321         ;;
 322         st8 [r14]=r26                           // save b5
 323         st8 [r15]=r21                           // save ar.lc
 324         stf.spill [r2]=f16,32
 325         stf.spill [r3]=f17,32
 326         ;;
 327         stf.spill [r2]=f18,32
 328         stf.spill [r3]=f19,32
 329         ;;
 330         stf.spill [r2]=f20,32
 331         stf.spill [r3]=f21,32
 332         ;;
 333         stf.spill [r2]=f22,32
 334         stf.spill [r3]=f23,32
 335         ;;
 336         stf.spill [r2]=f24,32
 337         stf.spill [r3]=f25,32
 338         ;;
 339         stf.spill [r2]=f26,32
 340         stf.spill [r3]=f27,32
 341         ;;
 342         stf.spill [r2]=f28,32
 343         stf.spill [r3]=f29,32
 344         ;;
 345         stf.spill [r2]=f30,SW(AR_UNAT)-SW(F30)
 346         stf.spill [r3]=f31,SW(PR)-SW(F31)
 347         add r14=SW(CALLER_UNAT)+16,sp
 348         ;;
 349         st8 [r2]=r29,SW(AR_RNAT)-SW(AR_UNAT)    // save ar.unat
 350         st8 [r14]=r17,SW(AR_FPSR)-SW(CALLER_UNAT) // save caller_unat
 351         mov r21=pr
 352         ;;
 353         st8 [r2]=r19,SW(AR_BSPSTORE)-SW(AR_RNAT) // save ar.rnat
 354         st8 [r3]=r21                            // save predicate registers
 355         ;;
 356         st8 [r2]=r20                            // save ar.bspstore
 357         st8 [r14]=r18                           // save fpsr
 358         mov ar.rsc=3            // put RSE back into eager mode, pl 0
 359         br.cond.sptk.many b7
 360 END(save_switch_stack)
 361
 362 /*
 363  * load_switch_stack:
 364  *      - "invala" MUST be done at call site (normally in DO_LOAD_SWITCH_STACK)
 365  *      - b7 holds address to return to
 366  *      - must not touch r8-r11
 367  */
 368 ENTRY(load_switch_stack)
 369         .prologue
 370         .altrp b7
 371
 372         .body
 373         lfetch.fault.nt1 [sp]
 374         adds r2=SW(AR_BSPSTORE)+16,sp
 375         adds r3=SW(AR_UNAT)+16,sp
 376         mov ar.rsc=0                                            // put RSE into enforced lazy mode
 377         adds r14=SW(CALLER_UNAT)+16,sp
 378         adds r15=SW(AR_FPSR)+16,sp
 379         ;;
 380         ld8 r27=[r2],(SW(B0)-SW(AR_BSPSTORE))   // bspstore
 381         ld8 r29=[r3],(SW(B1)-SW(AR_UNAT))       // unat
 382         ;;
 383         ld8 r21=[r2],16         // restore b0
 384         ld8 r22=[r3],16         // restore b1
 385         ;;
 386         ld8 r23=[r2],16         // restore b2
 387         ld8 r24=[r3],16         // restore b3
 388         ;;
 389         ld8 r25=[r2],16         // restore b4
 390         ld8 r26=[r3],16         // restore b5
 391         ;;
 392         ld8 r16=[r2],(SW(PR)-SW(AR_PFS))        // ar.pfs
 393         ld8 r17=[r3],(SW(AR_RNAT)-SW(AR_LC))    // ar.lc
 394         ;;
 395         ld8 r28=[r2]            // restore pr
 396         ld8 r30=[r3]            // restore rnat
 397         ;;
 398         ld8 r18=[r14],16        // restore caller's unat
 399         ld8 r19=[r15],24        // restore fpsr
 400         ;;
 401         ldf.fill f2=[r14],32
 402         ldf.fill f3=[r15],32
 403         ;;
 404         ldf.fill f4=[r14],32
 405         ldf.fill f5=[r15],32
 406         ;;
 407         ldf.fill f12=[r14],32
 408         ldf.fill f13=[r15],32
 409         ;;
 410         ldf.fill f14=[r14],32
 411         ldf.fill f15=[r15],32
 412         ;;
 413         ldf.fill f16=[r14],32
 414         ldf.fill f17=[r15],32
 415         ;;
 416         ldf.fill f18=[r14],32
 417         ldf.fill f19=[r15],32
 418         mov b0=r21
 419         ;;
 420         ldf.fill f20=[r14],32
 421         ldf.fill f21=[r15],32
 422         mov b1=r22
 423         ;;
 424         ldf.fill f22=[r14],32
 425         ldf.fill f23=[r15],32
 426         mov b2=r23
 427         ;;
 428         mov ar.bspstore=r27
 429         mov ar.unat=r29         // establish unat holding the NaT bits for r4-r7
 430         mov b3=r24
 431         ;;
 432         ldf.fill f24=[r14],32
 433         ldf.fill f25=[r15],32
 434         mov b4=r25
 435         ;;
 436         ldf.fill f26=[r14],32
 437         ldf.fill f27=[r15],32
 438         mov b5=r26
 439         ;;
 440         ldf.fill f28=[r14],32
 441         ldf.fill f29=[r15],32
 442         mov ar.pfs=r16
 443         ;;
 444         ldf.fill f30=[r14],32
 445         ldf.fill f31=[r15],24
 446         mov ar.lc=r17
 447         ;;
 448         ld8.fill r4=[r14],16
 449         ld8.fill r5=[r15],16
 450         mov pr=r28,-1
 451         ;;
 452         ld8.fill r6=[r14],16
 453         ld8.fill r7=[r15],16
 454
 455         mov ar.unat=r18                         // restore caller's unat
 456         mov ar.rnat=r30                         // must restore after bspstore but before rsc!
 457         mov ar.fpsr=r19                         // restore fpsr
 458         mov ar.rsc=3                            // put RSE back into eager mode, pl 0
 459         br.cond.sptk.many b7
 460 END(load_switch_stack)
 461
 462 GLOBAL_ENTRY(__ia64_syscall)
 463         .regstk 6,0,0,0
 464         mov r15=in5                             // put syscall number in place
 465         break __BREAK_SYSCALL
 466         movl r2=errno
 467         cmp.eq p6,p7=-1,r10
 468         ;;
 469 (p6)    st4 [r2]=r8
 470 (p6)    mov r8=-1
 471         br.ret.sptk.many rp
 472 END(__ia64_syscall)
 473
 474 GLOBAL_ENTRY(execve)
 475         mov r15=__NR_execve                     // put syscall number in place
 476         break __BREAK_SYSCALL
 477         br.ret.sptk.many rp
 478 END(execve)
 479
 480 GLOBAL_ENTRY(clone)
 481         mov r15=__NR_clone                      // put syscall number in place
 482         break __BREAK_SYSCALL
 483         br.ret.sptk.many rp
 484 END(clone)
 485
 486         /*
 487          * Invoke a system call, but do some tracing before and after the call.
 488          * We MUST preserve the current register frame throughout this routine
 489          * because some system calls (such as ia64_execve) directly
 490          * manipulate ar.pfs.
 491          */
 492 GLOBAL_ENTRY(ia64_trace_syscall)
 493         PT_REGS_UNWIND_INFO(0)
 494         /*
 495          * We need to preserve the scratch registers f6-f11 in case the system
 496          * call is sigreturn.
 497          */
 498         adds r16=PT(F6)+16,sp
 499         adds r17=PT(F7)+16,sp
 500         ;;
 501         stf.spill [r16]=f6,32
 502         stf.spill [r17]=f7,32
 503         ;;
 504         stf.spill [r16]=f8,32
 505         stf.spill [r17]=f9,32
 506         ;;
 507         stf.spill [r16]=f10
 508         stf.spill [r17]=f11
 509         br.call.sptk.many rp=syscall_trace // give parent a chance to catch syscall args
 510         adds r16=PT(F6)+16,sp
 511         adds r17=PT(F7)+16,sp
 512         ;;
 513         ldf.fill f6=[r16],32
 514         ldf.fill f7=[r17],32
 515         ;;
 516         ldf.fill f8=[r16],32
 517         ldf.fill f9=[r17],32
 518         ;;
 519         ldf.fill f10=[r16]
 520         ldf.fill f11=[r17]
 521         // the syscall number may have changed, so re-load it and re-calculate the
 522         // syscall entry-point:
 523         adds r15=PT(R15)+16,sp                  // r15 = &pt_regs.r15 (syscall #)
 524         ;;
 525         ld8 r15=[r15]
 526         mov r3=NR_syscalls - 1
 527         ;;
 528         adds r15=-1024,r15
 529         movl r16=sys_call_table
 530         ;;
 531         shladd r20=r15,3,r16                    // r20 = sys_call_table + 8*(syscall-1024)
 532         cmp.leu p6,p7=r15,r3
 533         ;;
 534 (p6)    ld8 r20=[r20]                           // load address of syscall entry point
 535 (p7)    movl r20=sys_ni_syscall
 536         ;;
 537         mov b6=r20
 538         br.call.sptk.many rp=b6                 // do the syscall
 539 .strace_check_retval:
 540         cmp.lt p6,p0=r8,r0                      // syscall failed?
 541         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 542         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 543         mov r10=0
 544 (p6)    br.cond.sptk strace_error               // syscall failed ->
 545         ;;                                      // avoid RAW on r10
 546 .strace_save_retval:
 547 .mem.offset 0,0; st8.spill [r2]=r8              // store return value in slot for r8
 548 .mem.offset 8,0; st8.spill [r3]=r10             // clear error indication in slot for r10
 549         br.call.sptk.many rp=syscall_trace // give parent a chance to catch return value
 550 .ret3:  br.cond.sptk ia64_leave_syscall
 551
 552 strace_error:
 553         ld8 r3=[r2]                             // load pt_regs.r8
 554         sub r9=0,r8                             // negate return value to get errno value
 555         ;;
 556         cmp.ne p6,p0=r3,r0                      // is pt_regs.r8!=0?
 557         adds r3=16,r2                           // r3=&pt_regs.r10
 558         ;;
 559 (p6)    mov r10=-1
 560 (p6)    mov r8=r9
 561         br.cond.sptk .strace_save_retval
 562 END(ia64_trace_syscall)
 563
 564         /*
 565          * When traced and returning from sigreturn, we invoke syscall_trace but then
 566          * go straight to ia64_leave_kernel rather than ia64_leave_syscall.
 567          */
 568 GLOBAL_ENTRY(ia64_strace_leave_kernel)
 569         PT_REGS_UNWIND_INFO(0)
 570 {       /*
 571          * Some versions of gas generate bad unwind info if the first instruction of a
 572          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 573          */
 574         nop.m 0
 575         nop.i 0
 576         br.call.sptk.many rp=syscall_trace // give parent a chance to catch return value
 577 }
 578 .ret4:  br.cond.sptk ia64_leave_kernel
 579 END(ia64_strace_leave_kernel)
 580
 581 GLOBAL_ENTRY(ia64_ret_from_clone)
 582         PT_REGS_UNWIND_INFO(0)
 583 {       /*
 584          * Some versions of gas generate bad unwind info if the first instruction of a
 585          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 586          */
 587         nop.m 0
 588         nop.i 0
 589         /*
 590          * We need to call schedule_tail() to complete the scheduling process.
 591          * Called by ia64_switch_to() after do_fork()->copy_thread().  r8 contains the
 592          * address of the previously executing task.
 593          */
 594         br.call.sptk.many rp=ia64_invoke_schedule_tail
 595 }
 596 .ret8:
 597         adds r2=TI_FLAGS+IA64_TASK_SIZE,r13
 598         ;;
 599         ld4 r2=[r2]
 600         ;;
 601         mov r8=0
 602         tbit.nz p6,p0=r2,TIF_SYSCALL_TRACE
 603 (p6)    br.cond.spnt .strace_check_retval
 604         ;;                                      // added stop bits to prevent r8 dependency
 605 END(ia64_ret_from_clone)
 606         // fall through
 607 GLOBAL_ENTRY(ia64_ret_from_syscall)
 608         PT_REGS_UNWIND_INFO(0)
 609         cmp.ge p6,p7=r8,r0                      // syscall executed successfully?
 610         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 611         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 612         ;;
 613 .mem.offset 0,0; (p6) st8.spill [r2]=r8 // store return value in slot for r8 and set unat bit
 614 .mem.offset 8,0; (p6) st8.spill [r3]=r0 // clear error indication in slot for r10 and set unat bit
 615 (p7)    br.cond.spnt handle_syscall_error       // handle potential syscall failure
 616 END(ia64_ret_from_syscall)
 617         // fall through
 618 /*
 619  * ia64_leave_syscall(): Same as ia64_leave_kernel, except that it doesn't
 620  *      need to switch to bank 0 and doesn't restore the scratch registers.
 621  *      To avoid leaking kernel bits, the scratch registers are set to
 622  *      the following known-to-be-safe values:
 623  *
 624  *                r1: restored (global pointer)
 625  *                r2: cleared
 626  *                r3: 1 (when returning to user-level)
 627  *            r8-r11: restored (syscall return value(s))
 628  *               r12: restored (user-level stack pointer)
 629  *               r13: restored (user-level thread pointer)
 630  *               r14: cleared
 631  *               r15: restored (syscall #)
 632  *           r16-r19: cleared
 633  *               r20: user-level ar.fpsr
 634  *               r21: user-level b0
 635  *               r22: user-level b6
 636  *               r23: user-level ar.bspstore
 637  *               r24: user-level ar.rnat
 638  *               r25: user-level ar.unat
 639  *               r26: user-level ar.pfs
 640  *               r27: user-level ar.rsc
 641  *               r28: user-level ip
 642  *               r29: user-level psr
 643  *               r30: user-level cfm
 644  *               r31: user-level pr
 645  *            f6-f11: cleared
 646  *                pr: restored (user-level pr)
 647  *                b0: restored (user-level rp)
 648  *                b6: restored
 649  *                b7: cleared
 650  *           ar.unat: restored (user-level ar.unat)
 651  *            ar.pfs: restored (user-level ar.pfs)
 652  *            ar.rsc: restored (user-level ar.rsc)
 653  *           ar.rnat: restored (user-level ar.rnat)
 654  *       ar.bspstore: restored (user-level ar.bspstore)
 655  *           ar.fpsr: restored (user-level ar.fpsr)
 656  *            ar.ccv: cleared
 657  *            ar.csd: cleared
 658  *            ar.ssd: cleared
 659  */
 660 GLOBAL_ENTRY(ia64_leave_syscall)
 661         PT_REGS_UNWIND_INFO(0)
 662         /*
 663          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 664          * user- or fsys-mode, hence we disable interrupts early on:
 665          */
 666 #ifdef CONFIG_PREEMPT
 667         rsm psr.i                               // disable interrupts
 668 #else
 669 (pUStk) rsm psr.i
 670 #endif
 671         cmp.eq pLvSys,p0=r0,r0                  // pLvSys=1: leave from syscall
 672 (pUStk) cmp.eq.unc p6,p0=r0,r0                  // p6 <- pUStk
 673 .work_processed_syscall:
 674 #ifdef CONFIG_PREEMPT
 675 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 676         ;;
 677         .pred.rel.mutex pUStk,pKStk
 678 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 679 (pUStk) mov r21=0                       // r21 <- 0
 680         ;;
 681 (p6)    cmp.eq.unc p6,p0=r21,r0         // p6 <- p6 && (r21 == 0)
 682 #endif /* CONFIG_PREEMPT */
 683         adds r16=PT(LOADRS)+16,r12
 684         adds r17=PT(AR_BSPSTORE)+16,r12
 685         adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
 686         ;;
 687 (p6)    ld4 r31=[r18]                           // load current_thread_info()->flags
 688         ld8 r19=[r16],PT(B6)-PT(LOADRS)         // load ar.rsc value for "loadrs"
 689         nop.i 0
 690         ;;
 691         ld8 r23=[r17],PT(R9)-PT(AR_BSPSTORE)    // load ar.bspstore (may be garbage)
 692         ld8 r22=[r16],PT(R8)-PT(B6)             // load b6
 693 (p6)    and r15=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 694         ;;
 695
 696         mov.m ar.ccv=r0         // clear ar.ccv
 697 (p6)    cmp4.ne.unc p6,p0=r15, r0               // any special work pending?
 698 (p6)    br.cond.spnt .work_pending
 699         ;;
 700         // start restoring the state saved on the kernel stack (struct pt_regs):
 701         ld8.fill r8=[r16],16
 702         ld8.fill r9=[r17],16
 703         mov f6=f0               // clear f6
 704         ;;
 705         ld8.fill r10=[r16],16
 706         ld8.fill r11=[r17],16
 707         mov f7=f0               // clear f7
 708         ;;
 709         ld8 r29=[r16],16        // load cr.ipsr
 710         ld8 r28=[r17],16        // load cr.iip
 711         mov f8=f0               // clear f8
 712         ;;
 713         ld8 r30=[r16],16        // load cr.ifs
 714         ld8 r25=[r17],16        // load ar.unat
 715         cmp.eq p9,p0=r0,r0      // set p9 to indicate that we should restore cr.ifs
 716         ;;
 717         rsm psr.i | psr.ic      // initiate turning off of interrupt and interruption collection
 718         invala                  // invalidate ALAT
 719         mov f9=f0               // clear f9
 720
 721         mov.m ar.ssd=r0         // clear ar.ssd
 722         mov.m ar.csd=r0         // clear ar.csd
 723         mov f10=f0              // clear f10
 724         ;;
 725         ld8 r26=[r16],16        // load ar.pfs
 726         ld8 r27=[r17],PT(PR)-PT(AR_RSC) // load ar.rsc
 727         mov f11=f0              // clear f11
 728         ;;
 729         ld8 r24=[r16],PT(B0)-PT(AR_RNAT)        // load ar.rnat (may be garbage)
 730         ld8 r31=[r17],PT(R1)-PT(PR)             // load predicates
 731 (pUStk) add r14=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
 732         ;;
 733         ld8 r21=[r16],PT(R12)-PT(B0) // load b0
 734         ld8.fill r1=[r17],16    // load r1
 735 (pUStk) mov r3=1
 736         ;;
 737         ld8.fill r12=[r16],16
 738         ld8.fill r13=[r17],16
 739         mov r2=r0               // clear r2
 740         ;;
 741         ld8 r20=[r16]           // load ar.fpsr
 742         ld8.fill r15=[r17]      // load r15
 743         mov b7=r0               // clear b7
 744         ;;
 745 (pUStk) st1 [r14]=r3
 746         addl r17=THIS_CPU(ia64_phys_stacked_size_p8),r0
 747         ;;
 748         mov r16=ar.bsp          // get existing backing store pointer
 749         srlz.i                  // ensure interruption collection is off
 750         mov r14=r0              // clear r14
 751         ;;
 752         ld4 r17=[r17]           // r17 = cpu_data->phys_stacked_size_p8
 753         mov b6=r22                              // restore b6
 754         shr.u r18=r19,16        // get byte size of existing "dirty" partition
 755 (pKStk) br.cond.dpnt.many skip_rbs_switch
 756 (pNonSys) br.cond.dpnt.many dont_preserve_current_frame
 757         br.cond.sptk.many rbs_switch
 758 END(ia64_leave_syscall)
 759
 760 #ifdef CONFIG_IA32_SUPPORT
 761 GLOBAL_ENTRY(ia64_ret_from_ia32_execve)
 762         PT_REGS_UNWIND_INFO(0)
 763         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 764         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 765         ;;
 766         .mem.offset 0,0
 767         st8.spill [r2]=r8       // store return value in slot for r8 and set unat bit
 768         .mem.offset 8,0
 769         st8.spill [r3]=r0       // clear error indication in slot for r10 and set unat bit
 770 END(ia64_ret_from_ia32_execve_syscall)
 771         // fall through
 772 #endif /* CONFIG_IA32_SUPPORT */
 773 GLOBAL_ENTRY(ia64_leave_kernel)
 774         PT_REGS_UNWIND_INFO(0)
 775         /*
 776          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 777          * user- or fsys-mode, hence we disable interrupts early on:
 778          */
 779 #ifdef CONFIG_PREEMPT
 780         rsm psr.i                               // disable interrupts
 781 #else
 782 (pUStk) rsm psr.i
 783 #endif
 784         cmp.eq p0,pLvSys=r0,r0                  // pLvSys=0: leave from kernel
 785 (pUStk) cmp.eq.unc p6,p0=r0,r0                  // p6 <- pUStk
 786         ;;
 787 .work_processed_kernel:
 788 #ifdef CONFIG_PREEMPT
 789         adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 790         ;;
 791         .pred.rel.mutex pUStk,pKStk
 792 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 793 (pUStk) mov r21=0                       // r21 <- 0
 794         ;;
 795 (p6)    cmp.eq.unc p6,p0=r21,r0         // p6 <- p6 && (r21 == 0)
 796 #endif /* CONFIG_PREEMPT */
 797         adds r17=TI_FLAGS+IA64_TASK_SIZE,r13
 798         ;;
 799 (p6)    ld4 r31=[r17]                           // load current_thread_info()->flags
 800         adds r21=PT(PR)+16,r12
 801         ;;
 802
 803         lfetch [r21],PT(CR_IPSR)-PT(PR)
 804         adds r2=PT(B6)+16,r12
 805         adds r3=PT(R16)+16,r12
 806         ;;
 807         lfetch [r21]
 808         ld8 r28=[r2],8          // load b6
 809         adds r29=PT(R24)+16,r12
 810
 811         ld8.fill r16=[r3],PT(AR_CSD)-PT(R16)
 812         adds r30=PT(AR_CCV)+16,r12
 813 (p6)    and r19=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 814         ;;
 815         ld8.fill r24=[r29]
 816         ld8 r15=[r30]           // load ar.ccv
 817 (p6)    cmp4.ne.unc p6,p0=r19, r0               // any special work pending?
 818         ;;
 819         ld8 r29=[r2],16         // load b7
 820         ld8 r30=[r3],16         // load ar.csd
 821 (p6)    br.cond.spnt .work_pending
 822         ;;
 823         ld8 r31=[r2],16         // load ar.ssd
 824         ld8.fill r8=[r3],16
 825         ;;
 826         ld8.fill r9=[r2],16
 827         ld8.fill r10=[r3],PT(R17)-PT(R10)
 828         ;;
 829         ld8.fill r11=[r2],PT(R18)-PT(R11)
 830         ld8.fill r17=[r3],16
 831         ;;
 832         ld8.fill r18=[r2],16
 833         ld8.fill r19=[r3],16
 834         ;;
 835         ld8.fill r20=[r2],16
 836         ld8.fill r21=[r3],16
 837         mov ar.csd=r30
 838         mov ar.ssd=r31
 839         ;;
 840         rsm psr.i | psr.ic      // initiate turning off of interrupt and interruption collection
 841         invala                  // invalidate ALAT
 842         ;;
 843         ld8.fill r22=[r2],24
 844         ld8.fill r23=[r3],24
 845         mov b6=r28
 846         ;;
 847         ld8.fill r25=[r2],16
 848         ld8.fill r26=[r3],16
 849         mov b7=r29
 850         ;;
 851         ld8.fill r27=[r2],16
 852         ld8.fill r28=[r3],16
 853         ;;
 854         ld8.fill r29=[r2],16
 855         ld8.fill r30=[r3],24
 856         ;;
 857         ld8.fill r31=[r2],PT(F9)-PT(R31)
 858         adds r3=PT(F10)-PT(F6),r3
 859         ;;
 860         ldf.fill f9=[r2],PT(F6)-PT(F9)
 861         ldf.fill f10=[r3],PT(F8)-PT(F10)
 862         ;;
 863         ldf.fill f6=[r2],PT(F7)-PT(F6)
 864         ;;
 865         ldf.fill f7=[r2],PT(F11)-PT(F7)
 866         ldf.fill f8=[r3],32
 867         ;;
 868         srlz.i                  // ensure interruption collection is off
 869         mov ar.ccv=r15
 870         ;;
 871         bsw.0                   // switch back to bank 0 (no stop bit required beforehand...)
 872         ;;
 873         ldf.fill f11=[r2]
 874 (pUStk) mov r18=IA64_KR(CURRENT)        // Itanium 2: 12 cycle read latency
 875         adds r16=PT(CR_IPSR)+16,r12
 876         adds r17=PT(CR_IIP)+16,r12
 877         ;;
 878         ld8 r29=[r16],16        // load cr.ipsr
 879         ld8 r28=[r17],16        // load cr.iip
 880         ;;
 881         ld8 r30=[r16],16        // load cr.ifs
 882         ld8 r25=[r17],16        // load ar.unat
 883         ;;
 884         ld8 r26=[r16],16        // load ar.pfs
 885         ld8 r27=[r17],16        // load ar.rsc
 886         cmp.eq p9,p0=r0,r0      // set p9 to indicate that we should restore cr.ifs
 887         ;;
 888         ld8 r24=[r16],16        // load ar.rnat (may be garbage)
 889         ld8 r23=[r17],16// load ar.bspstore (may be garbage)
 890         ;;
 891         ld8 r31=[r16],16        // load predicates
 892         ld8 r21=[r17],16        // load b0
 893         ;;
 894         ld8 r19=[r16],16        // load ar.rsc value for "loadrs"
 895         ld8.fill r1=[r17],16    // load r1
 896         ;;
 897         ld8.fill r12=[r16],16
 898         ld8.fill r13=[r17],16
 899 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18
 900         ;;
 901         ld8 r20=[r16],16        // ar.fpsr
 902         ld8.fill r15=[r17],16
 903         ;;
 904         ld8.fill r14=[r16],16
 905         ld8.fill r2=[r17]
 906 (pUStk) mov r17=1
 907         ;;
 908         ld8.fill r3=[r16]
 909 (pUStk) st1 [r18]=r17           // restore current->thread.on_ustack
 910         shr.u r18=r19,16        // get byte size of existing "dirty" partition
 911         ;;
 912         mov r16=ar.bsp          // get existing backing store pointer
 913         addl r17=THIS_CPU(ia64_phys_stacked_size_p8),r0
 914         ;;
 915         ld4 r17=[r17]           // r17 = cpu_data->phys_stacked_size_p8
 916 (pKStk) br.cond.dpnt skip_rbs_switch
 917
 918         /*
 919          * Restore user backing store.
 920          *
 921          * NOTE: alloc, loadrs, and cover can't be predicated.
 922          */
 923 (pNonSys) br.cond.dpnt dont_preserve_current_frame
 924
 925 rbs_switch:
 926         cover                           // add current frame into dirty partition and set cr.ifs
 927         ;;
 928         mov r19=ar.bsp                  // get new backing store pointer
 929         sub r16=r16,r18                 // krbs = old bsp - size of dirty partition
 930         cmp.ne p9,p0=r0,r0              // clear p9 to skip restore of cr.ifs
 931         ;;
 932         sub r19=r19,r16                 // calculate total byte size of dirty partition
 933         add r18=64,r18                  // don't force in0-in7 into memory...
 934         ;;
 935         shl r19=r19,16                  // shift size of dirty partition into loadrs position
 936         ;;
 937 dont_preserve_current_frame:
 938         /*
 939          * To prevent leaking bits between the kernel and user-space,
 940          * we must clear the stacked registers in the "invalid" partition here.
 941          * Not pretty, but at least it's fast (3.34 registers/cycle on Itanium,
 942          * 5 registers/cycle on McKinley).
 943          */
 944 #       define pRecurse p6
 945 #       define pReturn  p7
 946 #ifdef CONFIG_ITANIUM
 947 #       define Nregs    10
 948 #else
 949 #       define Nregs    14
 950 #endif
 951         alloc loc0=ar.pfs,2,Nregs-2,2,0
 952         shr.u loc1=r18,9                // RNaTslots <= floor(dirtySize / (64*8))
 953         sub r17=r17,r18                 // r17 = (physStackedSize + 8) - dirtySize
 954         ;;
 955         mov ar.rsc=r19                  // load ar.rsc to be used for "loadrs"
 956         shladd in0=loc1,3,r17
 957         mov in1=0
 958         ;;
 959 rse_clear_invalid:
 960 #ifdef CONFIG_ITANIUM
 961         // cycle 0
 962  { .mii
 963         alloc loc0=ar.pfs,2,Nregs-2,2,0
 964         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
 965         add out0=-Nregs*8,in0
 966 }{ .mfb
 967         add out1=1,in1                  // increment recursion count
 968         nop.f 0
 969         nop.b 0                         // can't do br.call here because of alloc (WAW on CFM)
 970         ;;
 971 }{ .mfi // cycle 1
 972         mov loc1=0
 973         nop.f 0
 974         mov loc2=0
 975 }{ .mib
 976         mov loc3=0
 977         mov loc4=0
 978 (pRecurse) br.call.sptk.many b0=rse_clear_invalid
 979
 980 }{ .mfi // cycle 2
 981         mov loc5=0
 982         nop.f 0
 983         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
 984 }{ .mib
 985         mov loc6=0
 986         mov loc7=0
 987 (pReturn) br.ret.sptk.many b0
 988 }
 989 #else /* !CONFIG_ITANIUM */
 990         alloc loc0=ar.pfs,2,Nregs-2,2,0
 991         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
 992         add out0=-Nregs*8,in0
 993         add out1=1,in1                  // increment recursion count
 994         mov loc1=0
 995         mov loc2=0
 996         ;;
 997         mov loc3=0
 998         mov loc4=0
 999         mov loc5=0
1000         mov loc6=0
1001         mov loc7=0
1002 (pRecurse) br.call.sptk.few b0=rse_clear_invalid
1003         ;;
1004         mov loc8=0
1005         mov loc9=0
1006         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
1007         mov loc10=0
1008         mov loc11=0
1009 (pReturn) br.ret.sptk.many b0
1010 #endif /* !CONFIG_ITANIUM */
1011 #       undef pRecurse
1012 #       undef pReturn
1013         ;;
1014         alloc r17=ar.pfs,0,0,0,0        // drop current register frame
1015         ;;
1016         loadrs
1017         ;;
1018 skip_rbs_switch:
1019 (pLvSys)        mov r19=r0              // clear r19 for leave_syscall, no-op otherwise
1020         mov b0=r21
1021         mov ar.pfs=r26
1022 (pUStk) mov ar.bspstore=r23
1023 (p9)    mov cr.ifs=r30
1024 (pLvSys)mov r16=r0              // clear r16 for leave_syscall, no-op otherwise
1025         mov cr.ipsr=r29
1026         mov ar.fpsr=r20
1027 (pLvSys)mov r17=r0              // clear r17 for leave_syscall, no-op otherwise
1028         mov cr.iip=r28
1029         ;;
1030 (pUStk) mov ar.rnat=r24         // must happen with RSE in lazy mode
1031 (pLvSys)mov r18=r0              // clear r18 for leave_syscall, no-op otherwise
1032         mov ar.rsc=r27
1033         mov ar.unat=r25
1034         mov pr=r31,-1
1035         rfi
1036
1037         /*
1038          * On entry:
1039          *      r20 = &current->thread_info->pre_count (if CONFIG_PREEMPT)
1040          *      r31 = current->thread_info->flags
1041          * On exit:
1042          *      p6 = TRUE if work-pending-check needs to be redone
1043          */
1044 .work_pending:
1045         tbit.z p6,p0=r31,TIF_NEED_RESCHED               // current_thread_info()->need_resched==0?
1046 (p6)    br.cond.sptk.few .notify
1047 #ifdef CONFIG_PREEMPT
1048 (pKStk) dep r21=-1,r0,PREEMPT_ACTIVE_BIT,1
1049         ;;
1050 (pKStk) st4 [r20]=r21
1051         ssm psr.i               // enable interrupts
1052 #endif
1053         br.call.spnt.many rp=schedule
1054 .ret9:  cmp.eq p6,p0=r0,r0                              // p6 <- 1
1055         rsm psr.i               // disable interrupts
1056         ;;
1057 #ifdef CONFIG_PREEMPT
1058 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
1059         ;;
1060 (pKStk) st4 [r20]=r0            // preempt_count() <- 0
1061 #endif
1062 (pLvSys)br.cond.sptk.many .work_processed_syscall       // re-check
1063         br.cond.sptk.many .work_processed_kernel        // re-check
1064
1065 .notify:
1066         br.call.spnt.many rp=notify_resume_user
1067 .ret10: cmp.ne p6,p0=r0,r0                              // p6 <- 0
1068 (pLvSys)br.cond.sptk.many .work_processed_syscall       // don't re-check
1069         br.cond.sptk.many .work_processed_kernel        // don't re-check
1070 END(ia64_leave_kernel)
1071
1072 ENTRY(handle_syscall_error)
1073         /*
1074          * Some system calls (e.g., ptrace, mmap) can return arbitrary values which could
1075          * lead us to mistake a negative return value as a failed syscall.  Those syscall
1076          * must deposit a non-zero value in pt_regs.r8 to indicate an error.  If
1077          * pt_regs.r8 is zero, we assume that the call completed successfully.
1078          */
1079         PT_REGS_UNWIND_INFO(0)
1080         ld8 r3=[r2]             // load pt_regs.r8
1081         sub r9=0,r8             // negate return value to get errno
1082         ;;
1083         mov r10=-1              // return -1 in pt_regs.r10 to indicate error
1084         cmp.eq p6,p7=r3,r0      // is pt_regs.r8==0?
1085         adds r3=16,r2           // r3=&pt_regs.r10
1086         ;;
1087 (p6)    mov r9=r8
1088 (p6)    mov r10=0
1089         ;;
1090 .mem.offset 0,0; st8.spill [r2]=r9      // store errno in pt_regs.r8 and set unat bit
1091 .mem.offset 8,0; st8.spill [r3]=r10     // store error indication in pt_regs.r10 and set unat bit
1092         br.cond.sptk ia64_leave_syscall
1093 END(handle_syscall_error)
1094
1095         /*
1096          * Invoke schedule_tail(task) while preserving in0-in7, which may be needed
1097          * in case a system call gets restarted.
1098          */
1099 GLOBAL_ENTRY(ia64_invoke_schedule_tail)
1100         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1101         alloc loc1=ar.pfs,8,2,1,0
1102         mov loc0=rp
1103         mov out0=r8                             // Address of previous task
1104         ;;
1105         br.call.sptk.many rp=schedule_tail
1106 .ret11: mov ar.pfs=loc1
1107         mov rp=loc0
1108         br.ret.sptk.many rp
1109 END(ia64_invoke_schedule_tail)
1110
1111         /*
1112          * Setup stack and call do_notify_resume_user().  Note that pSys and pNonSys need to
1113          * be set up by the caller.  We declare 8 input registers so the system call
1114          * args get preserved, in case we need to restart a system call.
1115          */
1116 ENTRY(notify_resume_user)
1117         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1118         alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1119         mov r9=ar.unat
1120         mov loc0=rp                             // save return address
1121         mov out0=0                              // there is no "oldset"
1122         adds out1=8,sp                          // out1=&sigscratch->ar_pfs
1123 (pSys)  mov out2=1                              // out2==1 => we're in a syscall
1124         ;;
1125 (pNonSys) mov out2=0                            // out2==0 => not a syscall
1126         .fframe 16
1127         .spillpsp ar.unat, 16                   // (note that offset is relative to psp+0x10!)
1128         st8 [sp]=r9,-16                         // allocate space for ar.unat and save it
1129         st8 [out1]=loc1,-8                      // save ar.pfs, out1=&sigscratch
1130         .body
1131         br.call.sptk.many rp=do_notify_resume_user
1132 .ret15: .restore sp
1133         adds sp=16,sp                           // pop scratch stack space
1134         ;;
1135         ld8 r9=[sp]                             // load new unat from sigscratch->scratch_unat
1136         mov rp=loc0
1137         ;;
1138         mov ar.unat=r9
1139         mov ar.pfs=loc1
1140         br.ret.sptk.many rp
1141 END(notify_resume_user)
1142
1143 GLOBAL_ENTRY(sys_rt_sigsuspend)
1144         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1145         alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1146         mov r9=ar.unat
1147         mov loc0=rp                             // save return address
1148         mov out0=in0                            // mask
1149         mov out1=in1                            // sigsetsize
1150         adds out2=8,sp                          // out2=&sigscratch->ar_pfs
1151         ;;
1152         .fframe 16
1153         .spillpsp ar.unat, 16                   // (note that offset is relative to psp+0x10!)
1154         st8 [sp]=r9,-16                         // allocate space for ar.unat and save it
1155         st8 [out2]=loc1,-8                      // save ar.pfs, out2=&sigscratch
1156         .body
1157         br.call.sptk.many rp=ia64_rt_sigsuspend
1158 .ret17: .restore sp
1159         adds sp=16,sp                           // pop scratch stack space
1160         ;;
1161         ld8 r9=[sp]                             // load new unat from sw->caller_unat
1162         mov rp=loc0
1163         ;;
1164         mov ar.unat=r9
1165         mov ar.pfs=loc1
1166         br.ret.sptk.many rp
1167 END(sys_rt_sigsuspend)
1168
1169 ENTRY(sys_rt_sigreturn)
1170         PT_REGS_UNWIND_INFO(0)
1171         alloc r2=ar.pfs,0,0,1,0
1172         .prologue
1173         PT_REGS_SAVES(16)
1174         adds sp=-16,sp
1175         .body
1176         cmp.eq pNonSys,pSys=r0,r0               // sigreturn isn't a normal syscall...
1177         ;;
1178         /*
1179          * leave_kernel() restores f6-f11 from pt_regs, but since the streamlined
1180          * syscall-entry path does not save them we save them here instead.  Note: we
1181          * don't need to save any other registers that are not saved by the stream-lined
1182          * syscall path, because restore_sigcontext() restores them.
1183          */
1184         adds r16=PT(F6)+32,sp
1185         adds r17=PT(F7)+32,sp
1186         ;;
1187         stf.spill [r16]=f6,32
1188         stf.spill [r17]=f7,32
1189         ;;
1190         stf.spill [r16]=f8,32
1191         stf.spill [r17]=f9,32
1192         ;;
1193         stf.spill [r16]=f10
1194         stf.spill [r17]=f11
1195         adds out0=16,sp                         // out0 = &sigscratch
1196         br.call.sptk.many rp=ia64_rt_sigreturn
1197 .ret19: .restore sp 0
1198         adds sp=16,sp
1199         ;;
1200         ld8 r9=[sp]                             // load new ar.unat
1201         mov.sptk b7=r8,ia64_leave_kernel
1202         ;;
1203         mov ar.unat=r9
1204         br.many b7
1205 END(sys_rt_sigreturn)
1206
1207 GLOBAL_ENTRY(ia64_prepare_handle_unaligned)
1208         .prologue
1209         /*
1210          * r16 = fake ar.pfs, we simply need to make sure privilege is still 0
1211          */
1212         mov r16=r0
1213         DO_SAVE_SWITCH_STACK
1214         br.call.sptk.many rp=ia64_handle_unaligned      // stack frame setup in ivt
1215 .ret21: .body
1216         DO_LOAD_SWITCH_STACK
1217         br.cond.sptk.many rp                            // goes to ia64_leave_kernel
1218 END(ia64_prepare_handle_unaligned)
1219
1220         //
1221         // unw_init_running(void (*callback)(info, arg), void *arg)
1222         //
1223 #       define EXTRA_FRAME_SIZE ((UNW_FRAME_INFO_SIZE+15)&~15)
1224
1225 GLOBAL_ENTRY(unw_init_running)
1226         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1227         alloc loc1=ar.pfs,2,3,3,0
1228         ;;
1229         ld8 loc2=[in0],8
1230         mov loc0=rp
1231         mov r16=loc1
1232         DO_SAVE_SWITCH_STACK
1233         .body
1234
1235         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1236         .fframe IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE
1237         SWITCH_STACK_SAVES(EXTRA_FRAME_SIZE)
1238         adds sp=-EXTRA_FRAME_SIZE,sp
1239         .body
1240         ;;
1241         adds out0=16,sp                         // &info
1242         mov out1=r13                            // current
1243         adds out2=16+EXTRA_FRAME_SIZE,sp        // &switch_stack
1244         br.call.sptk.many rp=unw_init_frame_info
1245 1:      adds out0=16,sp                         // &info
1246         mov b6=loc2
1247         mov loc2=gp                             // save gp across indirect function call
1248         ;;
1249         ld8 gp=[in0]
1250         mov out1=in1                            // arg
1251         br.call.sptk.many rp=b6                 // invoke the callback function
1252 1:      mov gp=loc2                             // restore gp
1253
1254         // For now, we don't allow changing registers from within
1255         // unw_init_running; if we ever want to allow that, we'd
1256         // have to do a load_switch_stack here:
1257         .restore sp
1258         adds sp=IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE,sp
1259
1260         mov ar.pfs=loc1
1261         mov rp=loc0
1262         br.ret.sptk.many rp
1263 END(unw_init_running)
1264
1265         .rodata
1266         .align 8
1267         .globl sys_call_table
1268 sys_call_table:
1269         data8 sys_ni_syscall            //  This must be sys_ni_syscall!  See ivt.S.
1270         data8 sys_exit                          // 1025
1271         data8 sys_read
1272         data8 sys_write
1273         data8 sys_open
1274         data8 sys_close
1275         data8 sys_creat                         // 1030
1276         data8 sys_link
1277         data8 sys_unlink
1278         data8 ia64_execve
1279         data8 sys_chdir
1280         data8 sys_fchdir                        // 1035
1281         data8 sys_utimes
1282         data8 sys_mknod
1283         data8 sys_chmod
1284         data8 sys_chown
1285         data8 sys_lseek                         // 1040
1286         data8 sys_getpid
1287         data8 sys_getppid
1288         data8 sys_mount
1289         data8 sys_umount
1290         data8 sys_setuid                        // 1045
1291         data8 sys_getuid
1292         data8 sys_geteuid
1293         data8 sys_ptrace
1294         data8 sys_access
1295         data8 sys_sync                          // 1050
1296         data8 sys_fsync
1297         data8 sys_fdatasync
1298         data8 sys_kill
1299         data8 sys_rename
1300         data8 sys_mkdir                         // 1055
1301         data8 sys_rmdir
1302         data8 sys_dup
1303         data8 sys_pipe
1304         data8 sys_times
1305         data8 ia64_brk                          // 1060
1306         data8 sys_setgid
1307         data8 sys_getgid
1308         data8 sys_getegid
1309         data8 sys_acct
1310         data8 sys_ioctl                         // 1065
1311         data8 sys_fcntl
1312         data8 sys_umask
1313         data8 sys_chroot
1314         data8 sys_ustat
1315         data8 sys_dup2                          // 1070
1316         data8 sys_setreuid
1317         data8 sys_setregid
1318         data8 sys_getresuid
1319         data8 sys_setresuid
1320         data8 sys_getresgid                     // 1075
1321         data8 sys_setresgid
1322         data8 sys_getgroups
1323         data8 sys_setgroups
1324         data8 sys_getpgid
1325         data8 sys_setpgid                       // 1080
1326         data8 sys_setsid
1327         data8 sys_getsid
1328         data8 sys_sethostname
1329         data8 sys_setrlimit
1330         data8 sys_getrlimit                     // 1085
1331         data8 sys_getrusage
1332         data8 sys_gettimeofday
1333         data8 sys_settimeofday
1334         data8 sys_select
1335         data8 sys_poll                          // 1090
1336         data8 sys_symlink
1337         data8 sys_readlink
1338         data8 sys_uselib
1339         data8 sys_swapon
1340         data8 sys_swapoff                       // 1095
1341         data8 sys_reboot
1342         data8 sys_truncate
1343         data8 sys_ftruncate
1344         data8 sys_fchmod
1345         data8 sys_fchown                        // 1100
1346         data8 ia64_getpriority
1347         data8 sys_setpriority
1348         data8 sys_statfs
1349         data8 sys_fstatfs
1350         data8 sys_gettid                        // 1105
1351         data8 sys_semget
1352         data8 sys_semop
1353         data8 sys_semctl
1354         data8 sys_msgget
1355         data8 sys_msgsnd                        // 1110
1356         data8 sys_msgrcv
1357         data8 sys_msgctl
1358         data8 sys_shmget
1359         data8 ia64_shmat
1360         data8 sys_shmdt                         // 1115
1361         data8 sys_shmctl
1362         data8 sys_syslog
1363         data8 sys_setitimer
1364         data8 sys_getitimer
1365         data8 sys_ni_syscall                    // 1120         /* was: ia64_oldstat */
1366         data8 sys_ni_syscall                                    /* was: ia64_oldlstat */
1367         data8 sys_ni_syscall                                    /* was: ia64_oldfstat */
1368         data8 sys_vhangup
1369         data8 sys_lchown
1370         data8 sys_remap_file_pages              // 1125
1371         data8 sys_wait4
1372         data8 sys_sysinfo
1373         data8 sys_clone
1374         data8 sys_setdomainname
1375         data8 sys_newuname                      // 1130
1376         data8 sys_adjtimex
1377         data8 sys_ni_syscall                                    /* was: ia64_create_module */
1378         data8 sys_init_module
1379         data8 sys_delete_module
1380         data8 sys_ni_syscall                    // 1135         /* was: sys_get_kernel_syms */
1381         data8 sys_ni_syscall                                    /* was: sys_query_module */
1382         data8 sys_quotactl
1383         data8 sys_bdflush
1384         data8 sys_sysfs
1385         data8 sys_personality                   // 1140
1386         data8 sys_ni_syscall            // sys_afs_syscall
1387         data8 sys_setfsuid
1388         data8 sys_setfsgid
1389         data8 sys_getdents
1390         data8 sys_flock                         // 1145
1391         data8 sys_readv
1392         data8 sys_writev
1393         data8 sys_pread64
1394         data8 sys_pwrite64
1395         data8 sys_sysctl                        // 1150
1396         data8 sys_mmap
1397         data8 sys_munmap
1398         data8 sys_mlock
1399         data8 sys_mlockall
1400         data8 sys_mprotect                      // 1155
1401         data8 ia64_mremap
1402         data8 sys_msync
1403         data8 sys_munlock
1404         data8 sys_munlockall
1405         data8 sys_sched_getparam                // 1160
1406         data8 sys_sched_setparam
1407         data8 sys_sched_getscheduler
1408         data8 sys_sched_setscheduler
1409         data8 sys_sched_yield
1410         data8 sys_sched_get_priority_max        // 1165
1411         data8 sys_sched_get_priority_min
1412         data8 sys_sched_rr_get_interval
1413         data8 sys_nanosleep
1414         data8 sys_nfsservctl
1415         data8 sys_prctl                         // 1170
1416         data8 sys_getpagesize
1417         data8 sys_mmap2
1418         data8 sys_pciconfig_read
1419         data8 sys_pciconfig_write
1420         data8 sys_perfmonctl                    // 1175
1421         data8 sys_sigaltstack
1422         data8 sys_rt_sigaction
1423         data8 sys_rt_sigpending
1424         data8 sys_rt_sigprocmask
1425         data8 sys_rt_sigqueueinfo               // 1180
1426         data8 sys_rt_sigreturn
1427         data8 sys_rt_sigsuspend
1428         data8 sys_rt_sigtimedwait
1429         data8 sys_getcwd
1430         data8 sys_capget                        // 1185
1431         data8 sys_capset
1432         data8 sys_sendfile64
1433         data8 sys_ni_syscall            // sys_getpmsg (STREAMS)
1434         data8 sys_ni_syscall            // sys_putpmsg (STREAMS)
1435         data8 sys_socket                        // 1190
1436         data8 sys_bind
1437         data8 sys_connect
1438         data8 sys_listen
1439         data8 sys_accept
1440         data8 sys_getsockname                   // 1195
1441         data8 sys_getpeername
1442         data8 sys_socketpair
1443         data8 sys_send
1444         data8 sys_sendto
1445         data8 sys_recv                          // 1200
1446         data8 sys_recvfrom
1447         data8 sys_shutdown
1448         data8 sys_setsockopt
1449         data8 sys_getsockopt
1450         data8 sys_sendmsg                       // 1205
1451         data8 sys_recvmsg
1452         data8 sys_pivot_root
1453         data8 sys_mincore
1454         data8 sys_madvise
1455         data8 sys_newstat                       // 1210
1456         data8 sys_newlstat
1457         data8 sys_newfstat
1458         data8 sys_clone2
1459         data8 sys_getdents64
1460         data8 sys_getunwind                     // 1215
1461         data8 sys_readahead
1462         data8 sys_setxattr
1463         data8 sys_lsetxattr
1464         data8 sys_fsetxattr
1465         data8 sys_getxattr                      // 1220
1466         data8 sys_lgetxattr
1467         data8 sys_fgetxattr
1468         data8 sys_listxattr
1469         data8 sys_llistxattr
1470         data8 sys_flistxattr                    // 1225
1471         data8 sys_removexattr
1472         data8 sys_lremovexattr
1473         data8 sys_fremovexattr
1474         data8 sys_tkill
1475         data8 sys_futex                         // 1230
1476         data8 sys_sched_setaffinity
1477         data8 sys_sched_getaffinity
1478         data8 sys_set_tid_address
1479         data8 sys_fadvise64_64
1480         data8 sys_tgkill                        // 1235
1481         data8 sys_exit_group
1482         data8 sys_lookup_dcookie
1483         data8 sys_io_setup
1484         data8 sys_io_destroy
1485         data8 sys_io_getevents                  // 1240
1486         data8 sys_io_submit
1487         data8 sys_io_cancel
1488         data8 sys_epoll_create
1489         data8 sys_epoll_ctl
1490         data8 sys_epoll_wait                    // 1245
1491         data8 sys_restart_syscall
1492         data8 sys_semtimedop
1493         data8 sys_timer_create
1494         data8 sys_timer_settime
1495         data8 sys_timer_gettime                 // 1250
1496         data8 sys_timer_getoverrun
1497         data8 sys_timer_delete
1498         data8 sys_clock_settime
1499         data8 sys_clock_gettime
1500         data8 sys_clock_getres                  // 1255
1501         data8 sys_clock_nanosleep
1502         data8 sys_fstatfs64
1503         data8 sys_statfs64
1504         data8 sys_mbind
1505         data8 sys_get_mempolicy                 // 1260
1506         data8 sys_set_mempolicy
1507         data8 sys_mq_open
1508         data8 sys_mq_unlink
1509         data8 sys_mq_timedsend
1510         data8 sys_mq_timedreceive               // 1265
1511         data8 sys_mq_notify
1512         data8 sys_mq_getsetattr
1513         data8 sys_ni_syscall                    // reserved for kexec_load
1514         data8 sys_vserver
1515         data8 sys_ni_syscall                    // 1270
1516         data8 sys_ni_syscall
1517         data8 sys_ni_syscall
1518         data8 sys_ni_syscall
1519         data8 sys_ni_syscall
1520         data8 sys_ni_syscall                    // 1275
1521         data8 sys_ni_syscall
1522         data8 sys_ni_syscall
1523         data8 sys_ni_syscall
1524         data8 sys_ni_syscall
1525
1526         .org sys_call_table + 8*NR_syscalls     // guard against failures to increase NR_syscalls