arch/m68k/kernel/vmlinux-sun3.lds

   1 /* ld script to make m68k Linux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4
   5 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   6 OUTPUT_ARCH(m68k)
   7 ENTRY(_start)
   8 jiffies = jiffies_64 + 4;
   9 SECTIONS
  10 {
  11   . = 0xE004000;
  12   _text = .;                    /* Text and read-only data */
  13   .text : {
  14         *(.head)
  15         *(.text)
  16         SCHED_TEXT
  17         *(.fixup)
  18         *(.gnu.warning)
  19         } = 0x4e75
  20         RODATA
  21
  22   _etext = .;                   /* End of text section */
  23
  24   .data : {                     /* Data */
  25         *(.data)
  26         CONSTRUCTORS
  27         . = ALIGN(16);          /* Exception table */
  28         __start___ex_table = .;
  29         *(__ex_table)
  30         __stop___ex_table = .;
  31         }
  32   /* End of data goes *here* so that freeing init code works properly. */
  33   _edata = .;
  34
  35   /* will be freed after init */
  36   . = ALIGN(8192);      /* Init code and data */
  37 __init_begin = .;
  38         .init.text : {
  39                 _sinittext = .;
  40                 *(.init.text)
  41                 _einittext = .;
  42         }
  43         .init.data : { *(.init.data) }
  44         . = ALIGN(16);
  45         __setup_start = .;
  46         .init.setup : { *(.init.setup) }
  47         __setup_end = .;
  48         __start___param = .;
  49         __param : { *(__param) }
  50         __stop___param = .;
  51         __initcall_start = .;
  52         .initcall.init : {
  53                 *(.initcall1.init)
  54                 *(.initcall2.init)
  55                 *(.initcall3.init)
  56                 *(.initcall4.init)
  57                 *(.initcall5.init)
  58                 *(.initcall6.init)
  59                 *(.initcall7.init)
  60         }
  61         __initcall_end = .;
  62         __con_initcall_start = .;
  63         .con_initcall.init : { *(.con_initcall.init) }
  64         __con_initcall_end = .;
  65         SECURITY_INIT
  66         . = ALIGN(8192);
  67         __initramfs_start = .;
  68         .init.ramfs : { *(.init.ramfs) }
  69         __initramfs_end = .;
  70         . = ALIGN(8192);
  71         __init_end = .;
  72         .init.task : { *(init_task) }
  73
  74
  75   .bss : { *(.bss) }            /* BSS */
  76
  77   _end = . ;
  78
  79   /* Sections to be discarded */
  80   /DISCARD/ : {
  81         *(.exit.text)
  82         *(.exit.data)
  83         *(.exitcall.exit)
  84         }
  85
  86   .crap : {
  87         /* Stabs debugging sections.  */
  88         *(.stab)
  89         *(.stabstr)
  90         *(.stab.excl)
  91         *(.stab.exclstr)
  92         *(.stab.index)
  93         *(.stab.indexstr)
  94         *(.comment)
  95         *(.note)
  96   }
  97
  98 }