arch/ia64/kernel/ivt.S

   1 /*
   2  * arch/ia64/kernel/ivt.S
   3  *
   4  * Copyright (C) 1998-2001, 2003 Hewlett-Packard Co
   5  *      Stephane Eranian <eranian@hpl.hp.com>
   6  *      David Mosberger <davidm@hpl.hp.com>
   7  * Copyright (C) 2000, 2002-2003 Intel Co
   8  *      Asit Mallick <asit.k.mallick@intel.com>
   9  *      Suresh Siddha <suresh.b.siddha@intel.com>
  10  *      Kenneth Chen <kenneth.w.chen@intel.com>
  11  *      Fenghua Yu <fenghua.yu@intel.com>
  12  *
  13  * 00/08/23 Asit Mallick <asit.k.mallick@intel.com> TLB handling for SMP
  14  * 00/12/20 David Mosberger-Tang <davidm@hpl.hp.com> DTLB/ITLB handler now uses virtual PT.
  15  */
  16 /*
  17  * This file defines the interruption vector table used by the CPU.
  18  * It does not include one entry per possible cause of interruption.
  19  *
  20  * The first 20 entries of the table contain 64 bundles each while the
  21  * remaining 48 entries contain only 16 bundles each.
  22  *
  23  * The 64 bundles are used to allow inlining the whole handler for critical
  24  * interruptions like TLB misses.
  25  *
  26  *  For each entry, the comment is as follows:
  27  *
  28  *              // 0x1c00 Entry 7 (size 64 bundles) Data Key Miss (12,51)
  29  *  entry offset ----/     /         /                  /          /
  30  *  entry number ---------/         /                  /          /
  31  *  size of the entry -------------/                  /          /
  32  *  vector name -------------------------------------/          /
  33  *  interruptions triggering this vector ----------------------/
  34  *
  35  * The table is 32KB in size and must be aligned on 32KB boundary.
  36  * (The CPU ignores the 15 lower bits of the address)
  37  *
  38  * Table is based upon EAS2.6 (Oct 1999)
  39  */
  40
  41 #include <linux/config.h>
  42
  43 #include <asm/asmmacro.h>
  44 #include <asm/break.h>
  45 #include <asm/ia32.h>
  46 #include <asm/kregs.h>
  47 #include <asm/offsets.h>
  48 #include <asm/pgtable.h>
  49 #include <asm/processor.h>
  50 #include <asm/ptrace.h>
  51 #include <asm/system.h>
  52 #include <asm/thread_info.h>
  53 #include <asm/unistd.h>
  54
  55 #if 1
  56 # define PSR_DEFAULT_BITS       psr.ac
  57 #else
  58 # define PSR_DEFAULT_BITS       0
  59 #endif
  60
  61 #if 0
  62   /*
  63    * This lets you track the last eight faults that occurred on the CPU.  Make sure ar.k2 isn't
  64    * needed for something else before enabling this...
  65    */
  66 # define DBG_FAULT(i)   mov r16=ar.k2;; shl r16=r16,8;; add r16=(i),r16;;mov ar.k2=r16
  67 #else
  68 # define DBG_FAULT(i)
  69 #endif
  70
  71 #define MINSTATE_VIRT   /* needed by minstate.h */
  72 #include "minstate.h"
  73
  74 #define FAULT(n)                                                                        \
  75         mov r31=pr;                                                                     \
  76         mov r19=n;;                     /* prepare to save predicates */                \
  77         br.sptk.many dispatch_to_fault_handler
  78
  79         .section .text.ivt,"ax"
  80
  81         .align 32768    // align on 32KB boundary
  82         .global ia64_ivt
  83 ia64_ivt:
  84 /////////////////////////////////////////////////////////////////////////////////////////
  85 // 0x0000 Entry 0 (size 64 bundles) VHPT Translation (8,20,47)
  86 ENTRY(vhpt_miss)
  87         DBG_FAULT(0)
  88         /*
  89          * The VHPT vector is invoked when the TLB entry for the virtual page table
  90          * is missing.  This happens only as a result of a previous
  91          * (the "original") TLB miss, which may either be caused by an instruction
  92          * fetch or a data access (or non-access).
  93          *
  94          * What we do here is normal TLB miss handing for the _original_ miss, followed
  95          * by inserting the TLB entry for the virtual page table page that the VHPT
  96          * walker was attempting to access.  The latter gets inserted as long
  97          * as both L1 and L2 have valid mappings for the faulting address.
  98          * The TLB entry for the original miss gets inserted only if
  99          * the L3 entry indicates that the page is present.
 100          *
 101          * do_page_fault gets invoked in the following cases:
 102          *      - the faulting virtual address uses unimplemented address bits
 103          *      - the faulting virtual address has no L1, L2, or L3 mapping
 104          */
 105         mov r16=cr.ifa                          // get address that caused the TLB miss
 106 #ifdef CONFIG_HUGETLB_PAGE
 107         movl r18=PAGE_SHIFT
 108         mov r25=cr.itir
 109 #endif
 110         ;;
 111         rsm psr.dt                              // use physical addressing for data
 112         mov r31=pr                              // save the predicate registers
 113         mov r19=IA64_KR(PT_BASE)                // get page table base address
 114         shl r21=r16,3                           // shift bit 60 into sign bit
 115         shr.u r17=r16,61                        // get the region number into r17
 116         ;;
 117         shr r22=r21,3
 118 #ifdef CONFIG_HUGETLB_PAGE
 119         extr.u r26=r25,2,6
 120         ;;
 121         cmp.ne p8,p0=r18,r26
 122         sub r27=r26,r18
 123         ;;
 124 (p8)    dep r25=r18,r25,2,6
 125 (p8)    shr r22=r22,r27
 126 #endif
 127         ;;
 128         cmp.eq p6,p7=5,r17                      // is IFA pointing into to region 5?
 129         shr.u r18=r22,PGDIR_SHIFT               // get bits 33-63 of the faulting address
 130         ;;
 131 (p7)    dep r17=r17,r19,(PAGE_SHIFT-3),3        // put region number bits in place
 132
 133         srlz.d
 134         LOAD_PHYSICAL(p6, r19, swapper_pg_dir)  // region 5 is rooted at swapper_pg_dir
 135
 136         .pred.rel "mutex", p6, p7
 137 (p6)    shr.u r21=r21,PGDIR_SHIFT+PAGE_SHIFT
 138 (p7)    shr.u r21=r21,PGDIR_SHIFT+PAGE_SHIFT-3
 139         ;;
 140 (p6)    dep r17=r18,r19,3,(PAGE_SHIFT-3)        // r17=PTA + IFA(33,42)*8
 141 (p7)    dep r17=r18,r17,3,(PAGE_SHIFT-6)        // r17=PTA + (((IFA(61,63) << 7) | IFA(33,39))*8)
 142         cmp.eq p7,p6=0,r21                      // unused address bits all zeroes?
 143         shr.u r18=r22,PMD_SHIFT                 // shift L2 index into position
 144         ;;
 145         ld8 r17=[r17]                           // fetch the L1 entry (may be 0)
 146         ;;
 147 (p7)    cmp.eq p6,p7=r17,r0                     // was L1 entry NULL?
 148         dep r17=r18,r17,3,(PAGE_SHIFT-3)        // compute address of L2 page table entry
 149         ;;
 150 (p7)    ld8 r20=[r17]                           // fetch the L2 entry (may be 0)
 151         shr.u r19=r22,PAGE_SHIFT                // shift L3 index into position
 152         ;;
 153 (p7)    cmp.eq.or.andcm p6,p7=r20,r0            // was L2 entry NULL?
 154         dep r21=r19,r20,3,(PAGE_SHIFT-3)        // compute address of L3 page table entry
 155         ;;
 156 (p7)    ld8 r18=[r21]                           // read the L3 PTE
 157         mov r19=cr.isr                          // cr.isr bit 0 tells us if this is an insn miss
 158         ;;
 159 (p7)    tbit.z p6,p7=r18,_PAGE_P_BIT            // page present bit cleared?
 160         mov r22=cr.iha                          // get the VHPT address that caused the TLB miss
 161         ;;                                      // avoid RAW on p7
 162 (p7)    tbit.nz.unc p10,p11=r19,32              // is it an instruction TLB miss?
 163         dep r23=0,r20,0,PAGE_SHIFT              // clear low bits to get page address
 164         ;;
 165 (p10)   itc.i r18                               // insert the instruction TLB entry
 166 (p11)   itc.d r18                               // insert the data TLB entry
 167 (p6)    br.cond.spnt.many page_fault            // handle bad address/page not present (page fault)
 168         mov cr.ifa=r22
 169
 170 #ifdef CONFIG_HUGETLB_PAGE
 171 (p8)    mov cr.itir=r25                         // change to default page-size for VHPT
 172 #endif
 173
 174         /*
 175          * Now compute and insert the TLB entry for the virtual page table.  We never
 176          * execute in a page table page so there is no need to set the exception deferral
 177          * bit.
 178          */
 179         adds r24=__DIRTY_BITS_NO_ED|_PAGE_PL_0|_PAGE_AR_RW,r23
 180         ;;
 181 (p7)    itc.d r24
 182         ;;
 183 #ifdef CONFIG_SMP
 184         /*
 185          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 186          * cannot possibly affect the following loads:
 187          */
 188         dv_serialize_data
 189
 190         /*
 191          * Re-check L2 and L3 pagetable.  If they changed, we may have received a ptc.g
 192          * between reading the pagetable and the "itc".  If so, flush the entry we
 193          * inserted and retry.
 194          */
 195         ld8 r25=[r21]                           // read L3 PTE again
 196         ld8 r26=[r17]                           // read L2 entry again
 197         ;;
 198         cmp.ne p6,p7=r26,r20                    // did L2 entry change
 199         mov r27=PAGE_SHIFT<<2
 200         ;;
 201 (p6)    ptc.l r22,r27                           // purge PTE page translation
 202 (p7)    cmp.ne.or.andcm p6,p7=r25,r18           // did L3 PTE change
 203         ;;
 204 (p6)    ptc.l r16,r27                           // purge translation
 205 #endif
 206
 207         mov pr=r31,-1                           // restore predicate registers
 208         rfi
 209 END(vhpt_miss)
 210
 211         .org ia64_ivt+0x400
 212 /////////////////////////////////////////////////////////////////////////////////////////
 213 // 0x0400 Entry 1 (size 64 bundles) ITLB (21)
 214 ENTRY(itlb_miss)
 215         DBG_FAULT(1)
 216         /*
 217          * The ITLB handler accesses the L3 PTE via the virtually mapped linear
 218          * page table.  If a nested TLB miss occurs, we switch into physical
 219          * mode, walk the page table, and then re-execute the L3 PTE read
 220          * and go on normally after that.
 221          */
 222         mov r16=cr.ifa                          // get virtual address
 223         mov r29=b0                              // save b0
 224         mov r31=pr                              // save predicates
 225 .itlb_fault:
 226         mov r17=cr.iha                          // get virtual address of L3 PTE
 227         movl r30=1f                             // load nested fault continuation point
 228         ;;
 229 1:      ld8 r18=[r17]                           // read L3 PTE
 230         ;;
 231         mov b0=r29
 232         tbit.z p6,p0=r18,_PAGE_P_BIT            // page present bit cleared?
 233 (p6)    br.cond.spnt page_fault
 234         ;;
 235         itc.i r18
 236         ;;
 237 #ifdef CONFIG_SMP
 238         /*
 239          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 240          * cannot possibly affect the following loads:
 241          */
 242         dv_serialize_data
 243
 244         ld8 r19=[r17]                           // read L3 PTE again and see if same
 245         mov r20=PAGE_SHIFT<<2                   // setup page size for purge
 246         ;;
 247         cmp.ne p7,p0=r18,r19
 248         ;;
 249 (p7)    ptc.l r16,r20
 250 #endif
 251         mov pr=r31,-1
 252         rfi
 253 END(itlb_miss)
 254
 255         .org ia64_ivt+0x0800
 256 /////////////////////////////////////////////////////////////////////////////////////////
 257 // 0x0800 Entry 2 (size 64 bundles) DTLB (9,48)
 258 ENTRY(dtlb_miss)
 259         DBG_FAULT(2)
 260         /*
 261          * The DTLB handler accesses the L3 PTE via the virtually mapped linear
 262          * page table.  If a nested TLB miss occurs, we switch into physical
 263          * mode, walk the page table, and then re-execute the L3 PTE read
 264          * and go on normally after that.
 265          */
 266         mov r16=cr.ifa                          // get virtual address
 267         mov r29=b0                              // save b0
 268         mov r31=pr                              // save predicates
 269 dtlb_fault:
 270         mov r17=cr.iha                          // get virtual address of L3 PTE
 271         movl r30=1f                             // load nested fault continuation point
 272         ;;
 273 1:      ld8 r18=[r17]                           // read L3 PTE
 274         ;;
 275         mov b0=r29
 276         tbit.z p6,p0=r18,_PAGE_P_BIT            // page present bit cleared?
 277 (p6)    br.cond.spnt page_fault
 278         ;;
 279         itc.d r18
 280         ;;
 281 #ifdef CONFIG_SMP
 282         /*
 283          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 284          * cannot possibly affect the following loads:
 285          */
 286         dv_serialize_data
 287
 288         ld8 r19=[r17]                           // read L3 PTE again and see if same
 289         mov r20=PAGE_SHIFT<<2                   // setup page size for purge
 290         ;;
 291         cmp.ne p7,p0=r18,r19
 292         ;;
 293 (p7)    ptc.l r16,r20
 294 #endif
 295         mov pr=r31,-1
 296         rfi
 297 END(dtlb_miss)
 298
 299         .org ia64_ivt+0x0c00
 300 /////////////////////////////////////////////////////////////////////////////////////////
 301 // 0x0c00 Entry 3 (size 64 bundles) Alt ITLB (19)
 302 ENTRY(alt_itlb_miss)
 303         DBG_FAULT(3)
 304         mov r16=cr.ifa          // get address that caused the TLB miss
 305         movl r17=PAGE_KERNEL
 306         mov r21=cr.ipsr
 307         movl r19=(((1 << IA64_MAX_PHYS_BITS) - 1) & ~0xfff)
 308         mov r31=pr
 309         ;;
 310 #ifdef CONFIG_DISABLE_VHPT
 311         shr.u r22=r16,61                        // get the region number into r21
 312         ;;
 313         cmp.gt p8,p0=6,r22                      // user mode
 314         ;;
 315 (p8)    thash r17=r16
 316         ;;
 317 (p8)    mov cr.iha=r17
 318 (p8)    mov r29=b0                              // save b0
 319 (p8)    br.cond.dptk .itlb_fault
 320 #endif
 321         extr.u r23=r21,IA64_PSR_CPL0_BIT,2      // extract psr.cpl
 322         and r19=r19,r16         // clear ed, reserved bits, and PTE control bits
 323         shr.u r18=r16,57        // move address bit 61 to bit 4
 324         ;;
 325         andcm r18=0x10,r18      // bit 4=~address-bit(61)
 326         cmp.ne p8,p0=r0,r23     // psr.cpl != 0?
 327         or r19=r17,r19          // insert PTE control bits into r19
 328         ;;
 329         or r19=r19,r18          // set bit 4 (uncached) if the access was to region 6
 330 (p8)    br.cond.spnt page_fault
 331         ;;
 332         itc.i r19               // insert the TLB entry
 333         mov pr=r31,-1
 334         rfi
 335 END(alt_itlb_miss)
 336
 337         .org ia64_ivt+0x1000
 338 /////////////////////////////////////////////////////////////////////////////////////////
 339 // 0x1000 Entry 4 (size 64 bundles) Alt DTLB (7,46)
 340 ENTRY(alt_dtlb_miss)
 341         DBG_FAULT(4)
 342         mov r16=cr.ifa          // get address that caused the TLB miss
 343         movl r17=PAGE_KERNEL
 344         mov r20=cr.isr
 345         movl r19=(((1 << IA64_MAX_PHYS_BITS) - 1) & ~0xfff)
 346         mov r21=cr.ipsr
 347         mov r31=pr
 348         ;;
 349 #ifdef CONFIG_DISABLE_VHPT
 350         shr.u r22=r16,61                        // get the region number into r21
 351         ;;
 352         cmp.gt p8,p0=6,r22                      // access to region 0-5
 353         ;;
 354 (p8)    thash r17=r16
 355         ;;
 356 (p8)    mov cr.iha=r17
 357 (p8)    mov r29=b0                              // save b0
 358 (p8)    br.cond.dptk dtlb_fault
 359 #endif
 360         extr.u r23=r21,IA64_PSR_CPL0_BIT,2      // extract psr.cpl
 361         and r22=IA64_ISR_CODE_MASK,r20          // get the isr.code field
 362         tbit.nz p6,p7=r20,IA64_ISR_SP_BIT       // is speculation bit on?
 363         shr.u r18=r16,57                        // move address bit 61 to bit 4
 364         and r19=r19,r16                         // clear ed, reserved bits, and PTE control bits
 365         tbit.nz p9,p0=r20,IA64_ISR_NA_BIT       // is non-access bit on?
 366         ;;
 367         andcm r18=0x10,r18      // bit 4=~address-bit(61)
 368         cmp.ne p8,p0=r0,r23
 369 (p9)    cmp.eq.or.andcm p6,p7=IA64_ISR_CODE_LFETCH,r22  // check isr.code field
 370 (p8)    br.cond.spnt page_fault
 371
 372         dep r21=-1,r21,IA64_PSR_ED_BIT,1
 373         or r19=r19,r17          // insert PTE control bits into r19
 374         ;;
 375         or r19=r19,r18          // set bit 4 (uncached) if the access was to region 6
 376 (p6)    mov cr.ipsr=r21
 377         ;;
 378 (p7)    itc.d r19               // insert the TLB entry
 379         mov pr=r31,-1
 380         rfi
 381 END(alt_dtlb_miss)
 382
 383         .org ia64_ivt+0x1400
 384 /////////////////////////////////////////////////////////////////////////////////////////
 385 // 0x1400 Entry 5 (size 64 bundles) Data nested TLB (6,45)
 386 ENTRY(nested_dtlb_miss)
 387         /*
 388          * In the absence of kernel bugs, we get here when the virtually mapped linear
 389          * page table is accessed non-speculatively (e.g., in the Dirty-bit, Instruction
 390          * Access-bit, or Data Access-bit faults).  If the DTLB entry for the virtual page
 391          * table is missing, a nested TLB miss fault is triggered and control is
 392          * transferred to this point.  When this happens, we lookup the pte for the
 393          * faulting address by walking the page table in physical mode and return to the
 394          * continuation point passed in register r30 (or call page_fault if the address is
 395          * not mapped).
 396          *
 397          * Input:       r16:    faulting address
 398          *              r29:    saved b0
 399          *              r30:    continuation address
 400          *              r31:    saved pr
 401          *
 402          * Output:      r17:    physical address of L3 PTE of faulting address
 403          *              r29:    saved b0
 404          *              r30:    continuation address
 405          *              r31:    saved pr
 406          *
 407          * Clobbered:   b0, r18, r19, r21, psr.dt (cleared)
 408          */
 409         rsm psr.dt                              // switch to using physical data addressing
 410         mov r19=IA64_KR(PT_BASE)                // get the page table base address
 411         shl r21=r16,3                           // shift bit 60 into sign bit
 412         ;;
 413         shr.u r17=r16,61                        // get the region number into r17
 414         ;;
 415         cmp.eq p6,p7=5,r17                      // is faulting address in region 5?
 416         shr.u r18=r16,PGDIR_SHIFT               // get bits 33-63 of faulting address
 417         ;;
 418 (p7)    dep r17=r17,r19,(PAGE_SHIFT-3),3        // put region number bits in place
 419
 420         srlz.d
 421         LOAD_PHYSICAL(p6, r19, swapper_pg_dir)  // region 5 is rooted at swapper_pg_dir
 422
 423         .pred.rel "mutex", p6, p7
 424 (p6)    shr.u r21=r21,PGDIR_SHIFT+PAGE_SHIFT
 425 (p7)    shr.u r21=r21,PGDIR_SHIFT+PAGE_SHIFT-3
 426         ;;
 427 (p6)    dep r17=r18,r19,3,(PAGE_SHIFT-3)        // r17=PTA + IFA(33,42)*8
 428 (p7)    dep r17=r18,r17,3,(PAGE_SHIFT-6)        // r17=PTA + (((IFA(61,63) << 7) | IFA(33,39))*8)
 429         cmp.eq p7,p6=0,r21                      // unused address bits all zeroes?
 430         shr.u r18=r16,PMD_SHIFT                 // shift L2 index into position
 431         ;;
 432         ld8 r17=[r17]                           // fetch the L1 entry (may be 0)
 433         ;;
 434 (p7)    cmp.eq p6,p7=r17,r0                     // was L1 entry NULL?
 435         dep r17=r18,r17,3,(PAGE_SHIFT-3)        // compute address of L2 page table entry
 436         ;;
 437 (p7)    ld8 r17=[r17]                           // fetch the L2 entry (may be 0)
 438         shr.u r19=r16,PAGE_SHIFT                // shift L3 index into position
 439         ;;
 440 (p7)    cmp.eq.or.andcm p6,p7=r17,r0            // was L2 entry NULL?
 441         dep r17=r19,r17,3,(PAGE_SHIFT-3)        // compute address of L3 page table entry
 442 (p6)    br.cond.spnt page_fault
 443         mov b0=r30
 444         br.sptk.many b0                         // return to continuation point
 445 END(nested_dtlb_miss)
 446
 447         .org ia64_ivt+0x1800
 448 /////////////////////////////////////////////////////////////////////////////////////////
 449 // 0x1800 Entry 6 (size 64 bundles) Instruction Key Miss (24)
 450 ENTRY(ikey_miss)
 451         DBG_FAULT(6)
 452         FAULT(6)
 453 END(ikey_miss)
 454
 455         //-----------------------------------------------------------------------------------
 456         // call do_page_fault (predicates are in r31, psr.dt may be off, r16 is faulting address)
 457 ENTRY(page_fault)
 458         ssm psr.dt
 459         ;;
 460         srlz.i
 461         ;;
 462         SAVE_MIN_WITH_COVER
 463         alloc r15=ar.pfs,0,0,3,0
 464         mov out0=cr.ifa
 465         mov out1=cr.isr
 466         adds r3=8,r2                            // set up second base pointer
 467         ;;
 468         ssm psr.ic | PSR_DEFAULT_BITS
 469         ;;
 470         srlz.i                                  // guarantee that interruption collectin is on
 471         ;;
 472 (p15)   ssm psr.i                               // restore psr.i
 473         movl r14=ia64_leave_kernel
 474         ;;
 475         SAVE_REST
 476         mov rp=r14
 477         ;;
 478         adds out2=16,r12                        // out2 = pointer to pt_regs
 479         br.call.sptk.many b6=ia64_do_page_fault // ignore return address
 480 END(page_fault)
 481
 482         .org ia64_ivt+0x1c00
 483 /////////////////////////////////////////////////////////////////////////////////////////
 484 // 0x1c00 Entry 7 (size 64 bundles) Data Key Miss (12,51)
 485 ENTRY(dkey_miss)
 486         DBG_FAULT(7)
 487         FAULT(7)
 488 END(dkey_miss)
 489
 490         .org ia64_ivt+0x2000
 491 /////////////////////////////////////////////////////////////////////////////////////////
 492 // 0x2000 Entry 8 (size 64 bundles) Dirty-bit (54)
 493 ENTRY(dirty_bit)
 494         DBG_FAULT(8)
 495         /*
 496          * What we do here is to simply turn on the dirty bit in the PTE.  We need to
 497          * update both the page-table and the TLB entry.  To efficiently access the PTE,
 498          * we address it through the virtual page table.  Most likely, the TLB entry for
 499          * the relevant virtual page table page is still present in the TLB so we can
 500          * normally do this without additional TLB misses.  In case the necessary virtual
 501          * page table TLB entry isn't present, we take a nested TLB miss hit where we look
 502          * up the physical address of the L3 PTE and then continue at label 1 below.
 503          */
 504         mov r16=cr.ifa                          // get the address that caused the fault
 505         movl r30=1f                             // load continuation point in case of nested fault
 506         ;;
 507         thash r17=r16                           // compute virtual address of L3 PTE
 508         mov r29=b0                              // save b0 in case of nested fault
 509         mov r31=pr                              // save pr
 510 #ifdef CONFIG_SMP
 511         mov r28=ar.ccv                          // save ar.ccv
 512         ;;
 513 1:      ld8 r18=[r17]
 514         ;;                                      // avoid RAW on r18
 515         mov ar.ccv=r18                          // set compare value for cmpxchg
 516         or r25=_PAGE_D|_PAGE_A,r18              // set the dirty and accessed bits
 517         ;;
 518         cmpxchg8.acq r26=[r17],r25,ar.ccv
 519         mov r24=PAGE_SHIFT<<2
 520         ;;
 521         cmp.eq p6,p7=r26,r18
 522         ;;
 523 (p6)    itc.d r25                               // install updated PTE
 524         ;;
 525         /*
 526          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 527          * cannot possibly affect the following loads:
 528          */
 529         dv_serialize_data
 530
 531         ld8 r18=[r17]                           // read PTE again
 532         ;;
 533         cmp.eq p6,p7=r18,r25                    // is it same as the newly installed
 534         ;;
 535 (p7)    ptc.l r16,r24
 536         mov b0=r29                              // restore b0
 537         mov ar.ccv=r28
 538 #else
 539         ;;
 540 1:      ld8 r18=[r17]
 541         ;;                                      // avoid RAW on r18
 542         or r18=_PAGE_D|_PAGE_A,r18              // set the dirty and accessed bits
 543         mov b0=r29                              // restore b0
 544         ;;
 545         st8 [r17]=r18                           // store back updated PTE
 546         itc.d r18                               // install updated PTE
 547 #endif
 548         mov pr=r31,-1                           // restore pr
 549         rfi
 550 END(idirty_bit)
 551
 552         .org ia64_ivt+0x2400
 553 /////////////////////////////////////////////////////////////////////////////////////////
 554 // 0x2400 Entry 9 (size 64 bundles) Instruction Access-bit (27)
 555 ENTRY(iaccess_bit)
 556         DBG_FAULT(9)
 557         // Like Entry 8, except for instruction access
 558         mov r16=cr.ifa                          // get the address that caused the fault
 559         movl r30=1f                             // load continuation point in case of nested fault
 560         mov r31=pr                              // save predicates
 561 #ifdef CONFIG_ITANIUM
 562         /*
 563          * Erratum 10 (IFA may contain incorrect address) has "NoFix" status.
 564          */
 565         mov r17=cr.ipsr
 566         ;;
 567         mov r18=cr.iip
 568         tbit.z p6,p0=r17,IA64_PSR_IS_BIT        // IA64 instruction set?
 569         ;;
 570 (p6)    mov r16=r18                             // if so, use cr.iip instead of cr.ifa
 571 #endif /* CONFIG_ITANIUM */
 572         ;;
 573         thash r17=r16                           // compute virtual address of L3 PTE
 574         mov r29=b0                              // save b0 in case of nested fault)
 575 #ifdef CONFIG_SMP
 576         mov r28=ar.ccv                          // save ar.ccv
 577         ;;
 578 1:      ld8 r18=[r17]
 579         ;;
 580         mov ar.ccv=r18                          // set compare value for cmpxchg
 581         or r25=_PAGE_A,r18                      // set the accessed bit
 582         ;;
 583         cmpxchg8.acq r26=[r17],r25,ar.ccv
 584         mov r24=PAGE_SHIFT<<2
 585         ;;
 586         cmp.eq p6,p7=r26,r18
 587         ;;
 588 (p6)    itc.i r25                               // install updated PTE
 589         ;;
 590         /*
 591          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 592          * cannot possibly affect the following loads:
 593          */
 594         dv_serialize_data
 595
 596         ld8 r18=[r17]                           // read PTE again
 597         ;;
 598         cmp.eq p6,p7=r18,r25                    // is it same as the newly installed
 599         ;;
 600 (p7)    ptc.l r16,r24
 601         mov b0=r29                              // restore b0
 602         mov ar.ccv=r28
 603 #else /* !CONFIG_SMP */
 604         ;;
 605 1:      ld8 r18=[r17]
 606         ;;
 607         or r18=_PAGE_A,r18                      // set the accessed bit
 608         mov b0=r29                              // restore b0
 609         ;;
 610         st8 [r17]=r18                           // store back updated PTE
 611         itc.i r18                               // install updated PTE
 612 #endif /* !CONFIG_SMP */
 613         mov pr=r31,-1
 614         rfi
 615 END(iaccess_bit)
 616
 617         .org ia64_ivt+0x2800
 618 /////////////////////////////////////////////////////////////////////////////////////////
 619 // 0x2800 Entry 10 (size 64 bundles) Data Access-bit (15,55)
 620 ENTRY(daccess_bit)
 621         DBG_FAULT(10)
 622         // Like Entry 8, except for data access
 623         mov r16=cr.ifa                          // get the address that caused the fault
 624         movl r30=1f                             // load continuation point in case of nested fault
 625         ;;
 626         thash r17=r16                           // compute virtual address of L3 PTE
 627         mov r31=pr
 628         mov r29=b0                              // save b0 in case of nested fault)
 629 #ifdef CONFIG_SMP
 630         mov r28=ar.ccv                          // save ar.ccv
 631         ;;
 632 1:      ld8 r18=[r17]
 633         ;;                                      // avoid RAW on r18
 634         mov ar.ccv=r18                          // set compare value for cmpxchg
 635         or r25=_PAGE_A,r18                      // set the dirty bit
 636         ;;
 637         cmpxchg8.acq r26=[r17],r25,ar.ccv
 638         mov r24=PAGE_SHIFT<<2
 639         ;;
 640         cmp.eq p6,p7=r26,r18
 641         ;;
 642 (p6)    itc.d r25                               // install updated PTE
 643         /*
 644          * Tell the assemblers dependency-violation checker that the above "itc" instructions
 645          * cannot possibly affect the following loads:
 646          */
 647         dv_serialize_data
 648         ;;
 649         ld8 r18=[r17]                           // read PTE again
 650         ;;
 651         cmp.eq p6,p7=r18,r25                    // is it same as the newly installed
 652         ;;
 653 (p7)    ptc.l r16,r24
 654         mov ar.ccv=r28
 655 #else
 656         ;;
 657 1:      ld8 r18=[r17]
 658         ;;                                      // avoid RAW on r18
 659         or r18=_PAGE_A,r18                      // set the accessed bit
 660         ;;
 661         st8 [r17]=r18                           // store back updated PTE
 662         itc.d r18                               // install updated PTE
 663 #endif
 664         mov b0=r29                              // restore b0
 665         mov pr=r31,-1
 666         rfi
 667 END(daccess_bit)
 668
 669         .org ia64_ivt+0x2c00
 670 /////////////////////////////////////////////////////////////////////////////////////////
 671 // 0x2c00 Entry 11 (size 64 bundles) Break instruction (33)
 672 ENTRY(break_fault)
 673         /*
 674          * The streamlined system call entry/exit paths only save/restore the initial part
 675          * of pt_regs.  This implies that the callers of system-calls must adhere to the
 676          * normal procedure calling conventions.
 677          *
 678          *   Registers to be saved & restored:
 679          *      CR registers: cr.ipsr, cr.iip, cr.ifs
 680          *      AR registers: ar.unat, ar.pfs, ar.rsc, ar.rnat, ar.bspstore, ar.fpsr
 681          *      others: pr, b0, b6, loadrs, r1, r11, r12, r13, r15
 682          *   Registers to be restored only:
 683          *      r8-r11: output value from the system call.
 684          *
 685          * During system call exit, scratch registers (including r15) are modified/cleared
 686          * to prevent leaking bits from kernel to user level.
 687          */
 688         DBG_FAULT(11)
 689         mov r16=IA64_KR(CURRENT)                // r16 = current task; 12 cycle read lat.
 690         mov r17=cr.iim
 691         mov r18=__IA64_BREAK_SYSCALL
 692         mov r21=ar.fpsr
 693         mov r29=cr.ipsr
 694         mov r19=b6
 695         mov r25=ar.unat
 696         mov r27=ar.rsc
 697         mov r26=ar.pfs
 698         mov r28=cr.iip
 699         mov r31=pr                              // prepare to save predicates
 700         mov r20=r1
 701         ;;
 702         adds r16=IA64_TASK_THREAD_ON_USTACK_OFFSET,r16
 703         cmp.eq p0,p7=r18,r17                    // is this a system call? (p7 <- false, if so)
 704 (p7)    br.cond.spnt non_syscall
 705         ;;
 706         ld1 r17=[r16]                           // load current->thread.on_ustack flag
 707         st1 [r16]=r0                            // clear current->thread.on_ustack flag
 708         add r1=-IA64_TASK_THREAD_ON_USTACK_OFFSET,r16   // set r1 for MINSTATE_START_SAVE_MIN_VIRT
 709         ;;
 710         invala
 711
 712         /* adjust return address so we skip over the break instruction: */
 713
 714         extr.u r8=r29,41,2                      // extract ei field from cr.ipsr
 715         ;;
 716         cmp.eq p6,p7=2,r8                       // isr.ei==2?
 717         mov r2=r1                               // setup r2 for ia64_syscall_setup
 718         ;;
 719 (p6)    mov r8=0                                // clear ei to 0
 720 (p6)    adds r28=16,r28                         // switch cr.iip to next bundle cr.ipsr.ei wrapped
 721 (p7)    adds r8=1,r8                            // increment ei to next slot
 722         ;;
 723         cmp.eq pKStk,pUStk=r0,r17               // are we in kernel mode already?
 724         dep r29=r8,r29,41,2                     // insert new ei into cr.ipsr
 725         ;;
 726
 727         // switch from user to kernel RBS:
 728         MINSTATE_START_SAVE_MIN_VIRT
 729         br.call.sptk.many b7=ia64_syscall_setup
 730         ;;
 731         MINSTATE_END_SAVE_MIN_VIRT              // switch to bank 1
 732         ssm psr.ic | PSR_DEFAULT_BITS
 733         ;;
 734         srlz.i                                  // guarantee that interruption collection is on
 735         ;;
 736 (p15)   ssm psr.i                               // restore psr.i
 737         ;;
 738         mov r3=NR_syscalls - 1
 739         movl r16=sys_call_table
 740
 741         adds r15=-1024,r15                      // r15 contains the syscall number---subtract 1024
 742         movl r2=ia64_ret_from_syscall
 743         ;;
 744         shladd r20=r15,3,r16                    // r20 = sys_call_table + 8*(syscall-1024)
 745         cmp.leu p6,p7=r15,r3                    // (syscall > 0 && syscall < 1024 + NR_syscalls) ?
 746         mov rp=r2                               // set the real return addr
 747         ;;
 748 (p6)    ld8 r20=[r20]                           // load address of syscall entry point
 749 (p7)    movl r20=sys_ni_syscall
 750
 751         add r2=TI_FLAGS+IA64_TASK_SIZE,r13
 752         ;;
 753         ld4 r2=[r2]                             // r2 = current_thread_info()->flags
 754         ;;
 755         tbit.z p8,p0=r2,TIF_SYSCALL_TRACE
 756         mov b6=r20
 757         ;;
 758 (p8)    br.call.sptk.many b6=b6                 // ignore this return addr
 759         br.cond.sptk ia64_trace_syscall
 760         // NOT REACHED
 761 END(break_fault)
 762
 763         .org ia64_ivt+0x3000
 764 /////////////////////////////////////////////////////////////////////////////////////////
 765 // 0x3000 Entry 12 (size 64 bundles) External Interrupt (4)
 766 ENTRY(interrupt)
 767         DBG_FAULT(12)
 768         mov r31=pr              // prepare to save predicates
 769         ;;
 770         SAVE_MIN_WITH_COVER     // uses r31; defines r2 and r3
 771         ssm psr.ic | PSR_DEFAULT_BITS
 772         ;;
 773         adds r3=8,r2            // set up second base pointer for SAVE_REST
 774         srlz.i                  // ensure everybody knows psr.ic is back on
 775         ;;
 776         SAVE_REST
 777         ;;
 778         alloc r14=ar.pfs,0,0,2,0 // must be first in an insn group
 779         mov out0=cr.ivr         // pass cr.ivr as first arg
 780         add out1=16,sp          // pass pointer to pt_regs as second arg
 781         ;;
 782         srlz.d                  // make sure we see the effect of cr.ivr
 783         movl r14=ia64_leave_kernel
 784         ;;
 785         mov rp=r14
 786         br.call.sptk.many b6=ia64_handle_irq
 787 END(interrupt)
 788
 789         .org ia64_ivt+0x3400
 790 /////////////////////////////////////////////////////////////////////////////////////////
 791 // 0x3400 Entry 13 (size 64 bundles) Reserved
 792         DBG_FAULT(13)
 793         FAULT(13)
 794
 795         .org ia64_ivt+0x3800
 796 /////////////////////////////////////////////////////////////////////////////////////////
 797 // 0x3800 Entry 14 (size 64 bundles) Reserved
 798         DBG_FAULT(14)
 799         FAULT(14)
 800
 801         /*
 802          * There is no particular reason for this code to be here, other than that
 803          * there happens to be space here that would go unused otherwise.  If this
 804          * fault ever gets "unreserved", simply moved the following code to a more
 805          * suitable spot...
 806          *
 807          * ia64_syscall_setup() is a separate subroutine so that it can
 808          *      allocate stacked registers so it can safely demine any
 809          *      potential NaT values from the input registers.
 810          *
 811          * On entry:
 812          *      - executing on bank 0 or bank 1 register set (doesn't matter)
 813          *      -  r1: stack pointer
 814          *      -  r2: current task pointer
 815          *      -  r3: preserved
 816          *      - r11: original contents (saved ar.pfs to be saved)
 817          *      - r12: original contents (sp to be saved)
 818          *      - r13: original contents (tp to be saved)
 819          *      - r15: original contents (syscall # to be saved)
 820          *      - r18: saved bsp (after switching to kernel stack)
 821          *      - r19: saved b6
 822          *      - r20: saved r1 (gp)
 823          *      - r21: saved ar.fpsr
 824          *      - r22: kernel's register backing store base (krbs_base)
 825          *      - r23: saved ar.bspstore
 826          *      - r24: saved ar.rnat
 827          *      - r25: saved ar.unat
 828          *      - r26: saved ar.pfs
 829          *      - r27: saved ar.rsc
 830          *      - r28: saved cr.iip
 831          *      - r29: saved cr.ipsr
 832          *      - r31: saved pr
 833          *      -  b0: original contents (to be saved)
 834          * On exit:
 835          *      - executing on bank 1 registers
 836          *      - psr.ic enabled, interrupts restored
 837          *      -  r1: kernel's gp
 838          *      -  r3: preserved (same as on entry)
 839          *      - r12: points to kernel stack
 840          *      - r13: points to current task
 841          *      - p15: TRUE if interrupts need to be re-enabled
 842          *      - ar.fpsr: set to kernel settings
 843          */
 844 GLOBAL_ENTRY(ia64_syscall_setup)
 845 #if PT(B6) != 0
 846 # error This code assumes that b6 is the first field in pt_regs.
 847 #endif
 848         st8 [r1]=r19                            // save b6
 849         add r16=PT(CR_IPSR),r1                  // initialize first base pointer
 850         add r17=PT(R11),r1                      // initialize second base pointer
 851         ;;
 852         alloc r19=ar.pfs,8,0,0,0                // ensure in0-in7 are writable
 853         st8 [r16]=r29,PT(CR_IFS)-PT(CR_IPSR)    // save cr.ipsr
 854         tnat.nz p8,p0=in0
 855
 856         st8.spill [r17]=r11,PT(CR_IIP)-PT(R11)  // save r11
 857         tnat.nz p9,p0=in1
 858 (pKStk) mov r18=r0                              // make sure r18 isn't NaT
 859         ;;
 860
 861         st8 [r17]=r28,PT(AR_UNAT)-PT(CR_IIP)    // save cr.iip
 862         mov r28=b0                              // save b0 (2 cyc)
 863 (p8)    mov in0=-1
 864         ;;
 865
 866         st8 [r16]=r0,PT(AR_PFS)-PT(CR_IFS)      // clear cr.ifs
 867         st8 [r17]=r25,PT(AR_RSC)-PT(AR_UNAT)    // save ar.unat
 868 (p9)    mov in1=-1
 869         ;;
 870
 871         st8 [r16]=r26,PT(AR_RNAT)-PT(AR_PFS)    // save ar.pfs
 872         st8 [r17]=r27,PT(AR_BSPSTORE)-PT(AR_RSC)// save ar.rsc
 873         tnat.nz p10,p0=in2
 874
 875 (pUStk) sub r18=r18,r22                         // r18=RSE.ndirty*8
 876         tbit.nz p15,p0=r29,IA64_PSR_I_BIT
 877         tnat.nz p11,p0=in3
 878         ;;
 879 (pKStk) adds r16=PT(PR)-PT(AR_RNAT),r16         // skip over ar_rnat field
 880 (pKStk) adds r17=PT(B0)-PT(AR_BSPSTORE),r17     // skip over ar_bspstore field
 881 (p10)   mov in2=-1
 882
 883 (p11)   mov in3=-1
 884         tnat.nz p12,p0=in4
 885         tnat.nz p13,p0=in5
 886         ;;
 887 (pUStk) st8 [r16]=r24,PT(PR)-PT(AR_RNAT)        // save ar.rnat
 888 (pUStk) st8 [r17]=r23,PT(B0)-PT(AR_BSPSTORE)    // save ar.bspstore
 889         shl r18=r18,16                          // compute ar.rsc to be used for "loadrs"
 890         ;;
 891         st8 [r16]=r31,PT(LOADRS)-PT(PR)         // save predicates
 892         st8 [r17]=r28,PT(R1)-PT(B0)             // save b0
 893 (p12)   mov in4=-1
 894         ;;
 895         st8 [r16]=r18,PT(R12)-PT(LOADRS)        // save ar.rsc value for "loadrs"
 896         st8.spill [r17]=r20,PT(R13)-PT(R1)      // save original r1
 897 (p13)   mov in5=-1
 898         ;;
 899
 900 .mem.offset 0,0; st8.spill [r16]=r12,PT(AR_FPSR)-PT(R12)        // save r12
 901 .mem.offset 8,0; st8.spill [r17]=r13,PT(R15)-PT(R13)            // save r13
 902         tnat.nz p14,p0=in6
 903         ;;
 904         st8 [r16]=r21,PT(R8)-PT(AR_FPSR)        // save ar.fpsr
 905         st8.spill [r17]=r15                     // save r15
 906         tnat.nz p8,p0=in7
 907         ;;
 908         stf8 [r16]=f1           // ensure pt_regs.r8 != 0 (see handle_syscall_error)
 909         adds r12=-16,r1         // switch to kernel memory stack (with 16 bytes of scratch)
 910 (p14)   mov in6=-1
 911
 912         mov r13=r2                              // establish `current'
 913         movl r1=__gp                            // establish kernel global pointer
 914         ;;
 915 (p8)    mov in7=-1
 916         tnat.nz p9,p0=r15
 917
 918         cmp.eq pSys,pNonSys=r0,r0               // set pSys=1, pNonSys=0
 919         movl r17=FPSR_DEFAULT
 920         ;;
 921         mov.m ar.fpsr=r17                       // set ar.fpsr to kernel default value
 922 (p9)    mov r15=-1
 923         br.ret.sptk.many b7
 924 END(ia64_syscall_setup)
 925
 926         .org ia64_ivt+0x3c00
 927 /////////////////////////////////////////////////////////////////////////////////////////
 928 // 0x3c00 Entry 15 (size 64 bundles) Reserved
 929         DBG_FAULT(15)
 930         FAULT(15)
 931
 932         /*
 933          * Squatting in this space ...
 934          *
 935          * This special case dispatcher for illegal operation faults allows preserved
 936          * registers to be modified through a callback function (asm only) that is handed
 937          * back from the fault handler in r8. Up to three arguments can be passed to the
 938          * callback function by returning an aggregate with the callback as its first
 939          * element, followed by the arguments.
 940          */
 941 ENTRY(dispatch_illegal_op_fault)
 942         SAVE_MIN_WITH_COVER
 943         ssm psr.ic | PSR_DEFAULT_BITS
 944         ;;
 945         srlz.i          // guarantee that interruption collection is on
 946         ;;
 947 (p15)   ssm psr.i       // restore psr.i
 948         adds r3=8,r2    // set up second base pointer for SAVE_REST
 949         ;;
 950         alloc r14=ar.pfs,0,0,1,0        // must be first in insn group
 951         mov out0=ar.ec
 952         ;;
 953         SAVE_REST
 954         ;;
 955         br.call.sptk.many rp=ia64_illegal_op_fault
 956 .ret0:  ;;
 957         alloc r14=ar.pfs,0,0,3,0        // must be first in insn group
 958         mov out0=r9
 959         mov out1=r10
 960         mov out2=r11
 961         movl r15=ia64_leave_kernel
 962         ;;
 963         mov rp=r15
 964         mov b6=r8
 965         ;;
 966         cmp.ne p6,p0=0,r8
 967 (p6)    br.call.dpnt.many b6=b6         // call returns to ia64_leave_kernel
 968         br.sptk.many ia64_leave_kernel
 969 END(dispatch_illegal_op_fault)
 970
 971         .org ia64_ivt+0x4000
 972 /////////////////////////////////////////////////////////////////////////////////////////
 973 // 0x4000 Entry 16 (size 64 bundles) Reserved
 974         DBG_FAULT(16)
 975         FAULT(16)
 976
 977         .org ia64_ivt+0x4400
 978 /////////////////////////////////////////////////////////////////////////////////////////
 979 // 0x4400 Entry 17 (size 64 bundles) Reserved
 980         DBG_FAULT(17)
 981         FAULT(17)
 982
 983 ENTRY(non_syscall)
 984         SAVE_MIN_WITH_COVER
 985
 986         // There is no particular reason for this code to be here, other than that
 987         // there happens to be space here that would go unused otherwise.  If this
 988         // fault ever gets "unreserved", simply moved the following code to a more
 989         // suitable spot...
 990
 991         alloc r14=ar.pfs,0,0,2,0
 992         mov out0=cr.iim
 993         add out1=16,sp
 994         adds r3=8,r2                    // set up second base pointer for SAVE_REST
 995
 996         ssm psr.ic | PSR_DEFAULT_BITS
 997         ;;
 998         srlz.i                          // guarantee that interruption collection is on
 999         ;;
