arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *  S390 version
   6  *    Copyright (C) 1999,2000 IBM Deutschland Entwicklung GmbH, IBM Corporation
   7  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   8  *               Hartmut Penner (hp@de.ibm.com),
   9  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/config.h>
  15 #include <asm/cache.h>
  16 #include <asm/lowcore.h>
  17 #include <asm/errno.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/offsets.h>
  21 #include <asm/unistd.h>
  22
  23 /*
  24  * Stack layout for the system_call stack entry.
  25  * The first few entries are identical to the user_regs_struct.
  26  */
  27 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  28 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  29 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  30 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  31 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  32 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  33 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  34 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  35 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  36 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  37 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  38 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  39 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  40 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  41 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  42 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  43 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  44 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  45 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  46 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  47 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  48 SP_TRAP      =  STACK_FRAME_OVERHEAD + __PT_TRAP
  49 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  50
  51 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | \
  52                  _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  53 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NEED_RESCHED)
  54
  55 #define BASED(name) name-system_call(%r13)
  56
  57 /*
  58  * Register usage in interrupt handlers:
  59  *    R9  - pointer to current task structure
  60  *    R13 - pointer to literal pool
  61  *    R14 - return register for function calls
  62  *    R15 - kernel stack pointer
  63  */
  64
  65         .macro  SAVE_ALL_BASE psworg,savearea,sync
  66         stm     %r12,%r15,\savearea
  67         l       %r13,__LC_SVC_NEW_PSW+4   # load &system_call to %r13
  68         .endm
  69
  70         .macro  CLEANUP_SAVE_ALL_BASE psworg,savearea,sync
  71         l       %r1,SP_PSW+4(%r15)
  72         cli     1(%r1),0xcf
  73         bne     BASED(0f)
  74         mvc     \savearea(16),SP_R12(%r15)
  75 0:      st      %r13,SP_R13(%r15)
  76         .endm
  77
  78         .macro  SAVE_ALL psworg,savearea,sync
  79         .if     \sync
  80         tm      \psworg+1,0x01            # test problem state bit
  81         bz      BASED(1f)                 # skip stack setup save
  82         l       %r15,__LC_KERNEL_STACK    # problem state -> load ksp
  83         .else
  84         tm      \psworg+1,0x01            # test problem state bit
  85         bnz     BASED(0f)                 # from user -> load async stack
  86         l       %r14,__LC_ASYNC_STACK     # are we already on the async stack ?
  87         slr     %r14,%r15
  88         sra     %r14,13
  89         be      BASED(1f)
  90 0:      l       %r15,__LC_ASYNC_STACK
  91         .endif
  92 1:      s       %r15,BASED(.Lc_spsize)    # make room for registers & psw
  93         l       %r14,BASED(.L\psworg)
  94         slr     %r12,%r12
  95         icm     %r14,12,__LC_SVC_ILC
  96         stm     %r0,%r11,SP_R0(%r15)      # store gprs 0-12 to kernel stack
  97         st      %r2,SP_ORIG_R2(%r15)      # store original content of gpr 2
  98         mvc     SP_R12(16,%r15),\savearea # move R13-R15 to stack
  99         mvc     SP_PSW(8,%r15),\psworg    # move user PSW to stack
 100         st      %r14,SP_ILC(%r15)
 101         st      %r12,0(%r15)              # clear back chain
 102         .endm
 103
 104         .macro  CLEANUP_SAVE_ALL psworg,savearea,sync
 105         l       %r1,\savearea+12
 106         .if     \sync
 107         tm      \psworg+1,0x01
 108         bz      BASED(1f)
 109         l       %r1,__LC_KERNEL_STACK
 110         .else
 111         tm      \psworg+1,0x01
 112         bnz     BASED(0f)
 113         l       %r0,__LC_ASYNC_STACK
 114         slr     %r0,%r1
 115         sra     %r0,13
 116         bz      BASED(1f)
 117 0:      l       %r1,__LC_ASYNC_STACK
 118         .endif
 119 1:      s       %r1,BASED(.Lc_spsize)
 120         st      %r1,SP_R15(%r15)
 121         l       %r0,BASED(.L\psworg)
 122         xc      SP_R12(4,%r15),SP_R12(%r15)
 123         icm     %r0,12,__LC_SVC_ILC
 124         st      %r0,SP_R14(%r15)
 125         mvc     SP_R0(48,%r1),SP_R0(%r15)
 126         mvc     SP_ORIG_R2(4,%r1),SP_R2(%r15)
 127         mvc     SP_R12(16,%r1),\savearea
 128         mvc     SP_PSW(8,%r1),\psworg
 129         st      %r0,SP_ILC(%r1)
 130         xc      0(4,%r1),0(%r1)
 131         .endm
 132
 133         .macro  RESTORE_ALL               # system exit macro
 134         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)  # move user PSW to lowcore
 135         ni      __LC_RETURN_PSW+1,0xfd    # clear wait state bit
 136         lm      %r0,%r15,SP_R0(%r15)      # load gprs 0-15 of user
 137         lpsw    __LC_RETURN_PSW           # back to caller
 138         .endm
 139
 140         .macro  CLEANUP_RESTORE_ALL
 141         l       %r1,SP_PSW+4(%r15)
 142         cli     0(%r1),0x82
 143         bne     BASED(0f)
 144         mvc     SP_PSW(8,%r15),__LC_RETURN_PSW
 145         b       BASED(1f)
 146 0:      l       %r1,SP_R15(%r15)
 147         mvc     SP_PSW(8,%r15),SP_PSW(%r1)
 148         mvc     SP_R0(64,%r15),SP_R0(%r1)
 149 1:
 150         .endm
 151
 152         .macro  GET_THREAD_INFO
 153         l       %r9,__LC_THREAD_INFO
 154         .endm
 155
 156         .macro  CHECK_CRITICAL
 157         tm      SP_PSW+1(%r15),0x01      # test problem state bit
 158         bnz     BASED(0f)                # from user -> not critical
 159         clc     SP_PSW+4(4,%r15),BASED(.Lcritical_end)
 160         bnl     BASED(0f)
 161         clc     SP_PSW+4(4,%r15),BASED(.Lcritical_start)
 162         bl      BASED(0f)
 163         l       %r1,BASED(.Lcleanup_critical)
 164         basr    %r14,%r1
 165 0:
 166         .endm
 167
 168 /*
 169  * Scheduler resume function, called by switch_to
 170  *  gpr2 = (task_struct *) prev
 171  *  gpr3 = (task_struct *) next
 172  * Returns:
 173  *  gpr2 = prev
 174  */
 175         .globl  __switch_to
 176 __switch_to:
 177         basr    %r1,0
 178 __switch_to_base:
 179         tm      __THREAD_per(%r3),0xe8          # new process is using per ?
 180         bz      __switch_to_noper-__switch_to_base(%r1) # if not we're fine
 181         stctl   %c9,%c11,24(%r15)               # We are using per stuff
 182         clc     __THREAD_per(12,%r3),24(%r15)
 183         be      __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
 184         lctl    %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 185 __switch_to_noper:
 186         stm     %r6,%r15,24(%r15)       # store __switch_to registers of prev task
 187         st      %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 188         l       %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 189         lm      %r6,%r15,24(%r15)       # load __switch_to registers of next task
 190         st      %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 191         l       %r3,__THREAD_info(%r3)  # load thread_info from task struct
 192         st      %r3,__LC_THREAD_INFO
 193         ahi     %r3,8192
 194         st      %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 195         br      %r14
 196
 197 /*
 198  * do_softirq calling function. We want to run the softirq functions on the
 199  * asynchronous interrupt stack.
 200  */
 201         .global do_call_softirq
 202 do_call_softirq:
 203         stnsm   24(%r15),0xfc
 204         stm     %r12,%r15,28(%r15)
 205         lr      %r12,%r15
 206         basr    %r13,0
 207 do_call_base:
 208         l       %r0,__LC_ASYNC_STACK
 209         slr     %r0,%r15
 210         sra     %r0,13
 211         be      0f-do_call_base(%r13)
 212         l       %r15,__LC_ASYNC_STACK
 213 0:      sl      %r15,.Lc_overhead-do_call_base(%r13)
 214         st      %r12,0(%r15)    # store backchain
 215         l       %r1,.Ldo_softirq-do_call_base(%r13)
 216         basr    %r14,%r1
 217         lm      %r12,%r15,28(%r12)
 218         ssm     24(%r15)
 219         br      %r14
 220
 221 __critical_start:
 222 /*
 223  * SVC interrupt handler routine. System calls are synchronous events and
 224  * are executed with interrupts enabled.
 225  */
 226
 227         .globl  system_call
 228 system_call:
 229         SAVE_ALL_BASE __LC_SVC_OLD_PSW,__LC_SAVE_AREA,1
 230         SAVE_ALL __LC_SVC_OLD_PSW,__LC_SAVE_AREA,1
 231         lh      %r7,0x8a          # get svc number from lowcore
 232 sysc_enter:
 233         GET_THREAD_INFO           # load pointer to task_struct to R9
 234 sysc_do_svc:
 235         sla     %r7,2             # *4 and test for svc 0
 236         bnz     BASED(sysc_nr_ok) # svc number > 0
 237         # svc 0: system call number in %r1
 238         cl      %r1,BASED(.Lnr_syscalls)
 239         bnl     BASED(sysc_nr_ok)
 240         lr      %r7,%r1           # copy svc number to %r7
 241         sla     %r7,2             # *4
 242 sysc_nr_ok:
 243         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 244 sysc_do_restart:
 245         tm      __TI_flags+3(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 246         l       %r8,sys_call_table-system_call(%r7,%r13) # get system call addr.
 247         bnz     BASED(sysc_tracesys)
 248         basr    %r14,%r8          # call sys_xxxx
 249         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 250                                   # ATTENTION: check sys_execve_glue before
 251                                   # changing anything here !!
 252
 253 sysc_return:
 254         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 255         bno     BASED(sysc_leave)
 256         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 257         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
 258 sysc_leave:
 259         RESTORE_ALL
 260
 261 #
 262 # recheck if there is more work to do
 263 #
 264 sysc_work_loop:
 265         GET_THREAD_INFO           # load pointer to task_struct to R9
 266         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 267         bz      BASED(sysc_leave)      # there is no work to do
 268 #
 269 # One of the work bits is on. Find out which one.
 270 #
 271 sysc_work:
 272         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 273         bo      BASED(sysc_reschedule)
 274         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 275         bo      BASED(sysc_sigpending)
 276         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 277         bo      BASED(sysc_restart)
 278         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 279         bo      BASED(sysc_singlestep)
 280         b       BASED(sysc_leave)
 281
 282 #
 283 # _TIF_NEED_RESCHED is set, call schedule
 284 #
 285 sysc_reschedule:
 286         l       %r1,BASED(.Lschedule)
 287         la      %r14,BASED(sysc_work_loop)
 288         br      %r1                    # call scheduler
 289
 290 #
 291 # _TIF_SIGPENDING is set, call do_signal
 292 #
 293 sysc_sigpending:
 294         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 295         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 296         sr      %r3,%r3                # clear *oldset
 297         l       %r1,BASED(.Ldo_signal)
 298         basr    %r14,%r1               # call do_signal
 299         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 300         bo      BASED(sysc_restart)
 301         b       BASED(sysc_leave)      # out of here, do NOT recheck
 302
 303 #
 304 # _TIF_RESTART_SVC is set, set up registers and restart svc
 305 #
 306 sysc_restart:
 307         ni      __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 308         l       %r7,SP_R2(%r15)        # load new svc number
 309         sla     %r7,2
 310         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
 311         lm      %r2,%r6,SP_R2(%r15)    # load svc arguments
 312         b       BASED(sysc_do_restart) # restart svc
 313
 314 #
 315 # _TIF_SINGLE_STEP is set, call do_single_step
 316 #
 317 sysc_singlestep:
 318         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 319         mvi     SP_TRAP+1(%r15),0x28    # set trap indication to pgm check
 320         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 321         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 322         la      %r14,BASED(sysc_return) # load adr. of system return
 323         br      %r1                     # branch to do_single_step
 324
 325 __critical_end:
 326
 327 #
 328 # call trace before and after sys_call
 329 #
 330 sysc_tracesys:
 331         l       %r1,BASED(.Ltrace)
 332         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 333         la      %r3,0
 334         srl     %r7,2
 335         st      %r7,SP_R2(%r15)
 336         basr    %r14,%r1
 337         clc     SP_R2(4,%r15),BASED(.Lnr_syscalls)
 338         bnl     BASED(sysc_tracenogo)
 339         l       %r7,SP_R2(%r15)        # strace might have changed the
 340         sll     %r7,2                  #  system call
 341         l       %r8,sys_call_table-system_call(%r7,%r13)
 342 sysc_tracego:
 343         lm      %r3,%r6,SP_R3(%r15)
 344         l       %r2,SP_ORIG_R2(%r15)
 345         basr    %r14,%r8          # call sys_xxx
 346         st      %r2,SP_R2(%r15)   # store return value
 347 sysc_tracenogo:
 348         tm      __TI_flags+3(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 349         bz      BASED(sysc_return)
 350         l       %r1,BASED(.Ltrace)
 351         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 352         la      %r3,1
 353         la      %r14,BASED(sysc_return)
 354         br      %r1
 355
 356 #
 357 # a new process exits the kernel with ret_from_fork
 358 #
 359         .globl  ret_from_fork
 360 ret_from_fork:
 361         l       %r13,__LC_SVC_NEW_PSW+4
 362         GET_THREAD_INFO           # load pointer to task_struct to R9
 363         l       %r1,BASED(.Lschedtail)
 364         basr    %r14,%r1
 365         stosm   24(%r15),0x03     # reenable interrupts
 366         b       BASED(sysc_return)
 367
 368 #
 369 # clone, fork, vfork, exec and sigreturn need glue,
 370 # because they all expect pt_regs as parameter,
 371 # but are called with different parameter.
 372 # return-address is set up above
 373 #
 374 sys_clone_glue:
 375         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 376         l       %r1,BASED(.Lclone)
 377         br      %r1                   # branch to sys_clone
 378
 379 sys_fork_glue:
 380         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 381         l       %r1,BASED(.Lfork)
 382         br      %r1                   # branch to sys_fork
 383
 384 sys_vfork_glue:
 385         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 386         l       %r1,BASED(.Lvfork)
 387         br      %r1                   # branch to sys_vfork
 388
 389 sys_execve_glue:
 390         la      %r2,SP_PTREGS(%r15)   # load pt_regs
 391         l       %r1,BASED(.Lexecve)
 392         lr      %r12,%r14             # save return address
 393         basr    %r14,%r1              # call sys_execve
 394         ltr     %r2,%r2               # check if execve failed
 395         bnz     0(%r12)               # it did fail -> store result in gpr2
 396         b       4(%r12)               # SKIP ST 2,SP_R2(15) after BASR 14,8
 397                                       # in system_call/sysc_tracesys
 398
 399 sys_sigreturn_glue:
 400         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 401         l       %r1,BASED(.Lsigreturn)
 402         br      %r1                   # branch to sys_sigreturn
 403
 404 sys_rt_sigreturn_glue:
 405         la      %r2,SP_PTREGS(%r15)   # load pt_regs as parameter
 406         l       %r1,BASED(.Lrt_sigreturn)
 407         br      %r1                   # branch to sys_sigreturn
 408
 409 #
 410 # sigsuspend and rt_sigsuspend need pt_regs as an additional
 411 # parameter and they have to skip the store of %r2 into the
 412 # user register %r2 because the return value was set in
 413 # sigsuspend and rt_sigsuspend already and must not be overwritten!
 414 #
 415
 416 sys_sigsuspend_glue:
 417         lr      %r5,%r4               # move mask back
 418         lr      %r4,%r3               # move history1 parameter
 419         lr      %r3,%r2               # move history0 parameter
 420         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
 421         l       %r1,BASED(.Lsigsuspend)
 422         la      %r14,4(%r14)          # skip store of return value
 423         br      %r1                   # branch to sys_sigsuspend
 424
 425 sys_rt_sigsuspend_glue:
 426         lr      %r4,%r3               # move sigsetsize parameter
 427         lr      %r3,%r2               # move unewset parameter
 428         la      %r2,SP_PTREGS(%r15)   # load pt_regs as first parameter
 429         l       %r1,BASED(.Lrt_sigsuspend)
 430         la      %r14,4(%r14)          # skip store of return value
 431         br      %r1                   # branch to sys_rt_sigsuspend
 432
 433 sys_sigaltstack_glue:
 434         la      %r4,SP_PTREGS(%r15)   # load pt_regs as parameter
 435         l       %r1,BASED(.Lsigaltstack)
 436         br      %r1                   # branch to sys_sigreturn
 437
 438
 439 /*
 440  * Program check handler routine
 441  */
 442
 443         .globl  pgm_check_handler
 444 pgm_check_handler:
 445 /*
 446  * First we need to check for a special case:
 447  * Single stepping an instruction that disables the PER event mask will
 448  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 449  * For a single stepped SVC the program check handler gets control after
 450  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 451  * then handle the PER event. Therefore we update the SVC old PSW to point
 452  * to the pgm_check_handler and branch to the SVC handler after we checked
 453  * if we have to load the kernel stack register.
 454  * For every other possible cause for PER event without the PER mask set
 455  * we just ignore the PER event (FIXME: is there anything we have to do
 456  * for LPSW?).
 457  */
 458         SAVE_ALL_BASE __LC_PGM_OLD_PSW,__LC_SAVE_AREA,1
 459         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 460         bnz     BASED(pgm_per)           # got per exception -> special case
 461         SAVE_ALL __LC_PGM_OLD_PSW,__LC_SAVE_AREA,1
 462         l       %r3,__LC_PGM_ILC         # load program interruption code
 463         la      %r8,0x7f
 464         nr      %r8,%r3
 465 pgm_do_call:
 466         l       %r7,BASED(.Ljump_table)
 467         sll     %r8,2
 468         GET_THREAD_INFO
 469         l       %r7,0(%r8,%r7)           # load address of handler routine
 470         la      %r2,SP_PTREGS(%r15)      # address of register-save area
 471         la      %r14,BASED(sysc_return)
 472         br      %r7                      # branch to interrupt-handler
 473
 474 #
 475 # handle per exception
 476 #
 477 pgm_per:
 478         tm      __LC_PGM_OLD_PSW,0x40    # test if per event recording is on
 479         bnz     BASED(pgm_per_std)       # ok, normal per event from user space
 480 # ok its one of the special cases, now we need to find out which one
 481         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
 482         be      BASED(pgm_svcper)
 483 # no interesting special case, ignore PER event
 484         lm      %r13,%r15,__LC_SAVE_AREA
 485         lpsw    0x28
 486
 487 #
 488 # Normal per exception
 489 #
 490 pgm_per_std:
 491         SAVE_ALL __LC_PGM_OLD_PSW,__LC_SAVE_AREA,1
 492         GET_THREAD_INFO
 493         l       %r1,__TI_task(%r9)
 494         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 495         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 496         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 497         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 498         l       %r3,__LC_PGM_ILC         # load program interruption code
 499         la      %r8,0x7f
 500         nr      %r8,%r3                  # clear per-event-bit and ilc
 501         be      BASED(sysc_return)       # only per or per+check ?
 502         b       BASED(pgm_do_call)
 503
 504 #
 505 # it was a single stepped SVC that is causing all the trouble
 506 #
 507 pgm_svcper:
 508         SAVE_ALL __LC_SVC_OLD_PSW,__LC_SAVE_AREA,1
 509         lh      %r7,0x8a                # get svc number from lowcore
 510         GET_THREAD_INFO                 # load pointer to task_struct to R9
 511         l       %r1,__TI_task(%r9)
 512         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 513         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 514         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 515         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 516         stosm   24(%r15),0x03           # reenable interrupts
 517         b       BASED(sysc_do_svc)
 518
 519 /*
 520  * IO interrupt handler routine
 521  */
 522
 523         .globl io_int_handler
 524 io_int_handler:
 525         SAVE_ALL_BASE __LC_IO_OLD_PSW,__LC_SAVE_AREA+16,0
 526         SAVE_ALL __LC_IO_OLD_PSW,__LC_SAVE_AREA+16,0
 527         stck    __LC_INT_CLOCK
 528         CHECK_CRITICAL
 529         GET_THREAD_INFO           # load pointer to task_struct to R9
 530         l       %r1,BASED(.Ldo_IRQ)        # load address of do_IRQ
 531         la      %r2,SP_PTREGS(%r15) # address of register-save area
 532         basr    %r14,%r1          # branch to standard irq handler
 533
 534 io_return:
 535         tm      SP_PSW+1(%r15),0x01    # returning to user ?
 536 #ifdef CONFIG_PREEMPT
 537         bno     BASED(io_preempt)      # no -> check for preemptive scheduling
 538 #else
 539         bno     BASED(io_leave)        # no-> skip resched & signal
 540 #endif
 541         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 542         bnz     BASED(io_work)         # there is work to do (signals etc.)
 543 io_leave:
 544         RESTORE_ALL
 545
 546 #ifdef CONFIG_PREEMPT
 547 io_preempt:
 548         icm     %r0,15,__TI_precount(%r9)
 549         bnz     BASED(io_leave)
 550         l       %r1,SP_R15(%r15)
 551         s       %r1,BASED(.Lc_spsize)
 552         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 553         xc      0(4,%r1),0(%r1)        # clear back chain
 554         lr      %r15,%r1
 555 io_resume_loop:
 556         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 557         bno     BASED(io_leave)
 558         mvc     __TI_precount(4,%r9),BASED(.Lc_pactive)
 559         stosm   24(%r15),0x03          # reenable interrupts
 560         l       %r1,BASED(.Lschedule)
 561         basr    %r14,%r1               # call schedule
 562         stnsm   24(%r15),0xfc          # disable I/O and ext. interrupts
 563         GET_THREAD_INFO                # load pointer to task_struct to R9
 564         xc      __TI_precount(4,%r9),__TI_precount(%r9)
 565         b       BASED(io_resume_loop)
 566 #endif
 567
 568 #
 569 # switch to kernel stack, then check the TIF bits
 570 #
 571 io_work:
 572         l       %r1,__LC_KERNEL_STACK
 573         s       %r1,BASED(.Lc_spsize)
 574         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 575         xc      0(4,%r1),0(%r1)        # clear back chain
 576         lr      %r15,%r1
 577 #
 578 # One of the work bits is on. Find out which one.
 579 # Checked are: _TIF_SIGPENDING and _TIF_NEED_RESCHED
 580 #
 581 io_work_loop:
 582         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 583         bo      BASED(io_reschedule)
 584         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 585         bo      BASED(io_sigpending)
 586         b       BASED(io_leave)
 587
 588 #
 589 # _TIF_NEED_RESCHED is set, call schedule
 590 #
 591 io_reschedule:
 592         l       %r1,BASED(.Lschedule)
 593         stosm   24(%r15),0x03          # reenable interrupts
 594         basr    %r14,%r1               # call scheduler
 595         stnsm   24(%r15),0xfc          # disable I/O and ext. interrupts
 596         GET_THREAD_INFO                # load pointer to task_struct to R9
 597         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 598         bz      BASED(io_leave)        # there is no work to do
 599         b       BASED(io_work_loop)
 600
 601 #
 602 # _TIF_SIGPENDING is set, call do_signal
 603 #
 604 io_sigpending:
 605         stosm   24(%r15),0x03          # reenable interrupts
 606         la      %r2,SP_PTREGS(%r15)    # load pt_regs
 607         sr      %r3,%r3                # clear *oldset
 608         l       %r1,BASED(.Ldo_signal)
 609         basr    %r14,%r1               # call do_signal
 610         stnsm   24(%r15),0xfc          # disable I/O and ext. interrupts
 611         b       BASED(io_leave)        # out of here, do NOT recheck
 612
 613 /*
 614  * External interrupt handler routine
 615  */
 616
 617         .globl  ext_int_handler
 618 ext_int_handler:
 619         SAVE_ALL_BASE __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16,0
 620         SAVE_ALL __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16,0
 621         stck    __LC_INT_CLOCK
 622         CHECK_CRITICAL
 623         GET_THREAD_INFO                # load pointer to task_struct to R9
 624         la      %r2,SP_PTREGS(%r15)    # address of register-save area
 625         lh      %r3,__LC_EXT_INT_CODE  # get interruption code
 626         l       %r1,BASED(.Ldo_extint)
 627         basr    %r14,%r1
 628         b       BASED(io_return)
 629
 630 /*
 631  * Machine check handler routines
 632  */
 633
 634         .globl mcck_int_handler
 635 mcck_int_handler:
 636         SAVE_ALL_BASE __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32,0
 637         SAVE_ALL __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32,0
 638         l       %r1,BASED(.Ls390_mcck)
 639         basr    %r14,%r1          # call machine check handler
 640 mcck_return:
 641         RESTORE_ALL
 642
 643 #ifdef CONFIG_SMP
 644 /*
 645  * Restart interruption handler, kick starter for additional CPUs
 646  */
 647         .globl restart_int_handler
 648 restart_int_handler:
 649         l       %r15,__LC_SAVE_AREA+60 # load ksp
 650         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
 651         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
 652         stosm   0(%r15),0x04           # now we can turn dat on
 653         lm      %r6,%r15,24(%r15)      # load registers from clone
 654         basr    %r14,0
 655         l       %r14,restart_addr-.(%r14)
 656         br      %r14                   # branch to start_secondary
 657 restart_addr:
 658         .long   start_secondary
 659 #else
 660 /*
 661  * If we do not run with SMP enabled, let the new CPU crash ...
 662  */
 663         .globl restart_int_handler
 664 restart_int_handler:
 665         basr    %r1,0
 666 restart_base:
 667         lpsw    restart_crash-restart_base(%r1)
 668         .align 8
 669 restart_crash:
 670         .long  0x000a0000,0x00000000
 671 restart_go:
 672 #endif
 673
 674 cleanup_table:
 675         .long   system_call, sysc_enter, cleanup_sysc_enter
 676         .long   sysc_return, sysc_leave, cleanup_sysc_return
 677         .long   sysc_leave, sysc_work_loop, cleanup_sysc_leave
 678         .long   sysc_work_loop, sysc_reschedule, cleanup_sysc_return
 679 cleanup_table_entries=(.-cleanup_table) / 12
 680
 681 cleanup_critical:
 682         lhi     %r0,cleanup_table_entries
 683         la      %r1,BASED(cleanup_table)
 684         l       %r2,SP_PSW+4(%r15)
 685         la      %r2,0(%r2)
 686 cleanup_loop:
 687         cl      %r2,0(%r1)
 688         bl      BASED(cleanup_cont)
 689         cl      %r2,4(%r1)
 690         bl      BASED(cleanup_found)
 691 cleanup_cont:
 692         la      %r1,12(%r1)
 693         bct     %r0,BASED(cleanup_loop)
 694         br      %r14
 695 cleanup_found:
 696         l       %r1,8(%r1)
 697         br      %r1
 698
 699 cleanup_sysc_enter:
 700         CLEANUP_SAVE_ALL_BASE __LC_SVC_OLD_PSW,__LC_SAVE_AREA,1
 701         CLEANUP_SAVE_ALL __LC_SVC_OLD_PSW,__LC_SAVE_AREA,1
 702         lh      %r0,0x8a
 703         st      %r0,SP_R7(%r15)
 704         la      %r1,BASED(sysc_enter)
 705         o       %r1,BASED(.Lamode)
 706         st      %r1,SP_PSW+4(%r15)
 707         br      %r14
 708
 709 cleanup_sysc_return:
 710         la      %r1,BASED(sysc_return)
 711         o       %r1,BASED(.Lamode)
 712         st      %r1,SP_PSW+4(%r15)
 713         br      %r14
 714
 715 cleanup_sysc_leave:
 716         CLEANUP_RESTORE_ALL
 717         br      %r14
 718
 719 /*
 720  * Integer constants
 721  */
 722                .align 4
 723 .Lc_spsize:    .long  SP_SIZE
 724 .Lc_overhead:  .long  STACK_FRAME_OVERHEAD
 725 .Lc_pactive:   .long  PREEMPT_ACTIVE
 726 .Lnr_syscalls: .long  NR_syscalls
 727 .L0x018:       .long  0x018
 728 .L0x020:       .long  0x020
 729 .L0x028:       .long  0x028
 730 .L0x030:       .long  0x030
 731 .L0x038:       .long  0x038
 732 .Lamode:       .long  0x80000000
 733
 734 /*
 735  * Symbol constants
 736  */
 737 .Ls390_mcck:   .long  s390_do_machine_check
 738 .Ldo_IRQ:      .long  do_IRQ
 739 .Ldo_extint:   .long  do_extint
 740 .Ldo_signal:   .long  do_signal
 741 .Ldo_softirq:  .long  do_softirq
 742 .Lhandle_per:  .long  do_single_step
 743 .Ljump_table:  .long  pgm_check_table
 744 .Lschedule:    .long  schedule
 745 .Lclone:       .long  sys_clone
 746 .Lexecve:      .long  sys_execve
 747 .Lfork:        .long  sys_fork
 748 .Lrt_sigreturn:.long  sys_rt_sigreturn
 749 .Lrt_sigsuspend:
 750                .long  sys_rt_sigsuspend
 751 .Lsigreturn:   .long  sys_sigreturn
 752 .Lsigsuspend:  .long  sys_sigsuspend
 753 .Lsigaltstack: .long  sys_sigaltstack
 754 .Ltrace:       .long  syscall_trace
 755 .Lvfork:       .long  sys_vfork
 756 .Lschedtail:   .long  schedule_tail
 757
 758 .Lcritical_start:
 759                .long  __critical_start + 0x80000000
 760 .Lcritical_end:
 761                .long  __critical_end + 0x80000000
 762 .Lcleanup_critical:
 763                .long  cleanup_critical
 764
 765 #define SYSCALL(esa,esame,emu)  .long esa
 766         .globl  sys_call_table
 767 sys_call_table:
 768 #include "syscalls.S"
 769 #undef SYSCALL
 770