arch/ia64/lib/memcpy_mck.S

   1 /*
   2  * Itanium 2-optimized version of memcpy and copy_user function
   3  *
   4  * Inputs:
   5  *      in0:    destination address
   6  *      in1:    source address
   7  *      in2:    number of bytes to copy
   8  * Output:
   9  *      0 if success, or number of byte NOT copied if error occurred.
  10  *
  11  * Copyright (C) 2002 Intel Corp.
  12  * Copyright (C) 2002 Ken Chen <kenneth.w.chen@intel.com>
  13  */
  14 #include <linux/config.h>
  15 #include <asm/asmmacro.h>
  16 #include <asm/page.h>
  17
  18 #define EK(y...) EX(y)
  19
  20 GLOBAL_ENTRY(bcopy)
  21         .regstk 3,0,0,0
  22         mov r8=in0
  23         mov in0=in1
  24         ;;
  25         mov in1=r8
  26         ;;
  27 END(bcopy)
  28
  29 /* McKinley specific optimization */
  30
  31 #define retval          r8
  32 #define saved_pfs       r31
  33 #define saved_lc        r10
  34 #define saved_pr        r11
  35 #define saved_in0       r14
  36 #define saved_in1       r15
  37 #define saved_in2       r16
  38
  39 #define src0            r2
  40 #define src1            r3
  41 #define dst0            r17
  42 #define dst1            r18
  43 #define cnt             r9
  44
  45 /* r19-r30 are temp for each code section */
  46 #define PREFETCH_DIST   8
  47 #define src_pre_mem     r19
  48 #define dst_pre_mem     r20
  49 #define src_pre_l2      r21
  50 #define dst_pre_l2      r22
  51 #define t1              r23
  52 #define t2              r24
  53 #define t3              r25
  54 #define t4              r26
  55 #define t5              t1      // alias!
  56 #define t6              t2      // alias!
  57 #define t7              t3      // alias!
  58 #define n8              r27
  59 #define t9              t5      // alias!
  60 #define t10             t4      // alias!
  61 #define t11             t7      // alias!
  62 #define t12             t6      // alias!
  63 #define t14             t10     // alias!
  64 #define t13             r28
  65 #define t15             r29
  66 #define tmp             r30
  67
  68 /* defines for long_copy block */
  69 #define A       0
  70 #define B       (PREFETCH_DIST)
  71 #define C       (B + PREFETCH_DIST)
  72 #define D       (C + 1)
  73 #define N       (D + 1)
  74 #define Nrot    ((N + 7) & ~7)
  75
  76 /* alias */
  77 #define in0             r32
  78 #define in1             r33
  79 #define in2             r34
  80
  81 GLOBAL_ENTRY(memcpy)
  82         and     r28=0x7,in0
  83         and     r29=0x7,in1
  84         mov     f6=f0
  85         br.cond.sptk .common_code
  86         ;;
  87 GLOBAL_ENTRY(__copy_user)
  88         .prologue
  89 // check dest alignment
  90         and     r28=0x7,in0
  91         and     r29=0x7,in1
  92         mov     f6=f1
  93         mov     saved_in0=in0   // save dest pointer
  94         mov     saved_in1=in1   // save src pointer
  95         mov     saved_in2=in2   // save len
  96         ;;
  97 .common_code:
  98         cmp.gt  p15,p0=8,in2    // check for small size
  99         cmp.ne  p13,p0=0,r28    // check dest alignment
 100         cmp.ne  p14,p0=0,r29    // check src alignment
 101         add     src0=0,in1
 102         sub     r30=8,r28       // for .align_dest
 103         mov     retval=r0       // initialize return value
 104         ;;
 105         add     dst0=0,in0
 106         add     dst1=1,in0      // dest odd index
 107         cmp.le  p6,p0 = 1,r30   // for .align_dest
 108 (p15)   br.cond.dpnt .memcpy_short
 109 (p13)   br.cond.dpnt .align_dest
 110 (p14)   br.cond.dpnt .unaligned_src
 111         ;;
 112
 113 // both dest and src are aligned on 8-byte boundary
 114 .aligned_src:
 115         .save ar.pfs, saved_pfs
 116         alloc   saved_pfs=ar.pfs,3,Nrot-3,0,Nrot
 117         .save pr, saved_pr
 118         mov     saved_pr=pr
 119
 120         shr.u   cnt=in2,7       // this much cache line
 121         ;;
 122         cmp.lt  p6,p0=2*PREFETCH_DIST,cnt
 123         cmp.lt  p7,p8=1,cnt
 124         .save ar.lc, saved_lc
 125         mov     saved_lc=ar.lc
 126         .body
 127         add     cnt=-1,cnt
 128         add     src_pre_mem=0,in1       // prefetch src pointer
 129         add     dst_pre_mem=0,in0       // prefetch dest pointer
 130         ;;
 131 (p7)    mov     ar.lc=cnt       // prefetch count
 132 (p8)    mov     ar.lc=r0
 133 (p6)    br.cond.dpnt .long_copy
 134         ;;
 135
 136 .prefetch:
 137         lfetch.fault      [src_pre_mem], 128
 138         lfetch.fault.excl [dst_pre_mem], 128
 139         br.cloop.dptk.few .prefetch
 140         ;;
 141
 142 .medium_copy:
 143         and     tmp=31,in2      // copy length after iteration
 144         shr.u   r29=in2,5       // number of 32-byte iteration
 145         add     dst1=8,dst0     // 2nd dest pointer
 146         ;;
 147         add     cnt=-1,r29      // ctop iteration adjustment
 148         cmp.eq  p10,p0=r29,r0   // do we really need to loop?
 149         add     src1=8,src0     // 2nd src pointer
 150         cmp.le  p6,p0=8,tmp
 151         ;;
 152         cmp.le  p7,p0=16,tmp
 153         mov     ar.lc=cnt       // loop setup
 154         cmp.eq  p16,p17 = r0,r0
 155         mov     ar.ec=2
 156 (p10)   br.dpnt.few .aligned_src_tail
 157         ;;
 158         TEXT_ALIGN(32)
 159 1:
 160 EX(.ex_handler, (p16)   ld8     r34=[src0],16)
 161 EK(.ex_handler, (p16)   ld8     r38=[src1],16)
 162 EX(.ex_handler, (p17)   st8     [dst0]=r33,16)
 163 EK(.ex_handler, (p17)   st8     [dst1]=r37,16)
 164         ;;
 165 EX(.ex_handler, (p16)   ld8     r32=[src0],16)
 166 EK(.ex_handler, (p16)   ld8     r36=[src1],16)
 167 EX(.ex_handler, (p16)   st8     [dst0]=r34,16)
 168 EK(.ex_handler, (p16)   st8     [dst1]=r38,16)
 169         br.ctop.dptk.few 1b
 170         ;;
 171
 172 .aligned_src_tail:
 173 EX(.ex_handler, (p6)    ld8     t1=[src0])
 174         mov     ar.lc=saved_lc
 175         mov     ar.pfs=saved_pfs
 176 EX(.ex_hndlr_s, (p7)    ld8     t2=[src1],8)
 177         cmp.le  p8,p0=24,tmp
 178         and     r21=-8,tmp
 179         ;;
 180 EX(.ex_hndlr_s, (p8)    ld8     t3=[src1])
 181 EX(.ex_handler, (p6)    st8     [dst0]=t1)      // store byte 1
 182         and     in2=7,tmp       // remaining length
 183 EX(.ex_hndlr_d, (p7)    st8     [dst1]=t2,8)    // store byte 2
 184         add     src0=src0,r21   // setting up src pointer
 185         add     dst0=dst0,r21   // setting up dest pointer
 186         ;;
 187 EX(.ex_handler, (p8)    st8     [dst1]=t3)      // store byte 3
 188         mov     pr=saved_pr,-1
 189         br.dptk.many .memcpy_short
 190         ;;
 191
 192 /* code taken from copy_page_mck */
 193 .long_copy:
 194         .rotr v[2*PREFETCH_DIST]
 195         .rotp p[N]
 196
 197         mov src_pre_mem = src0
 198         mov pr.rot = 0x10000
 199         mov ar.ec = 1                           // special unrolled loop
 200
 201         mov dst_pre_mem = dst0
 202
 203         add src_pre_l2 = 8*8, src0
 204         add dst_pre_l2 = 8*8, dst0
 205         ;;
 206         add src0 = 8, src_pre_mem               // first t1 src
 207         mov ar.lc = 2*PREFETCH_DIST - 1
 208         shr.u cnt=in2,7                         // number of lines
 209         add src1 = 3*8, src_pre_mem             // first t3 src
 210         add dst0 = 8, dst_pre_mem               // first t1 dst
 211         add dst1 = 3*8, dst_pre_mem             // first t3 dst
 212         ;;
 213         and tmp=127,in2                         // remaining bytes after this block
 214         add cnt = -(2*PREFETCH_DIST) - 1, cnt
 215         // same as .line_copy loop, but with all predicated-off instructions removed:
 216 .prefetch_loop:
 217 EX(.ex_hndlr_lcpy_1, (p[A])     ld8 v[A] = [src_pre_mem], 128)          // M0
 218 EK(.ex_hndlr_lcpy_1, (p[B])     st8 [dst_pre_mem] = v[B], 128)          // M2
 219         br.ctop.sptk .prefetch_loop
 220         ;;
 221         cmp.eq p16, p0 = r0, r0                 // reset p16 to 1
 222         mov ar.lc = cnt
 223         mov ar.ec = N                           // # of stages in pipeline
 224         ;;
 225 .line_copy:
 226 EX(.ex_handler, (p[D])  ld8 t2 = [src0], 3*8)                   // M0
 227 EK(.ex_handler, (p[D])  ld8 t4 = [src1], 3*8)                   // M1
 228 EX(.ex_handler_lcpy,    (p[B])  st8 [dst_pre_mem] = v[B], 128)          // M2 prefetch dst from memory
 229 EK(.ex_handler_lcpy,    (p[D])  st8 [dst_pre_l2] = n8, 128)             // M3 prefetch dst from L2
 230         ;;
 231 EX(.ex_handler_lcpy,    (p[A])  ld8 v[A] = [src_pre_mem], 128)          // M0 prefetch src from memory
 232 EK(.ex_handler_lcpy,    (p[C])  ld8 n8 = [src_pre_l2], 128)             // M1 prefetch src from L2
 233 EX(.ex_handler, (p[D])  st8 [dst0] =  t1, 8)                    // M2
 234 EK(.ex_handler, (p[D])  st8 [dst1] =  t3, 8)                    // M3
 235         ;;
 236 EX(.ex_handler, (p[D])  ld8  t5 = [src0], 8)
 237 EK(.ex_handler, (p[D])  ld8  t7 = [src1], 3*8)
 238 EX(.ex_handler, (p[D])  st8 [dst0] =  t2, 3*8)
 239 EK(.ex_handler, (p[D])  st8 [dst1] =  t4, 3*8)
 240         ;;
 241 EX(.ex_handler, (p[D])  ld8  t6 = [src0], 3*8)
 242 EK(.ex_handler, (p[D])  ld8 t10 = [src1], 8)
 243 EX(.ex_handler, (p[D])  st8 [dst0] =  t5, 8)
 244 EK(.ex_handler, (p[D])  st8 [dst1] =  t7, 3*8)
 245         ;;
 246 EX(.ex_handler, (p[D])  ld8  t9 = [src0], 3*8)
 247 EK(.ex_handler, (p[D])  ld8 t11 = [src1], 3*8)
 248 EX(.ex_handler, (p[D])  st8 [dst0] =  t6, 3*8)
 249 EK(.ex_handler, (p[D])  st8 [dst1] = t10, 8)
 250         ;;
 251 EX(.ex_handler, (p[D])  ld8 t12 = [src0], 8)
 252 EK(.ex_handler, (p[D])  ld8 t14 = [src1], 8)
 253 EX(.ex_handler, (p[D])  st8 [dst0] =  t9, 3*8)
 254 EK(.ex_handler, (p[D])  st8 [dst1] = t11, 3*8)
 255         ;;
 256 EX(.ex_handler, (p[D])  ld8 t13 = [src0], 4*8)
 257 EK(.ex_handler, (p[D])  ld8 t15 = [src1], 4*8)
 258 EX(.ex_handler, (p[D])  st8 [dst0] = t12, 8)
 259 EK(.ex_handler, (p[D])  st8 [dst1] = t14, 8)
 260         ;;
 261 EX(.ex_handler, (p[C])  ld8  t1 = [src0], 8)
 262 EK(.ex_handler, (p[C])  ld8  t3 = [src1], 8)
 263 EX(.ex_handler, (p[D])  st8 [dst0] = t13, 4*8)
 264 EK(.ex_handler, (p[D])  st8 [dst1] = t15, 4*8)
 265         br.ctop.sptk .line_copy
 266         ;;
 267
 268         add dst0=-8,dst0
 269         add src0=-8,src0
 270         mov in2=tmp
 271         .restore sp
 272         br.sptk.many .medium_copy
 273         ;;
 274
 275 #define BLOCK_SIZE      128*32
 276 #define blocksize       r23
 277 #define curlen          r24
 278
 279 // dest is on 8-byte boundary, src is not. We need to do
 280 // ld8-ld8, shrp, then st8.  Max 8 byte copy per cycle.
 281 .unaligned_src:
 282         .prologue
 283         .save ar.pfs, saved_pfs
 284         alloc   saved_pfs=ar.pfs,3,5,0,8
 285         .save ar.lc, saved_lc
 286         mov     saved_lc=ar.lc
 287         .save pr, saved_pr
 288         mov     saved_pr=pr
 289         .body
 290 .4k_block:
 291         mov     saved_in0=dst0  // need to save all input arguments
 292         mov     saved_in2=in2
 293         mov     blocksize=BLOCK_SIZE
 294         ;;
 295         cmp.lt  p6,p7=blocksize,in2
 296         mov     saved_in1=src0
 297         ;;
 298 (p6)    mov     in2=blocksize
 299         ;;
 300         shr.u   r21=in2,7       // this much cache line
 301         shr.u   r22=in2,4       // number of 16-byte iteration
 302         and     curlen=15,in2   // copy length after iteration
 303         and     r30=7,src0      // source alignment
 304         ;;
 305         cmp.lt  p7,p8=1,r21
 306         add     cnt=-1,r21
 307         ;;
 308
 309         add     src_pre_mem=0,src0      // prefetch src pointer
 310         add     dst_pre_mem=0,dst0      // prefetch dest pointer
 311         and     src0=-8,src0            // 1st src pointer
 312 (p7)    mov     ar.lc = r21
 313 (p8)    mov     ar.lc = r0
 314         ;;
 315         TEXT_ALIGN(32)
 316 1:      lfetch.fault      [src_pre_mem], 128
 317         lfetch.fault.excl [dst_pre_mem], 128
 318         br.cloop.dptk.few 1b
 319         ;;
 320
 321         shladd  dst1=r22,3,dst0 // 2nd dest pointer
 322         shladd  src1=r22,3,src0 // 2nd src pointer
 323         cmp.eq  p8,p9=r22,r0    // do we really need to loop?
 324         cmp.le  p6,p7=8,curlen; // have at least 8 byte remaining?
 325         add     cnt=-1,r22      // ctop iteration adjustment
 326         ;;
 327 EX(.ex_handler, (p9)    ld8     r33=[src0],8)   // loop primer
 328 EK(.ex_handler, (p9)    ld8     r37=[src1],8)
 329 (p8)    br.dpnt.few .noloop
 330         ;;
 331
 332 // The jump address is calculated based on src alignment. The COPYU
 333 // macro below need to confine its size to power of two, so an entry
 334 // can be caulated using shl instead of an expensive multiply. The
 335 // size is then hard coded by the following #define to match the
 336 // actual size.  This make it somewhat tedious when COPYU macro gets
 337 // changed and this need to be adjusted to match.
 338 #define LOOP_SIZE 6
 339 1:
 340         mov     r29=ip          // jmp_table thread
 341         mov     ar.lc=cnt
 342         ;;
 343         add     r29=.jump_table - 1b - (.jmp1-.jump_table), r29
 344         shl     r28=r30, LOOP_SIZE      // jmp_table thread
 345         mov     ar.ec=2         // loop setup
 346         ;;
 347         add     r29=r29,r28             // jmp_table thread
 348         cmp.eq  p16,p17=r0,r0
 349         ;;
 350         mov     b6=r29                  // jmp_table thread
 351         ;;
 352         br.cond.sptk.few b6
 353
 354 // for 8-15 byte case
 355 // We will skip the loop, but need to replicate the side effect
 356 // that the loop produces.
 357 .noloop:
 358 EX(.ex_handler, (p6)    ld8     r37=[src1],8)
 359         add     src0=8,src0
 360 (p6)    shl     r25=r30,3
 361         ;;
 362 EX(.ex_handler, (p6)    ld8     r27=[src1])
 363 (p6)    shr.u   r28=r37,r25
 364 (p6)    sub     r26=64,r25
 365         ;;
 366 (p6)    shl     r27=r27,r26
 367         ;;
 368 (p6)    or      r21=r28,r27
 369
 370 .unaligned_src_tail:
 371 /* check if we have more than blocksize to copy, if so go back */
 372         cmp.gt  p8,p0=saved_in2,blocksize
 373         ;;
 374 (p8)    add     dst0=saved_in0,blocksize
 375 (p8)    add     src0=saved_in1,blocksize
 376 (p8)    sub     in2=saved_in2,blocksize
 377 (p8)    br.dpnt .4k_block
 378         ;;
 379
 380 /* we have up to 15 byte to copy in the tail.
 381  * part of work is already done in the jump table code
 382  * we are at the following state.
 383  * src side:
 384  *
 385  *   xxxxxx xx                   <----- r21 has xxxxxxxx already
 386  * -------- -------- --------
 387  * 0        8        16
 388  *          ^
 389  *          |
 390  *          src1
 391  *
 392  * dst
 393  * -------- -------- --------
 394  * ^
 395  * |
 396  * dst1
 397  */
 398 EX(.ex_handler, (p6)    st8     [dst1]=r21,8)   // more than 8 byte to copy
 399 (p6)    add     curlen=-8,curlen        // update length
 400         mov     ar.pfs=saved_pfs
 401         ;;
 402         mov     ar.lc=saved_lc
 403         mov     pr=saved_pr,-1
 404         mov     in2=curlen      // remaining length
 405         mov     dst0=dst1       // dest pointer
 406         add     src0=src1,r30   // forward by src alignment
 407         ;;
 408
 409 // 7 byte or smaller.
 410 .memcpy_short:
 411         cmp.le  p8,p9   = 1,in2
 412         cmp.le  p10,p11 = 2,in2
 413         cmp.le  p12,p13 = 3,in2
 414         cmp.le  p14,p15 = 4,in2
 415         add     src1=1,src0     // second src pointer
 416         add     dst1=1,dst0     // second dest pointer
 417         ;;
 418
 419 EX(.ex_handler_short, (p8)      ld1     t1=[src0],2)
 420 EK(.ex_handler_short, (p10)     ld1     t2=[src1],2)
 421 (p9)    br.ret.dpnt rp          // 0 byte copy
 422         ;;
 423
 424 EX(.ex_handler_short, (p8)      st1     [dst0]=t1,2)
 425 EK(.ex_handler_short, (p10)     st1     [dst1]=t2,2)
 426 (p11)   br.ret.dpnt rp          // 1 byte copy
 427
 428 EX(.ex_handler_short, (p12)     ld1     t3=[src0],2)
 429 EK(.ex_handler_short, (p14)     ld1     t4=[src1],2)
 430 (p13)   br.ret.dpnt rp          // 2 byte copy
 431         ;;
 432
 433         cmp.le  p6,p7   = 5,in2
 434         cmp.le  p8,p9   = 6,in2
 435         cmp.le  p10,p11 = 7,in2
 436
 437 EX(.ex_handler_short, (p12)     st1     [dst0]=t3,2)
 438 EK(.ex_handler_short, (p14)     st1     [dst1]=t4,2)
 439 (p15)   br.ret.dpnt rp          // 3 byte copy
 440         ;;
 441
 442 EX(.ex_handler_short, (p6)      ld1     t5=[src0],2)
 443 EK(.ex_handler_short, (p8)      ld1     t6=[src1],2)
 444 (p7)    br.ret.dpnt rp          // 4 byte copy
 445         ;;
 446
 447 EX(.ex_handler_short, (p6)      st1     [dst0]=t5,2)
 448 EK(.ex_handler_short, (p8)      st1     [dst1]=t6,2)
 449 (p9)    br.ret.dptk rp          // 5 byte copy
 450
 451 EX(.ex_handler_short, (p10)     ld1     t7=[src0],2)
 452 (p11)   br.ret.dptk rp          // 6 byte copy
 453         ;;
 454
 455 EX(.ex_handler_short, (p10)     st1     [dst0]=t7,2)
 456         br.ret.dptk rp          // done all cases
 457
 458
 459 /* Align dest to nearest 8-byte boundary. We know we have at
 460  * least 7 bytes to copy, enough to crawl to 8-byte boundary.
 461  * Actual number of byte to crawl depend on the dest alignment.
 462  * 7 byte or less is taken care at .memcpy_short
 463
 464  * src0 - source even index
 465  * src1 - source  odd index
 466  * dst0 - dest even index
 467  * dst1 - dest  odd index
 468  * r30  - distance to 8-byte boundary
 469  */
 470
 471 .align_dest:
 472         add     src1=1,in1      // source odd index
 473         cmp.le  p7,p0 = 2,r30   // for .align_dest
 474         cmp.le  p8,p0 = 3,r30   // for .align_dest
 475 EX(.ex_handler_short, (p6)      ld1     t1=[src0],2)
 476         cmp.le  p9,p0 = 4,r30   // for .align_dest
 477         cmp.le  p10,p0 = 5,r30
 478         ;;
 479 EX(.ex_handler_short, (p7)      ld1     t2=[src1],2)
 480 EK(.ex_handler_short, (p8)      ld1     t3=[src0],2)
 481         cmp.le  p11,p0 = 6,r30
 482 EX(.ex_handler_short, (p6)      st1     [dst0] = t1,2)
 483         cmp.le  p12,p0 = 7,r30
 484         ;;
 485 EX(.ex_handler_short, (p9)      ld1     t4=[src1],2)
 486 EK(.ex_handler_short, (p10)     ld1     t5=[src0],2)
 487 EX(.ex_handler_short, (p7)      st1     [dst1] = t2,2)
 488 EK(.ex_handler_short, (p8)      st1     [dst0] = t3,2)
 489         ;;
 490 EX(.ex_handler_short, (p11)     ld1     t6=[src1],2)
 491 EK(.ex_handler_short, (p12)     ld1     t7=[src0],2)
 492         cmp.eq  p6,p7=r28,r29
 493 EX(.ex_handler_short, (p9)      st1     [dst1] = t4,2)
 494 EK(.ex_handler_short, (p10)     st1     [dst0] = t5,2)
 495         sub     in2=in2,r30
 496         ;;
 497 EX(.ex_handler_short, (p11)     st1     [dst1] = t6,2)
 498 EK(.ex_handler_short, (p12)     st1     [dst0] = t7)
 499         add     dst0=in0,r30    // setup arguments
 500         add     src0=in1,r30
 501 (p6)    br.cond.dptk .aligned_src
 502 (p7)    br.cond.dpnt .unaligned_src
 503         ;;
 504
 505 /* main loop body in jump table format */
 506 #define COPYU(shift)                                                                    \
 507 1:                                                                                      \
 508 EX(.ex_handler,  (p16)  ld8     r32=[src0],8);          /* 1 */                         \
 509 EK(.ex_handler,  (p16)  ld8     r36=[src1],8);                                          \
 510                  (p17)  shrp    r35=r33,r34,shift;;     /* 1 */                         \
 511 EX(.ex_handler,  (p6)   ld8     r22=[src1]);    /* common, prime for tail section */    \
 512                  nop.m  0;                                                              \
 513                  (p16)  shrp    r38=r36,r37,shift;                                      \
 514 EX(.ex_handler,  (p17)  st8     [dst0]=r35,8);          /* 1 */                         \
 515 EK(.ex_handler,  (p17)  st8     [dst1]=r39,8);                                          \
 516                  br.ctop.dptk.few 1b;;                                                  \
 517                  (p7)   add     src1=-8,src1;   /* back out for <8 byte case */         \
 518                  shrp   r21=r22,r38,shift;      /* speculative work */                  \
 519                  br.sptk.few .unaligned_src_tail /* branch out of jump table */         \
 520                  ;;
 521         TEXT_ALIGN(32)
 522 .jump_table:
 523         COPYU(8)        // unaligned cases
 524 .jmp1:
 525         COPYU(16)
 526         COPYU(24)
 527         COPYU(32)
 528         COPYU(40)
 529         COPYU(48)
 530         COPYU(56)
 531
 532 #undef A
 533 #undef B
 534 #undef C
 535 #undef D
 536 END(memcpy)
 537
 538 /*
 539  * Due to lack of local tag support in gcc 2.x assembler, it is not clear which
 540  * instruction failed in the bundle.  The exception algorithm is that we
 541  * first figure out the faulting address, then detect if there is any
 542  * progress made on the copy, if so, redo the copy from last known copied
 543  * location up to the faulting address (exclusive). In the copy_from_user
 544  * case, remaining byte in kernel buffer will be zeroed.
 545  *
 546  * Take copy_from_user as an example, in the code there are multiple loads
 547  * in a bundle and those multiple loads could span over two pages, the
 548  * faulting address is calculated as page_round_down(max(src0, src1)).
 549  * This is based on knowledge that if we can access one byte in a page, we
 550  * can access any byte in that page.
 551  *
 552  * predicate used in the exception handler:
 553  * p6-p7: direction
 554  * p10-p11: src faulting addr calculation
 555  * p12-p13: dst faulting addr calculation
 556  */
 557
 558 #define A       r19
 559 #define B       r20
 560 #define C       r21
 561 #define D       r22
 562 #define F       r28
 563
 564 #define memset_arg0     r32
 565 #define memset_arg2     r33
 566
 567 #define saved_retval    loc0
 568 #define saved_rtlink    loc1
 569 #define saved_pfs_stack loc2
 570
 571 .ex_hndlr_s:
 572         add     src0=8,src0
 573         br.sptk .ex_handler
 574         ;;
 575 .ex_hndlr_d:
 576         add     dst0=8,dst0
 577         br.sptk .ex_handler
 578         ;;
 579 .ex_hndlr_lcpy_1:
 580         mov     src1=src_pre_mem
 581         mov     dst1=dst_pre_mem
 582         cmp.gtu p10,p11=src_pre_mem,saved_in1
 583         cmp.gtu p12,p13=dst_pre_mem,saved_in0
 584         ;;
 585 (p10)   add     src0=8,saved_in1
 586 (p11)   mov     src0=saved_in1
 587 (p12)   add     dst0=8,saved_in0
 588 (p13)   mov     dst0=saved_in0
 589         br.sptk .ex_handler
 590 .ex_handler_lcpy:
 591         // in line_copy block, the preload addresses should always ahead
 592         // of the other two src/dst pointers.  Furthermore, src1/dst1 should
 593         // always ahead of src0/dst0.
 594         mov     src1=src_pre_mem
 595         mov     dst1=dst_pre_mem
 596 .ex_handler:
 597         mov     pr=saved_pr,-1          // first restore pr, lc, and pfs
 598         mov     ar.lc=saved_lc
 599         mov     ar.pfs=saved_pfs
 600         ;;
 601 .ex_handler_short: // fault occurred in these sections didn't change pr, lc, pfs
 602         cmp.ltu p6,p7=saved_in0, saved_in1      // get the copy direction
 603         cmp.ltu p10,p11=src0,src1
 604         cmp.ltu p12,p13=dst0,dst1
 605         fcmp.eq p8,p0=f6,f0             // is it memcpy?
 606         mov     tmp = dst0
 607         ;;
 608 (p11)   mov     src1 = src0             // pick the larger of the two
 609 (p13)   mov     dst0 = dst1             // make dst0 the smaller one
 610 (p13)   mov     dst1 = tmp              // and dst1 the larger one
 611         ;;
 612 (p6)    dep     F = r0,dst1,0,PAGE_SHIFT // usr dst round down to page boundary
 613 (p7)    dep     F = r0,src1,0,PAGE_SHIFT // usr src round down to page boundary
 614         ;;
 615 (p6)    cmp.le  p14,p0=dst0,saved_in0   // no progress has been made on store
 616 (p7)    cmp.le  p14,p0=src0,saved_in1   // no progress has been made on load
 617         mov     retval=saved_in2
 618 (p8)    ld1     tmp=[src1]              // force an oops for memcpy call
 619 (p8)    st1     [dst1]=r0               // force an oops for memcpy call
 620 (p14)   br.ret.sptk.many rp
 621
 622 /*
 623  * The remaining byte to copy is calculated as:
 624  *
 625  * A =  (faulting_addr - orig_src)      -> len to faulting ld address
 626  *      or
 627  *      (faulting_addr - orig_dst)      -> len to faulting st address
 628  * B =  (cur_dst - orig_dst)            -> len copied so far
 629  * C =  A - B                           -> len need to be copied
 630  * D =  orig_len - A                    -> len need to be zeroed
 631  */
 632 (p6)    sub     A = F, saved_in0
 633 (p7)    sub     A = F, saved_in1
 634         clrrrb
 635         ;;
 636         alloc   saved_pfs_stack=ar.pfs,3,3,3,0
 637         sub     B = dst0, saved_in0     // how many byte copied so far
 638         ;;
 639         sub     C = A, B
 640         sub     D = saved_in2, A
 641         ;;
 642         cmp.gt  p8,p0=C,r0              // more than 1 byte?
 643         add     memset_arg0=saved_in0, A
 644 (p6)    mov     memset_arg2=0           // copy_to_user should not call memset
 645 (p7)    mov     memset_arg2=D           // copy_from_user need to have kbuf zeroed
 646         mov     r8=0
 647         mov     saved_retval = D
 648         mov     saved_rtlink = b0
 649
 650         add     out0=saved_in0, B
 651         add     out1=saved_in1, B
 652         mov     out2=C
 653 (p8)    br.call.sptk.few b0=__copy_user // recursive call
 654         ;;
 655
 656         add     saved_retval=saved_retval,r8    // above might return non-zero value
 657         cmp.gt  p8,p0=memset_arg2,r0    // more than 1 byte?
 658         mov     out0=memset_arg0        // *s
 659         mov     out1=r0                 // c
 660         mov     out2=memset_arg2        // n
 661 (p8)    br.call.sptk.few b0=memset
 662         ;;
 663
 664         mov     retval=saved_retval
 665         mov     ar.pfs=saved_pfs_stack
 666         mov     b0=saved_rtlink
 667         br.ret.sptk.many rp
 668
 669 /* end of McKinley specific optimization */
 670 END(__copy_user)