arch/sh/kernel/entry.S

   1 /* $Id: entry.S,v 1.35 2004/02/21 14:45:47 lethal Exp $
   2  *
   3  *  linux/arch/sh/entry.S
   4  *
   5  *  Copyright (C) 1999, 2000, 2002  Niibe Yutaka
   6  *  Copyright (C) 2003  Paul Mundt
   7  *
   8  * This file is subject to the terms and conditions of the GNU General Public
   9  * License.  See the file "COPYING" in the main directory of this archive
  10  * for more details.
  11  *
  12  */
  13
  14 #include <linux/sys.h>
  15 #include <linux/linkage.h>
  16 #include <linux/config.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/unistd.h>
  19
  20 #if !defined(CONFIG_NFSD) && !defined(CONFIG_NFSD_MODULE)
  21 #define sys_nfsservctl          sys_ni_syscall
  22 #endif
  23
  24 #if !defined(CONFIG_MMU)
  25 #define sys_madvise             sys_ni_syscall
  26 #define sys_readahead           sys_ni_syscall
  27 #define sys_mprotect            sys_ni_syscall
  28 #define sys_msync               sys_ni_syscall
  29 #define sys_mlock               sys_ni_syscall
  30 #define sys_munlock             sys_ni_syscall
  31 #define sys_mlockall            sys_ni_syscall
  32 #define sys_munlockall          sys_ni_syscall
  33 #define sys_mremap              sys_ni_syscall
  34 #define sys_mincore             sys_ni_syscall
  35 #define sys_remap_file_pages    sys_ni_syscall
  36 #endif
  37
  38 ! NOTE:
  39 ! GNU as (as of 2.9.1) changes bf/s into bt/s and bra, when the address
  40 ! to be jumped is too far, but it causes illegal slot exception.
  41
  42 /*
  43  * entry.S contains the system-call and fault low-level handling routines.
  44  * This also contains the timer-interrupt handler, as well as all interrupts
  45  * and faults that can result in a task-switch.
  46  *
  47  * NOTE: This code handles signal-recognition, which happens every time
  48  * after a timer-interrupt and after each system call.
  49  *
  50  * NOTE: This code uses a convention that instructions in the delay slot
  51  * of a transfer-control instruction are indented by an extra space, thus:
  52  *
  53  *    jmp       @k0         ! control-transfer instruction
  54  *     ldc      k1, ssr     ! delay slot
  55  *
  56  * Stack layout in 'ret_from_syscall':
  57  *      ptrace needs to have all regs on the stack.
  58  *      if the order here is changed, it needs to be
  59  *      updated in ptrace.c and ptrace.h
  60  *
  61  *      r0
  62  *      ...
  63  *      r15 = stack pointer
  64  *      spc
  65  *      pr
  66  *      ssr
  67  *      gbr
  68  *      mach
  69  *      macl
  70  *      syscall #
  71  *
  72  */
  73
  74 ENOSYS = 38
  75 EINVAL = 22
  76
  77 #if defined(CONFIG_CPU_SH3)
  78 TRA     = 0xffffffd0
  79 EXPEVT  = 0xffffffd4
  80 #if defined(CONFIG_CPU_SUBTYPE_SH7707) || defined(CONFIG_CPU_SUBTYPE_SH7709)
  81 INTEVT  = 0xa4000000            ! INTEVTE2(0xa4000000)
  82 #else
  83 INTEVT  = 0xffffffd8
  84 #endif
  85 MMU_TEA = 0xfffffffc            ! TLB Exception Address Register
  86 #elif defined(CONFIG_CPU_SH4)
  87 TRA     = 0xff000020
  88 EXPEVT  = 0xff000024
  89 INTEVT  = 0xff000028
  90 MMU_TEA = 0xff00000c            ! TLB Exception Address Register
  91 #endif
  92
  93 #if defined(CONFIG_KGDB_NMI)
  94 NMI_VEC = 0x1c0                 ! Must catch early for debounce
  95 #endif
  96
  97 /* Offsets to the stack */
  98 OFF_R0  =  0            /* Return value. New ABI also arg4 */
  99 OFF_R1  =  4            /* New ABI: arg5 */
 100 OFF_R2  =  8            /* New ABI: arg6 */
 101 OFF_R3  =  12           /* New ABI: syscall_nr */
 102 OFF_R4  =  16           /* New ABI: arg0 */
 103 OFF_R5  =  20           /* New ABI: arg1 */
 104 OFF_R6  =  24           /* New ABI: arg2 */
 105 OFF_R7  =  28           /* New ABI: arg3 */
 106 OFF_SP  =  (15*4)
 107 OFF_PC  =  (16*4)
 108 OFF_SR  =  (16*4+8)
 109 OFF_TRA =  (16*4+6*4)
 110
 111
 112 #define k0      r0
 113 #define k1      r1
 114 #define k2      r2
 115 #define k3      r3
 116 #define k4      r4
 117
 118 #define k_ex_code       r2_bank /* r2_bank1 */
 119 #define g_imask         r6      /* r6_bank1 */
 120 #define k_g_imask       r6_bank /* r6_bank1 */
 121 #define current         r7      /* r7_bank1 */
 122
 123 /*
 124  * Kernel mode register usage:
 125  *      k0      scratch
 126  *      k1      scratch
 127  *      k2      scratch (Exception code)
 128  *      k3      scratch (Return address)
 129  *      k4      scratch
 130  *      k5      reserved
 131  *      k6      Global Interrupt Mask (0--15 << 4)
 132  *      k7      CURRENT_THREAD_INFO (pointer to current thread info)
 133  */
 134
 135 !
 136 ! TLB Miss / Initial Page write exception handling
 137 !                       _and_
 138 ! TLB hits, but the access violate the protection.
 139 ! It can be valid access, such as stack grow and/or C-O-W.
 140 !
 141 !
 142 ! Find the pmd/pte entry and loadtlb
 143 ! If it's not found, cause address error (SEGV)
 144 !
 145 ! Although this could be written in assembly language (and it'd be faster),
 146 ! this first version depends *much* on C implementation.
 147 !
 148
 149 #define CLI()                           \
 150         stc     sr, r0;                 \
 151         or      #0xf0, r0;              \
 152         ldc     r0, sr
 153
 154 #define STI()                           \
 155         mov.l   __INV_IMASK, r11;       \
 156         stc     sr, r10;                \
 157         and     r11, r10;               \
 158         stc     k_g_imask, r11;         \
 159         or      r11, r10;               \
 160         ldc     r10, sr
 161
 162 #if defined(CONFIG_PREEMPT)
 163 #  define preempt_stop()        CLI()
 164 #else
 165 #  define preempt_stop()
 166 #  define resume_kernel         restore_all
 167 #endif
 168
 169 #if defined(CONFIG_MMU)
 170         .align  2
 171 ENTRY(tlb_miss_load)
 172         bra     call_dpf
 173          mov    #0, r5
 174
 175         .align  2
 176 ENTRY(tlb_miss_store)
 177         bra     call_dpf
 178          mov    #1, r5
 179
 180         .align  2
 181 ENTRY(initial_page_write)
 182         bra     call_dpf
 183          mov    #1, r5
 184
 185         .align  2
 186 ENTRY(tlb_protection_violation_load)
 187         bra     call_dpf
 188          mov    #0, r5
 189
 190         .align  2
 191 ENTRY(tlb_protection_violation_store)
 192         bra     call_dpf
 193          mov    #1, r5
 194
 195 call_dpf:
 196         mov.l   1f, r0
 197         mov     r5, r8
 198         mov.l   @r0, r6
 199         mov     r6, r9
 200         mov.l   2f, r0
 201         sts     pr, r10
 202         jsr     @r0
 203          mov    r15, r4
 204         !
 205         tst     r0, r0
 206         bf/s    0f
 207          lds    r10, pr
 208         rts
 209          nop
 210 0:      STI()
 211         mov.l   3f, r0
 212         mov     r9, r6
 213         mov     r8, r5
 214         jmp     @r0
 215          mov    r15, r4
 216
 217         .align 2
 218 1:      .long   MMU_TEA
 219 2:      .long   __do_page_fault
 220 3:      .long   do_page_fault
 221
 222         .align  2
 223 ENTRY(address_error_load)
 224         bra     call_dae
 225          mov    #0,r5           ! writeaccess = 0
 226
 227         .align  2
 228 ENTRY(address_error_store)
 229         bra     call_dae
 230          mov    #1,r5           ! writeaccess = 1
 231
 232         .align  2
 233 call_dae:
 234         mov.l   1f, r0
 235         mov.l   @r0, r6         ! address
 236         mov.l   2f, r0
 237         jmp     @r0
 238          mov    r15, r4         ! regs
 239
 240         .align 2
 241 1:      .long   MMU_TEA
 242 2:      .long   do_address_error
 243 #endif /* CONFIG_MMU */
 244
 245 #if defined(CONFIG_SH_STANDARD_BIOS) || defined(CONFIG_SH_KGDB)
 246 ! Handle kernel debug if either kgdb (SW) or gdb-stub (FW) is present.
 247 ! If both are configured, handle the debug traps (breakpoints) in SW,
 248 ! but still allow BIOS traps to FW.
 249
 250         .align  2
 251 debug_kernel:
 252 #if defined(CONFIG_SH_STANDARD_BIOS) && defined(CONFIG_SH_KGDB)
 253         /* Force BIOS call to FW (debug_trap put TRA in r8) */
 254         mov     r8,r0
 255         shlr2   r0
 256         cmp/eq  #0x3f,r0
 257         bt      debug_kernel_fw
 258 #endif /* CONFIG_SH_STANDARD_BIOS && CONFIG_SH_KGDB */
 259
 260 debug_enter:
 261 #if defined(CONFIG_SH_KGDB)
 262         /* Jump to kgdb, pass stacked regs as arg */
 263 debug_kernel_sw:
 264         mov.l   3f, r0
 265         jmp     @r0
 266          mov    r15, r4
 267         .align  2
 268 3:      .long   kgdb_handle_exception
 269 #endif /* CONFIG_SH_KGDB */
 270
 271 #if defined(CONFIG_SH_STANDARD_BIOS)
 272         /* Unwind the stack and jmp to the debug entry */
 273 debug_kernel_fw:
 274         mov.l   @r15+, r0
 275         mov.l   @r15+, r1
 276         mov.l   @r15+, r2
 277         mov.l   @r15+, r3
 278         mov.l   @r15+, r4
 279         mov.l   @r15+, r5
 280         mov.l   @r15+, r6
 281         mov.l   @r15+, r7
 282         stc     sr, r8
 283         mov.l   1f, r9                  ! BL =1, RB=1, IMASK=0x0F
 284         or      r9, r8
 285         ldc     r8, sr                  ! here, change the register bank
 286         mov.l   @r15+, r8
 287         mov.l   @r15+, r9
 288         mov.l   @r15+, r10
 289         mov.l   @r15+, r11
 290         mov.l   @r15+, r12
 291         mov.l   @r15+, r13
 292         mov.l   @r15+, r14
 293         mov.l   @r15+, k0
 294         ldc.l   @r15+, spc
 295         lds.l   @r15+, pr
 296         mov.l   @r15+, k1
 297         ldc.l   @r15+, gbr
 298         lds.l   @r15+, mach
 299         lds.l   @r15+, macl
 300         mov     k0, r15
 301         !
 302         mov.l   2f, k0
 303         mov.l   @k0, k0
 304         jmp     @k0
 305          ldc    k1, ssr
 306         .align  2
 307 1:      .long   0x300000f0
 308 2:      .long   gdb_vbr_vector
 309 #endif /* CONFIG_SH_STANDARD_BIOS */
 310
 311 #endif /* CONFIG_SH_STANDARD_BIOS || CONFIG_SH_KGDB */
 312
 313
 314         .align  2
 315 debug_trap:
 316 #if defined(CONFIG_SH_STANDARD_BIOS) || defined(CONFIG_SH_KGDB)
 317         mov     #OFF_SR, r0
 318         mov.l   @(r0,r15), r0           ! get status register
 319         shll    r0
 320         shll    r0                      ! kernel space?
 321         bt/s    debug_kernel
 322 #endif
 323          mov.l  @r15, r0                ! Restore R0 value
 324         mov.l   1f, r8
 325         jmp     @r8
 326          nop
 327
 328         .align  2
 329 ENTRY(exception_error)
 330         !
 331         STI()
 332         mov.l   2f, r0
 333         jmp     @r0
 334          nop
 335
 336 !
 337         .align  2
 338 1:      .long   break_point_trap_software
 339 2:      .long   do_exception_error
 340
 341         .align  2
 342 ret_from_exception:
 343         preempt_stop()
 344 ret_from_irq:
 345         !
 346         mov     #OFF_SR, r0
 347         mov.l   @(r0,r15), r0   ! get status register
 348         shll    r0
 349         shll    r0              ! kernel space?
 350         bt/s    resume_kernel   ! Yes, it's from kernel, go back soon
 351          GET_THREAD_INFO(r8)
 352
 353 #ifdef CONFIG_PREEMPT
 354         bra     resume_userspace
 355          nop
 356 ENTRY(resume_kernel)
 357         mov.l   @(TI_PRE_COUNT,r8), r0  ! current_thread_info->preempt_count
 358         tst     r0, r0
 359         bf      noresched
 360 need_resched:
 361         mov.l   @(TI_FLAGS,r8), r0      ! current_thread_info->flags
 362         tst     #_TIF_NEED_RESCHED, r0  ! need_resched set?
 363         bt      noresched
 364
 365         mov     #OFF_SR, r0
 366         mov.l   @(r0,r15), r0           ! get status register
 367         and     #0xf0, r0               ! interrupts off (exception path)?
 368         cmp/eq  #0xf0, r0
 369         bt      noresched
 370
 371         mov.l   1f, r0
 372         mov.l   r0, @(TI_PRE_COUNT,r8)
 373
 374         STI()
 375         mov.l   2f, r0
 376         jsr     @r0
 377          nop
 378         mov     #0, r0
 379         mov.l   r0, @(TI_PRE_COUNT,r8)
 380         CLI()
 381
 382         bra     need_resched
 383          nop
 384 noresched:
 385         bra     restore_all
 386          nop
 387
 388         .align 2
 389 1:      .long   PREEMPT_ACTIVE
 390 2:      .long   schedule
 391 #endif
 392
 393 ENTRY(resume_userspace)
 394         ! r8: current_thread_info
 395         CLI()
 396         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 397         tst     #_TIF_WORK_MASK, r0
 398         bt/s    restore_all
 399          tst    #_TIF_NEED_RESCHED, r0
 400
 401         .align  2
 402 work_pending:
 403         ! r0: current_thread_info->flags
 404         ! r8: current_thread_info
 405         ! t:  result of "tst    #_TIF_NEED_RESCHED, r0"
 406         bf/s    work_resched
 407          tst    #_TIF_SIGPENDING, r0
 408 work_notifysig:
 409         bt/s    restore_all
 410          mov    r15, r4
 411         mov     #0, r5
 412         mov.l   2f, r1
 413         mova    restore_all, r0
 414         jmp     @r1
 415          lds    r0, pr
 416 work_resched:
 417 #ifndef CONFIG_PREEMPT
 418         ! gUSA handling
 419         mov.l   @(OFF_SP,r15), r0       ! get user space stack pointer
 420         mov     r0, r1
 421         shll    r0
 422         bf/s    1f
 423          shll   r0
 424         bf/s    1f
 425          mov    #OFF_PC, r0
 426         !                                 SP >= 0xc0000000 : gUSA mark
 427         mov.l   @(r0,r15), r2           ! get user space PC (program counter)
 428         mov.l   @(OFF_R0,r15), r3       ! end point
 429         cmp/hs  r3, r2                  ! r2 >= r3?
 430         bt      1f
 431         add     r3, r1                  ! rewind point #2
 432         mov.l   r1, @(r0,r15)           ! reset PC to rewind point #2
 433         !
 434 1:
 435 #endif
 436         mov.l   1f, r1
 437         jsr     @r1                             ! schedule
 438          nop
 439         CLI()
 440         !
 441         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 442         tst     #_TIF_WORK_MASK, r0
 443         bt      restore_all
 444         bra     work_pending
 445          tst    #_TIF_NEED_RESCHED, r0
 446
 447         .align  2
 448 1:      .long   schedule
 449 2:      .long   do_signal
 450
 451         .align  2
 452 syscall_exit_work:
 453         ! r0: current_thread_info->flags
 454         ! r8: current_thread_info
 455         tst     #_TIF_SYSCALL_TRACE, r0
 456         bt/s    work_pending
 457          tst    #_TIF_NEED_RESCHED, r0
 458         STI()
 459         ! XXX setup arguments...
 460         mov.l   4f, r0                  ! do_syscall_trace
 461         jsr     @r0
 462          nop
 463         bra     resume_userspace
 464          nop
 465
 466         .align  2
 467 syscall_trace_entry:
 468         !                       Yes it is traced.
 469         ! XXX setup arguments...
 470         mov.l   4f, r11         ! Call do_syscall_trace which notifies
 471         jsr     @r11            ! superior (will chomp R[0-7])
 472          nop
 473         !                       Reload R0-R4 from kernel stack, where the
 474         !                       parent may have modified them using
 475         !                       ptrace(POKEUSR).  (Note that R0-R2 are
 476         !                       used by the system call handler directly
 477         !                       from the kernel stack anyway, so don't need
 478         !                       to be reloaded here.)  This allows the parent
 479         !                       to rewrite system calls and args on the fly.
 480         mov.l   @(OFF_R4,r15), r4   ! arg0
 481         mov.l   @(OFF_R5,r15), r5
 482         mov.l   @(OFF_R6,r15), r6
 483         mov.l   @(OFF_R7,r15), r7   ! arg3
 484         mov.l   @(OFF_R3,r15), r3   ! syscall_nr
 485         !                   Arrange for do_syscall_trace to be called
 486         !                   again as the system call returns.
 487         mov.l   2f, r10                 ! Number of syscalls
 488         cmp/hs  r10, r3
 489         bf      syscall_call
 490         mov     #-ENOSYS, r0
 491         bra     syscall_exit
 492          mov.l  r0, @(OFF_R0,r15)       ! Return value
 493
 494 /*
 495  * Syscall interface:
 496  *
 497  *      Syscall #: R3
 498  *      Arguments #0 to #3: R4--R7
 499  *      Arguments #4 to #6: R0, R1, R2
 500  *      TRA: (number of arguments + 0x10) x 4
 501  *
 502  * This code also handles delegating other traps to the BIOS/gdb stub
 503  * according to:
 504  *
 505  * Trap number
 506  * (TRA>>2)         Purpose
 507  * --------         -------
 508  * 0x0-0xf          old syscall ABI
 509  * 0x10-0x1f        new syscall ABI
 510  * 0x20-0xff        delegated through debug_trap to BIOS/gdb stub.
 511  *
 512  * Note: When we're first called, the TRA value must be shifted
 513  * right 2 bits in order to get the value that was used as the "trapa"
 514  * argument.
 515  */
 516
 517         .align  2
 518         .globl  ret_from_fork
 519 ret_from_fork:
 520         mov.l   1f, r8
 521         jsr     @r8
 522          mov    r0, r4
 523         bra     syscall_exit
 524          nop
 525         .align  2
 526 1:      .long   schedule_tail
 527         !
 528 ENTRY(system_call)
 529         mov.l   1f, r9
 530         mov.l   @r9, r8         ! Read from TRA (Trap Address) Register
 531         !
 532         ! Is the trap argument >= 0x20? (TRA will be >= 0x80)
 533         mov     #0x7f, r9
 534         cmp/hi  r9, r8
 535         bt/s    0f
 536          mov    #OFF_TRA, r9
 537         add     r15, r9
 538         !
 539         mov.l   r8, @r9                 ! set TRA value to tra
 540         STI()
 541         !                   Call the system call handler through the table.
 542         !                   First check for bad syscall number
 543         mov     r3, r9
 544         mov.l   2f, r8                  ! Number of syscalls
 545         cmp/hs  r8, r9
 546         bf/s    good_system_call
 547          GET_THREAD_INFO(r8)
 548 syscall_badsys:                 ! Bad syscall number
 549         mov     #-ENOSYS, r0
 550         bra     resume_userspace
 551          mov.l  r0, @(OFF_R0,r15)       ! Return value
 552         !
 553 0:
 554         bra     debug_trap
 555          nop
 556         !
 557 good_system_call:               ! Good syscall number
 558         mov.l   @(TI_FLAGS,r8), r8
 559         mov     #_TIF_SYSCALL_TRACE, r10
 560         tst     r10, r8
 561         bf      syscall_trace_entry
 562         !
 563 syscall_call:
 564         shll2   r9              ! x4
 565         mov.l   3f, r8          ! Load the address of sys_call_table
 566         add     r8, r9
 567         mov.l   @r9, r8
 568         jsr     @r8             ! jump to specific syscall handler
 569          nop
 570         mov.l   r0, @(OFF_R0,r15)               ! save the return value
 571         !
 572 syscall_exit:
 573         CLI()
 574         !
 575         GET_THREAD_INFO(r8)
 576         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 577         tst     #_TIF_ALLWORK_MASK, r0
 578         bf      syscall_exit_work
 579 restore_all:
 580         mov.l   @r15+, r0
 581         mov.l   @r15+, r1
 582         mov.l   @r15+, r2
 583         mov.l   @r15+, r3
 584         mov.l   @r15+, r4
 585         mov.l   @r15+, r5
 586         mov.l   @r15+, r6
 587         mov.l   @r15+, r7
 588         !
 589         stc     sr, r8
 590         mov.l   7f, r9
 591         or      r9, r8                  ! BL =1, RB=1
 592         ldc     r8, sr                  ! here, change the register bank
 593         !
 594         mov.l   @r15+, r8
 595         mov.l   @r15+, r9
 596         mov.l   @r15+, r10
 597         mov.l   @r15+, r11
 598         mov.l   @r15+, r12
 599         mov.l   @r15+, r13
 600         mov.l   @r15+, r14
 601         mov.l   @r15+, k4               ! original stack pointer
 602         ldc.l   @r15+, spc
 603         lds.l   @r15+, pr
 604         mov.l   @r15+, k3               ! original SR
 605         ldc.l   @r15+, gbr
 606         lds.l   @r15+, mach
 607         lds.l   @r15+, macl
 608         add     #4, r15                 ! Skip syscall number
 609         !
 610 #ifdef CONFIG_SH_DSP
 611         mov.l   @r15+, k0               ! DSP mode marker
 612         mov.l   5f, k1
 613         cmp/eq  k0, k1                  ! Do we have a DSP stack frame?
 614         bf      skip_restore
 615
 616         stc     sr, k0                  ! Enable CPU DSP mode
 617         or      k1, k0                  ! (within kernel it may be disabled)
 618         ldc     k0, sr
 619         mov     r2, k0                  ! Backup r2
 620
 621         ! Restore DSP registers from stack
 622         mov     r15, r2
 623         movs.l  @r2+, a1
 624         movs.l  @r2+, a0g
 625         movs.l  @r2+, a1g
 626         movs.l  @r2+, m0
 627         movs.l  @r2+, m1
 628         mov     r2, r15
 629
 630         lds.l   @r15+, a0
 631         lds.l   @r15+, x0
 632         lds.l   @r15+, x1
 633         lds.l   @r15+, y0
 634         lds.l   @r15+, y1
 635         lds.l   @r15+, dsr
 636         ldc.l   @r15+, rs
 637         ldc.l   @r15+, re
 638         ldc.l   @r15+, mod
 639
 640         mov     k0, r2                  ! Restore r2
 641 skip_restore:
 642 #endif
 643         !
 644         ! Calculate new SR value
 645         mov     k3, k2                  ! original SR value
 646         mov.l   9f, k1
 647         and     k1, k2                  ! Mask orignal SR value
 648         !
 649         mov     k3, k0                  ! Calculate IMASK-bits
 650         shlr2   k0
 651         and     #0x3c, k0
 652         cmp/eq  #0x3c, k0
 653         bt/s    6f
 654          shll2  k0
 655         mov     g_imask, k0
 656         !
 657 6:      or      k0, k2                  ! Set the IMASK-bits
 658         ldc     k2, ssr
 659         !
 660 #if defined(CONFIG_KGDB_NMI)
 661         ! Clear in_nmi
 662         mov.l   4f, k0
 663         mov     #0, k1
 664         mov.b   k1, @k0
 665 #endif
 666         mov.l   @r15+, k2               ! restore EXPEVT
 667         mov     k4, r15
 668         rte
 669          nop
 670
 671         .align  2
 672 1:      .long   TRA
 673 2:      .long   NR_syscalls
 674 3:      .long   sys_call_table
 675 4:      .long   do_syscall_trace
 676 5:      .long   0x00001000      ! DSP
 677 7:      .long   0x30000000
 678 9:
 679 __INV_IMASK:
 680         .long   0xffffff0f      ! ~(IMASK)
 681
 682 ! Exception Vector Base
 683 !
 684 !       Should be aligned page boundary.
 685 !
 686         .balign         4096,0,4096
 687 ENTRY(vbr_base)
 688         .long   0
 689 !
 690         .balign         256,0,256
 691 general_exception:
 692         mov.l   1f, k2
 693         mov.l   2f, k3
 694         bra     handle_exception
 695          mov.l  @k2, k2
 696         .align  2
 697 1:      .long   EXPEVT
 698 2:      .long   ret_from_exception
 699 !
 700 !
 701         .balign         1024,0,1024
 702 tlb_miss:
 703         mov.l   1f, k2
 704         mov.l   4f, k3
 705         bra     handle_exception
 706          mov.l  @k2, k2
 707 !
 708         .balign         512,0,512
 709 interrupt:
 710         mov.l   2f, k2
 711         mov.l   3f, k3
 712 #if defined(CONFIG_KGDB_NMI)
 713         ! Debounce (filter nested NMI)
 714         mov.l   @k2, k0
 715         mov.l   5f, k1
 716         cmp/eq  k1, k0
 717         bf      0f
 718         mov.l   6f, k1
 719         tas.b   @k1
 720         bt      0f
 721         rte
 722          nop
 723         .align  2
 724 5:      .long   NMI_VEC
 725 6:      .long   in_nmi
 726 0:
 727 #endif /* defined(CONFIG_KGDB_NMI) */
 728         bra     handle_exception
 729          mov.l  @k2, k2
 730
 731         .align  2
 732 1:      .long   EXPEVT
 733 2:      .long   INTEVT
 734 3:      .long   ret_from_irq
 735 4:      .long   ret_from_exception
 736
 737 !
 738 !
 739         .align  2
 740 handle_exception:
 741         ! Using k0, k1 for scratch registers (r0_bank1, r1_bank),
 742         ! save all registers onto stack.
 743         !
 744         stc     ssr, k0         ! Is it from kernel space?
 745         shll    k0              ! Check MD bit (bit30) by shifting it into...
 746         shll    k0              !       ...the T bit
 747         bt/s    1f              ! It's a kernel to kernel transition.
 748          mov    r15, k0         ! save original stack to k0
 749         /* User space to kernel */
 750         mov     #0x20, k1
 751         shll8   k1              ! k1 := 8192 (== THREAD_SIZE)
 752         add     current, k1
 753         mov     k1, r15         ! change to kernel stack
 754         !
 755 1:      mov     #-1, k4
 756         mov.l   2f, k1
 757         !
 758 #ifdef CONFIG_SH_DSP
 759         mov.l   r2, @-r15               ! Save r2, we need another reg
 760         stc     sr, k4
 761         mov.l   1f, r2
 762         tst     r2, k4                  ! Check if in DSP mode
 763         mov.l   @r15+, r2               ! Restore r2 now
 764         bt/s    skip_save
 765          mov    #0, k4                  ! Set marker for no stack frame
 766
 767         mov     r2, k4                  ! Backup r2 (in k4) for later
 768
 769         ! Save DSP registers on stack
 770         stc.l   mod, @-r15
 771         stc.l   re, @-r15
 772         stc.l   rs, @-r15
 773         sts.l   dsr, @-r15
 774         sts.l   y1, @-r15
 775         sts.l   y0, @-r15
 776         sts.l   x1, @-r15
 777         sts.l   x0, @-r15
 778         sts.l   a0, @-r15
 779
 780         ! GAS is broken, does not generate correct "movs.l Ds,@-As" instr.
 781
 782         ! FIXME: Make sure that this is still the case with newer toolchains,
 783         ! as we're not at all interested in supporting ancient toolchains at
 784         ! this point. -- PFM.
 785
 786         mov     r15, r2
 787         .word   0xf653                  ! movs.l        a1, @-r2
 788         .word   0xf6f3                  ! movs.l        a0g, @-r2
 789         .word   0xf6d3                  ! movs.l        a1g, @-r2
 790         .word   0xf6c3                  ! movs.l        m0, @-r2
 791         .word   0xf6e3                  ! movs.l        m1, @-r2
 792         mov     r2, r15
 793
 794         mov     k4, r2                  ! Restore r2
 795         mov.l   1f, k4                  ! Force DSP stack frame
 796 skip_save:
 797         mov.l   k4, @-r15               ! Push DSP mode marker onto stack
 798 #endif
 799         ! Save the user registers on the stack.
 800         mov.l   k2, @-r15       ! EXPEVT
 801         mov.l   k4, @-r15       ! set TRA (default: -1)
 802         !
 803         sts.l   macl, @-r15
 804         sts.l   mach, @-r15
 805         stc.l   gbr, @-r15
 806         stc.l   ssr, @-r15
 807         sts.l   pr, @-r15
 808         stc.l   spc, @-r15
 809         !
 810         lds     k3, pr          ! Set the return address to pr
 811         !
 812         mov.l   k0, @-r15       ! save orignal stack
 813         mov.l   r14, @-r15
 814         mov.l   r13, @-r15
 815         mov.l   r12, @-r15
 816         mov.l   r11, @-r15
 817         mov.l   r10, @-r15
 818         mov.l   r9, @-r15
 819         mov.l   r8, @-r15
 820         !
 821         stc     sr, r8          ! Back to normal register bank, and
 822         or      k1, r8          ! Block all interrupts
 823         mov.l   3f, k1
 824         and     k1, r8          ! ...
 825         ldc     r8, sr          ! ...changed here.
 826         !
 827         mov.l   r7, @-r15
 828         mov.l   r6, @-r15
 829         mov.l   r5, @-r15
 830         mov.l   r4, @-r15
 831         mov.l   r3, @-r15
 832         mov.l   r2, @-r15
 833         mov.l   r1, @-r15
 834         mov.l   r0, @-r15
 835         ! Then, dispatch to the handler, according to the exception code.
 836         stc     k_ex_code, r8
 837         shlr2   r8
 838         shlr    r8
 839         mov.l   4f, r9
 840         add     r8, r9
 841         mov.l   @r9, r9
 842         jmp     @r9
 843          nop
 844
 845         .align  2
 846 1:      .long   0x00001000      ! DSP=1
 847 2:      .long   0x000080f0      ! FD=1, IMASK=15
 848 3:      .long   0xcfffffff      ! RB=0, BL=0
 849 4:      .long   exception_handling_table
 850
 851         .align  2
 852 ENTRY(exception_none)
 853         rts
 854          nop
 855
 856         .data
 857 ENTRY(sys_call_table)
 858         .long sys_ni_syscall    /* 0  -  old "setup()" system call*/
 859         .long sys_exit
 860         .long sys_fork
 861         .long sys_read
 862         .long sys_write
 863         .long sys_open          /* 5 */
 864         .long sys_close
 865         .long sys_waitpid
 866         .long sys_creat
 867         .long sys_link
 868         .long sys_unlink                /* 10 */
 869         .long sys_execve
 870         .long sys_chdir
 871         .long sys_time
 872         .long sys_mknod
 873         .long sys_chmod         /* 15 */
 874         .long sys_lchown16
 875         .long sys_ni_syscall    /* old break syscall holder */
 876         .long sys_stat
 877         .long sys_lseek
 878         .long sys_getpid                /* 20 */
 879         .long sys_mount
 880         .long sys_oldumount
 881         .long sys_setuid16
 882         .long sys_getuid16
 883         .long sys_stime         /* 25 */
 884         .long sys_ptrace
 885         .long sys_alarm
 886         .long sys_fstat
 887         .long sys_pause
 888         .long sys_utime         /* 30 */
 889         .long sys_ni_syscall    /* old stty syscall holder */
 890         .long sys_ni_syscall    /* old gtty syscall holder */
 891         .long sys_access
 892         .long sys_nice
 893         .long sys_ni_syscall    /* 35 */                /* old ftime syscall holder */
 894         .long sys_sync
 895         .long sys_kill
 896         .long sys_rename
 897         .long sys_mkdir
 898         .long sys_rmdir         /* 40 */
 899         .long sys_dup
 900         .long sys_pipe
 901         .long sys_times
 902         .long sys_ni_syscall    /* old prof syscall holder */
 903         .long sys_brk           /* 45 */
 904         .long sys_setgid16
 905         .long sys_getgid16
 906         .long sys_signal
 907         .long sys_geteuid16
 908         .long sys_getegid16     /* 50 */
 909         .long sys_acct
 910         .long sys_umount                /* recycled never used phys() */
 911         .long sys_ni_syscall    /* old lock syscall holder */
 912         .long sys_ioctl
 913         .long sys_fcntl         /* 55 */
 914         .long sys_ni_syscall    /* old mpx syscall holder */
 915         .long sys_setpgid
 916         .long sys_ni_syscall    /* old ulimit syscall holder */
 917         .long sys_ni_syscall    /* sys_olduname */
 918         .long sys_umask         /* 60 */
 919         .long sys_chroot
 920         .long sys_ustat
 921         .long sys_dup2
 922         .long sys_getppid
 923         .long sys_getpgrp               /* 65 */
 924         .long sys_setsid
 925         .long sys_sigaction
 926         .long sys_sgetmask
 927         .long sys_ssetmask
 928         .long sys_setreuid16    /* 70 */
 929         .long sys_setregid16
 930         .long sys_sigsuspend
 931         .long sys_sigpending
 932         .long sys_sethostname
 933         .long sys_setrlimit     /* 75 */
 934         .long sys_old_getrlimit
 935         .long sys_getrusage
 936         .long sys_gettimeofday
 937         .long sys_settimeofday
 938         .long sys_getgroups16   /* 80 */
 939         .long sys_setgroups16
 940         .long sys_ni_syscall    /* sys_oldselect */
 941         .long sys_symlink
 942         .long sys_lstat
 943         .long sys_readlink              /* 85 */
 944         .long sys_uselib
 945         .long sys_swapon
 946         .long sys_reboot
 947         .long old_readdir
 948         .long old_mmap          /* 90 */
 949         .long sys_munmap
 950         .long sys_truncate
 951         .long sys_ftruncate
 952         .long sys_fchmod
 953         .long sys_fchown16              /* 95 */
 954         .long sys_getpriority
 955         .long sys_setpriority
 956         .long sys_ni_syscall    /* old profil syscall holder */
 957         .long sys_statfs
 958         .long sys_fstatfs               /* 100 */
 959         .long sys_ni_syscall    /* ioperm */
 960         .long sys_socketcall
 961         .long sys_syslog
 962         .long sys_setitimer
 963         .long sys_getitimer     /* 105 */
 964         .long sys_newstat
 965         .long sys_newlstat
 966         .long sys_newfstat
 967         .long sys_uname
 968         .long sys_ni_syscall    /* 110 */ /* iopl */
 969         .long sys_vhangup
 970         .long sys_ni_syscall    /* idle */
 971         .long sys_ni_syscall    /* vm86old */
 972         .long sys_wait4
 973         .long sys_swapoff               /* 115 */
 974         .long sys_sysinfo
 975         .long sys_ipc
 976         .long sys_fsync
 977         .long sys_sigreturn
 978         .long sys_clone         /* 120 */
 979         .long sys_setdomainname
 980         .long sys_newuname
 981         .long sys_ni_syscall    /* sys_modify_ldt */
 982         .long sys_adjtimex
 983         .long sys_mprotect              /* 125 */
 984         .long sys_sigprocmask
 985         .long sys_ni_syscall    /* old "create_module" */
 986         .long sys_init_module
 987         .long sys_delete_module
 988         .long sys_ni_syscall    /* 130: old "get_kernel_syms" */
 989         .long sys_quotactl
 990         .long sys_getpgid
 991         .long sys_fchdir
 992         .long sys_bdflush
 993         .long sys_sysfs         /* 135 */
 994         .long sys_personality
 995         .long sys_ni_syscall    /* for afs_syscall */
 996         .long sys_setfsuid16
 997         .long sys_setfsgid16
 998         .long sys_llseek                /* 140 */
 999         .long sys_getdents
1000         .long sys_select
1001         .long sys_flock
1002         .long sys_msync
1003         .long sys_readv         /* 145 */
1004         .long sys_writev
1005         .long sys_getsid
1006         .long sys_fdatasync
1007         .long sys_sysctl
1008         .long sys_mlock         /* 150 */
1009         .long sys_munlock
1010         .long sys_mlockall
1011         .long sys_munlockall
1012         .long sys_sched_setparam
1013         .long sys_sched_getparam   /* 155 */
1014         .long sys_sched_setscheduler
1015         .long sys_sched_getscheduler
1016         .long sys_sched_yield
1017         .long sys_sched_get_priority_max
1018         .long sys_sched_get_priority_min  /* 160 */
1019         .long sys_sched_rr_get_interval
1020         .long sys_nanosleep
1021         .long sys_mremap
1022         .long sys_setresuid16
1023         .long sys_getresuid16   /* 165 */
1024         .long sys_ni_syscall    /* vm86 */
1025         .long sys_ni_syscall    /* old "query_module" */
1026         .long sys_poll
1027         .long sys_nfsservctl
1028         .long sys_setresgid16   /* 170 */
1029         .long sys_getresgid16
1030         .long sys_prctl
1031         .long sys_rt_sigreturn
1032         .long sys_rt_sigaction
1033         .long sys_rt_sigprocmask        /* 175 */
1034         .long sys_rt_sigpending
1035         .long sys_rt_sigtimedwait
1036         .long sys_rt_sigqueueinfo
1037         .long sys_rt_sigsuspend
1038         .long sys_pread_wrapper    /* 180 */
1039         .long sys_pwrite_wrapper
1040         .long sys_chown16
1041         .long sys_getcwd
1042         .long sys_capget
1043         .long sys_capset           /* 185 */
1044         .long sys_sigaltstack
1045         .long sys_sendfile
1046         .long sys_ni_syscall    /* streams1 */
1047         .long sys_ni_syscall    /* streams2 */
1048         .long sys_vfork            /* 190 */
1049         .long sys_getrlimit
1050         .long sys_mmap2
1051         .long sys_truncate64
1052         .long sys_ftruncate64
1053         .long sys_stat64                /* 195 */
1054         .long sys_lstat64
1055         .long sys_fstat64
1056         .long sys_lchown
1057         .long sys_getuid
1058         .long sys_getgid                /* 200 */
1059         .long sys_geteuid
1060         .long sys_getegid
1061         .long sys_setreuid
1062         .long sys_setregid
1063         .long sys_getgroups     /* 205 */
1064         .long sys_setgroups
1065         .long sys_fchown
1066         .long sys_setresuid
1067         .long sys_getresuid
1068         .long sys_setresgid     /* 210 */
1069         .long sys_getresgid
1070         .long sys_chown
1071         .long sys_setuid
1072         .long sys_setgid
1073         .long sys_setfsuid              /* 215 */
1074         .long sys_setfsgid
1075         .long sys_pivot_root
1076         .long sys_mincore
1077         .long sys_madvise
1078         .long sys_getdents64    /* 220 */
1079         .long sys_fcntl64
1080         .long sys_ni_syscall    /* reserved for TUX */
1081         .long sys_ni_syscall    /* Reserved for Security */
1082         .long sys_gettid
1083         .long sys_readahead     /* 225 */
1084         .long sys_setxattr
1085         .long sys_lsetxattr
1086         .long sys_fsetxattr
1087         .long sys_getxattr
1088         .long sys_lgetxattr     /* 230 */
1089         .long sys_fgetxattr
1090         .long sys_listxattr
1091         .long sys_llistxattr
1092         .long sys_flistxattr
1093         .long sys_removexattr   /* 235 */
1094         .long sys_lremovexattr
1095         .long sys_fremovexattr
1096         .long sys_tkill
1097         .long sys_sendfile64
1098         .long sys_futex         /* 240 */
1099         .long sys_sched_setaffinity
1100         .long sys_sched_getaffinity
1101         .long sys_ni_syscall
1102         .long sys_ni_syscall
1103         .long sys_io_setup      /* 245 */
1104         .long sys_io_destroy
1105         .long sys_io_getevents
1106         .long sys_io_submit
1107         .long sys_io_cancel
1108         .long sys_fadvise64     /* 250 */
1109         .long sys_ni_syscall
1110         .long sys_exit_group
1111         .long sys_lookup_dcookie
1112         .long sys_epoll_create
1113         .long sys_epoll_ctl     /* 255 */
1114         .long sys_epoll_wait
1115         .long sys_remap_file_pages
1116         .long sys_set_tid_address
1117         .long sys_timer_create
1118         .long sys_timer_settime         /* 260 */
1119         .long sys_timer_gettime
1120         .long sys_timer_getoverrun
1121         .long sys_timer_delete
1122         .long sys_clock_settime
1123         .long sys_clock_gettime         /* 265 */
1124         .long sys_clock_getres
1125         .long sys_clock_nanosleep
1126         .long sys_statfs64
1127         .long sys_fstatfs64
1128         .long sys_tgkill                /* 270 */
1129         .long sys_utimes
1130         .long sys_fadvise64_64_wrapper
1131         .long sys_ni_syscall    /* Reserved for vserver */
1132         .long sys_ni_syscall
1133
1134 /* End of entry.S */