arch/ia64/kernel/head.S

   1 /*
   2  * Here is where the ball gets rolling as far as the kernel is concerned.
   3  * When control is transferred to _start, the bootload has already
   4  * loaded us to the correct address.  All that's left to do here is
   5  * to set up the kernel's global pointer and jump to the kernel
   6  * entry point.
   7  *
   8  * Copyright (C) 1998-2001, 2003 Hewlett-Packard Co
   9  *      David Mosberger-Tang <davidm@hpl.hp.com>
  10  *      Stephane Eranian <eranian@hpl.hp.com>
  11  * Copyright (C) 1999 VA Linux Systems
  12  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  13  * Copyright (C) 1999 Intel Corp.
  14  * Copyright (C) 1999 Asit Mallick <Asit.K.Mallick@intel.com>
  15  * Copyright (C) 1999 Don Dugger <Don.Dugger@intel.com>
  16  * Copyright (C) 2002 Fenghua Yu <fenghua.yu@intel.com>
  17  *   -Optimize __ia64_save_fpu() and __ia64_load_fpu() for Itanium 2.
  18  */
  19
  20 #include <linux/config.h>
  21
  22 #include <asm/asmmacro.h>
  23 #include <asm/fpu.h>
  24 #include <asm/kregs.h>
  25 #include <asm/mmu_context.h>
  26 #include <asm/offsets.h>
  27 #include <asm/pal.h>
  28 #include <asm/pgtable.h>
  29 #include <asm/processor.h>
  30 #include <asm/ptrace.h>
  31 #include <asm/system.h>
  32
  33         .section __special_page_section,"ax"
  34
  35         .global empty_zero_page
  36 empty_zero_page:
  37         .skip PAGE_SIZE
  38
  39         .global swapper_pg_dir
  40 swapper_pg_dir:
  41         .skip PAGE_SIZE
  42
  43         .rodata
  44 halt_msg:
  45         stringz "Halting kernel\n"
  46
  47         .text
  48
  49         .global start_ap
  50
  51         /*
  52          * Start the kernel.  When the bootloader passes control to _start(), r28
  53          * points to the address of the boot parameter area.  Execution reaches
  54          * here in physical mode.
  55          */
  56 GLOBAL_ENTRY(_start)
  57 start_ap:
  58         .prologue
  59         .save rp, r4            // terminate unwind chain with a NULL rp
  60         mov r4=r0
  61         .body
  62
  63         rsm psr.i | psr.ic
  64         ;;
  65         srlz.i
  66         ;;
  67         /*
  68          * Initialize kernel region registers:
  69          *      rr[5]: VHPT enabled, page size = PAGE_SHIFT
  70          *      rr[6]: VHPT disabled, page size = IA64_GRANULE_SHIFT
  71          *      rr[5]: VHPT disabled, page size = IA64_GRANULE_SHIFT
  72          */
  73         mov r16=((ia64_rid(IA64_REGION_ID_KERNEL, (5<<61)) << 8) | (PAGE_SHIFT << 2) | 1)
  74         movl r17=(5<<61)
  75         mov r18=((ia64_rid(IA64_REGION_ID_KERNEL, (6<<61)) << 8) | (IA64_GRANULE_SHIFT << 2))
  76         movl r19=(6<<61)
  77         mov r20=((ia64_rid(IA64_REGION_ID_KERNEL, (7<<61)) << 8) | (IA64_GRANULE_SHIFT << 2))
  78         movl r21=(7<<61)
  79         ;;
  80         mov rr[r17]=r16
  81         mov rr[r19]=r18
  82         mov rr[r21]=r20
  83         ;;
  84         /*
  85          * Now pin mappings into the TLB for kernel text and data
  86          */
  87         mov r18=KERNEL_TR_PAGE_SHIFT<<2
  88         movl r17=KERNEL_START
  89         ;;
  90         mov cr.itir=r18
  91         mov cr.ifa=r17
  92         mov r16=IA64_TR_KERNEL
  93         mov r3=ip
  94         movl r18=PAGE_KERNEL
  95         ;;
  96         dep r2=0,r3,0,KERNEL_TR_PAGE_SHIFT
  97         ;;
  98         or r18=r2,r18
  99         ;;
 100         srlz.i
 101         ;;
 102         itr.i itr[r16]=r18
 103         ;;
 104         itr.d dtr[r16]=r18
 105         ;;
 106         srlz.i
 107
 108         /*
 109          * Switch into virtual mode:
 110          */
 111         movl r16=(IA64_PSR_IT|IA64_PSR_IC|IA64_PSR_DT|IA64_PSR_RT|IA64_PSR_DFH|IA64_PSR_BN \
 112                   |IA64_PSR_DI)
 113         ;;
 114         mov cr.ipsr=r16
 115         movl r17=1f
 116         ;;
 117         mov cr.iip=r17
 118         mov cr.ifs=r0
 119         ;;
 120         rfi
 121         ;;
 122 1:      // now we are in virtual mode
 123
 124         // set IVT entry point---can't access I/O ports without it
 125         movl r3=ia64_ivt
 126         ;;
 127         mov cr.iva=r3
 128         movl r2=FPSR_DEFAULT
 129         ;;
 130         srlz.i
 131         movl gp=__gp
 132
 133         mov ar.fpsr=r2
 134         ;;
 135
 136 #define isAP    p2      // are we an Application Processor?
 137 #define isBP    p3      // are we the Bootstrap Processor?
 138
 139 #ifdef CONFIG_SMP
 140         /*
 141          * Find the init_task for the currently booting CPU.  At poweron, and in
 142          * UP mode, task_for_booting_cpu is NULL.
 143          */
 144         movl r3=task_for_booting_cpu
 145         ;;
 146         ld8 r3=[r3]
 147         movl r2=init_task
 148         ;;
 149         cmp.eq isBP,isAP=r3,r0
 150         ;;
 151 (isAP)  mov r2=r3
 152 #else
 153         movl r2=init_task
 154         cmp.eq isBP,isAP=r0,r0
 155 #endif
 156         ;;
 157         tpa r3=r2               // r3 == phys addr of task struct
 158         // load mapping for stack (virtaddr in r2, physaddr in r3)
 159         rsm psr.ic
 160         movl r17=PAGE_KERNEL
 161         ;;
 162         srlz.d
 163         dep r18=0,r3,0,12
 164         ;;
 165         or r18=r17,r18
 166         dep r2=-1,r3,61,3       // IMVA of task
 167         ;;
 168         mov r17=rr[r2]
 169         shr.u r16=r3,IA64_GRANULE_SHIFT
 170         ;;
 171         dep r17=0,r17,8,24
 172         ;;
 173         mov cr.itir=r17
 174         mov cr.ifa=r2
 175
 176         mov r19=IA64_TR_CURRENT_STACK
 177         ;;
 178         itr.d dtr[r19]=r18
 179         ;;
 180         ssm psr.ic
 181         srlz.d
 182         ;;
 183
 184         // load the "current" pointer (r13) and ar.k6 with the current task
 185         mov IA64_KR(CURRENT)=r2         // virtual address
 186         mov IA64_KR(CURRENT_STACK)=r16
 187         mov r13=r2
 188         /*
 189          * Reserve space at the top of the stack for "struct pt_regs".  Kernel threads
 190          * don't store interesting values in that structure, but the space still needs
 191          * to be there because time-critical stuff such as the context switching can
 192          * be implemented more efficiently (for example, __switch_to()
 193          * always sets the psr.dfh bit of the task it is switching to).
 194          */
 195         addl r12=IA64_STK_OFFSET-IA64_PT_REGS_SIZE-16,r2
 196         addl r2=IA64_RBS_OFFSET,r2      // initialize the RSE
 197         mov ar.rsc=0            // place RSE in enforced lazy mode
 198         ;;
 199         loadrs                  // clear the dirty partition
 200         ;;
 201         mov ar.bspstore=r2      // establish the new RSE stack
 202         ;;
 203         mov ar.rsc=0x3          // place RSE in eager mode
 204
 205 (isBP)  dep r28=-1,r28,61,3     // make address virtual
 206 (isBP)  movl r2=ia64_boot_param
 207         ;;
 208 (isBP)  st8 [r2]=r28            // save the address of the boot param area passed by the bootloader
 209
 210 #ifdef CONFIG_IA64_EARLY_PRINTK
 211         .rodata
 212 alive_msg:
 213         stringz "I'm alive and well\n"
 214 alive_msg_end:
 215         .previous
 216
 217         alloc r2=ar.pfs,0,0,2,0
 218         movl out0=alive_msg
 219         movl out1=alive_msg_end-alive_msg-1
 220         ;;
 221         br.call.sptk.many rp=early_printk
 222 1:      // force new bundle
 223 #endif /* CONFIG_IA64_EARLY_PRINTK */
 224
 225 #ifdef CONFIG_SMP
 226 (isAP)  br.call.sptk.many rp=start_secondary
 227 .ret0:
 228 (isAP)  br.cond.sptk self
 229 #endif
 230
 231         // This is executed by the bootstrap processor (bsp) only:
 232
 233 #ifdef CONFIG_IA64_FW_EMU
 234         // initialize PAL & SAL emulator:
 235         br.call.sptk.many rp=sys_fw_init
 236 .ret1:
 237 #endif
 238         br.call.sptk.many rp=start_kernel
 239 .ret2:  addl r3=@ltoff(halt_msg),gp
 240         ;;
 241         alloc r2=ar.pfs,8,0,2,0
 242         ;;
 243         ld8 out0=[r3]
 244         br.call.sptk.many b0=console_print
 245 self:   br.sptk.many self               // endless loop
 246 END(_start)
 247
 248 GLOBAL_ENTRY(ia64_save_debug_regs)
 249         alloc r16=ar.pfs,1,0,0,0
 250         mov r20=ar.lc                   // preserve ar.lc
 251         mov ar.lc=IA64_NUM_DBG_REGS-1
 252         mov r18=0
 253         add r19=IA64_NUM_DBG_REGS*8,in0
 254         ;;
 255 1:      mov r16=dbr[r18]
 256 #ifdef CONFIG_ITANIUM
 257         ;;
 258         srlz.d
 259 #endif
 260         mov r17=ibr[r18]
 261         add r18=1,r18
 262         ;;
 263         st8.nta [in0]=r16,8
 264         st8.nta [r19]=r17,8
 265         br.cloop.sptk.many 1b
 266         ;;
 267         mov ar.lc=r20                   // restore ar.lc
 268         br.ret.sptk.many rp
 269 END(ia64_save_debug_regs)
 270
 271 GLOBAL_ENTRY(ia64_load_debug_regs)
 272         alloc r16=ar.pfs,1,0,0,0
 273         lfetch.nta [in0]
 274         mov r20=ar.lc                   // preserve ar.lc
 275         add r19=IA64_NUM_DBG_REGS*8,in0
 276         mov ar.lc=IA64_NUM_DBG_REGS-1
 277         mov r18=-1
 278         ;;
 279 1:      ld8.nta r16=[in0],8
 280         ld8.nta r17=[r19],8
 281         add r18=1,r18
 282         ;;
 283         mov dbr[r18]=r16
 284 #ifdef CONFIG_ITANIUM
 285         ;;
 286         srlz.d                          // Errata 132 (NoFix status)
 287 #endif
 288         mov ibr[r18]=r17
 289         br.cloop.sptk.many 1b
 290         ;;
 291         mov ar.lc=r20                   // restore ar.lc
 292         br.ret.sptk.many rp
 293 END(ia64_load_debug_regs)
 294
 295 GLOBAL_ENTRY(__ia64_save_fpu)
 296         alloc r2=ar.pfs,1,4,0,0
 297         adds loc0=96*16-16,in0
 298         adds loc1=96*16-16-128,in0
 299         ;;
 300         stf.spill.nta [loc0]=f127,-256
 301         stf.spill.nta [loc1]=f119,-256
 302         ;;
 303         stf.spill.nta [loc0]=f111,-256
 304         stf.spill.nta [loc1]=f103,-256
 305         ;;
 306         stf.spill.nta [loc0]=f95,-256
 307         stf.spill.nta [loc1]=f87,-256
 308         ;;
 309         stf.spill.nta [loc0]=f79,-256
 310         stf.spill.nta [loc1]=f71,-256
 311         ;;
 312         stf.spill.nta [loc0]=f63,-256
 313         stf.spill.nta [loc1]=f55,-256
 314         adds loc2=96*16-32,in0
 315         ;;
 316         stf.spill.nta [loc0]=f47,-256
 317         stf.spill.nta [loc1]=f39,-256
 318         adds loc3=96*16-32-128,in0
 319         ;;
 320         stf.spill.nta [loc2]=f126,-256
 321         stf.spill.nta [loc3]=f118,-256
 322         ;;
 323         stf.spill.nta [loc2]=f110,-256
 324         stf.spill.nta [loc3]=f102,-256
 325         ;;
 326         stf.spill.nta [loc2]=f94,-256
 327         stf.spill.nta [loc3]=f86,-256
 328         ;;
 329         stf.spill.nta [loc2]=f78,-256
 330         stf.spill.nta [loc3]=f70,-256
 331         ;;
 332         stf.spill.nta [loc2]=f62,-256
 333         stf.spill.nta [loc3]=f54,-256
 334         adds loc0=96*16-48,in0
 335         ;;
 336         stf.spill.nta [loc2]=f46,-256
 337         stf.spill.nta [loc3]=f38,-256
 338         adds loc1=96*16-48-128,in0
 339         ;;
 340         stf.spill.nta [loc0]=f125,-256
 341         stf.spill.nta [loc1]=f117,-256
 342         ;;
 343         stf.spill.nta [loc0]=f109,-256
 344         stf.spill.nta [loc1]=f101,-256
 345         ;;
 346         stf.spill.nta [loc0]=f93,-256
 347         stf.spill.nta [loc1]=f85,-256
 348         ;;
 349         stf.spill.nta [loc0]=f77,-256
 350         stf.spill.nta [loc1]=f69,-256
 351         ;;
 352         stf.spill.nta [loc0]=f61,-256
 353         stf.spill.nta [loc1]=f53,-256
 354         adds loc2=96*16-64,in0
 355         ;;
 356         stf.spill.nta [loc0]=f45,-256
 357         stf.spill.nta [loc1]=f37,-256
 358         adds loc3=96*16-64-128,in0
 359         ;;
 360         stf.spill.nta [loc2]=f124,-256
 361         stf.spill.nta [loc3]=f116,-256
 362         ;;
 363         stf.spill.nta [loc2]=f108,-256
 364         stf.spill.nta [loc3]=f100,-256
 365         ;;
 366         stf.spill.nta [loc2]=f92,-256
 367         stf.spill.nta [loc3]=f84,-256
 368         ;;
 369         stf.spill.nta [loc2]=f76,-256
 370         stf.spill.nta [loc3]=f68,-256
 371         ;;
 372         stf.spill.nta [loc2]=f60,-256
 373         stf.spill.nta [loc3]=f52,-256
 374         adds loc0=96*16-80,in0
 375         ;;
 376         stf.spill.nta [loc2]=f44,-256
 377         stf.spill.nta [loc3]=f36,-256
 378         adds loc1=96*16-80-128,in0
 379         ;;
 380         stf.spill.nta [loc0]=f123,-256
 381         stf.spill.nta [loc1]=f115,-256
 382         ;;
 383         stf.spill.nta [loc0]=f107,-256
 384         stf.spill.nta [loc1]=f99,-256
 385         ;;
 386         stf.spill.nta [loc0]=f91,-256
 387         stf.spill.nta [loc1]=f83,-256
 388         ;;
 389         stf.spill.nta [loc0]=f75,-256
 390         stf.spill.nta [loc1]=f67,-256
 391         ;;
 392         stf.spill.nta [loc0]=f59,-256
 393         stf.spill.nta [loc1]=f51,-256
 394         adds loc2=96*16-96,in0
 395         ;;
 396         stf.spill.nta [loc0]=f43,-256
 397         stf.spill.nta [loc1]=f35,-256
 398         adds loc3=96*16-96-128,in0
 399         ;;
 400         stf.spill.nta [loc2]=f122,-256
 401         stf.spill.nta [loc3]=f114,-256
 402         ;;
 403         stf.spill.nta [loc2]=f106,-256
 404         stf.spill.nta [loc3]=f98,-256
 405         ;;
 406         stf.spill.nta [loc2]=f90,-256
 407         stf.spill.nta [loc3]=f82,-256
 408         ;;
 409         stf.spill.nta [loc2]=f74,-256
 410         stf.spill.nta [loc3]=f66,-256
 411         ;;
 412         stf.spill.nta [loc2]=f58,-256
 413         stf.spill.nta [loc3]=f50,-256
 414         adds loc0=96*16-112,in0
 415         ;;
 416         stf.spill.nta [loc2]=f42,-256
 417         stf.spill.nta [loc3]=f34,-256
 418         adds loc1=96*16-112-128,in0
 419         ;;
 420         stf.spill.nta [loc0]=f121,-256
 421         stf.spill.nta [loc1]=f113,-256
 422         ;;
 423         stf.spill.nta [loc0]=f105,-256
 424         stf.spill.nta [loc1]=f97,-256
 425         ;;
 426         stf.spill.nta [loc0]=f89,-256
 427         stf.spill.nta [loc1]=f81,-256
 428         ;;
 429         stf.spill.nta [loc0]=f73,-256
 430         stf.spill.nta [loc1]=f65,-256
 431         ;;
 432         stf.spill.nta [loc0]=f57,-256
 433         stf.spill.nta [loc1]=f49,-256
 434         adds loc2=96*16-128,in0
 435         ;;
 436         stf.spill.nta [loc0]=f41,-256
 437         stf.spill.nta [loc1]=f33,-256
 438         adds loc3=96*16-128-128,in0
 439         ;;
 440         stf.spill.nta [loc2]=f120,-256
 441         stf.spill.nta [loc3]=f112,-256
 442         ;;
 443         stf.spill.nta [loc2]=f104,-256
 444         stf.spill.nta [loc3]=f96,-256
 445         ;;
 446         stf.spill.nta [loc2]=f88,-256
 447         stf.spill.nta [loc3]=f80,-256
 448         ;;
 449         stf.spill.nta [loc2]=f72,-256
 450         stf.spill.nta [loc3]=f64,-256
 451         ;;
 452         stf.spill.nta [loc2]=f56,-256
 453         stf.spill.nta [loc3]=f48,-256
 454         ;;
 455         stf.spill.nta [loc2]=f40
 456         stf.spill.nta [loc3]=f32
 457         br.ret.sptk.many rp
 458 END(__ia64_save_fpu)
 459
 460 GLOBAL_ENTRY(__ia64_load_fpu)
 461         alloc r2=ar.pfs,1,2,0,0
 462         adds r3=128,in0
 463         adds r14=256,in0
 464         adds r15=384,in0
 465         mov loc0=512
 466         mov loc1=-1024+16
 467         ;;
 468         ldf.fill.nta f32=[in0],loc0
 469         ldf.fill.nta f40=[ r3],loc0
 470         ldf.fill.nta f48=[r14],loc0
 471         ldf.fill.nta f56=[r15],loc0
 472         ;;
 473         ldf.fill.nta f64=[in0],loc0
 474         ldf.fill.nta f72=[ r3],loc0
 475         ldf.fill.nta f80=[r14],loc0
 476         ldf.fill.nta f88=[r15],loc0
 477         ;;
 478         ldf.fill.nta f96=[in0],loc1
 479         ldf.fill.nta f104=[ r3],loc1
 480         ldf.fill.nta f112=[r14],loc1
 481         ldf.fill.nta f120=[r15],loc1
 482         ;;
 483         ldf.fill.nta f33=[in0],loc0
 484         ldf.fill.nta f41=[ r3],loc0
 485         ldf.fill.nta f49=[r14],loc0
 486         ldf.fill.nta f57=[r15],loc0
 487         ;;
 488         ldf.fill.nta f65=[in0],loc0
 489         ldf.fill.nta f73=[ r3],loc0
 490         ldf.fill.nta f81=[r14],loc0
 491         ldf.fill.nta f89=[r15],loc0
 492         ;;
 493         ldf.fill.nta f97=[in0],loc1
 494         ldf.fill.nta f105=[ r3],loc1
 495         ldf.fill.nta f113=[r14],loc1
 496         ldf.fill.nta f121=[r15],loc1
 497         ;;
 498         ldf.fill.nta f34=[in0],loc0
 499         ldf.fill.nta f42=[ r3],loc0
 500         ldf.fill.nta f50=[r14],loc0
 501         ldf.fill.nta f58=[r15],loc0
 502         ;;
 503         ldf.fill.nta f66=[in0],loc0
 504         ldf.fill.nta f74=[ r3],loc0
 505         ldf.fill.nta f82=[r14],loc0
 506         ldf.fill.nta f90=[r15],loc0
 507         ;;
 508         ldf.fill.nta f98=[in0],loc1
 509         ldf.fill.nta f106=[ r3],loc1
 510         ldf.fill.nta f114=[r14],loc1
 511         ldf.fill.nta f122=[r15],loc1
 512         ;;
 513         ldf.fill.nta f35=[in0],loc0
 514         ldf.fill.nta f43=[ r3],loc0
 515         ldf.fill.nta f51=[r14],loc0
 516         ldf.fill.nta f59=[r15],loc0
 517         ;;
 518         ldf.fill.nta f67=[in0],loc0
 519         ldf.fill.nta f75=[ r3],loc0
 520         ldf.fill.nta f83=[r14],loc0
 521         ldf.fill.nta f91=[r15],loc0
 522         ;;
 523         ldf.fill.nta f99=[in0],loc1
 524         ldf.fill.nta f107=[ r3],loc1
 525         ldf.fill.nta f115=[r14],loc1
 526         ldf.fill.nta f123=[r15],loc1
 527         ;;
 528         ldf.fill.nta f36=[in0],loc0
 529         ldf.fill.nta f44=[ r3],loc0
 530         ldf.fill.nta f52=[r14],loc0
 531         ldf.fill.nta f60=[r15],loc0
 532         ;;
 533         ldf.fill.nta f68=[in0],loc0
 534         ldf.fill.nta f76=[ r3],loc0
 535         ldf.fill.nta f84=[r14],loc0
 536         ldf.fill.nta f92=[r15],loc0
 537         ;;
 538         ldf.fill.nta f100=[in0],loc1
 539         ldf.fill.nta f108=[ r3],loc1
 540         ldf.fill.nta f116=[r14],loc1
 541         ldf.fill.nta f124=[r15],loc1
 542         ;;
 543         ldf.fill.nta f37=[in0],loc0
 544         ldf.fill.nta f45=[ r3],loc0
 545         ldf.fill.nta f53=[r14],loc0
 546         ldf.fill.nta f61=[r15],loc0
 547         ;;
 548         ldf.fill.nta f69=[in0],loc0
 549         ldf.fill.nta f77=[ r3],loc0
 550         ldf.fill.nta f85=[r14],loc0
 551         ldf.fill.nta f93=[r15],loc0
 552         ;;
 553         ldf.fill.nta f101=[in0],loc1
 554         ldf.fill.nta f109=[ r3],loc1
 555         ldf.fill.nta f117=[r14],loc1
 556         ldf.fill.nta f125=[r15],loc1
 557         ;;
 558         ldf.fill.nta f38 =[in0],loc0
 559         ldf.fill.nta f46 =[ r3],loc0
 560         ldf.fill.nta f54 =[r14],loc0
 561         ldf.fill.nta f62 =[r15],loc0
 562         ;;
 563         ldf.fill.nta f70 =[in0],loc0
 564         ldf.fill.nta f78 =[ r3],loc0
 565         ldf.fill.nta f86 =[r14],loc0
 566         ldf.fill.nta f94 =[r15],loc0
 567         ;;
 568         ldf.fill.nta f102=[in0],loc1
 569         ldf.fill.nta f110=[ r3],loc1
 570         ldf.fill.nta f118=[r14],loc1
 571         ldf.fill.nta f126=[r15],loc1
 572         ;;
 573         ldf.fill.nta f39 =[in0],loc0
 574         ldf.fill.nta f47 =[ r3],loc0
 575         ldf.fill.nta f55 =[r14],loc0
 576         ldf.fill.nta f63 =[r15],loc0
 577         ;;
 578         ldf.fill.nta f71 =[in0],loc0
 579         ldf.fill.nta f79 =[ r3],loc0
 580         ldf.fill.nta f87 =[r14],loc0
 581         ldf.fill.nta f95 =[r15],loc0
 582         ;;
 583         ldf.fill.nta f103=[in0]
 584         ldf.fill.nta f111=[ r3]
 585         ldf.fill.nta f119=[r14]
 586         ldf.fill.nta f127=[r15]
 587         br.ret.sptk.many rp
 588 END(__ia64_load_fpu)
 589
 590 GLOBAL_ENTRY(__ia64_init_fpu)
 591         stf.spill [sp]=f0               // M3
 592         mov      f32=f0                 // F
 593         nop.b    0
 594
 595         ldfps    f33,f34=[sp]           // M0
 596         ldfps    f35,f36=[sp]           // M1
 597         mov      f37=f0                 // F
 598         ;;
 599
 600         setf.s   f38=r0                 // M2
 601         setf.s   f39=r0                 // M3
 602         mov      f40=f0                 // F
 603
 604         ldfps    f41,f42=[sp]           // M0
 605         ldfps    f43,f44=[sp]           // M1
 606         mov      f45=f0                 // F
 607
 608         setf.s   f46=r0                 // M2
 609         setf.s   f47=r0                 // M3
 610         mov      f48=f0                 // F
 611
 612         ldfps    f49,f50=[sp]           // M0
 613         ldfps    f51,f52=[sp]           // M1
 614         mov      f53=f0                 // F
 615
 616         setf.s   f54=r0                 // M2
 617         setf.s   f55=r0                 // M3
 618         mov      f56=f0                 // F
 619
 620         ldfps    f57,f58=[sp]           // M0
 621         ldfps    f59,f60=[sp]           // M1
 622         mov      f61=f0                 // F
 623
 624         setf.s   f62=r0                 // M2
 625         setf.s   f63=r0                 // M3
 626         mov      f64=f0                 // F
 627
 628         ldfps    f65,f66=[sp]           // M0
 629         ldfps    f67,f68=[sp]           // M1
 630         mov      f69=f0                 // F
 631
 632         setf.s   f70=r0                 // M2
 633         setf.s   f71=r0                 // M3
 634         mov      f72=f0                 // F
 635
 636         ldfps    f73,f74=[sp]           // M0
 637         ldfps    f75,f76=[sp]           // M1
 638         mov      f77=f0                 // F
 639
 640         setf.s   f78=r0                 // M2
 641         setf.s   f79=r0                 // M3
 642         mov      f80=f0                 // F
 643
 644         ldfps    f81,f82=[sp]           // M0
 645         ldfps    f83,f84=[sp]           // M1
 646         mov      f85=f0                 // F
 647
 648         setf.s   f86=r0                 // M2
 649         setf.s   f87=r0                 // M3
 650         mov      f88=f0                 // F
 651
 652         /*
 653          * When the instructions are cached, it would be faster to initialize
 654          * the remaining registers with simply mov instructions (F-unit).
 655          * This gets the time down to ~29 cycles.  However, this would use up
 656          * 33 bundles, whereas continuing with the above pattern yields
 657          * 10 bundles and ~30 cycles.
 658          */
 659
 660         ldfps    f89,f90=[sp]           // M0
 661         ldfps    f91,f92=[sp]           // M1
 662         mov      f93=f0                 // F
 663
 664         setf.s   f94=r0                 // M2
 665         setf.s   f95=r0                 // M3
 666         mov      f96=f0                 // F
 667
 668         ldfps    f97,f98=[sp]           // M0
 669         ldfps    f99,f100=[sp]          // M1
 670         mov      f101=f0                // F
 671
 672         setf.s   f102=r0                // M2
 673         setf.s   f103=r0                // M3
 674         mov      f104=f0                // F
 675
 676         ldfps    f105,f106=[sp]         // M0
 677         ldfps    f107,f108=[sp]         // M1
 678         mov      f109=f0                // F
 679
 680         setf.s   f110=r0                // M2
 681         setf.s   f111=r0                // M3
 682         mov      f112=f0                // F
 683
 684         ldfps    f113,f114=[sp]         // M0
 685         ldfps    f115,f116=[sp]         // M1
 686         mov      f117=f0                // F
 687
 688         setf.s   f118=r0                // M2
 689         setf.s   f119=r0                // M3
 690         mov      f120=f0                // F
 691
 692         ldfps    f121,f122=[sp]         // M0
 693         ldfps    f123,f124=[sp]         // M1
 694         mov      f125=f0                // F
 695
 696         setf.s   f126=r0                // M2
 697         setf.s   f127=r0                // M3
 698         br.ret.sptk.many rp             // F
 699 END(__ia64_init_fpu)
 700
 701 /*
 702  * Switch execution mode from virtual to physical
 703  *
 704  * Inputs:
 705  *      r16 = new psr to establish
 706  *
 707  * Note: RSE must already be in enforced lazy mode
 708  */
 709 GLOBAL_ENTRY(ia64_switch_mode_phys)
 710  {
 711         alloc r2=ar.pfs,0,0,0,0
 712         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 713         mov r15=ip
 714  }
 715         ;;
 716  {
 717         flushrs                         // must be first insn in group
 718         srlz.i
 719  }
 720         ;;
 721         mov cr.ipsr=r16                 // set new PSR
 722         add r3=1f-ia64_switch_mode_phys,r15
 723
 724         mov r17=ar.bsp
 725         mov r14=rp                      // get return address into a general register
 726         ;;
 727
 728         // going to physical mode, use tpa to translate virt->phys
 729         tpa r17=r17
 730         tpa r3=r3
 731         tpa sp=sp
 732         tpa r14=r14
 733         ;;
 734
 735         mov r18=ar.rnat                 // save ar.rnat
 736         mov ar.bspstore=r17             // this steps on ar.rnat
 737         mov cr.iip=r3
 738         mov cr.ifs=r0
 739         ;;
 740         mov ar.rnat=r18                 // restore ar.rnat
 741         rfi                             // must be last insn in group
 742         ;;
 743 1:      mov rp=r14
 744         br.ret.sptk.many rp
 745 END(ia64_switch_mode_phys)
 746
 747 /*
 748  * Switch execution mode from physical to virtual
 749  *
 750  * Inputs:
 751  *      r16 = new psr to establish
 752  *
 753  * Note: RSE must already be in enforced lazy mode
 754  */
 755 GLOBAL_ENTRY(ia64_switch_mode_virt)
 756  {
 757         alloc r2=ar.pfs,0,0,0,0
 758         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 759         mov r15=ip
 760  }
 761         ;;
 762  {
 763         flushrs                         // must be first insn in group
 764         srlz.i
 765  }
 766         ;;
 767         mov cr.ipsr=r16                 // set new PSR
 768         add r3=1f-ia64_switch_mode_virt,r15
 769
 770         mov r17=ar.bsp
 771         mov r14=rp                      // get return address into a general register
 772         ;;
 773
 774         // going to virtual
 775         //   - for code addresses, set upper bits of addr to KERNEL_START
 776         //   - for stack addresses, set upper 3 bits to 0xe.... Dont change any of the
 777         //     lower bits since we want it to stay identity mapped
 778         movl r18=KERNEL_START
 779         dep r3=0,r3,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 780         dep r14=0,r14,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 781         dep r17=-1,r17,61,3
 782         dep sp=-1,sp,61,3
 783         ;;
 784         or r3=r3,r18
 785         or r14=r14,r18
 786         ;;
 787
 788         mov r18=ar.rnat                 // save ar.rnat
 789         mov ar.bspstore=r17             // this steps on ar.rnat
 790         mov cr.iip=r3
 791         mov cr.ifs=r0
 792         ;;
 793         mov ar.rnat=r18                 // restore ar.rnat
 794         rfi                             // must be last insn in group
 795         ;;
 796 1:      mov rp=r14
 797         br.ret.sptk.many rp
 798 END(ia64_switch_mode_virt)
 799
 800 GLOBAL_ENTRY(ia64_delay_loop)
 801         .prologue
 802 {       nop 0                   // work around GAS unwind info generation bug...
 803         .save ar.lc,r2
 804         mov r2=ar.lc
 805         .body
 806         ;;
 807         mov ar.lc=r32
 808 }
 809         ;;
 810         // force loop to be 32-byte aligned (GAS bug means we cannot use .align
 811         // inside function body without corrupting unwind info).
 812 {       nop 0 }
 813 1:      br.cloop.sptk.few 1b
 814         ;;
 815         mov ar.lc=r2
 816         br.ret.sptk.many rp
 817 END(ia64_delay_loop)
 818
 819 GLOBAL_ENTRY(start_kernel_thread)
 820         .prologue
 821         .save rp, r0                            // this is the end of the call-chain
 822         .body
 823         alloc r2 = ar.pfs, 0, 0, 2, 0
 824         mov out0 = r9
 825         mov out1 = r11;;
 826         br.call.sptk.many rp = kernel_thread_helper;;
 827         mov out0 = r8
 828         br.call.sptk.many rp = sys_exit;;
 829 1:      br.sptk.few 1b                          // not reached
 830 END(start_kernel_thread)
 831
 832 #ifdef CONFIG_IA64_BRL_EMU
 833
 834 /*
 835  *  Assembly routines used by brl_emu.c to set preserved register state.
 836  */
 837
 838 #define SET_REG(reg)                            \
 839  GLOBAL_ENTRY(ia64_set_##reg);                  \
 840         alloc r16=ar.pfs,1,0,0,0;               \
 841         mov reg=r32;                            \
 842         ;;                                      \
 843         br.ret.sptk.many rp;                    \
 844  END(ia64_set_##reg)
 845
 846 SET_REG(b1);
 847 SET_REG(b2);
 848 SET_REG(b3);
 849 SET_REG(b4);
 850 SET_REG(b5);
 851
 852 #endif /* CONFIG_IA64_BRL_EMU */
 853
 854 #ifdef CONFIG_SMP
 855         /*
 856          * This routine handles spinlock contention.  It uses a non-standard calling
 857          * convention to avoid converting leaf routines into interior routines.  Because
 858          * of this special convention, there are several restrictions:
 859          *
 860          * - do not use gp relative variables, this code is called from the kernel
 861          *   and from modules, r1 is undefined.
 862          * - do not use stacked registers, the caller owns them.
 863          * - do not use the scratch stack space, the caller owns it.
 864          * - do not use any registers other than the ones listed below
 865          *
 866          * Inputs:
 867          *   ar.pfs - saved CFM of caller
 868          *   ar.ccv - 0 (and available for use)
 869          *   r28    - available for use.
 870          *   r29    - available for use.
 871          *   r30    - available for use.
 872          *   r31    - address of lock, available for use.
 873          *   b6     - return address
 874          *   p14    - available for use.
 875          *
 876          * If you patch this code to use more registers, do not forget to update
 877          * the clobber lists for spin_lock() in include/asm-ia64/spinlock.h.
 878          */
 879
 880 #if __GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 3)
 881
 882 GLOBAL_ENTRY(ia64_spinlock_contention_pre3_4)
 883         .prologue
 884         .save ar.pfs, r0        // this code effectively has a zero frame size
 885         .save rp, r28
 886         .body
 887         nop 0
 888         nop 0
 889         .restore sp             // pop existing prologue after next insn
 890         mov b6 = r28
 891         .prologue
 892         .save ar.pfs, r0
 893         .altrp b6
 894         .body
 895 .wait:
 896         // exponential backoff, kdb, lockmeter etc. go in here
 897         hint @pause
 898         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
 899         nop 0
 900         ;;
 901         cmp4.eq p14,p0=r30,r0
 902 (p14)   br.cond.sptk.few b6     // lock is now free, try to acquire
 903         br.cond.sptk.few .wait
 904 END(ia64_spinlock_contention_pre3_4)
 905
 906 #else
 907
 908 GLOBAL_ENTRY(ia64_spinlock_contention)
 909         .prologue
 910         .altrp b6
 911         .body
 912 .wait:
 913         // exponential backoff, kdb, lockmeter etc. go in here
 914         hint @pause
 915         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
 916         ;;
 917         cmp4.ne p14,p0=r30,r0
 918         mov r30 = 1
 919 (p14)   br.cond.sptk.few .wait
 920         ;;
 921         cmpxchg4.acq r30=[r31], r30, ar.ccv
 922         ;;
 923         cmp4.ne p14,p0=r0,r30
 924 (p14)   br.cond.sptk.few .wait
 925
 926         br.ret.sptk.many b6     // lock is now taken
 927 END(ia64_spinlock_contention)
 928
 929 #endif
 930
 931 #endif /* CONFIG_SMP */