arch/ppc/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_ARCH(powerpc:common)
   4 jiffies = jiffies_64 + 4;
   5 SECTIONS
   6 {
   7   /* Read-only sections, merged into text segment: */
   8   . = + SIZEOF_HEADERS;
   9   .interp : { *(.interp) }
  10   .hash          : { *(.hash)           }
  11   .dynsym        : { *(.dynsym)         }
  12   .dynstr        : { *(.dynstr)         }
  13   .rel.text      : { *(.rel.text)               }
  14   .rela.text     : { *(.rela.text)      }
  15   .rel.data      : { *(.rel.data)               }
  16   .rela.data     : { *(.rela.data)      }
  17   .rel.rodata    : { *(.rel.rodata)     }
  18   .rela.rodata   : { *(.rela.rodata)    }
  19   .rel.got       : { *(.rel.got)                }
  20   .rela.got      : { *(.rela.got)               }
  21   .rel.ctors     : { *(.rel.ctors)      }
  22   .rela.ctors    : { *(.rela.ctors)     }
  23   .rel.dtors     : { *(.rel.dtors)      }
  24   .rela.dtors    : { *(.rela.dtors)     }
  25   .rel.bss       : { *(.rel.bss)                }
  26   .rela.bss      : { *(.rela.bss)               }
  27   .rel.plt       : { *(.rel.plt)                }
  28   .rela.plt      : { *(.rela.plt)               }
  29 /*  .init          : { *(.init) } =0*/
  30   .plt : { *(.plt) }
  31   .text      :
  32   {
  33     *(.text)
  34     SCHED_TEXT
  35     LOCK_TEXT
  36     *(.fixup)
  37     *(.got1)
  38     __got2_start = .;
  39     *(.got2)
  40     __got2_end = .;
  41   }
  42   _etext = .;
  43   PROVIDE (etext = .);
  44
  45   RODATA
  46   .fini      : { *(.fini)    } =0
  47   .ctors     : { *(.ctors)   }
  48   .dtors     : { *(.dtors)   }
  49
  50   .fixup   : { *(.fixup) }
  51
  52         __ex_table : {
  53                 __start___ex_table = .;
  54                 *(__ex_table)
  55                 __stop___ex_table = .;
  56         }
  57
  58         __bug_table : {
  59                 __start___bug_table = .;
  60                 *(__bug_table)
  61                 __stop___bug_table = .;
  62         }
  63
  64   /* Read-write section, merged into data segment: */
  65   . = ALIGN(4096);
  66   .data    :
  67   {
  68     *(.data)
  69     *(.data1)
  70     *(.sdata)
  71     *(.sdata2)
  72     *(.got.plt) *(.got)
  73     *(.dynamic)
  74     CONSTRUCTORS
  75   }
  76
  77   . = ALIGN(32);
  78   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  79
  80   _edata  =  .;
  81   PROVIDE (edata = .);
  82
  83   . = ALIGN(8192);
  84   .data.init_task : { *(.data.init_task) }
  85
  86   . = ALIGN(4096);
  87   __init_begin = .;
  88   .init.text : {
  89         _sinittext = .;
  90         *(.init.text)
  91         _einittext = .;
  92   }
  93   .init.data : {
  94     *(.init.data);
  95     __vtop_table_begin = .;
  96     *(.vtop_fixup);
  97     __vtop_table_end = .;
  98     __ptov_table_begin = .;
  99     *(.ptov_fixup);
 100     __ptov_table_end = .;
 101   }
 102   . = ALIGN(16);
 103   __setup_start = .;
 104   .init.setup : { *(.init.setup) }
 105   __setup_end = .;
 106   __initcall_start = .;
 107   .initcall.init : {
 108         *(.initcall1.init)
 109         *(.initcall2.init)
 110         *(.initcall3.init)
 111         *(.initcall4.init)
 112         *(.initcall5.init)
 113         *(.initcall6.init)
 114         *(.initcall7.init)
 115   }
 116   __initcall_end = .;
 117
 118   __con_initcall_start = .;
 119   .con_initcall.init : { *(.con_initcall.init) }
 120   __con_initcall_end = .;
 121
 122   SECURITY_INIT
 123
 124   __start___ftr_fixup = .;
 125   __ftr_fixup : { *(__ftr_fixup) }
 126   __stop___ftr_fixup = .;
 127
 128   . = ALIGN(32);
 129   __per_cpu_start = .;
 130   .data.percpu  : { *(.data.percpu) }
 131   __per_cpu_end = .;
 132
 133   . = ALIGN(4096);
 134   __initramfs_start = .;
 135   .init.ramfs : { *(.init.ramfs) }
 136   __initramfs_end = .;
 137
 138   . = ALIGN(4096);
 139   __init_end = .;
 140
 141   . = ALIGN(4096);
 142   __pmac_begin = .;
 143   .pmac.text : { *(.pmac.text) }
 144   .pmac.data : { *(.pmac.data) }
 145   . = ALIGN(4096);
 146   __pmac_end = .;
 147
 148   . = ALIGN(4096);
 149   __prep_begin = .;
 150   .prep.text : { *(.prep.text) }
 151   .prep.data : { *(.prep.data) }
 152   . = ALIGN(4096);
 153   __prep_end = .;
 154
 155   . = ALIGN(4096);
 156   __chrp_begin = .;
 157   .chrp.text : { *(.chrp.text) }
 158   .chrp.data : { *(.chrp.data) }
 159   . = ALIGN(4096);
 160   __chrp_end = .;
 161
 162   . = ALIGN(4096);
 163   __openfirmware_begin = .;
 164   .openfirmware.text : { *(.openfirmware.text) }
 165   .openfirmware.data : { *(.openfirmware.data) }
 166   . = ALIGN(4096);
 167   __openfirmware_end = .;
 168
 169   __bss_start = .;
 170   .bss       :
 171   {
 172    *(.sbss) *(.scommon)
 173    *(.dynbss)
 174    *(.bss)
 175    *(COMMON)
 176   }
 177   __bss_stop = .;
 178
 179   _end = . ;
 180   PROVIDE (end = .);
 181
 182   /* Sections to be discarded. */
 183   /DISCARD/ : {
 184     *(.exitcall.exit)
 185   }
 186 }