1000 (p15)   ssm psr.i                       // restore psr.i
1001         movl r15=ia64_leave_kernel
1002         ;;
1003         SAVE_REST
1004         mov rp=r15
1005         ;;
1006         br.call.sptk.many b6=ia64_bad_break     // avoid WAW on CFM and ignore return addr
1007 END(non_syscall)
1008
1009         .org ia64_ivt+0x4800
1010 /////////////////////////////////////////////////////////////////////////////////////////
1011 // 0x4800 Entry 18 (size 64 bundles) Reserved
1012         DBG_FAULT(18)
1013         FAULT(18)
1014
1015         /*
1016          * There is no particular reason for this code to be here, other than that
1017          * there happens to be space here that would go unused otherwise.  If this
1018          * fault ever gets "unreserved", simply moved the following code to a more
1019          * suitable spot...
1020          */
1021
1022 ENTRY(dispatch_unaligned_handler)
1023         SAVE_MIN_WITH_COVER
1024         ;;
1025         alloc r14=ar.pfs,0,0,2,0                // now it's safe (must be first in insn group!)
1026         mov out0=cr.ifa
1027         adds out1=16,sp
1028
1029         ssm psr.ic | PSR_DEFAULT_BITS
1030         ;;
1031         srlz.i                                  // guarantee that interruption collection is on
1032         ;;
1033 (p15)   ssm psr.i                               // restore psr.i
1034         adds r3=8,r2                            // set up second base pointer
1035         ;;
1036         SAVE_REST
1037         movl r14=ia64_leave_kernel
1038         ;;
1039         mov rp=r14
1040         br.sptk.many ia64_prepare_handle_unaligned
1041 END(dispatch_unaligned_handler)
1042
1043         .org ia64_ivt+0x4c00
1044 /////////////////////////////////////////////////////////////////////////////////////////
1045 // 0x4c00 Entry 19 (size 64 bundles) Reserved
1046         DBG_FAULT(19)
1047         FAULT(19)
1048
1049         /*
1050          * There is no particular reason for this code to be here, other than that
1051          * there happens to be space here that would go unused otherwise.  If this
1052          * fault ever gets "unreserved", simply moved the following code to a more
1053          * suitable spot...
1054          */
1055
1056 ENTRY(dispatch_to_fault_handler)
1057         /*
1058          * Input:
1059          *      psr.ic: off
1060          *      r19:    fault vector number (e.g., 24 for General Exception)
1061          *      r31:    contains saved predicates (pr)
1062          */
1063         SAVE_MIN_WITH_COVER_R19
1064         alloc r14=ar.pfs,0,0,5,0
1065         mov out0=r15
1066         mov out1=cr.isr
1067         mov out2=cr.ifa
1068         mov out3=cr.iim
1069         mov out4=cr.itir
1070         ;;
1071         ssm psr.ic | PSR_DEFAULT_BITS
1072         ;;
1073         srlz.i                                  // guarantee that interruption collection is on
1074         ;;
1075 (p15)   ssm psr.i                               // restore psr.i
1076         adds r3=8,r2                            // set up second base pointer for SAVE_REST
1077         ;;
1078         SAVE_REST
1079         movl r14=ia64_leave_kernel
1080         ;;
1081         mov rp=r14
1082         br.call.sptk.many b6=ia64_fault
1083 END(dispatch_to_fault_handler)
1084
1085 //
1086 // --- End of long entries, Beginning of short entries
1087 //
1088
1089         .org ia64_ivt+0x5000
1090 /////////////////////////////////////////////////////////////////////////////////////////
1091 // 0x5000 Entry 20 (size 16 bundles) Page Not Present (10,22,49)
1092 ENTRY(page_not_present)
1093         DBG_FAULT(20)
1094         mov r16=cr.ifa
1095         rsm psr.dt
1096         /*
1097          * The Linux page fault handler doesn't expect non-present pages to be in
1098          * the TLB.  Flush the existing entry now, so we meet that expectation.
1099          */
1100         mov r17=PAGE_SHIFT<<2
1101         ;;
1102         ptc.l r16,r17
1103         ;;
1104         mov r31=pr
1105         srlz.d
1106         br.sptk.many page_fault
1107 END(page_not_present)
1108
1109         .org ia64_ivt+0x5100
1110 /////////////////////////////////////////////////////////////////////////////////////////
1111 // 0x5100 Entry 21 (size 16 bundles) Key Permission (13,25,52)
1112 ENTRY(key_permission)
1113         DBG_FAULT(21)
1114         mov r16=cr.ifa
1115         rsm psr.dt
1116         mov r31=pr
1117         ;;
1118         srlz.d
1119         br.sptk.many page_fault
1120 END(key_permission)
1121
1122         .org ia64_ivt+0x5200
1123 /////////////////////////////////////////////////////////////////////////////////////////
1124 // 0x5200 Entry 22 (size 16 bundles) Instruction Access Rights (26)
1125 ENTRY(iaccess_rights)
1126         DBG_FAULT(22)
1127         mov r16=cr.ifa
1128         rsm psr.dt
1129         mov r31=pr
1130         ;;
1131         srlz.d
1132         br.sptk.many page_fault
1133 END(iaccess_rights)
1134
1135         .org ia64_ivt+0x5300
1136 /////////////////////////////////////////////////////////////////////////////////////////
1137 // 0x5300 Entry 23 (size 16 bundles) Data Access Rights (14,53)
1138 ENTRY(daccess_rights)
1139         DBG_FAULT(23)
1140         mov r16=cr.ifa
1141         rsm psr.dt
1142         mov r31=pr
1143         ;;
1144         srlz.d
1145         br.sptk.many page_fault
1146 END(daccess_rights)
1147
1148         .org ia64_ivt+0x5400
1149 /////////////////////////////////////////////////////////////////////////////////////////
1150 // 0x5400 Entry 24 (size 16 bundles) General Exception (5,32,34,36,38,39)
1151 ENTRY(general_exception)
1152         DBG_FAULT(24)
1153         mov r16=cr.isr
1154         mov r31=pr
1155         ;;
1156         cmp4.eq p6,p0=0,r16
1157 (p6)    br.sptk.many dispatch_illegal_op_fault
1158         ;;
1159         mov r19=24              // fault number
1160         br.sptk.many dispatch_to_fault_handler
1161 END(general_exception)
1162
1163         .org ia64_ivt+0x5500
1164 /////////////////////////////////////////////////////////////////////////////////////////
1165 // 0x5500 Entry 25 (size 16 bundles) Disabled FP-Register (35)
1166 ENTRY(disabled_fp_reg)
1167         DBG_FAULT(25)
1168         rsm psr.dfh             // ensure we can access fph
1169         ;;
1170         srlz.d
1171         mov r31=pr
1172         mov r19=25
1173         br.sptk.many dispatch_to_fault_handler
1174 END(disabled_fp_reg)
1175
1176         .org ia64_ivt+0x5600
1177 /////////////////////////////////////////////////////////////////////////////////////////
1178 // 0x5600 Entry 26 (size 16 bundles) Nat Consumption (11,23,37,50)
1179 ENTRY(nat_consumption)
1180         DBG_FAULT(26)
1181         FAULT(26)
1182 END(nat_consumption)
1183
1184         .org ia64_ivt+0x5700
1185 /////////////////////////////////////////////////////////////////////////////////////////
1186 // 0x5700 Entry 27 (size 16 bundles) Speculation (40)
1187 ENTRY(speculation_vector)
1188         DBG_FAULT(27)
1189         /*
1190          * A [f]chk.[as] instruction needs to take the branch to the recovery code but
1191          * this part of the architecture is not implemented in hardware on some CPUs, such
1192          * as Itanium.  Thus, in general we need to emulate the behavior.  IIM contains
1193          * the relative target (not yet sign extended).  So after sign extending it we
1194          * simply add it to IIP.  We also need to reset the EI field of the IPSR to zero,
1195          * i.e., the slot to restart into.
1196          *
1197          * cr.imm contains zero_ext(imm21)
1198          */
1199         mov r18=cr.iim
1200         ;;
1201         mov r17=cr.iip
1202         shl r18=r18,43                  // put sign bit in position (43=64-21)
1203         ;;
1204
1205         mov r16=cr.ipsr
1206         shr r18=r18,39                  // sign extend (39=43-4)
1207         ;;
1208
1209         add r17=r17,r18                 // now add the offset
1210         ;;
1211         mov cr.iip=r17
1212         dep r16=0,r16,41,2              // clear EI
1213         ;;
1214
1215         mov cr.ipsr=r16
1216         ;;
1217
1218         rfi                             // and go back
1219 END(speculation_vector)
1220
1221         .org ia64_ivt+0x5800
1222 /////////////////////////////////////////////////////////////////////////////////////////
1223 // 0x5800 Entry 28 (size 16 bundles) Reserved
1224         DBG_FAULT(28)
1225         FAULT(28)
1226
1227         .org ia64_ivt+0x5900
1228 /////////////////////////////////////////////////////////////////////////////////////////
1229 // 0x5900 Entry 29 (size 16 bundles) Debug (16,28,56)
1230 ENTRY(debug_vector)
1231         DBG_FAULT(29)
1232         FAULT(29)
1233 END(debug_vector)
1234
1235         .org ia64_ivt+0x5a00
1236 /////////////////////////////////////////////////////////////////////////////////////////
1237 // 0x5a00 Entry 30 (size 16 bundles) Unaligned Reference (57)
1238 ENTRY(unaligned_access)
1239         DBG_FAULT(30)
1240         mov r16=cr.ipsr
1241         mov r31=pr              // prepare to save predicates
1242         ;;
1243         br.sptk.many dispatch_unaligned_handler
1244 END(unaligned_access)
1245
1246         .org ia64_ivt+0x5b00
1247 /////////////////////////////////////////////////////////////////////////////////////////
1248 // 0x5b00 Entry 31 (size 16 bundles) Unsupported Data Reference (57)
1249 ENTRY(unsupported_data_reference)
1250         DBG_FAULT(31)
1251         FAULT(31)
1252 END(unsupported_data_reference)
1253
1254         .org ia64_ivt+0x5c00
1255 /////////////////////////////////////////////////////////////////////////////////////////
1256 // 0x5c00 Entry 32 (size 16 bundles) Floating-Point Fault (64)
1257 ENTRY(floating_point_fault)
1258         DBG_FAULT(32)
1259         FAULT(32)
1260 END(floating_point_fault)
1261
1262         .org ia64_ivt+0x5d00
1263 /////////////////////////////////////////////////////////////////////////////////////////
1264 // 0x5d00 Entry 33 (size 16 bundles) Floating Point Trap (66)
1265 ENTRY(floating_point_trap)
1266         DBG_FAULT(33)
1267         FAULT(33)
1268 END(floating_point_trap)
1269
1270         .org ia64_ivt+0x5e00
1271 /////////////////////////////////////////////////////////////////////////////////////////
1272 // 0x5e00 Entry 34 (size 16 bundles) Lower Privilege Transfer Trap (66)
1273 ENTRY(lower_privilege_trap)
1274         DBG_FAULT(34)
1275         FAULT(34)
1276 END(lower_privilege_trap)
1277
1278         .org ia64_ivt+0x5f00
1279 /////////////////////////////////////////////////////////////////////////////////////////
1280 // 0x5f00 Entry 35 (size 16 bundles) Taken Branch Trap (68)
1281 ENTRY(taken_branch_trap)
1282         DBG_FAULT(35)
1283         FAULT(35)
1284 END(taken_branch_trap)
1285
1286         .org ia64_ivt+0x6000
1287 /////////////////////////////////////////////////////////////////////////////////////////
1288 // 0x6000 Entry 36 (size 16 bundles) Single Step Trap (69)
1289 ENTRY(single_step_trap)
1290         DBG_FAULT(36)
1291         FAULT(36)
1292 END(single_step_trap)
1293
1294         .org ia64_ivt+0x6100
1295 /////////////////////////////////////////////////////////////////////////////////////////
1296 // 0x6100 Entry 37 (size 16 bundles) Reserved
1297         DBG_FAULT(37)
1298         FAULT(37)
1299
1300         .org ia64_ivt+0x6200
1301 /////////////////////////////////////////////////////////////////////////////////////////
1302 // 0x6200 Entry 38 (size 16 bundles) Reserved
1303         DBG_FAULT(38)
1304         FAULT(38)
1305
1306         .org ia64_ivt+0x6300
1307 /////////////////////////////////////////////////////////////////////////////////////////
1308 // 0x6300 Entry 39 (size 16 bundles) Reserved
1309         DBG_FAULT(39)
1310         FAULT(39)
1311
1312         .org ia64_ivt+0x6400
1313 /////////////////////////////////////////////////////////////////////////////////////////
1314 // 0x6400 Entry 40 (size 16 bundles) Reserved
1315         DBG_FAULT(40)
1316         FAULT(40)
1317
1318         .org ia64_ivt+0x6500
1319 /////////////////////////////////////////////////////////////////////////////////////////
1320 // 0x6500 Entry 41 (size 16 bundles) Reserved
1321         DBG_FAULT(41)
1322         FAULT(41)
1323
1324         .org ia64_ivt+0x6600
1325 /////////////////////////////////////////////////////////////////////////////////////////
1326 // 0x6600 Entry 42 (size 16 bundles) Reserved
1327         DBG_FAULT(42)
1328         FAULT(42)
1329
1330         .org ia64_ivt+0x6700
1331 /////////////////////////////////////////////////////////////////////////////////////////
1332 // 0x6700 Entry 43 (size 16 bundles) Reserved
1333         DBG_FAULT(43)
1334         FAULT(43)
1335
1336         .org ia64_ivt+0x6800
1337 /////////////////////////////////////////////////////////////////////////////////////////
1338 // 0x6800 Entry 44 (size 16 bundles) Reserved
1339         DBG_FAULT(44)
1340         FAULT(44)
1341
1342         .org ia64_ivt+0x6900
1343 /////////////////////////////////////////////////////////////////////////////////////////
1344 // 0x6900 Entry 45 (size 16 bundles) IA-32 Exeception (17,18,29,41,42,43,44,58,60,61,62,72,73,75,76,77)
1345 ENTRY(ia32_exception)
1346         DBG_FAULT(45)
1347         FAULT(45)
1348 END(ia32_exception)
1349
1350         .org ia64_ivt+0x6a00
1351 /////////////////////////////////////////////////////////////////////////////////////////
1352 // 0x6a00 Entry 46 (size 16 bundles) IA-32 Intercept  (30,31,59,70,71)
1353 ENTRY(ia32_intercept)
1354         DBG_FAULT(46)
1355 #ifdef  CONFIG_IA32_SUPPORT
1356         mov r31=pr
1357         mov r16=cr.isr
1358         ;;
1359         extr.u r17=r16,16,8     // get ISR.code
1360         mov r18=ar.eflag
1361         mov r19=cr.iim          // old eflag value
1362         ;;
1363         cmp.ne p6,p0=2,r17
1364 (p6)    br.cond.spnt 1f         // not a system flag fault
1365         xor r16=r18,r19
1366         ;;
1367         extr.u r17=r16,18,1     // get the eflags.ac bit
1368         ;;
1369         cmp.eq p6,p0=0,r17
1370 (p6)    br.cond.spnt 1f         // eflags.ac bit didn't change
1371         ;;
1372         mov pr=r31,-1           // restore predicate registers
1373         rfi
1374
1375 1:
1376 #endif  // CONFIG_IA32_SUPPORT
1377         FAULT(46)
1378 END(ia32_intercept)
1379
1380         .org ia64_ivt+0x6b00
1381 /////////////////////////////////////////////////////////////////////////////////////////
1382 // 0x6b00 Entry 47 (size 16 bundles) IA-32 Interrupt  (74)
1383 ENTRY(ia32_interrupt)
1384         DBG_FAULT(47)
1385 #ifdef CONFIG_IA32_SUPPORT
1386         mov r31=pr
1387         br.sptk.many dispatch_to_ia32_handler
1388 #else
1389         FAULT(47)
1390 #endif
1391 END(ia32_interrupt)
1392
1393         .org ia64_ivt+0x6c00
1394 /////////////////////////////////////////////////////////////////////////////////////////
1395 // 0x6c00 Entry 48 (size 16 bundles) Reserved
1396         DBG_FAULT(48)
1397         FAULT(48)
1398
1399         .org ia64_ivt+0x6d00
1400 /////////////////////////////////////////////////////////////////////////////////////////
1401 // 0x6d00 Entry 49 (size 16 bundles) Reserved
1402         DBG_FAULT(49)
1403         FAULT(49)
1404
1405         .org ia64_ivt+0x6e00
1406 /////////////////////////////////////////////////////////////////////////////////////////
1407 // 0x6e00 Entry 50 (size 16 bundles) Reserved
1408         DBG_FAULT(50)
1409         FAULT(50)
1410
1411         .org ia64_ivt+0x6f00
1412 /////////////////////////////////////////////////////////////////////////////////////////
1413 // 0x6f00 Entry 51 (size 16 bundles) Reserved
1414         DBG_FAULT(51)
1415         FAULT(51)
1416
1417         .org ia64_ivt+0x7000
1418 /////////////////////////////////////////////////////////////////////////////////////////
1419 // 0x7000 Entry 52 (size 16 bundles) Reserved
1420         DBG_FAULT(52)
1421         FAULT(52)
1422
1423         .org ia64_ivt+0x7100
1424 /////////////////////////////////////////////////////////////////////////////////////////
1425 // 0x7100 Entry 53 (size 16 bundles) Reserved
1426         DBG_FAULT(53)
1427         FAULT(53)
1428
1429         .org ia64_ivt+0x7200
1430 /////////////////////////////////////////////////////////////////////////////////////////
1431 // 0x7200 Entry 54 (size 16 bundles) Reserved
1432         DBG_FAULT(54)
1433         FAULT(54)
1434
1435         .org ia64_ivt+0x7300
1436 /////////////////////////////////////////////////////////////////////////////////////////
1437 // 0x7300 Entry 55 (size 16 bundles) Reserved
1438         DBG_FAULT(55)
1439         FAULT(55)
1440
1441         .org ia64_ivt+0x7400
1442 /////////////////////////////////////////////////////////////////////////////////////////
1443 // 0x7400 Entry 56 (size 16 bundles) Reserved
1444         DBG_FAULT(56)
1445         FAULT(56)
1446
1447         .org ia64_ivt+0x7500
1448 /////////////////////////////////////////////////////////////////////////////////////////
1449 // 0x7500 Entry 57 (size 16 bundles) Reserved
1450         DBG_FAULT(57)
1451         FAULT(57)
1452
1453         .org ia64_ivt+0x7600
1454 /////////////////////////////////////////////////////////////////////////////////////////
1455 // 0x7600 Entry 58 (size 16 bundles) Reserved
1456         DBG_FAULT(58)
1457         FAULT(58)
1458
1459         .org ia64_ivt+0x7700
1460 /////////////////////////////////////////////////////////////////////////////////////////
1461 // 0x7700 Entry 59 (size 16 bundles) Reserved
1462         DBG_FAULT(59)
1463         FAULT(59)
1464
1465         .org ia64_ivt+0x7800
1466 /////////////////////////////////////////////////////////////////////////////////////////
1467 // 0x7800 Entry 60 (size 16 bundles) Reserved
1468         DBG_FAULT(60)
1469         FAULT(60)
1470
1471         .org ia64_ivt+0x7900
1472 /////////////////////////////////////////////////////////////////////////////////////////
1473 // 0x7900 Entry 61 (size 16 bundles) Reserved
1474         DBG_FAULT(61)
1475         FAULT(61)
1476
1477         .org ia64_ivt+0x7a00
1478 /////////////////////////////////////////////////////////////////////////////////////////
1479 // 0x7a00 Entry 62 (size 16 bundles) Reserved
1480         DBG_FAULT(62)
1481         FAULT(62)
1482
1483         .org ia64_ivt+0x7b00
1484 /////////////////////////////////////////////////////////////////////////////////////////
1485 // 0x7b00 Entry 63 (size 16 bundles) Reserved
1486         DBG_FAULT(63)
1487         FAULT(63)
1488
1489         .org ia64_ivt+0x7c00
1490 /////////////////////////////////////////////////////////////////////////////////////////
1491 // 0x7c00 Entry 64 (size 16 bundles) Reserved
1492         DBG_FAULT(64)
1493         FAULT(64)
1494
1495         .org ia64_ivt+0x7d00
1496 /////////////////////////////////////////////////////////////////////////////////////////
1497 // 0x7d00 Entry 65 (size 16 bundles) Reserved
1498         DBG_FAULT(65)
1499         FAULT(65)
1500
1501         .org ia64_ivt+0x7e00
1502 /////////////////////////////////////////////////////////////////////////////////////////
1503 // 0x7e00 Entry 66 (size 16 bundles) Reserved
1504         DBG_FAULT(66)
1505         FAULT(66)
1506
1507         .org ia64_ivt+0x7f00
1508 /////////////////////////////////////////////////////////////////////////////////////////
1509 // 0x7f00 Entry 67 (size 16 bundles) Reserved
1510         DBG_FAULT(67)
1511         FAULT(67)
1512
1513 #ifdef CONFIG_IA32_SUPPORT
1514
1515         /*
1516          * There is no particular reason for this code to be here, other than that
1517          * there happens to be space here that would go unused otherwise.  If this
1518          * fault ever gets "unreserved", simply moved the following code to a more
1519          * suitable spot...
1520          */
1521
1522         // IA32 interrupt entry point
1523
1524 ENTRY(dispatch_to_ia32_handler)
1525         SAVE_MIN
1526         ;;
1527         mov r14=cr.isr
1528         ssm psr.ic | PSR_DEFAULT_BITS
1529         ;;
1530         srlz.i                                  // guarantee that interruption collection is on
1531         ;;
1532 (p15)   ssm psr.i
1533         adds r3=8,r2            // Base pointer for SAVE_REST
1534         ;;
1535         SAVE_REST
1536         ;;
1537         mov r15=0x80
1538         shr r14=r14,16          // Get interrupt number
1539         ;;
1540         cmp.ne p6,p0=r14,r15
1541 (p6)    br.call.dpnt.many b6=non_ia32_syscall
1542
1543         adds r14=IA64_PT_REGS_R8_OFFSET + 16,sp // 16 byte hole per SW conventions
1544         adds r15=IA64_PT_REGS_R1_OFFSET + 16,sp
1545         ;;
1546         cmp.eq pSys,pNonSys=r0,r0 // set pSys=1, pNonSys=0
1547         ld8 r8=[r14]            // get r8
1548         ;;
1549         st8 [r15]=r8            // save original EAX in r1 (IA32 procs don't use the GP)
1550         ;;
1551         alloc r15=ar.pfs,0,0,6,0        // must first in an insn group
1552         ;;
1553         ld4 r8=[r14],8          // r8 == eax (syscall number)
1554         mov r15=IA32_NR_syscalls
1555         ;;
1556         cmp.ltu.unc p6,p7=r8,r15
1557         ld4 out1=[r14],8        // r9 == ecx
1558         ;;
1559         ld4 out2=[r14],8        // r10 == edx
1560         ;;
1561         ld4 out0=[r14]          // r11 == ebx
1562         adds r14=(IA64_PT_REGS_R13_OFFSET) + 16,sp
1563         ;;
1564         ld4 out5=[r14],PT(R14)-PT(R13)  // r13 == ebp
1565         ;;
1566         ld4 out3=[r14],PT(R15)-PT(R14)  // r14 == esi
1567         adds r2=TI_FLAGS+IA64_TASK_SIZE,r13
1568         ;;
1569         ld4 out4=[r14]          // r15 == edi
1570         movl r16=ia32_syscall_table
1571         ;;
1572 (p6)    shladd r16=r8,3,r16     // force ni_syscall if not valid syscall number
1573         ld4 r2=[r2]             // r2 = current_thread_info()->flags
1574         ;;
1575         ld8 r16=[r16]
1576         tbit.z p8,p0=r2,TIF_SYSCALL_TRACE
1577         ;;
1578         mov b6=r16
1579         movl r15=ia32_ret_from_syscall
1580         ;;
1581         mov rp=r15
1582 (p8)    br.call.sptk.many b6=b6
1583         br.cond.sptk ia32_trace_syscall
1584
1585 non_ia32_syscall:
1586         alloc r15=ar.pfs,0,0,2,0
1587         mov out0=r14                            // interrupt #
1588         add out1=16,sp                          // pointer to pt_regs
1589         ;;                      // avoid WAW on CFM
1590         br.call.sptk.many rp=ia32_bad_interrupt
1591 .ret1:  movl r15=ia64_leave_kernel
1592         ;;
1593         mov rp=r15
1594         br.ret.sptk.many rp
1595 END(dispatch_to_ia32_handler)
1596
1597 #endif /* CONFIG_IA32_SUPPORT */