arch/ia64/kernel/head.S

   1 /*
   2  * Here is where the ball gets rolling as far as the kernel is concerned.
   3  * When control is transferred to _start, the bootload has already
   4  * loaded us to the correct address.  All that's left to do here is
   5  * to set up the kernel's global pointer and jump to the kernel
   6  * entry point.
   7  *
   8  * Copyright (C) 1998-2001, 2003 Hewlett-Packard Co
   9  *      David Mosberger-Tang <davidm@hpl.hp.com>
  10  *      Stephane Eranian <eranian@hpl.hp.com>
  11  * Copyright (C) 1999 VA Linux Systems
  12  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  13  * Copyright (C) 1999 Intel Corp.
  14  * Copyright (C) 1999 Asit Mallick <Asit.K.Mallick@intel.com>
  15  * Copyright (C) 1999 Don Dugger <Don.Dugger@intel.com>
  16  * Copyright (C) 2002 Fenghua Yu <fenghua.yu@intel.com>
  17  *   -Optimize __ia64_save_fpu() and __ia64_load_fpu() for Itanium 2.
  18  */
  19
  20 #include <linux/config.h>
  21
  22 #include <asm/asmmacro.h>
  23 #include <asm/fpu.h>
  24 #include <asm/kregs.h>
  25 #include <asm/mmu_context.h>
  26 #include <asm/offsets.h>
  27 #include <asm/pal.h>
  28 #include <asm/pgtable.h>
  29 #include <asm/processor.h>
  30 #include <asm/ptrace.h>
  31 #include <asm/system.h>
  32
  33         .section __special_page_section,"ax"
  34
  35         .global empty_zero_page
  36 empty_zero_page:
  37         .skip PAGE_SIZE
  38
  39         .global swapper_pg_dir
  40 swapper_pg_dir:
  41         .skip PAGE_SIZE
  42
  43         .rodata
  44 halt_msg:
  45         stringz "Halting kernel\n"
  46
  47         .text
  48
  49         .global start_ap
  50
  51         /*
  52          * Start the kernel.  When the bootloader passes control to _start(), r28
  53          * points to the address of the boot parameter area.  Execution reaches
  54          * here in physical mode.
  55          */
  56 GLOBAL_ENTRY(_start)
  57 start_ap:
  58         .prologue
  59         .save rp, r0            // terminate unwind chain with a NULL rp
  60         .body
  61
  62         rsm psr.i | psr.ic
  63         ;;
  64         srlz.i
  65         ;;
  66         /*
  67          * Initialize kernel region registers:
  68          *      rr[5]: VHPT enabled, page size = PAGE_SHIFT
  69          *      rr[6]: VHPT disabled, page size = IA64_GRANULE_SHIFT
  70          *      rr[5]: VHPT disabled, page size = IA64_GRANULE_SHIFT
  71          */
  72         mov r16=((ia64_rid(IA64_REGION_ID_KERNEL, (5<<61)) << 8) | (PAGE_SHIFT << 2) | 1)
  73         movl r17=(5<<61)
  74         mov r18=((ia64_rid(IA64_REGION_ID_KERNEL, (6<<61)) << 8) | (IA64_GRANULE_SHIFT << 2))
  75         movl r19=(6<<61)
  76         mov r20=((ia64_rid(IA64_REGION_ID_KERNEL, (7<<61)) << 8) | (IA64_GRANULE_SHIFT << 2))
  77         movl r21=(7<<61)
  78         ;;
  79         mov rr[r17]=r16
  80         mov rr[r19]=r18
  81         mov rr[r21]=r20
  82         ;;
  83         /*
  84          * Now pin mappings into the TLB for kernel text and data
  85          */
  86         mov r18=KERNEL_TR_PAGE_SHIFT<<2
  87         movl r17=KERNEL_START
  88         ;;
  89         mov cr.itir=r18
  90         mov cr.ifa=r17
  91         mov r16=IA64_TR_KERNEL
  92         mov r3=ip
  93         movl r18=PAGE_KERNEL
  94         ;;
  95         dep r2=0,r3,0,KERNEL_TR_PAGE_SHIFT
  96         ;;
  97         or r18=r2,r18
  98         ;;
  99         srlz.i
 100         ;;
 101         itr.i itr[r16]=r18
 102         ;;
 103         itr.d dtr[r16]=r18
 104         ;;
 105         srlz.i
 106
 107         /*
 108          * Switch into virtual mode:
 109          */
 110         movl r16=(IA64_PSR_IT|IA64_PSR_IC|IA64_PSR_DT|IA64_PSR_RT|IA64_PSR_DFH|IA64_PSR_BN \
 111                   |IA64_PSR_DI)
 112         ;;
 113         mov cr.ipsr=r16
 114         movl r17=1f
 115         ;;
 116         mov cr.iip=r17
 117         mov cr.ifs=r0
 118         ;;
 119         rfi
 120         ;;
 121 1:      // now we are in virtual mode
 122
 123         // set IVT entry point---can't access I/O ports without it
 124         movl r3=ia64_ivt
 125         ;;
 126         mov cr.iva=r3
 127         movl r2=FPSR_DEFAULT
 128         ;;
 129         srlz.i
 130         movl gp=__gp
 131
 132         mov ar.fpsr=r2
 133         ;;
 134
 135 #define isAP    p2      // are we an Application Processor?
 136 #define isBP    p3      // are we the Bootstrap Processor?
 137
 138 #ifdef CONFIG_SMP
 139         /*
 140          * Find the init_task for the currently booting CPU.  At poweron, and in
 141          * UP mode, task_for_booting_cpu is NULL.
 142          */
 143         movl r3=task_for_booting_cpu
 144         ;;
 145         ld8 r3=[r3]
 146         movl r2=init_task
 147         ;;
 148         cmp.eq isBP,isAP=r3,r0
 149         ;;
 150 (isAP)  mov r2=r3
 151 #else
 152         movl r2=init_task
 153         cmp.eq isBP,isAP=r0,r0
 154 #endif
 155         ;;
 156         tpa r3=r2               // r3 == phys addr of task struct
 157         // load mapping for stack (virtaddr in r2, physaddr in r3)
 158         rsm psr.ic
 159         movl r17=PAGE_KERNEL
 160         ;;
 161         srlz.d
 162         dep r18=0,r3,0,12
 163         ;;
 164         or r18=r17,r18
 165         dep r2=-1,r3,61,3       // IMVA of task
 166         ;;
 167         mov r17=rr[r2]
 168         shr.u r16=r3,IA64_GRANULE_SHIFT
 169         ;;
 170         dep r17=0,r17,8,24
 171         ;;
 172         mov cr.itir=r17
 173         mov cr.ifa=r2
 174
 175         mov r19=IA64_TR_CURRENT_STACK
 176         ;;
 177         itr.d dtr[r19]=r18
 178         ;;
 179         ssm psr.ic
 180         srlz.d
 181         ;;
 182
 183         // load the "current" pointer (r13) and ar.k6 with the current task
 184         mov IA64_KR(CURRENT)=r2         // virtual address
 185         mov IA64_KR(CURRENT_STACK)=r16
 186         mov r13=r2
 187         /*
 188          * Reserve space at the top of the stack for "struct pt_regs".  Kernel threads
 189          * don't store interesting values in that structure, but the space still needs
 190          * to be there because time-critical stuff such as the context switching can
 191          * be implemented more efficiently (for example, __switch_to()
 192          * always sets the psr.dfh bit of the task it is switching to).
 193          */
 194         addl r12=IA64_STK_OFFSET-IA64_PT_REGS_SIZE-16,r2
 195         addl r2=IA64_RBS_OFFSET,r2      // initialize the RSE
 196         mov ar.rsc=0            // place RSE in enforced lazy mode
 197         ;;
 198         loadrs                  // clear the dirty partition
 199         ;;
 200         mov ar.bspstore=r2      // establish the new RSE stack
 201         ;;
 202         mov ar.rsc=0x3          // place RSE in eager mode
 203
 204 (isBP)  dep r28=-1,r28,61,3     // make address virtual
 205 (isBP)  movl r2=ia64_boot_param
 206         ;;
 207 (isBP)  st8 [r2]=r28            // save the address of the boot param area passed by the bootloader
 208
 209 #ifdef CONFIG_IA64_EARLY_PRINTK
 210         .rodata
 211 alive_msg:
 212         stringz "I'm alive and well\n"
 213 alive_msg_end:
 214         .previous
 215
 216         alloc r2=ar.pfs,0,0,2,0
 217         movl out0=alive_msg
 218         movl out1=alive_msg_end-alive_msg-1
 219         ;;
 220         br.call.sptk.many rp=early_printk
 221 1:      // force new bundle
 222 #endif /* CONFIG_IA64_EARLY_PRINTK */
 223
 224 #ifdef CONFIG_SMP
 225 (isAP)  br.call.sptk.many rp=start_secondary
 226 .ret0:
 227 (isAP)  br.cond.sptk self
 228 #endif
 229
 230         // This is executed by the bootstrap processor (bsp) only:
 231
 232 #ifdef CONFIG_IA64_FW_EMU
 233         // initialize PAL & SAL emulator:
 234         br.call.sptk.many rp=sys_fw_init
 235 .ret1:
 236 #endif
 237         br.call.sptk.many rp=start_kernel
 238 .ret2:  addl r3=@ltoff(halt_msg),gp
 239         ;;
 240         alloc r2=ar.pfs,8,0,2,0
 241         ;;
 242         ld8 out0=[r3]
 243         br.call.sptk.many b0=console_print
 244 self:   br.sptk.many self               // endless loop
 245 END(_start)
 246
 247 GLOBAL_ENTRY(ia64_save_debug_regs)
 248         alloc r16=ar.pfs,1,0,0,0
 249         mov r20=ar.lc                   // preserve ar.lc
 250         mov ar.lc=IA64_NUM_DBG_REGS-1
 251         mov r18=0
 252         add r19=IA64_NUM_DBG_REGS*8,in0
 253         ;;
 254 1:      mov r16=dbr[r18]
 255 #ifdef CONFIG_ITANIUM
 256         ;;
 257         srlz.d
 258 #endif
 259         mov r17=ibr[r18]
 260         add r18=1,r18
 261         ;;
 262         st8.nta [in0]=r16,8
 263         st8.nta [r19]=r17,8
 264         br.cloop.sptk.many 1b
 265         ;;
 266         mov ar.lc=r20                   // restore ar.lc
 267         br.ret.sptk.many rp
 268 END(ia64_save_debug_regs)
 269
 270 GLOBAL_ENTRY(ia64_load_debug_regs)
 271         alloc r16=ar.pfs,1,0,0,0
 272         lfetch.nta [in0]
 273         mov r20=ar.lc                   // preserve ar.lc
 274         add r19=IA64_NUM_DBG_REGS*8,in0
 275         mov ar.lc=IA64_NUM_DBG_REGS-1
 276         mov r18=-1
 277         ;;
 278 1:      ld8.nta r16=[in0],8
 279         ld8.nta r17=[r19],8
 280         add r18=1,r18
 281         ;;
 282         mov dbr[r18]=r16
 283 #ifdef CONFIG_ITANIUM
 284         ;;
 285         srlz.d                          // Errata 132 (NoFix status)
 286 #endif
 287         mov ibr[r18]=r17
 288         br.cloop.sptk.many 1b
 289         ;;
 290         mov ar.lc=r20                   // restore ar.lc
 291         br.ret.sptk.many rp
 292 END(ia64_load_debug_regs)
 293
 294 GLOBAL_ENTRY(__ia64_save_fpu)
 295         alloc r2=ar.pfs,1,4,0,0
 296         adds loc0=96*16-16,in0
 297         adds loc1=96*16-16-128,in0
 298         ;;
 299         stf.spill.nta [loc0]=f127,-256
 300         stf.spill.nta [loc1]=f119,-256
 301         ;;
 302         stf.spill.nta [loc0]=f111,-256
 303         stf.spill.nta [loc1]=f103,-256
 304         ;;
 305         stf.spill.nta [loc0]=f95,-256
 306         stf.spill.nta [loc1]=f87,-256
 307         ;;
 308         stf.spill.nta [loc0]=f79,-256
 309         stf.spill.nta [loc1]=f71,-256
 310         ;;
 311         stf.spill.nta [loc0]=f63,-256
 312         stf.spill.nta [loc1]=f55,-256
 313         adds loc2=96*16-32,in0
 314         ;;
 315         stf.spill.nta [loc0]=f47,-256
 316         stf.spill.nta [loc1]=f39,-256
 317         adds loc3=96*16-32-128,in0
 318         ;;
 319         stf.spill.nta [loc2]=f126,-256
 320         stf.spill.nta [loc3]=f118,-256
 321         ;;
 322         stf.spill.nta [loc2]=f110,-256
 323         stf.spill.nta [loc3]=f102,-256
 324         ;;
 325         stf.spill.nta [loc2]=f94,-256
 326         stf.spill.nta [loc3]=f86,-256
 327         ;;
 328         stf.spill.nta [loc2]=f78,-256
 329         stf.spill.nta [loc3]=f70,-256
 330         ;;
 331         stf.spill.nta [loc2]=f62,-256
 332         stf.spill.nta [loc3]=f54,-256
 333         adds loc0=96*16-48,in0
 334         ;;
 335         stf.spill.nta [loc2]=f46,-256
 336         stf.spill.nta [loc3]=f38,-256
 337         adds loc1=96*16-48-128,in0
 338         ;;
 339         stf.spill.nta [loc0]=f125,-256
 340         stf.spill.nta [loc1]=f117,-256
 341         ;;
 342         stf.spill.nta [loc0]=f109,-256
 343         stf.spill.nta [loc1]=f101,-256
 344         ;;
 345         stf.spill.nta [loc0]=f93,-256
 346         stf.spill.nta [loc1]=f85,-256
 347         ;;
 348         stf.spill.nta [loc0]=f77,-256
 349         stf.spill.nta [loc1]=f69,-256
 350         ;;
 351         stf.spill.nta [loc0]=f61,-256
 352         stf.spill.nta [loc1]=f53,-256
 353         adds loc2=96*16-64,in0
 354         ;;
 355         stf.spill.nta [loc0]=f45,-256
 356         stf.spill.nta [loc1]=f37,-256
 357         adds loc3=96*16-64-128,in0
 358         ;;
 359         stf.spill.nta [loc2]=f124,-256
 360         stf.spill.nta [loc3]=f116,-256
 361         ;;
 362         stf.spill.nta [loc2]=f108,-256
 363         stf.spill.nta [loc3]=f100,-256
 364         ;;
 365         stf.spill.nta [loc2]=f92,-256
 366         stf.spill.nta [loc3]=f84,-256
 367         ;;
 368         stf.spill.nta [loc2]=f76,-256
 369         stf.spill.nta [loc3]=f68,-256
 370         ;;
 371         stf.spill.nta [loc2]=f60,-256
 372         stf.spill.nta [loc3]=f52,-256
 373         adds loc0=96*16-80,in0
 374         ;;
 375         stf.spill.nta [loc2]=f44,-256
 376         stf.spill.nta [loc3]=f36,-256
 377         adds loc1=96*16-80-128,in0
 378         ;;
 379         stf.spill.nta [loc0]=f123,-256
 380         stf.spill.nta [loc1]=f115,-256
 381         ;;
 382         stf.spill.nta [loc0]=f107,-256
 383         stf.spill.nta [loc1]=f99,-256
 384         ;;
 385         stf.spill.nta [loc0]=f91,-256
 386         stf.spill.nta [loc1]=f83,-256
 387         ;;
 388         stf.spill.nta [loc0]=f75,-256
 389         stf.spill.nta [loc1]=f67,-256
 390         ;;
 391         stf.spill.nta [loc0]=f59,-256
 392         stf.spill.nta [loc1]=f51,-256
 393         adds loc2=96*16-96,in0
 394         ;;
 395         stf.spill.nta [loc0]=f43,-256
 396         stf.spill.nta [loc1]=f35,-256
 397         adds loc3=96*16-96-128,in0
 398         ;;
 399         stf.spill.nta [loc2]=f122,-256
 400         stf.spill.nta [loc3]=f114,-256
 401         ;;
 402         stf.spill.nta [loc2]=f106,-256
 403         stf.spill.nta [loc3]=f98,-256
 404         ;;
 405         stf.spill.nta [loc2]=f90,-256
 406         stf.spill.nta [loc3]=f82,-256
 407         ;;
 408         stf.spill.nta [loc2]=f74,-256
 409         stf.spill.nta [loc3]=f66,-256
 410         ;;
 411         stf.spill.nta [loc2]=f58,-256
 412         stf.spill.nta [loc3]=f50,-256
 413         adds loc0=96*16-112,in0
 414         ;;
 415         stf.spill.nta [loc2]=f42,-256
 416         stf.spill.nta [loc3]=f34,-256
 417         adds loc1=96*16-112-128,in0
 418         ;;
 419         stf.spill.nta [loc0]=f121,-256
 420         stf.spill.nta [loc1]=f113,-256
 421         ;;
 422         stf.spill.nta [loc0]=f105,-256
 423         stf.spill.nta [loc1]=f97,-256
 424         ;;
 425         stf.spill.nta [loc0]=f89,-256
 426         stf.spill.nta [loc1]=f81,-256
 427         ;;
 428         stf.spill.nta [loc0]=f73,-256
 429         stf.spill.nta [loc1]=f65,-256
 430         ;;
 431         stf.spill.nta [loc0]=f57,-256
 432         stf.spill.nta [loc1]=f49,-256
 433         adds loc2=96*16-128,in0
 434         ;;
 435         stf.spill.nta [loc0]=f41,-256
 436         stf.spill.nta [loc1]=f33,-256
 437         adds loc3=96*16-128-128,in0
 438         ;;
 439         stf.spill.nta [loc2]=f120,-256
 440         stf.spill.nta [loc3]=f112,-256
 441         ;;
 442         stf.spill.nta [loc2]=f104,-256
 443         stf.spill.nta [loc3]=f96,-256
 444         ;;
 445         stf.spill.nta [loc2]=f88,-256
 446         stf.spill.nta [loc3]=f80,-256
 447         ;;
 448         stf.spill.nta [loc2]=f72,-256
 449         stf.spill.nta [loc3]=f64,-256
 450         ;;
 451         stf.spill.nta [loc2]=f56,-256
 452         stf.spill.nta [loc3]=f48,-256
 453         ;;
 454         stf.spill.nta [loc2]=f40
 455         stf.spill.nta [loc3]=f32
 456         br.ret.sptk.many rp
 457 END(__ia64_save_fpu)
 458
 459 GLOBAL_ENTRY(__ia64_load_fpu)
 460         alloc r2=ar.pfs,1,2,0,0
 461         adds r3=128,in0
 462         adds r14=256,in0
 463         adds r15=384,in0
 464         mov loc0=512
 465         mov loc1=-1024+16
 466         ;;
 467         ldf.fill.nta f32=[in0],loc0
 468         ldf.fill.nta f40=[ r3],loc0
 469         ldf.fill.nta f48=[r14],loc0
 470         ldf.fill.nta f56=[r15],loc0
 471         ;;
 472         ldf.fill.nta f64=[in0],loc0
 473         ldf.fill.nta f72=[ r3],loc0
 474         ldf.fill.nta f80=[r14],loc0
 475         ldf.fill.nta f88=[r15],loc0
 476         ;;
 477         ldf.fill.nta f96=[in0],loc1
 478         ldf.fill.nta f104=[ r3],loc1
 479         ldf.fill.nta f112=[r14],loc1
 480         ldf.fill.nta f120=[r15],loc1
 481         ;;
 482         ldf.fill.nta f33=[in0],loc0
 483         ldf.fill.nta f41=[ r3],loc0
 484         ldf.fill.nta f49=[r14],loc0
 485         ldf.fill.nta f57=[r15],loc0
 486         ;;
 487         ldf.fill.nta f65=[in0],loc0
 488         ldf.fill.nta f73=[ r3],loc0
 489         ldf.fill.nta f81=[r14],loc0
 490         ldf.fill.nta f89=[r15],loc0
 491         ;;
 492         ldf.fill.nta f97=[in0],loc1
 493         ldf.fill.nta f105=[ r3],loc1
 494         ldf.fill.nta f113=[r14],loc1
 495         ldf.fill.nta f121=[r15],loc1
 496         ;;
 497         ldf.fill.nta f34=[in0],loc0
 498         ldf.fill.nta f42=[ r3],loc0
 499         ldf.fill.nta f50=[r14],loc0
 500         ldf.fill.nta f58=[r15],loc0
 501         ;;
 502         ldf.fill.nta f66=[in0],loc0
 503         ldf.fill.nta f74=[ r3],loc0
 504         ldf.fill.nta f82=[r14],loc0
 505         ldf.fill.nta f90=[r15],loc0
 506         ;;
 507         ldf.fill.nta f98=[in0],loc1
 508         ldf.fill.nta f106=[ r3],loc1
 509         ldf.fill.nta f114=[r14],loc1
 510         ldf.fill.nta f122=[r15],loc1
 511         ;;
 512         ldf.fill.nta f35=[in0],loc0
 513         ldf.fill.nta f43=[ r3],loc0
 514         ldf.fill.nta f51=[r14],loc0
 515         ldf.fill.nta f59=[r15],loc0
 516         ;;
 517         ldf.fill.nta f67=[in0],loc0
 518         ldf.fill.nta f75=[ r3],loc0
 519         ldf.fill.nta f83=[r14],loc0
 520         ldf.fill.nta f91=[r15],loc0
 521         ;;
 522         ldf.fill.nta f99=[in0],loc1
 523         ldf.fill.nta f107=[ r3],loc1
 524         ldf.fill.nta f115=[r14],loc1
 525         ldf.fill.nta f123=[r15],loc1
 526         ;;
 527         ldf.fill.nta f36=[in0],loc0
 528         ldf.fill.nta f44=[ r3],loc0
 529         ldf.fill.nta f52=[r14],loc0
 530         ldf.fill.nta f60=[r15],loc0
 531         ;;
 532         ldf.fill.nta f68=[in0],loc0
 533         ldf.fill.nta f76=[ r3],loc0
 534         ldf.fill.nta f84=[r14],loc0
 535         ldf.fill.nta f92=[r15],loc0
 536         ;;
 537         ldf.fill.nta f100=[in0],loc1
 538         ldf.fill.nta f108=[ r3],loc1
 539         ldf.fill.nta f116=[r14],loc1
 540         ldf.fill.nta f124=[r15],loc1
 541         ;;
 542         ldf.fill.nta f37=[in0],loc0
 543         ldf.fill.nta f45=[ r3],loc0
 544         ldf.fill.nta f53=[r14],loc0
 545         ldf.fill.nta f61=[r15],loc0
 546         ;;
 547         ldf.fill.nta f69=[in0],loc0
 548         ldf.fill.nta f77=[ r3],loc0
 549         ldf.fill.nta f85=[r14],loc0
 550         ldf.fill.nta f93=[r15],loc0
 551         ;;
 552         ldf.fill.nta f101=[in0],loc1
 553         ldf.fill.nta f109=[ r3],loc1
 554         ldf.fill.nta f117=[r14],loc1
 555         ldf.fill.nta f125=[r15],loc1
 556         ;;
 557         ldf.fill.nta f38 =[in0],loc0
 558         ldf.fill.nta f46 =[ r3],loc0
 559         ldf.fill.nta f54 =[r14],loc0
 560         ldf.fill.nta f62 =[r15],loc0
 561         ;;
 562         ldf.fill.nta f70 =[in0],loc0
 563         ldf.fill.nta f78 =[ r3],loc0
 564         ldf.fill.nta f86 =[r14],loc0
 565         ldf.fill.nta f94 =[r15],loc0
 566         ;;
 567         ldf.fill.nta f102=[in0],loc1
 568         ldf.fill.nta f110=[ r3],loc1
 569         ldf.fill.nta f118=[r14],loc1
 570         ldf.fill.nta f126=[r15],loc1
 571         ;;
 572         ldf.fill.nta f39 =[in0],loc0
 573         ldf.fill.nta f47 =[ r3],loc0
 574         ldf.fill.nta f55 =[r14],loc0
 575         ldf.fill.nta f63 =[r15],loc0
 576         ;;
 577         ldf.fill.nta f71 =[in0],loc0
 578         ldf.fill.nta f79 =[ r3],loc0
 579         ldf.fill.nta f87 =[r14],loc0
 580         ldf.fill.nta f95 =[r15],loc0
 581         ;;
 582         ldf.fill.nta f103=[in0]
 583         ldf.fill.nta f111=[ r3]
 584         ldf.fill.nta f119=[r14]
 585         ldf.fill.nta f127=[r15]
 586         br.ret.sptk.many rp
 587 END(__ia64_load_fpu)
 588
 589 GLOBAL_ENTRY(__ia64_init_fpu)
 590         stf.spill [sp]=f0               // M3
 591         mov      f32=f0                 // F
 592         nop.b    0
 593
 594         ldfps    f33,f34=[sp]           // M0
 595         ldfps    f35,f36=[sp]           // M1
 596         mov      f37=f0                 // F
 597         ;;
 598
 599         setf.s   f38=r0                 // M2
 600         setf.s   f39=r0                 // M3
 601         mov      f40=f0                 // F
 602
 603         ldfps    f41,f42=[sp]           // M0
 604         ldfps    f43,f44=[sp]           // M1
 605         mov      f45=f0                 // F
 606
 607         setf.s   f46=r0                 // M2
 608         setf.s   f47=r0                 // M3
 609         mov      f48=f0                 // F
 610
 611         ldfps    f49,f50=[sp]           // M0
 612         ldfps    f51,f52=[sp]           // M1
 613         mov      f53=f0                 // F
 614
 615         setf.s   f54=r0                 // M2
 616         setf.s   f55=r0                 // M3
 617         mov      f56=f0                 // F
 618
 619         ldfps    f57,f58=[sp]           // M0
 620         ldfps    f59,f60=[sp]           // M1
 621         mov      f61=f0                 // F
 622
 623         setf.s   f62=r0                 // M2
 624         setf.s   f63=r0                 // M3
 625         mov      f64=f0                 // F
 626
 627         ldfps    f65,f66=[sp]           // M0
 628         ldfps    f67,f68=[sp]           // M1
 629         mov      f69=f0                 // F
 630
 631         setf.s   f70=r0                 // M2
 632         setf.s   f71=r0                 // M3
 633         mov      f72=f0                 // F
 634
 635         ldfps    f73,f74=[sp]           // M0
 636         ldfps    f75,f76=[sp]           // M1
 637         mov      f77=f0                 // F
 638
 639         setf.s   f78=r0                 // M2
 640         setf.s   f79=r0                 // M3
 641         mov      f80=f0                 // F
 642
 643         ldfps    f81,f82=[sp]           // M0
 644         ldfps    f83,f84=[sp]           // M1
 645         mov      f85=f0                 // F
 646
 647         setf.s   f86=r0                 // M2
 648         setf.s   f87=r0                 // M3
 649         mov      f88=f0                 // F
 650
 651         /*
 652          * When the instructions are cached, it would be faster to initialize
 653          * the remaining registers with simply mov instructions (F-unit).
 654          * This gets the time down to ~29 cycles.  However, this would use up
 655          * 33 bundles, whereas continuing with the above pattern yields
 656          * 10 bundles and ~30 cycles.
 657          */
 658
 659         ldfps    f89,f90=[sp]           // M0
 660         ldfps    f91,f92=[sp]           // M1
 661         mov      f93=f0                 // F
 662
 663         setf.s   f94=r0                 // M2
 664         setf.s   f95=r0                 // M3
 665         mov      f96=f0                 // F
 666
 667         ldfps    f97,f98=[sp]           // M0
 668         ldfps    f99,f100=[sp]          // M1
 669         mov      f101=f0                // F
 670
 671         setf.s   f102=r0                // M2
 672         setf.s   f103=r0                // M3
 673         mov      f104=f0                // F
 674
 675         ldfps    f105,f106=[sp]         // M0
 676         ldfps    f107,f108=[sp]         // M1
 677         mov      f109=f0                // F
 678
 679         setf.s   f110=r0                // M2
 680         setf.s   f111=r0                // M3
 681         mov      f112=f0                // F
 682
 683         ldfps    f113,f114=[sp]         // M0
 684         ldfps    f115,f116=[sp]         // M1
 685         mov      f117=f0                // F
 686
 687         setf.s   f118=r0                // M2
 688         setf.s   f119=r0                // M3
 689         mov      f120=f0                // F
 690
 691         ldfps    f121,f122=[sp]         // M0
 692         ldfps    f123,f124=[sp]         // M1
 693         mov      f125=f0                // F
 694
 695         setf.s   f126=r0                // M2
 696         setf.s   f127=r0                // M3
 697         br.ret.sptk.many rp             // F
 698 END(__ia64_init_fpu)
 699
 700 /*
 701  * Switch execution mode from virtual to physical
 702  *
 703  * Inputs:
 704  *      r16 = new psr to establish
 705  *
 706  * Note: RSE must already be in enforced lazy mode
 707  */
 708 GLOBAL_ENTRY(ia64_switch_mode_phys)
 709  {
 710         alloc r2=ar.pfs,0,0,0,0
 711         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 712         mov r15=ip
 713  }
 714         ;;
 715  {
 716         flushrs                         // must be first insn in group
 717         srlz.i
 718  }
 719         ;;
 720         mov cr.ipsr=r16                 // set new PSR
 721         add r3=1f-ia64_switch_mode_phys,r15
 722
 723         mov r17=ar.bsp
 724         mov r14=rp                      // get return address into a general register
 725         ;;
 726
 727         // going to physical mode, use tpa to translate virt->phys
 728         tpa r17=r17
 729         tpa r3=r3
 730         tpa sp=sp
 731         tpa r14=r14
 732         ;;
 733
 734         mov r18=ar.rnat                 // save ar.rnat
 735         mov ar.bspstore=r17             // this steps on ar.rnat
 736         mov cr.iip=r3
 737         mov cr.ifs=r0
 738         ;;
 739         mov ar.rnat=r18                 // restore ar.rnat
 740         rfi                             // must be last insn in group
 741         ;;
 742 1:      mov rp=r14
 743         br.ret.sptk.many rp
 744 END(ia64_switch_mode_phys)
 745
 746 /*
 747  * Switch execution mode from physical to virtual
 748  *
 749  * Inputs:
 750  *      r16 = new psr to establish
 751  *
 752  * Note: RSE must already be in enforced lazy mode
 753  */
 754 GLOBAL_ENTRY(ia64_switch_mode_virt)
 755  {
 756         alloc r2=ar.pfs,0,0,0,0
 757         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 758         mov r15=ip
 759  }
 760         ;;
 761  {
 762         flushrs                         // must be first insn in group
 763         srlz.i
 764  }
 765         ;;
 766         mov cr.ipsr=r16                 // set new PSR
 767         add r3=1f-ia64_switch_mode_virt,r15
 768
 769         mov r17=ar.bsp
 770         mov r14=rp                      // get return address into a general register
 771         ;;
 772
 773         // going to virtual
 774         //   - for code addresses, set upper bits of addr to KERNEL_START
 775         //   - for stack addresses, set upper 3 bits to 0xe.... Dont change any of the
 776         //     lower bits since we want it to stay identity mapped
 777         movl r18=KERNEL_START
 778         dep r3=0,r3,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 779         dep r14=0,r14,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 780         dep r17=-1,r17,61,3
 781         dep sp=-1,sp,61,3
 782         ;;
 783         or r3=r3,r18
 784         or r14=r14,r18
 785         ;;
 786
 787         mov r18=ar.rnat                 // save ar.rnat
 788         mov ar.bspstore=r17             // this steps on ar.rnat
 789         mov cr.iip=r3
 790         mov cr.ifs=r0
 791         ;;
 792         mov ar.rnat=r18                 // restore ar.rnat
 793         rfi                             // must be last insn in group
 794         ;;
 795 1:      mov rp=r14
 796         br.ret.sptk.many rp
 797 END(ia64_switch_mode_virt)
 798
 799 GLOBAL_ENTRY(ia64_delay_loop)
 800         .prologue
 801 {       nop 0                   // work around GAS unwind info generation bug...
 802         .save ar.lc,r2
 803         mov r2=ar.lc
 804         .body
 805         ;;
 806         mov ar.lc=r32
 807 }
 808         ;;
 809         // force loop to be 32-byte aligned (GAS bug means we cannot use .align
 810         // inside function body without corrupting unwind info).
 811 {       nop 0 }
 812 1:      br.cloop.sptk.few 1b
 813         ;;
 814         mov ar.lc=r2
 815         br.ret.sptk.many rp
 816 END(ia64_delay_loop)
 817
 818 /*
 819  * Return a CPU-local timestamp in nano-seconds.  This timestamp is
 820  * NOT synchronized across CPUs its return value must never be
 821  * compared against the values returned on another CPU.  The usage in
 822  * kernel/sched.c ensures that.
 823  *
 824  * The return-value of sched_clock() is NOT supposed to wrap-around.
 825  * If it did, it would cause some scheduling hiccups (at the worst).
 826  * Fortunately, with a 64-bit cycle-counter ticking at 100GHz, even
 827  * that would happen only once every 5+ years.
 828  *
 829  * The code below basically calculates:
 830  *
 831  *   (ia64_get_itc() * local_cpu_data->nsec_per_cyc) >> IA64_NSEC_PER_CYC_SHIFT
 832  *
 833  * except that the multiplication and the shift are done with 128-bit
 834  * intermediate precision so that we can produce a full 64-bit result.
 835  */
 836 GLOBAL_ENTRY(sched_clock)
 837         addl r8=THIS_CPU(cpu_info) + IA64_CPUINFO_NSEC_PER_CYC_OFFSET,r0
 838         mov.m r9=ar.itc         // fetch cycle-counter                          (35 cyc)
 839         ;;
 840         ldf8 f8=[r8]
 841         ;;
 842         setf.sig f9=r9          // certain to stall, so issue it _after_ ldf8...
 843         ;;
 844         xmpy.lu f10=f9,f8       // calculate low 64 bits of 128-bit product     (4 cyc)
 845         xmpy.hu f11=f9,f8       // calculate high 64 bits of 128-bit product
 846         ;;
 847         getf.sig r8=f10         //                                              (5 cyc)
 848         getf.sig r9=f11
 849         ;;
 850         shrp r8=r9,r8,IA64_NSEC_PER_CYC_SHIFT
 851         br.ret.sptk.many rp
 852 END(sched_clock)
 853
 854 GLOBAL_ENTRY(start_kernel_thread)
 855         .prologue
 856         .save rp, r0                            // this is the end of the call-chain
 857         .body
 858         alloc r2 = ar.pfs, 0, 0, 2, 0
 859         mov out0 = r9
 860         mov out1 = r11;;
 861         br.call.sptk.many rp = kernel_thread_helper;;
 862         mov out0 = r8
 863         br.call.sptk.many rp = sys_exit;;
 864 1:      br.sptk.few 1b                          // not reached
 865 END(start_kernel_thread)
 866
 867 #ifdef CONFIG_IA64_BRL_EMU
 868
 869 /*
 870  *  Assembly routines used by brl_emu.c to set preserved register state.
 871  */
 872
 873 #define SET_REG(reg)                            \
 874  GLOBAL_ENTRY(ia64_set_##reg);                  \
 875         alloc r16=ar.pfs,1,0,0,0;               \
 876         mov reg=r32;                            \
 877         ;;                                      \
 878         br.ret.sptk.many rp;                    \
 879  END(ia64_set_##reg)
 880
 881 SET_REG(b1);
 882 SET_REG(b2);
 883 SET_REG(b3);
 884 SET_REG(b4);
 885 SET_REG(b5);
 886
 887 #endif /* CONFIG_IA64_BRL_EMU */
 888
 889 #ifdef CONFIG_SMP
 890         /*
 891          * This routine handles spinlock contention.  It uses a non-standard calling
 892          * convention to avoid converting leaf routines into interior routines.  Because
 893          * of this special convention, there are several restrictions:
 894          *
 895          * - do not use gp relative variables, this code is called from the kernel
 896          *   and from modules, r1 is undefined.
 897          * - do not use stacked registers, the caller owns them.
 898          * - do not use the scratch stack space, the caller owns it.
 899          * - do not use any registers other than the ones listed below
 900          *
 901          * Inputs:
 902          *   ar.pfs - saved CFM of caller
 903          *   ar.ccv - 0 (and available for use)
 904          *   r27    - flags from spin_lock_irqsave or 0.  Must be preserved.
 905          *   r28    - available for use.
 906          *   r29    - available for use.
 907          *   r30    - available for use.
 908          *   r31    - address of lock, available for use.
 909          *   b6     - return address
 910          *   p14    - available for use.
 911          *   p15    - used to track flag status.
 912          *
 913          * If you patch this code to use more registers, do not forget to update
 914          * the clobber lists for spin_lock() in include/asm-ia64/spinlock.h.
 915          */
 916
 917 #if __GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 3)
 918
 919 GLOBAL_ENTRY(ia64_spinlock_contention_pre3_4)
 920         .prologue
 921         .save ar.pfs, r0        // this code effectively has a zero frame size
 922         .save rp, r28
 923         .body
 924         nop 0
 925         tbit.nz p15,p0=r27,IA64_PSR_I_BIT
 926         .restore sp             // pop existing prologue after next insn
 927         mov b6 = r28
 928         .prologue
 929         .save ar.pfs, r0
 930         .altrp b6
 931         .body
 932         ;;
 933 (p15)   ssm psr.i               // reenable interrupts if they were on
 934                                 // DavidM says that srlz.d is slow and is not required in this case
 935 .wait:
 936         // exponential backoff, kdb, lockmeter etc. go in here
 937         hint @pause
 938         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
 939         nop 0
 940         ;;
 941         cmp4.ne p14,p0=r30,r0
 942 (p14)   br.cond.sptk.few .wait
 943 (p15)   rsm psr.i               // disable interrupts if we reenabled them
 944         br.cond.sptk.few b6     // lock is now free, try to acquire
 945 END(ia64_spinlock_contention_pre3_4)
 946
 947 #else
 948
 949 GLOBAL_ENTRY(ia64_spinlock_contention)
 950         .prologue
 951         .altrp b6
 952         .body
 953         tbit.nz p15,p0=r27,IA64_PSR_I_BIT
 954         ;;
 955 .wait:
 956 (p15)   ssm psr.i               // reenable interrupts if they were on
 957                                 // DavidM says that srlz.d is slow and is not required in this case
 958 .wait2:
 959         // exponential backoff, kdb, lockmeter etc. go in here
 960         hint @pause
 961         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
 962         ;;
 963         cmp4.ne p14,p0=r30,r0
 964         mov r30 = 1
 965 (p14)   br.cond.sptk.few .wait2
 966 (p15)   rsm psr.i               // disable interrupts if we reenabled them
 967         ;;
 968         cmpxchg4.acq r30=[r31], r30, ar.ccv
 969         ;;
 970         cmp4.ne p14,p0=r0,r30
 971 (p14)   br.cond.sptk.few .wait
 972
 973         br.ret.sptk.many b6     // lock is now taken
 974 END(ia64_spinlock_contention)
 975
 976 #endif
 977
 978 #endif /* CONFIG_SMP */