arch/mips/kernel/vmlinux.lds.S

   1 #include <linux/config.h>
   2 #include <asm-generic/vmlinux.lds.h>
   3
   4 #undef mips             /* CPP really sucks for this job  */
   5 #define mips mips
   6 OUTPUT_ARCH(mips)
   7 ENTRY(kernel_entry)
   8 jiffies = JIFFIES;
   9 SECTIONS
  10 {
  11 #ifdef CONFIG_BOOT_ELF64
  12   /* Read-only sections, merged into text segment: */
  13   /* . = 0xc000000000000000; */
  14
  15   /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
  16   /* . = 0xc00000000001c000; */
  17
  18   /* Set the vaddr for the text segment to a value
  19         >= 0xa800 0000 0001 9000 if no symmon is going to configured
  20         >= 0xa800 0000 0030 0000 otherwise  */
  21
  22   /* . = 0xa800000000300000; */
  23   /* . = 0xa800000000300000; */
  24   . = 0xffffffff80300000;
  25 #endif
  26   . = LOADADDR;
  27   /* read-only */
  28   _text = .;                    /* Text and read-only data */
  29   .text : {
  30     *(.text)
  31     SCHED_TEXT
  32     LOCK_TEXT
  33     *(.fixup)
  34     *(.gnu.warning)
  35   } =0
  36
  37   _etext = .;                   /* End of text section */
  38
  39   . = ALIGN(16);                /* Exception table */
  40   __start___ex_table = .;
  41   __ex_table : { *(__ex_table) }
  42   __stop___ex_table = .;
  43
  44   __start___dbe_table = .;      /* Exception table for data bus errors */
  45   __dbe_table : { *(__dbe_table) }
  46   __stop___dbe_table = .;
  47
  48   RODATA
  49
  50   /* writeable */
  51   .data : {                     /* Data */
  52     . = . + MAPPED_OFFSET;      /* for CONFIG_MAPPED_KERNEL */
  53     *(.data.init_task)
  54
  55     *(.data)
  56
  57    /* Align the initial ramdisk image (INITRD) on page boundaries. */
  58    . = ALIGN(4096);
  59    __rd_start = .;
  60    *(.initrd)
  61    . = ALIGN(4096);
  62    __rd_end = .;
  63
  64     CONSTRUCTORS
  65   }
  66   _gp = . + 0x8000;
  67   .lit8 : { *(.lit8) }
  68   .lit4 : { *(.lit4) }
  69   /* We want the small data sections together, so single-instruction offsets
  70      can access them all, and initialized data all before uninitialized, so
  71      we can shorten the on-disk segment size.  */
  72   .sdata     : { *(.sdata) }
  73
  74   . = ALIGN(4096);
  75   __nosave_begin = .;
  76   .data_nosave : { *(.data.nosave) }
  77   . = ALIGN(4096);
  78   __nosave_end = .;
  79
  80   . = ALIGN(32);
  81   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  82
  83   _edata =  .;                  /* End of data section */
  84
  85   /* will be freed after init */
  86   . = ALIGN(4096);              /* Init code and data */
  87   __init_begin = .;
  88   /* /DISCARD/ doesn't work for .reginfo */
  89   .reginfo : { *(.reginfo) }
  90   .init.text : {
  91         _sinittext = .;
  92         *(.init.text)
  93         _einittext = .;
  94   }
  95   .init.data : { *(.init.data) }
  96   . = ALIGN(16);
  97   __setup_start = .;
  98   .init.setup : { *(.init.setup) }
  99   __setup_end = .;
 100
 101   .early_initcall.init : {
 102   __earlyinitcall_start = .;
 103         *(.initcall.early1.init)
 104   }
 105   __earlyinitcall_end = .;
 106
 107   __initcall_start = .;
 108   .initcall.init : {
 109         *(.initcall1.init)
 110         *(.initcall2.init)
 111         *(.initcall3.init)
 112         *(.initcall4.init)
 113         *(.initcall5.init)
 114         *(.initcall6.init)
 115         *(.initcall7.init)
 116   }
 117   __initcall_end = .;
 118
 119   __con_initcall_start = .;
 120   .con_initcall.init : { *(.con_initcall.init) }
 121   __con_initcall_end = .;
 122   SECURITY_INIT
 123   . = ALIGN(4096);
 124   __initramfs_start = .;
 125   .init.ramfs : { *(.init.ramfs) }
 126   __initramfs_end = .;
 127   . = ALIGN(32);
 128   __per_cpu_start = .;
 129   .data.percpu  : { *(.data.percpu) }
 130   __per_cpu_end = .;
 131   . = ALIGN(4096);
 132   __init_end = .;
 133   /* freed after init ends here */
 134
 135   __bss_start = .;              /* BSS */
 136   .sbss      : {
 137     *(.sbss)
 138     *(.scommon)
 139   }
 140   .bss : {
 141     *(.bss)
 142     *(COMMON)
 143   }
 144   __bss_stop = .;
 145
 146   _end = . ;
 147
 148   /* Sections to be discarded */
 149   /DISCARD/ : {
 150         *(.exit.text)
 151         *(.exit.data)
 152         *(.exitcall.exit)
 153   }
 154
 155   /* This is the MIPS specific mdebug section.  */
 156   .mdebug : { *(.mdebug) }
 157   /* These are needed for ELF backends which have not yet been
 158      converted to the new style linker.  */
 159   .stab 0 : { *(.stab) }
 160   .stabstr 0 : { *(.stabstr) }
 161   /* DWARF debug sections.
 162      Symbols in the .debug DWARF section are relative to the beginning of the
 163      section so we begin .debug at 0.  It's not clear yet what needs to happen
 164      for the others.   */
 165   .debug          0 : { *(.debug) }
 166   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 167   .debug_aranges  0 : { *(.debug_aranges) }
 168   .debug_pubnames 0 : { *(.debug_pubnames) }
 169   .debug_sfnames  0 : { *(.debug_sfnames) }
 170   .line           0 : { *(.line) }
 171   /* These must appear regardless of  .  */
 172   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
 173   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
 174   .comment : { *(.comment) }
 175   .note : { *(.note) }
 176 }