arch/mips/kernel/head.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1994, 1995 Waldorf Electronics
   7  * Written by Ralf Baechle and Andreas Busse
   8  * Copyright (C) 1994, 95, 96, 97, 98, 99, 2003 Ralf Baechle
   9  * Copyright (C) 1996 Paul M. Antoine
  10  * Modified for DECStation and hence R3000 support by Paul M. Antoine
  11  * Further modifications by David S. Miller and Harald Koerfgen
  12  * Copyright (C) 1999 Silicon Graphics, Inc.
  13  * Kevin Kissell, kevink@mips.com and Carsten Langgaard, carstenl@mips.com
  14  * Copyright (C) 2000 MIPS Technologies, Inc.  All rights reserved.
  15  */
  16 #include <linux/config.h>
  17 #include <linux/init.h>
  18 #include <linux/threads.h>
  19
  20 #include <asm/asm.h>
  21 #include <asm/regdef.h>
  22 #include <asm/page.h>
  23 #include <asm/mipsregs.h>
  24 #include <asm/stackframe.h>
  25 #ifdef CONFIG_SGI_IP27
  26 #include <asm/sn/addrs.h>
  27 #include <asm/sn/sn0/hubni.h>
  28 #include <asm/sn/klkernvars.h>
  29 #endif
  30
  31         .macro  ARC64_TWIDDLE_PC
  32 #if defined(CONFIG_ARC64) || defined(CONFIG_MAPPED_KERNEL)
  33         /* We get launched at a XKPHYS address but the kernel is linked to
  34            run at a KSEG0 address, so jump there.  */
  35         PTR_LA  t0, \@f
  36         jr      t0
  37 \@:
  38 #endif
  39         .endm
  40
  41 #ifdef CONFIG_SGI_IP27
  42         /*
  43          * outputs the local nasid into res.  IP27 stuff.
  44          */
  45         .macro GET_NASID_ASM res
  46         dli     \res, LOCAL_HUB_ADDR(NI_STATUS_REV_ID)
  47         ld      \res, (\res)
  48         and     \res, NSRI_NODEID_MASK
  49         dsrl    \res, NSRI_NODEID_SHFT
  50         .endm
  51 #endif /* CONFIG_SGI_IP27 */
  52
  53         /*
  54          * inputs are the text nasid in t1, data nasid in t2.
  55          */
  56         .macro MAPPED_KERNEL_SETUP_TLB
  57 #ifdef CONFIG_MAPPED_KERNEL
  58         /*
  59          * This needs to read the nasid - assume 0 for now.
  60          * Drop in 0xffffffffc0000000 in tlbhi, 0+VG in tlblo_0,
  61          * 0+DVG in tlblo_1.
  62          */
  63         dli     t0, 0xffffffffc0000000
  64         dmtc0   t0, CP0_ENTRYHI
  65         li      t0, 0x1c000             # Offset of text into node memory
  66         dsll    t1, NASID_SHFT          # Shift text nasid into place
  67         dsll    t2, NASID_SHFT          # Same for data nasid
  68         or      t1, t1, t0              # Physical load address of kernel text
  69         or      t2, t2, t0              # Physical load address of kernel data
  70         dsrl    t1, 12                  # 4K pfn
  71         dsrl    t2, 12                  # 4K pfn
  72         dsll    t1, 6                   # Get pfn into place
  73         dsll    t2, 6                   # Get pfn into place
  74         li      t0, ((_PAGE_GLOBAL|_PAGE_VALID| _CACHE_CACHABLE_COW) >> 6)
  75         or      t0, t0, t1
  76         mtc0    t0, CP0_ENTRYLO0        # physaddr, VG, cach exlwr
  77         li      t0, ((_PAGE_GLOBAL|_PAGE_VALID| _PAGE_DIRTY|_CACHE_CACHABLE_COW) >> 6)
  78         or      t0, t0, t2
  79         mtc0    t0, CP0_ENTRYLO1        # physaddr, DVG, cach exlwr
  80         li      t0, 0x1ffe000           # MAPPED_KERN_TLBMASK, TLBPGMASK_16M
  81         mtc0    t0, CP0_PAGEMASK
  82         li      t0, 0                   # KMAP_INX
  83         mtc0    t0, CP0_INDEX
  84         li      t0, 1
  85         mtc0    t0, CP0_WIRED
  86         tlbwi
  87 #else
  88         mtc0    zero, CP0_WIRED
  89 #endif
  90         .endm
  91
  92         /*
  93          * For the moment set ST0_KU so the CPU will not spit fire when
  94          * executing 64-bit instructions.  The full initialization of the
  95          * CPU's status register is done later in per_cpu_trap_init().
  96          */
  97         .macro  setup_c0_status
  98 #ifdef CONFIG_MIPS64
  99         mfc0    t0, CP0_STATUS
 100         or      t0, ST0_KX
 101         mtc0    t0, CP0_STATUS
 102 #endif
 103         .endm
 104
 105         /*
 106          * Reserved space for exception handlers.
 107          * Necessary for machines which link their kernels at KSEG0.
 108          */
 109         .fill   0x400
 110
 111 EXPORT(stext)                                   # used for profiling
 112 EXPORT(_stext)
 113
 114         __INIT
 115
 116 NESTED(kernel_entry, 16, sp)                    # kernel entry point
 117         setup_c0_status
 118
 119 #ifdef CONFIG_SGI_IP27
 120         GET_NASID_ASM   t1
 121         move    t2, t1                          # text and data are here
 122         MAPPED_KERNEL_SETUP_TLB
 123 #endif /* IP27 */
 124
 125         ARC64_TWIDDLE_PC
 126
 127         CLI                                     # disable interrupts
 128
 129         PTR_LA          t0, __bss_start         # clear .bss
 130         LONG_S          zero, (t0)
 131         PTR_LA          t1, __bss_stop - LONGSIZE
 132 1:
 133         PTR_ADDIU       t0, LONGSIZE
 134         LONG_S          zero, (t0)
 135         bne             t0, t1, 1b
 136
 137         LONG_S          a0, fw_arg0             # firmware arguments
 138         LONG_S          a1, fw_arg1
 139         LONG_S          a2, fw_arg2
 140         LONG_S          a3, fw_arg3
 141
 142         PTR_LA          $28, init_thread_union
 143         PTR_ADDIU       sp, $28, _THREAD_SIZE - 32
 144         set_saved_sp    sp, t0, t1
 145         PTR_SUBU        sp, 4 * SZREG           # init stack pointer
 146
 147         jal             start_kernel
 148         END(kernel_entry)
 149
 150 #ifdef CONFIG_SMP
 151 /*
 152  * SMP slave cpus entry point.  Board specific code for bootstrap calls this
 153  * function after setting up the stack and gp registers.
 154  */
 155 NESTED(smp_bootstrap, 16, sp)
 156 #ifdef CONFIG_SGI_IP27
 157         GET_NASID_ASM   t1
 158         dli     t0, KLDIR_OFFSET + (KLI_KERN_VARS * KLDIR_ENT_SIZE) + \
 159                     KLDIR_OFF_POINTER + CAC_BASE
 160         dsll    t1, NASID_SHFT
 161         or      t0, t0, t1
 162         ld      t0, 0(t0)                       # t0 points to kern_vars struct
 163         lh      t1, KV_RO_NASID_OFFSET(t0)
 164         lh      t2, KV_RW_NASID_OFFSET(t0)
 165         MAPPED_KERNEL_SETUP_TLB
 166         ARC64_TWIDDLE_PC
 167 #endif /* CONFIG_SGI_IP27 */
 168
 169         CLI
 170         setup_c0_status
 171         jal     start_secondary
 172         END(smp_bootstrap)
 173 #endif /* CONFIG_SMP */
 174
 175         __FINIT
 176
 177         .comm   kernelsp,    NR_CPUS * 8, 8
 178         .comm   pgd_current, NR_CPUS * 8, 8
 179
 180         .comm   fw_arg0, SZREG, SZREG           # firmware arguments
 181         .comm   fw_arg1, SZREG, SZREG
 182         .comm   fw_arg2, SZREG, SZREG
 183         .comm   fw_arg3, SZREG, SZREG
 184
 185         .macro  page name, order=0
 186         .globl  \name
 187 \name:  .size   \name, (_PAGE_SIZE << \order)
 188         .org    . + (_PAGE_SIZE << \order)
 189         .type   \name, @object
 190         .endm
 191
 192         .data
 193         .align  PAGE_SHIFT
 194
 195         /*
 196          * ... but on 64-bit we've got three-level pagetables with a
 197          * slightly different layout ...
 198          */
 199         page    swapper_pg_dir, _PGD_ORDER
 200 #ifdef CONFIG_MIPS64
 201         page    invalid_pmd_table, _PMD_ORDER
 202 #endif
 203         page    invalid_pte_table, _PTE_ORDER
 204
 205 #ifdef CONFIG_MIPS64
 206         /*
 207          * 64-bit kernel mappings are really screwed up ...
 208          */
 209         page    kptbl, _PGD_ORDER
 210         .globl  ekptbl
 211         page    kpmdtbl, 0
 212 ekptbl:
 213 #endif