arch/ppc64/kernel/entry.S

   1 /*
   2  *  arch/ppc64/kernel/entry.S
   3  *
   4  *  PowerPC version
   5  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   6  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   7  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   8  *  Adapted for Power Macintosh by Paul Mackerras.
   9  *  Low-level exception handlers and MMU support
  10  *  rewritten by Paul Mackerras.
  11  *    Copyright (C) 1996 Paul Mackerras.
  12  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  13  *
  14  *  This file contains the system call entry code, context switch
  15  *  code, and exception/interrupt return code for PowerPC.
  16  *
  17  *  This program is free software; you can redistribute it and/or
  18  *  modify it under the terms of the GNU General Public License
  19  *  as published by the Free Software Foundation; either version
  20  *  2 of the License, or (at your option) any later version.
  21  */
  22
  23 #include <linux/config.h>
  24 #include <linux/errno.h>
  25 #include <asm/unistd.h>
  26 #include <asm/processor.h>
  27 #include <asm/page.h>
  28 #include <asm/mmu.h>
  29 #include <asm/thread_info.h>
  30 #include <asm/ppc_asm.h>
  31 #include <asm/offsets.h>
  32 #include <asm/cputable.h>
  33
  34 #ifdef CONFIG_PPC_ISERIES
  35 #define DO_SOFT_DISABLE
  36 #endif
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 .SYS_CALL_TABLE:
  43         .tc .sys_call_table[TC],.sys_call_table
  44
  45 .SYS_CALL_TABLE32:
  46         .tc .sys_call_table32[TC],.sys_call_table32
  47
  48 /* This value is used to mark exception frames on the stack. */
  49 exception_marker:
  50         .tc     ID_72656773_68657265[TC],0x7265677368657265
  51
  52         .section        ".text"
  53         .align 7
  54
  55 #undef SHOW_SYSCALLS
  56
  57         .globl SystemCall_common
  58 SystemCall_common:
  59         andi.   r10,r12,MSR_PR
  60         mr      r10,r1
  61         addi    r1,r1,-INT_FRAME_SIZE
  62         beq-    1f
  63         ld      r1,PACAKSAVE(r13)
  64 1:      std     r10,0(r1)
  65         std     r11,_NIP(r1)
  66         std     r12,_MSR(r1)
  67         std     r0,GPR0(r1)
  68         std     r10,GPR1(r1)
  69         std     r2,GPR2(r1)
  70         std     r3,GPR3(r1)
  71         std     r4,GPR4(r1)
  72         std     r5,GPR5(r1)
  73         std     r6,GPR6(r1)
  74         std     r7,GPR7(r1)
  75         std     r8,GPR8(r1)
  76         li      r11,0
  77         std     r11,GPR9(r1)
  78         std     r11,GPR10(r1)
  79         std     r11,GPR11(r1)
  80         std     r11,GPR12(r1)
  81         std     r9,GPR13(r1)
  82         crclr   so
  83         mfcr    r9
  84         mflr    r10
  85         li      r11,0xc01
  86         std     r9,_CCR(r1)
  87         std     r10,_LINK(r1)
  88         std     r11,_TRAP(r1)
  89         mfxer   r9
  90         mfctr   r10
  91         std     r9,_XER(r1)
  92         std     r10,_CTR(r1)
  93         std     r3,ORIG_GPR3(r1)
  94         ld      r2,PACATOC(r13)
  95         addi    r9,r1,STACK_FRAME_OVERHEAD
  96         ld      r11,exception_marker@toc(r2)
  97         std     r11,-16(r9)             /* "regshere" marker */
  98 #ifdef CONFIG_PPC_ISERIES
  99         /* Hack for handling interrupts when soft-enabling on iSeries */
 100         cmpdi   cr1,r0,0x5555           /* syscall 0x5555 */
 101         andi.   r10,r12,MSR_PR          /* from kernel */
 102         crand   4*cr0+eq,4*cr1+eq,4*cr0+eq
 103         beq     HardwareInterrupt_entry
 104         lbz     r10,PACAPROCENABLED(r13)
 105         std     r10,SOFTE(r1)
 106 #endif
 107         mfmsr   r11
 108         ori     r11,r11,MSR_EE
 109         mtmsrd  r11,1
 110
 111 #ifdef SHOW_SYSCALLS
 112         bl      .do_show_syscall
 113         REST_GPR(0,r1)
 114         REST_4GPRS(3,r1)
 115         REST_2GPRS(7,r1)
 116         addi    r9,r1,STACK_FRAME_OVERHEAD
 117 #endif
 118         clrrdi  r11,r1,THREAD_SHIFT
 119         li      r12,0
 120         ld      r10,TI_FLAGS(r11)
 121         stb     r12,TI_SC_NOERR(r11)
 122         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 123         bne-    syscall_dotrace
 124 syscall_dotrace_cont:
 125         cmpli   0,r0,NR_syscalls
 126         bge-    syscall_enosys
 127
 128 system_call:                    /* label this so stack traces look sane */
 129 /*
 130  * Need to vector to 32 Bit or default sys_call_table here,
 131  * based on caller's run-mode / personality.
 132  */
 133         ld      r11,.SYS_CALL_TABLE@toc(2)
 134         andi.   r10,r10,_TIF_32BIT
 135         beq     15f
 136         ld      r11,.SYS_CALL_TABLE32@toc(2)
 137         clrldi  r3,r3,32
 138         clrldi  r4,r4,32
 139         clrldi  r5,r5,32
 140         clrldi  r6,r6,32
 141         clrldi  r7,r7,32
 142         clrldi  r8,r8,32
 143 15:
 144         slwi    r0,r0,3
 145         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 146         mtctr   r10
 147         bctrl                   /* Call handler */
 148
 149 syscall_exit:
 150 #ifdef SHOW_SYSCALLS
 151         std     r3,GPR3(r1)
 152         bl      .do_show_syscall_exit
 153         ld      r3,GPR3(r1)
 154 #endif
 155         std     r3,RESULT(r1)
 156         ld      r5,_CCR(r1)
 157         li      r10,-_LAST_ERRNO
 158         cmpld   r3,r10
 159         clrrdi  r12,r1,THREAD_SHIFT
 160         bge-    syscall_error
 161 syscall_error_cont:
 162
 163         /* check for syscall tracing or audit */
 164         ld      r9,TI_FLAGS(r12)
 165         andi.   r0,r9,_TIF_SYSCALL_T_OR_A
 166         bne-    syscall_exit_trace
 167 syscall_exit_trace_cont:
 168
 169         /* disable interrupts so current_thread_info()->flags can't change,
 170            and so that we don't get interrupted after loading SRR0/1. */
 171         ld      r8,_MSR(r1)
 172         andi.   r10,r8,MSR_RI
 173         beq-    unrecov_restore
 174         mfmsr   r10
 175         rldicl  r10,r10,48,1
 176         rotldi  r10,r10,16
 177         mtmsrd  r10,1
 178         ld      r9,TI_FLAGS(r12)
 179         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SIGPENDING|_TIF_NEED_RESCHED)
 180         bne-    syscall_exit_work
 181         ld      r7,_NIP(r1)
 182         stdcx.  r0,0,r1                 /* to clear the reservation */
 183         andi.   r6,r8,MSR_PR
 184         ld      r4,_LINK(r1)
 185         beq-    1f                      /* only restore r13 if */
 186         ld      r13,GPR13(r1)           /* returning to usermode */
 187 1:      ld      r2,GPR2(r1)
 188         ld      r1,GPR1(r1)
 189         li      r12,MSR_RI
 190         andc    r10,r10,r12
 191         mtmsrd  r10,1                   /* clear MSR.RI */
 192         mtlr    r4
 193         mtcr    r5
 194         mtspr   SRR0,r7
 195         mtspr   SRR1,r8
 196         rfid
 197         b       .       /* prevent speculative execution */
 198
 199 syscall_enosys:
 200         li      r3,-ENOSYS
 201         std     r3,RESULT(r1)
 202         clrrdi  r12,r1,THREAD_SHIFT
 203         ld      r5,_CCR(r1)
 204
 205 syscall_error:
 206         lbz     r11,TI_SC_NOERR(r12)
 207         cmpi    0,r11,0
 208         bne-    syscall_error_cont
 209         neg     r3,r3
 210         oris    r5,r5,0x1000    /* Set SO bit in CR */
 211         std     r5,_CCR(r1)
 212         b       syscall_error_cont
 213
 214 /* Traced system call support */
 215 syscall_dotrace:
 216         bl      .save_nvgprs
 217         addi    r3,r1,STACK_FRAME_OVERHEAD
 218         bl      .do_syscall_trace_enter
 219         ld      r0,GPR0(r1)     /* Restore original registers */
 220         ld      r3,GPR3(r1)
 221         ld      r4,GPR4(r1)
 222         ld      r5,GPR5(r1)
 223         ld      r6,GPR6(r1)
 224         ld      r7,GPR7(r1)
 225         ld      r8,GPR8(r1)
 226         addi    r9,r1,STACK_FRAME_OVERHEAD
 227         clrrdi  r10,r1,THREAD_SHIFT
 228         ld      r10,TI_FLAGS(r10)
 229         b       syscall_dotrace_cont
 230
 231 syscall_exit_trace:
 232         std     r3,GPR3(r1)
 233         bl      .save_nvgprs
 234         bl      .do_syscall_trace_leave
 235         REST_NVGPRS(r1)
 236         ld      r3,GPR3(r1)
 237         ld      r5,_CCR(r1)
 238         clrrdi  r12,r1,THREAD_SHIFT
 239         b       syscall_exit_trace_cont
 240
 241 /* Stuff to do on exit from a system call. */
 242 syscall_exit_work:
 243         std     r3,GPR3(r1)
 244         std     r5,_CCR(r1)
 245         b       .ret_from_except_lite
 246
 247 /* Save non-volatile GPRs, if not already saved. */
 248 _GLOBAL(save_nvgprs)
 249         ld      r11,_TRAP(r1)
 250         andi.   r0,r11,1
 251         beqlr-
 252         SAVE_NVGPRS(r1)
 253         clrrdi  r0,r11,1
 254         std     r0,_TRAP(r1)
 255         blr
 256
 257 /*
 258  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 259  * and thus put the process into the stopped state where we might
 260  * want to examine its user state with ptrace.  Therefore we need
 261  * to save all the nonvolatile registers (r14 - r31) before calling
 262  * the C code.  Similarly, fork, vfork and clone need the full
 263  * register state on the stack so that it can be copied to the child.
 264  */
 265 _GLOBAL(ppc32_sigsuspend)
 266         bl      .save_nvgprs
 267         bl      .sys32_sigsuspend
 268         b       syscall_exit
 269
 270 _GLOBAL(ppc64_rt_sigsuspend)
 271         bl      .save_nvgprs
 272         bl      .sys_rt_sigsuspend
 273         b       syscall_exit
 274
 275 _GLOBAL(ppc32_rt_sigsuspend)
 276         bl      .save_nvgprs
 277         bl      .sys32_rt_sigsuspend
 278         b       syscall_exit
 279
 280 _GLOBAL(ppc_fork)
 281         bl      .save_nvgprs
 282         bl      .sys_fork
 283         b       syscall_exit
 284
 285 _GLOBAL(ppc_vfork)
 286         bl      .save_nvgprs
 287         bl      .sys_vfork
 288         b       syscall_exit
 289
 290 _GLOBAL(ppc_clone)
 291         bl      .save_nvgprs
 292         bl      .sys_clone
 293         b       syscall_exit
 294
 295 _GLOBAL(ppc32_swapcontext)
 296         bl      .save_nvgprs
 297         bl      .sys32_swapcontext
 298         b       80f
 299
 300 _GLOBAL(ppc64_swapcontext)
 301         bl      .save_nvgprs
 302         bl      .sys_swapcontext
 303         b       80f
 304
 305 _GLOBAL(ppc32_sigreturn)
 306         bl      .sys32_sigreturn
 307         b       80f
 308
 309 _GLOBAL(ppc32_rt_sigreturn)
 310         bl      .sys32_rt_sigreturn
 311         b       80f
 312
 313 _GLOBAL(ppc64_rt_sigreturn)
 314         bl      .sys_rt_sigreturn
 315
 316 80:     cmpdi   0,r3,0
 317         blt     syscall_exit
 318         clrrdi  r4,r1,THREAD_SHIFT
 319         ld      r4,TI_FLAGS(r4)
 320         andi.   r4,r4,_TIF_SYSCALL_T_OR_A
 321         beq+    81f
 322         bl      .do_syscall_trace_leave
 323 81:     b       .ret_from_except
 324
 325 _GLOBAL(ret_from_fork)
 326         bl      .schedule_tail
 327         REST_NVGPRS(r1)
 328         li      r3,0
 329         b       syscall_exit
 330
 331 /*
 332  * This routine switches between two different tasks.  The process
 333  * state of one is saved on its kernel stack.  Then the state
 334  * of the other is restored from its kernel stack.  The memory
 335  * management hardware is updated to the second process's state.
 336  * Finally, we can return to the second process, via ret_from_except.
 337  * On entry, r3 points to the THREAD for the current task, r4
 338  * points to the THREAD for the new task.
 339  *
 340  * Note: there are two ways to get to the "going out" portion
 341  * of this code; either by coming in via the entry (_switch)
 342  * or via "fork" which must set up an environment equivalent
 343  * to the "_switch" path.  If you change this you'll have to change
 344  * the fork code also.
 345  *
 346  * The code which creates the new task context is in 'copy_thread'
 347  * in arch/ppc64/kernel/process.c
 348  */
 349         .align  7
 350 _GLOBAL(_switch)
 351         mflr    r0
 352         std     r0,16(r1)
 353         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 354         /* r3-r13 are caller saved -- Cort */
 355         SAVE_8GPRS(14, r1)
 356         SAVE_10GPRS(22, r1)
 357         mflr    r20             /* Return to switch caller */
 358         mfmsr   r22
 359         li      r0, MSR_FP
 360 #ifdef CONFIG_ALTIVEC
 361 BEGIN_FTR_SECTION
 362         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 363         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 364         std     r24,THREAD_VRSAVE(r3)
 365 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 366 #endif /* CONFIG_ALTIVEC */
 367         and.    r0,r0,r22
 368         beq+    1f
 369         andc    r22,r22,r0
 370         mtmsrd  r22
 371         isync
 372 1:      std     r20,_NIP(r1)
 373         mfcr    r23
 374         std     r23,_CCR(r1)
 375         std     r1,KSP(r3)      /* Set old stack pointer */
 376
 377 #ifdef CONFIG_SMP
 378         /* We need a sync somewhere here to make sure that if the
 379          * previous task gets rescheduled on another CPU, it sees all
 380          * stores it has performed on this one.
 381          */
 382         sync
 383 #endif /* CONFIG_SMP */
 384
 385         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 386         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 387
 388         ld      r8,KSP(r4)      /* new stack pointer */
 389 BEGIN_FTR_SECTION
 390         clrrdi  r6,r8,28        /* get its ESID */
 391         clrrdi  r9,r1,28        /* get current sp ESID */
 392         clrldi. r0,r6,2         /* is new ESID c00000000? */
 393         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 394         cror    eq,4*cr1+eq,eq
 395         beq     2f              /* if yes, don't slbie it */
 396         oris    r6,r6,0x0800    /* set C (class) bit */
 397         slbie   r6
 398         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 399 2:
 400 END_FTR_SECTION_IFSET(CPU_FTR_SLB)
 401         clrrdi  r7,r8,THREAD_SHIFT      /* base of new stack */
 402         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 403            because we don't need to leave the 288-byte ABI gap at the
 404            top of the kernel stack. */
 405         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 406
 407         mr      r1,r8           /* start using new stack pointer */
 408         std     r7,PACAKSAVE(r13)
 409
 410         ld      r6,_CCR(r1)
 411         mtcrf   0xFF,r6
 412
 413 #ifdef CONFIG_ALTIVEC
 414 BEGIN_FTR_SECTION
 415         ld      r0,THREAD_VRSAVE(r4)
 416         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 417 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 418 #endif /* CONFIG_ALTIVEC */
 419
 420         /* r3-r13 are destroyed -- Cort */
 421         REST_8GPRS(14, r1)
 422         REST_10GPRS(22, r1)
 423
 424 #ifdef CONFIG_PPC_ISERIES
 425         clrrdi  r7,r1,THREAD_SHIFT      /* get current_thread_info() */
 426         ld      r7,TI_FLAGS(r7)         /* Get run light flag */
 427         mfspr   r9,CTRLF
 428         srdi    r7,r7,TIF_RUN_LIGHT
 429         insrdi  r9,r7,1,63              /* Insert run light into CTRL */
 430         mtspr   CTRLT,r9
 431 #endif
 432
 433         /* convert old thread to its task_struct for return value */
 434         addi    r3,r3,-THREAD
 435         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 436         mtlr    r7
 437         addi    r1,r1,SWITCH_FRAME_SIZE
 438         blr
 439
 440         .align  7
 441 _GLOBAL(ret_from_except)
 442         ld      r11,_TRAP(r1)
 443         andi.   r0,r11,1
 444         bne     .ret_from_except_lite
 445         REST_NVGPRS(r1)
 446
 447 _GLOBAL(ret_from_except_lite)
 448         /*
 449          * Disable interrupts so that current_thread_info()->flags
 450          * can't change between when we test it and when we return
 451          * from the interrupt.
 452          */
 453         mfmsr   r10             /* Get current interrupt state */
 454         rldicl  r9,r10,48,1     /* clear MSR_EE */
 455         rotldi  r9,r9,16
 456         mtmsrd  r9,1            /* Update machine state */
 457
 458 #ifdef CONFIG_PREEMPT
 459         clrrdi  r9,r1,THREAD_SHIFT      /* current_thread_info() */
 460         li      r0,_TIF_NEED_RESCHED    /* bits to check */
 461         ld      r3,_MSR(r1)
 462         ld      r4,TI_FLAGS(r9)
 463         /* Move MSR_PR bit in r3 to _TIF_SIGPENDING position in r0 */
 464         rlwimi  r0,r3,32+TIF_SIGPENDING-MSR_PR_LG,_TIF_SIGPENDING
 465         and.    r0,r4,r0        /* check NEED_RESCHED and maybe SIGPENDING */
 466         bne     do_work
 467
 468 #else /* !CONFIG_PREEMPT */
 469         ld      r3,_MSR(r1)     /* Returning to user mode? */
 470         andi.   r3,r3,MSR_PR
 471         beq     restore         /* if not, just restore regs and return */
 472
 473         /* Check current_thread_info()->flags */
 474         clrrdi  r9,r1,THREAD_SHIFT
 475         ld      r4,TI_FLAGS(r9)
 476         andi.   r0,r4,_TIF_USER_WORK_MASK
 477         bne     do_work
 478 #endif
 479
 480 restore:
 481 #ifdef CONFIG_PPC_ISERIES
 482         ld      r5,SOFTE(r1)
 483         cmpdi   0,r5,0
 484         beq     4f
 485         /* Check for pending interrupts (iSeries) */
 486         ld      r3,PACALPPACA+LPPACAANYINT(r13)
 487         cmpdi   r3,0
 488         beq+    4f                      /* skip do_IRQ if no interrupts */
 489
 490         li      r3,0
 491         stb     r3,PACAPROCENABLED(r13) /* ensure we are soft-disabled */
 492         mtmsrd  r10                     /* hard-enable again */
 493         addi    r3,r1,STACK_FRAME_OVERHEAD
 494         bl      .do_IRQ
 495         b       .ret_from_except                /* loop back and handle more */
 496
 497 4:      stb     r5,PACAPROCENABLED(r13)
 498 #endif
 499
 500         ld      r3,_MSR(r1)
 501         andi.   r0,r3,MSR_RI
 502         beq-    unrecov_restore
 503
 504         andi.   r0,r3,MSR_PR
 505
 506         /*
 507          * r13 is our per cpu area, only restore it if we are returning to
 508          * userspace
 509          */
 510         beq     1f
 511         REST_GPR(13, r1)
 512 1:
 513         ld      r3,_CTR(r1)
 514         ld      r0,_LINK(r1)
 515         mtctr   r3
 516         mtlr    r0
 517         ld      r3,_XER(r1)
 518         mtspr   XER,r3
 519
 520         REST_8GPRS(5, r1)
 521
 522         stdcx.  r0,0,r1         /* to clear the reservation */
 523
 524         mfmsr   r0
 525         li      r2, MSR_RI
 526         andc    r0,r0,r2
 527         mtmsrd  r0,1
 528
 529         ld      r0,_MSR(r1)
 530         mtspr   SRR1,r0
 531
 532         ld      r2,_CCR(r1)
 533         mtcrf   0xFF,r2
 534         ld      r2,_NIP(r1)
 535         mtspr   SRR0,r2
 536
 537         ld      r0,GPR0(r1)
 538         ld      r2,GPR2(r1)
 539         ld      r3,GPR3(r1)
 540         ld      r4,GPR4(r1)
 541         ld      r1,GPR1(r1)
 542
 543         rfid
 544         b       .       /* prevent speculative execution */
 545
 546 /* Note: this must change if we start using the TIF_NOTIFY_RESUME bit */
 547 do_work:
 548 #ifdef CONFIG_PREEMPT
 549         andi.   r0,r3,MSR_PR    /* Returning to user mode? */
 550         bne     user_work
 551         /* Check that preempt_count() == 0 and interrupts are enabled */
 552         lwz     r8,TI_PREEMPT(r9)
 553         cmpwi   cr1,r8,0
 554 #ifdef CONFIG_PPC_ISERIES
 555         ld      r0,SOFTE(r1)
 556         cmpdi   r0,0
 557 #else
 558         andi.   r0,r3,MSR_EE
 559 #endif
 560         crandc  eq,cr1*4+eq,eq
 561         bne     restore
 562         /* here we are preempting the current task */
 563 1:      lis     r0,PREEMPT_ACTIVE@h
 564         stw     r0,TI_PREEMPT(r9)
 565 #ifdef CONFIG_PPC_ISERIES
 566         li      r0,1
 567         stb     r0,PACAPROCENABLED(r13)
 568 #endif
 569         mtmsrd  r10,1           /* reenable interrupts */
 570         bl      .schedule
 571         mfmsr   r10
 572         clrrdi  r9,r1,THREAD_SHIFT
 573         rldicl  r10,r10,48,1    /* disable interrupts again */
 574         li      r0,0
 575         rotldi  r10,r10,16
 576         mtmsrd  r10,1
 577         ld      r4,TI_FLAGS(r9)
 578         andi.   r0,r4,_TIF_NEED_RESCHED
 579         bne     1b
 580         stw     r0,TI_PREEMPT(r9)
 581         b       restore
 582
 583 user_work:
 584 #endif
 585         /* Enable interrupts */
 586         mtmsrd  r10,1
 587
 588         andi.   r0,r4,_TIF_NEED_RESCHED
 589         beq     1f
 590         bl      .schedule
 591         b       .ret_from_except_lite
 592
 593 1:      bl      .save_nvgprs
 594         li      r3,0
 595         addi    r4,r1,STACK_FRAME_OVERHEAD
 596         bl      .do_signal
 597         b       .ret_from_except
 598
 599 unrecov_restore:
 600         addi    r3,r1,STACK_FRAME_OVERHEAD
 601         bl      .unrecoverable_exception
 602         b       unrecov_restore
 603
 604 #ifdef CONFIG_PPC_PSERIES
 605 /*
 606  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 607  * called with the MMU off.
 608  *
 609  * In addition, we need to be in 32b mode, at least for now.
 610  *
 611  * Note: r3 is an input parameter to rtas, so don't trash it...
 612  */
 613 _GLOBAL(enter_rtas)
 614         mflr    r0
 615         std     r0,16(r1)
 616         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 617
 618         /* Because RTAS is running in 32b mode, it clobbers the high order half
 619          * of all registers that it saves.  We therefore save those registers
 620          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 621          */
 622         SAVE_GPR(2, r1)                 /* Save the TOC */
 623         SAVE_GPR(13, r1)                /* Save paca */
 624         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 625         SAVE_10GPRS(22, r1)             /* ditto */
 626
 627         mfcr    r4
 628         std     r4,_CCR(r1)
 629         mfctr   r5
 630         std     r5,_CTR(r1)
 631         mfspr   r6,XER
 632         std     r6,_XER(r1)
 633         mfdar   r7
 634         std     r7,_DAR(r1)
 635         mfdsisr r8
 636         std     r8,_DSISR(r1)
 637         mfsrr0  r9
 638         std     r9,_SRR0(r1)
 639         mfsrr1  r10
 640         std     r10,_SRR1(r1)
 641
 642         /* There is no way it is acceptable to get here with interrupts enabled,
 643          * check it with the asm equivalent of WARN_ON
 644          */
 645         mfmsr   r6
 646         andi.   r0,r6,MSR_EE
 647 1:      tdnei   r0,0
 648 .section __bug_table,"a"
 649         .llong  1b,__LINE__ + 0x1000000, 1f, 2f
 650 .previous
 651 .section .rodata,"a"
 652 1:      .asciz  __FILE__
 653 2:      .asciz "enter_rtas"
 654 .previous
 655
 656         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 657          * so they are saved in the PACA which allows us to restore
 658          * our original state after RTAS returns.
 659          */
 660         std     r1,PACAR1(r13)
 661         std     r6,PACASAVEDMSR(r13)
 662
 663         /* Setup our real return addr */
 664         SET_REG_TO_LABEL(r4,.rtas_return_loc)
 665         SET_REG_TO_CONST(r9,KERNELBASE)
 666         sub     r4,r4,r9
 667         mtlr    r4
 668
 669         li      r0,0
 670         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 671         andc    r0,r6,r0
 672
 673         li      r9,1
 674         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 675         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP
 676         andc    r6,r0,r9
 677         ori     r6,r6,MSR_RI
 678         sync                            /* disable interrupts so SRR0/1 */
 679         mtmsrd  r0                      /* don't get trashed */
 680
 681         SET_REG_TO_LABEL(r4,rtas)
 682         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 683         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 684
 685         mtspr   SRR0,r5
 686         mtspr   SRR1,r6
 687         rfid
 688         b       .       /* prevent speculative execution */
 689
 690 _STATIC(rtas_return_loc)
 691         /* relocation is off at this point */
 692         mfspr   r4,SPRG3                /* Get PACA */
 693         SET_REG_TO_CONST(r5, KERNELBASE)
 694         sub     r4,r4,r5                /* RELOC the PACA base pointer */
 695
 696         mfmsr   r6
 697         li      r0,MSR_RI
 698         andc    r6,r6,r0
 699         sync
 700         mtmsrd  r6
 701
 702         ld      r1,PACAR1(r4)           /* Restore our SP */
 703         LOADADDR(r3,.rtas_restore_regs)
 704         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 705
 706         mtspr   SRR0,r3
 707         mtspr   SRR1,r4
 708         rfid
 709         b       .       /* prevent speculative execution */
 710
 711 _STATIC(rtas_restore_regs)
 712         /* relocation is on at this point */
 713         REST_GPR(2, r1)                 /* Restore the TOC */
 714         REST_GPR(13, r1)                /* Restore paca */
 715         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 716         REST_10GPRS(22, r1)             /* ditto */
 717
 718         mfspr   r13,SPRG3
 719
 720         ld      r4,_CCR(r1)
 721         mtcr    r4
 722         ld      r5,_CTR(r1)
 723         mtctr   r5
 724         ld      r6,_XER(r1)
 725         mtspr   XER,r6
 726         ld      r7,_DAR(r1)
 727         mtdar   r7
 728         ld      r8,_DSISR(r1)
 729         mtdsisr r8
 730         ld      r9,_SRR0(r1)
 731         mtsrr0  r9
 732         ld      r10,_SRR1(r1)
 733         mtsrr1  r10
 734
 735         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 736         ld      r0,16(r1)               /* get return address */
 737
 738         mtlr    r0
 739         blr                             /* return to caller */
 740
 741 _GLOBAL(enter_prom)
 742         mflr    r0
 743         std     r0,16(r1)
 744         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 745
 746         /* Because PROM is running in 32b mode, it clobbers the high order half
 747          * of all registers that it saves.  We therefore save those registers
 748          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
 749          */
 750         SAVE_8GPRS(2, r1)
 751         SAVE_GPR(13, r1)
 752         SAVE_8GPRS(14, r1)
 753         SAVE_10GPRS(22, r1)
 754         mfcr    r4
 755         std     r4,_CCR(r1)
 756         mfctr   r5
 757         std     r5,_CTR(r1)
 758         mfspr   r6,XER
 759         std     r6,_XER(r1)
 760         mfdar   r7
 761         std     r7,_DAR(r1)
 762         mfdsisr r8
 763         std     r8,_DSISR(r1)
 764         mfsrr0  r9
 765         std     r9,_SRR0(r1)
 766         mfsrr1  r10
 767         std     r10,_SRR1(r1)
 768         mfmsr   r11
 769         std     r11,_MSR(r1)
 770
 771         /* Get the PROM entrypoint */
 772         bl      .reloc_offset
 773         LOADADDR(r12,prom)
 774         sub     r12,r12,r3
 775         ld      r12,PROMENTRY(r12)
 776         mtlr    r12
 777
 778         /* Switch MSR to 32 bits mode
 779          */
 780         mfmsr   r11
 781         li      r12,1
 782         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
 783         andc    r11,r11,r12
 784         li      r12,1
 785         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
 786         andc    r11,r11,r12
 787         mtmsrd  r11
 788         isync
 789
 790         /* Restore arguments & enter PROM here... */
 791         ld      r3,GPR3(r1)
 792         blrl
 793
 794         /* Just make sure that r1 top 32 bits didn't get
 795          * corrupt by OF
 796          */
 797         rldicl  r1,r1,0,32
 798
 799         /* Restore the MSR (back to 64 bits) */
 800         ld      r0,_MSR(r1)
 801         mtmsrd  r0
 802         isync
 803
 804         /* Restore other registers */
 805         REST_GPR(2, r1)
 806         REST_GPR(13, r1)
 807         REST_8GPRS(14, r1)
 808         REST_10GPRS(22, r1)
 809         ld      r4,_CCR(r1)
 810         mtcr    r4
 811         ld      r5,_CTR(r1)
 812         mtctr   r5
 813         ld      r6,_XER(r1)
 814         mtspr   XER,r6
 815         ld      r7,_DAR(r1)
 816         mtdar   r7
 817         ld      r8,_DSISR(r1)
 818         mtdsisr r8
 819         ld      r9,_SRR0(r1)
 820         mtsrr0  r9
 821         ld      r10,_SRR1(r1)
 822         mtsrr1  r10
 823
 824         addi    r1,r1,PROM_FRAME_SIZE
 825         ld      r0,16(r1)
 826         mtlr    r0
 827         blr
 828
 829 #endif  /* defined(CONFIG_PPC_PSERIES) */