arch/sparc64/kernel/etrap.S

   1 /* $Id: etrap.S,v 1.46 2002/02/09 19:49:30 davem Exp $
   2  * etrap.S: Preparing for entry into the kernel on Sparc V9.
   3  *
   4  * Copyright (C) 1996, 1997 David S. Miller (davem@caip.rutgers.edu)
   5  * Copyright (C) 1997, 1998, 1999 Jakub Jelinek (jj@ultra.linux.cz)
   6  */
   7
   8 #include <linux/config.h>
   9
  10 #include <asm/asi.h>
  11 #include <asm/pstate.h>
  12 #include <asm/ptrace.h>
  13 #include <asm/page.h>
  14 #include <asm/spitfire.h>
  15 #include <asm/head.h>
  16 #include <asm/processor.h>
  17
  18 #define         TASK_REGOFF             (THREAD_SIZE-TRACEREG_SZ-STACKFRAME_SZ)
  19 #define         ETRAP_PSTATE1           (PSTATE_RMO | PSTATE_PRIV)
  20 #define         ETRAP_PSTATE2           (PSTATE_RMO | PSTATE_PEF | PSTATE_PRIV | PSTATE_IE)
  21
  22 /*
  23  * On entry, %g7 is return address - 0x4.
  24  * %g4 and %g5 will be preserved %l4 and %l5 respectively.
  25  */
  26
  27                 .text
  28                 .align  64
  29                 .globl  etrap, etrap_irq, etraptl1
  30 etrap:          rdpr    %pil, %g2                                               ! Single        Group
  31 etrap_irq:
  32                 rdpr    %tstate, %g1                                            ! Single        Group
  33                 sllx    %g2, 20, %g3                                            ! IEU0          Group
  34                 andcc   %g1, TSTATE_PRIV, %g0                                   ! IEU1
  35                 or      %g1, %g3, %g1                                           ! IEU0          Group
  36                 bne,pn  %xcc, 1f                                                ! CTI
  37                  sub    %sp, STACKFRAME_SZ+TRACEREG_SZ-STACK_BIAS, %g2          ! IEU1
  38                 wrpr    %g0, 7, %cleanwin                                       ! Single        Group+4bubbles
  39
  40                 sethi   %hi(TASK_REGOFF), %g2                                   ! IEU0          Group
  41                 sethi   %hi(TSTATE_PEF), %g3                                    ! IEU1
  42                 or      %g2, %lo(TASK_REGOFF), %g2                              ! IEU0          Group
  43                 and     %g1, %g3, %g3                                           ! IEU1
  44                 brnz,pn %g3, 1f                                                 ! CTI+IEU1      Group
  45                  add    %g6, %g2, %g2                                           ! IEU0
  46                 wr      %g0, 0, %fprs                                           ! Single        Group+4bubbles
  47 1:              rdpr    %tpc, %g3                                               ! Single        Group
  48
  49                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TSTATE]               ! Store         Group
  50                 rdpr    %tnpc, %g1                                              ! Single        Group
  51                 stx     %g3, [%g2 + STACKFRAME_SZ + PT_V9_TPC]                  ! Store         Group
  52                 rd      %y, %g3                                                 ! Single        Group+4bubbles
  53                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TNPC]                 ! Store         Group
  54                 st      %g3, [%g2 + STACKFRAME_SZ + PT_V9_Y]                    ! Store         Group
  55                 save    %g2, -STACK_BIAS, %sp   ! Ordering here is critical     ! Single        Group
  56                 mov     %g6, %l6                                                ! IEU0          Group
  57
  58                 bne,pn  %xcc, 3f                                                ! CTI
  59                  mov    PRIMARY_CONTEXT, %l4                                    ! IEU1
  60                 rdpr    %canrestore, %g3                                        ! Single        Group+4bubbles
  61                 rdpr    %wstate, %g2                                            ! Single        Group+4bubbles
  62                 wrpr    %g0, 0, %canrestore                                     ! Single        Group+4bubbles
  63                 sll     %g2, 3, %g2                                             ! IEU0          Group
  64                 mov     1, %l5                                                  ! IEU1
  65                 stb     %l5, [%l6 + TI_FPDEPTH]                                 ! Store
  66
  67                 wrpr    %g3, 0, %otherwin                                       ! Single        Group+4bubbles
  68                 wrpr    %g2, 0, %wstate                                         ! Single        Group+4bubbles
  69                 stxa    %g0, [%l4] ASI_DMMU                                     ! Store         Group
  70                 flush   %l6                                                     ! Single        Group+9bubbles
  71                 wr      %g0, ASI_AIUS, %asi                                     ! Single        Group+4bubbles
  72 2:              wrpr    %g0, 0x0, %tl                                           ! Single        Group+4bubbles
  73                 mov     %g4, %l4                                                ! IEU1
  74                 mov     %g5, %l5                                                ! IEU0          Group
  75
  76                 mov     %g7, %l2                                                ! IEU1
  77                 wrpr    %g0, ETRAP_PSTATE1, %pstate                             ! Single        Group+4bubbles
  78                 stx     %g1, [%sp + PTREGS_OFF + PT_V9_G1]                      ! Store         Group
  79                 stx     %g2, [%sp + PTREGS_OFF + PT_V9_G2]                      ! Store         Group
  80                 stx     %g3, [%sp + PTREGS_OFF + PT_V9_G3]                      ! Store         Group
  81                 stx     %g4, [%sp + PTREGS_OFF + PT_V9_G4]                      ! Store         Group
  82                 stx     %g5, [%sp + PTREGS_OFF + PT_V9_G5]                      ! Store         Group
  83                 stx     %g6, [%sp + PTREGS_OFF + PT_V9_G6]                      ! Store         Group
  84
  85                 stx     %g7, [%sp + PTREGS_OFF + PT_V9_G7]                      ! Store         Group
  86                 stx     %i0, [%sp + PTREGS_OFF + PT_V9_I0]                      ! Store         Group
  87                 stx     %i1, [%sp + PTREGS_OFF + PT_V9_I1]                      ! Store         Group
  88                 stx     %i2, [%sp + PTREGS_OFF + PT_V9_I2]                      ! Store         Group
  89                 stx     %i3, [%sp + PTREGS_OFF + PT_V9_I3]                      ! Store         Group
  90                 stx     %i4, [%sp + PTREGS_OFF + PT_V9_I4]                      ! Store         Group
  91                 stx     %i5, [%sp + PTREGS_OFF + PT_V9_I5]                      ! Store         Group
  92
  93                 stx     %i6, [%sp + PTREGS_OFF + PT_V9_I6]                      ! Store         Group
  94                 stx     %i7, [%sp + PTREGS_OFF + PT_V9_I7]                      ! Store         Group
  95                 wrpr    %g0, ETRAP_PSTATE2, %pstate                             ! Single        Group+4bubbles
  96                 mov     %l6, %g6                                                ! IEU0
  97                 jmpl    %l2 + 0x4, %g0                                          ! CTI           Group
  98                  ldx    [%g6 + TI_TASK], %g4                                    ! Load
  99                 nop
 100                 nop
 101                 nop
 102
 103 3:              ldub    [%l6 + TI_FPDEPTH], %l5                                 ! Load          Group
 104                 add     %l6, TI_FPSAVED + 1, %l4                                ! IEU0
 105                 srl     %l5, 1, %l3                                             ! IEU0          Group
 106                 add     %l5, 2, %l5                                             ! IEU1
 107                 stb     %l5, [%l6 + TI_FPDEPTH]                                 ! Store
 108                 ba,pt   %xcc, 2b                                                ! CTI
 109                  stb    %g0, [%l4 + %l3]                                        ! Store         Group
 110                 nop
 111
 112 etraptl1:       /* Save tstate/tpc/tnpc of TL 1-->4 and the tl register itself.
 113                  * We place this right after pt_regs on the trap stack.  The layout
 114                  * is:
 115                  *      0x00    TL1's TSTATE
 116                  *      0x08    TL1's TPC
 117                  *      0x10    TL1's TNPC
 118                  *      0x18    TL1's TT
 119                  *       ...
 120                  *      0x58    TL4's TT
 121                  *      0x60    TL
 122                  */
 123                 sub     %sp, ((4 * 8) * 4) + 8, %g2
 124                 rdpr    %tl, %g1
 125
 126                 wrpr    %g0, 1, %tl
 127                 rdpr    %tstate, %g3
 128                 stx     %g3, [%g2 + STACK_BIAS + 0x00]
 129                 rdpr    %tpc, %g3
 130                 stx     %g3, [%g2 + STACK_BIAS + 0x08]
 131                 rdpr    %tnpc, %g3
 132                 stx     %g3, [%g2 + STACK_BIAS + 0x10]
 133                 rdpr    %tt, %g3
 134                 stx     %g3, [%g2 + STACK_BIAS + 0x18]
 135
 136                 wrpr    %g0, 2, %tl
 137                 rdpr    %tstate, %g3
 138                 stx     %g3, [%g2 + STACK_BIAS + 0x20]
 139                 rdpr    %tpc, %g3
 140                 stx     %g3, [%g2 + STACK_BIAS + 0x28]
 141                 rdpr    %tnpc, %g3
 142                 stx     %g3, [%g2 + STACK_BIAS + 0x30]
 143                 rdpr    %tt, %g3
 144                 stx     %g3, [%g2 + STACK_BIAS + 0x38]
 145
 146                 wrpr    %g0, 3, %tl
 147                 rdpr    %tstate, %g3
 148                 stx     %g3, [%g2 + STACK_BIAS + 0x40]
 149                 rdpr    %tpc, %g3
 150                 stx     %g3, [%g2 + STACK_BIAS + 0x48]
 151                 rdpr    %tnpc, %g3
 152                 stx     %g3, [%g2 + STACK_BIAS + 0x50]
 153                 rdpr    %tt, %g3
 154                 stx     %g3, [%g2 + STACK_BIAS + 0x58]
 155
 156                 wrpr    %g0, 4, %tl
 157                 rdpr    %tstate, %g3
 158                 stx     %g3, [%g2 + STACK_BIAS + 0x60]
 159                 rdpr    %tpc, %g3
 160                 stx     %g3, [%g2 + STACK_BIAS + 0x68]
 161                 rdpr    %tnpc, %g3
 162                 stx     %g3, [%g2 + STACK_BIAS + 0x70]
 163                 rdpr    %tt, %g3
 164                 stx     %g3, [%g2 + STACK_BIAS + 0x78]
 165
 166                 wrpr    %g1, %tl
 167                 stx     %g1, [%g2 + STACK_BIAS + 0x80]
 168
 169                 rdpr    %tstate, %g1                                            ! Single        Group+4bubbles
 170                 sub     %g2, STACKFRAME_SZ + TRACEREG_SZ - STACK_BIAS, %g2      ! IEU1
 171                 ba,pt   %xcc, 1b                                                ! CTI           Group
 172                  andcc  %g1, TSTATE_PRIV, %g0                                   ! IEU0
 173
 174                 .align  64
 175                 .globl  scetrap
 176 scetrap:        rdpr    %pil, %g2                                               ! Single        Group
 177                 rdpr    %tstate, %g1                                            ! Single        Group
 178                 sllx    %g2, 20, %g3                                            ! IEU0          Group
 179                 andcc   %g1, TSTATE_PRIV, %g0                                   ! IEU1
 180                 or      %g1, %g3, %g1                                           ! IEU0          Group
 181                 bne,pn  %xcc, 1f                                                ! CTI
 182                  sub    %sp, (STACKFRAME_SZ+TRACEREG_SZ-STACK_BIAS), %g2        ! IEU1
 183                 wrpr    %g0, 7, %cleanwin                                       ! Single        Group+4bubbles
 184
 185                 sllx    %g1, 51, %g3                                            ! IEU0          Group
 186                 sethi   %hi(TASK_REGOFF), %g2                                   ! IEU1
 187                 or      %g2, %lo(TASK_REGOFF), %g2                              ! IEU0          Group
 188                 brlz,pn %g3, 1f                                                 ! CTI+IEU1
 189                  add    %g6, %g2, %g2                                           ! IEU0          Group
 190                 wr      %g0, 0, %fprs                                           ! Single        Group+4bubbles
 191 1:              rdpr    %tpc, %g3                                               ! Single        Group
 192                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TSTATE]               ! Store         Group
 193
 194                 rdpr    %tnpc, %g1                                              ! Single        Group
 195                 stx     %g3, [%g2 + STACKFRAME_SZ + PT_V9_TPC]                  ! Store         Group
 196                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TNPC]                 ! Store         Group
 197                 save    %g2, -STACK_BIAS, %sp   ! Ordering here is critical     ! Single        Group
 198                 mov     %g6, %l6                                                ! IEU0          Group
 199                 bne,pn  %xcc, 2f                                                ! CTI
 200                  mov    ASI_P, %l7                                              ! IEU1
 201                 rdpr    %canrestore, %g3                                        ! Single        Group+4bubbles
 202
 203                 rdpr    %wstate, %g2                                            ! Single        Group+4bubbles
 204                 wrpr    %g0, 0, %canrestore                                     ! Single        Group+4bubbles
 205                 sll     %g2, 3, %g2                                             ! IEU0          Group
 206                 mov     PRIMARY_CONTEXT, %l4                                    ! IEU1
 207                 wrpr    %g3, 0, %otherwin                                       ! Single        Group+4bubbles
 208                 wrpr    %g2, 0, %wstate                                         ! Single        Group+4bubbles
 209                 stxa    %g0, [%l4] ASI_DMMU                                     ! Store
 210                 flush   %l6                                                     ! Single        Group+9bubbles
 211
 212                 mov     ASI_AIUS, %l7                                           ! IEU0          Group
 213 2:              mov     %g4, %l4                                                ! IEU1
 214                 mov     %g5, %l5                                                ! IEU0          Group
 215                 add     %g7, 0x4, %l2                                           ! IEU1
 216                 wrpr    %g0, ETRAP_PSTATE1, %pstate                             ! Single        Group+4bubbles
 217                 stx     %g1, [%sp + PTREGS_OFF + PT_V9_G1]                      ! Store         Group
 218                 stx     %g2, [%sp + PTREGS_OFF + PT_V9_G2]                      ! Store         Group
 219                 sllx    %l7, 24, %l7                                            ! IEU0
 220
 221                 stx     %g3, [%sp + PTREGS_OFF + PT_V9_G3]                      ! Store         Group
 222                 rdpr    %cwp, %l0                                               ! Single        Group
 223                 stx     %g4, [%sp + PTREGS_OFF + PT_V9_G4]                      ! Store         Group
 224                 stx     %g5, [%sp + PTREGS_OFF + PT_V9_G5]                      ! Store         Group
 225                 stx     %g6, [%sp + PTREGS_OFF + PT_V9_G6]                      ! Store         Group
 226                 stx     %g7, [%sp + PTREGS_OFF + PT_V9_G7]                      ! Store         Group
 227                 or      %l7, %l0, %l7                                           ! IEU0
 228                 sethi   %hi(TSTATE_RMO | TSTATE_PEF), %l0                       ! IEU1
 229
 230                 or      %l7, %l0, %l7                                           ! IEU0          Group
 231                 wrpr    %l2, %tnpc                                              ! Single        Group+4bubbles
 232                 wrpr    %l7, (TSTATE_PRIV | TSTATE_IE), %tstate                 ! Single        Group+4bubbles
 233                 stx     %i0, [%sp + PTREGS_OFF + PT_V9_I0]                      ! Store         Group
 234                 stx     %i1, [%sp + PTREGS_OFF + PT_V9_I1]                      ! Store         Group
 235                 stx     %i2, [%sp + PTREGS_OFF + PT_V9_I2]                      ! Store         Group
 236                 stx     %i3, [%sp + PTREGS_OFF + PT_V9_I3]                      ! Store         Group
 237                 stx     %i4, [%sp + PTREGS_OFF + PT_V9_I4]                      ! Store         Group
 238
 239                 stx     %i5, [%sp + PTREGS_OFF + PT_V9_I5]                      ! Store         Group
 240                 stx     %i6, [%sp + PTREGS_OFF + PT_V9_I6]                      ! Store         Group
 241                 mov     %l6, %g6                                                ! IEU1
 242                 stx     %i7, [%sp + PTREGS_OFF + PT_V9_I7]                      ! Store         Group
 243                 ldx     [%g6 + TI_TASK], %g4                                    ! Load          Group
 244                 done
 245                 nop
 246                 nop
 247
 248 #undef TASK_REGOFF
 249 #undef ETRAP_PSTATE1
 250 #undef ETRAP_PSTATE2