arch/sparc64/kernel/etrap.S

   1 /* $Id: etrap.S,v 1.46 2002/02/09 19:49:30 davem Exp $
   2  * etrap.S: Preparing for entry into the kernel on Sparc V9.
   3  *
   4  * Copyright (C) 1996, 1997 David S. Miller (davem@caip.rutgers.edu)
   5  * Copyright (C) 1997, 1998, 1999 Jakub Jelinek (jj@ultra.linux.cz)
   6  */
   7
   8 #include <linux/config.h>
   9
  10 #include <asm/asi.h>
  11 #include <asm/pstate.h>
  12 #include <asm/ptrace.h>
  13 #include <asm/page.h>
  14 #include <asm/spitfire.h>
  15 #include <asm/head.h>
  16 #include <asm/processor.h>
  17
  18 #define         TASK_REGOFF             (THREAD_SIZE-TRACEREG_SZ-STACKFRAME_SZ)
  19 #define         ETRAP_PSTATE1           (PSTATE_RMO | PSTATE_PRIV)
  20 #define         ETRAP_PSTATE2           \
  21                 (PSTATE_RMO | PSTATE_PEF | PSTATE_PRIV | PSTATE_IE)
  22
  23 /*
  24  * On entry, %g7 is return address - 0x4.
  25  * %g4 and %g5 will be preserved %l4 and %l5 respectively.
  26  */
  27
  28                 .text
  29                 .align  64
  30                 .globl  etrap, etrap_irq, etraptl1
  31 etrap:          rdpr    %pil, %g2
  32 etrap_irq:
  33                 rdpr    %tstate, %g1
  34                 sllx    %g2, 20, %g3
  35                 andcc   %g1, TSTATE_PRIV, %g0
  36                 or      %g1, %g3, %g1
  37                 bne,pn  %xcc, 1f
  38                  sub    %sp, STACKFRAME_SZ+TRACEREG_SZ-STACK_BIAS, %g2
  39                 wrpr    %g0, 7, %cleanwin
  40
  41                 sethi   %hi(TASK_REGOFF), %g2
  42                 sethi   %hi(TSTATE_PEF), %g3
  43                 or      %g2, %lo(TASK_REGOFF), %g2
  44                 and     %g1, %g3, %g3
  45                 brnz,pn %g3, 1f
  46                  add    %g6, %g2, %g2
  47                 wr      %g0, 0, %fprs
  48 1:              rdpr    %tpc, %g3
  49
  50                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TSTATE]
  51                 rdpr    %tnpc, %g1
  52                 stx     %g3, [%g2 + STACKFRAME_SZ + PT_V9_TPC]
  53                 rd      %y, %g3
  54                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TNPC]
  55                 st      %g3, [%g2 + STACKFRAME_SZ + PT_V9_Y]
  56                 save    %g2, -STACK_BIAS, %sp   ! Ordering here is critical
  57                 mov     %g6, %l6
  58
  59                 bne,pn  %xcc, 3f
  60                  mov    PRIMARY_CONTEXT, %l4
  61                 rdpr    %canrestore, %g3
  62                 rdpr    %wstate, %g2
  63                 wrpr    %g0, 0, %canrestore
  64                 sll     %g2, 3, %g2
  65                 mov     1, %l5
  66                 stb     %l5, [%l6 + TI_FPDEPTH]
  67
  68                 wrpr    %g3, 0, %otherwin
  69                 wrpr    %g2, 0, %wstate
  70                 stxa    %g0, [%l4] ASI_DMMU
  71                 flush   %l6
  72                 wr      %g0, ASI_AIUS, %asi
  73 2:              wrpr    %g0, 0x0, %tl
  74                 mov     %g4, %l4
  75                 mov     %g5, %l5
  76
  77                 mov     %g7, %l2
  78                 wrpr    %g0, ETRAP_PSTATE1, %pstate
  79                 stx     %g1, [%sp + PTREGS_OFF + PT_V9_G1]
  80                 stx     %g2, [%sp + PTREGS_OFF + PT_V9_G2]
  81                 stx     %g3, [%sp + PTREGS_OFF + PT_V9_G3]
  82                 stx     %g4, [%sp + PTREGS_OFF + PT_V9_G4]
  83                 stx     %g5, [%sp + PTREGS_OFF + PT_V9_G5]
  84                 stx     %g6, [%sp + PTREGS_OFF + PT_V9_G6]
  85
  86                 stx     %g7, [%sp + PTREGS_OFF + PT_V9_G7]
  87                 stx     %i0, [%sp + PTREGS_OFF + PT_V9_I0]
  88                 stx     %i1, [%sp + PTREGS_OFF + PT_V9_I1]
  89                 stx     %i2, [%sp + PTREGS_OFF + PT_V9_I2]
  90                 stx     %i3, [%sp + PTREGS_OFF + PT_V9_I3]
  91                 stx     %i4, [%sp + PTREGS_OFF + PT_V9_I4]
  92                 stx     %i5, [%sp + PTREGS_OFF + PT_V9_I5]
  93
  94                 stx     %i6, [%sp + PTREGS_OFF + PT_V9_I6]
  95                 stx     %i7, [%sp + PTREGS_OFF + PT_V9_I7]
  96                 wrpr    %g0, ETRAP_PSTATE2, %pstate
  97                 mov     %l6, %g6
  98                 jmpl    %l2 + 0x4, %g0
  99                  ldx    [%g6 + TI_TASK], %g4
 100                 nop
 101                 nop
 102                 nop
 103
 104 3:              ldub    [%l6 + TI_FPDEPTH], %l5
 105                 add     %l6, TI_FPSAVED + 1, %l4
 106                 srl     %l5, 1, %l3
 107                 add     %l5, 2, %l5
 108                 stb     %l5, [%l6 + TI_FPDEPTH]
 109                 ba,pt   %xcc, 2b
 110                  stb    %g0, [%l4 + %l3]
 111                 nop
 112
 113 etraptl1:       /* Save tstate/tpc/tnpc of TL 1-->4 and the tl register itself.
 114                  * We place this right after pt_regs on the trap stack.
 115                  * The layout is:
 116                  *      0x00    TL1's TSTATE
 117                  *      0x08    TL1's TPC
 118                  *      0x10    TL1's TNPC
 119                  *      0x18    TL1's TT
 120                  *       ...
 121                  *      0x58    TL4's TT
 122                  *      0x60    TL
 123                  */
 124                 sub     %sp, ((4 * 8) * 4) + 8, %g2
 125                 rdpr    %tl, %g1
 126
 127                 wrpr    %g0, 1, %tl
 128                 rdpr    %tstate, %g3
 129                 stx     %g3, [%g2 + STACK_BIAS + 0x00]
 130                 rdpr    %tpc, %g3
 131                 stx     %g3, [%g2 + STACK_BIAS + 0x08]
 132                 rdpr    %tnpc, %g3
 133                 stx     %g3, [%g2 + STACK_BIAS + 0x10]
 134                 rdpr    %tt, %g3
 135                 stx     %g3, [%g2 + STACK_BIAS + 0x18]
 136
 137                 wrpr    %g0, 2, %tl
 138                 rdpr    %tstate, %g3
 139                 stx     %g3, [%g2 + STACK_BIAS + 0x20]
 140                 rdpr    %tpc, %g3
 141                 stx     %g3, [%g2 + STACK_BIAS + 0x28]
 142                 rdpr    %tnpc, %g3
 143                 stx     %g3, [%g2 + STACK_BIAS + 0x30]
 144                 rdpr    %tt, %g3
 145                 stx     %g3, [%g2 + STACK_BIAS + 0x38]
 146
 147                 wrpr    %g0, 3, %tl
 148                 rdpr    %tstate, %g3
 149                 stx     %g3, [%g2 + STACK_BIAS + 0x40]
 150                 rdpr    %tpc, %g3
 151                 stx     %g3, [%g2 + STACK_BIAS + 0x48]
 152                 rdpr    %tnpc, %g3
 153                 stx     %g3, [%g2 + STACK_BIAS + 0x50]
 154                 rdpr    %tt, %g3
 155                 stx     %g3, [%g2 + STACK_BIAS + 0x58]
 156
 157                 wrpr    %g0, 4, %tl
 158                 rdpr    %tstate, %g3
 159                 stx     %g3, [%g2 + STACK_BIAS + 0x60]
 160                 rdpr    %tpc, %g3
 161                 stx     %g3, [%g2 + STACK_BIAS + 0x68]
 162                 rdpr    %tnpc, %g3
 163                 stx     %g3, [%g2 + STACK_BIAS + 0x70]
 164                 rdpr    %tt, %g3
 165                 stx     %g3, [%g2 + STACK_BIAS + 0x78]
 166
 167                 wrpr    %g1, %tl
 168                 stx     %g1, [%g2 + STACK_BIAS + 0x80]
 169
 170                 rdpr    %tstate, %g1
 171                 sub     %g2, STACKFRAME_SZ + TRACEREG_SZ - STACK_BIAS, %g2
 172                 ba,pt   %xcc, 1b
 173                  andcc  %g1, TSTATE_PRIV, %g0
 174
 175                 .align  64
 176                 .globl  scetrap
 177 scetrap:        rdpr    %pil, %g2
 178                 rdpr    %tstate, %g1
 179                 sllx    %g2, 20, %g3
 180                 andcc   %g1, TSTATE_PRIV, %g0
 181                 or      %g1, %g3, %g1
 182                 bne,pn  %xcc, 1f
 183                  sub    %sp, (STACKFRAME_SZ+TRACEREG_SZ-STACK_BIAS), %g2
 184                 wrpr    %g0, 7, %cleanwin
 185
 186                 sllx    %g1, 51, %g3
 187                 sethi   %hi(TASK_REGOFF), %g2
 188                 or      %g2, %lo(TASK_REGOFF), %g2
 189                 brlz,pn %g3, 1f
 190                  add    %g6, %g2, %g2
 191                 wr      %g0, 0, %fprs
 192 1:              rdpr    %tpc, %g3
 193                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TSTATE]
 194
 195                 rdpr    %tnpc, %g1
 196                 stx     %g3, [%g2 + STACKFRAME_SZ + PT_V9_TPC]
 197                 stx     %g1, [%g2 + STACKFRAME_SZ + PT_V9_TNPC]
 198                 save    %g2, -STACK_BIAS, %sp   ! Ordering here is critical
 199                 mov     %g6, %l6
 200                 bne,pn  %xcc, 2f
 201                  mov    ASI_P, %l7
 202                 rdpr    %canrestore, %g3
 203
 204                 rdpr    %wstate, %g2
 205                 wrpr    %g0, 0, %canrestore
 206                 sll     %g2, 3, %g2
 207                 mov     PRIMARY_CONTEXT, %l4
 208                 wrpr    %g3, 0, %otherwin
 209                 wrpr    %g2, 0, %wstate
 210                 stxa    %g0, [%l4] ASI_DMMU
 211                 flush   %l6
 212
 213                 mov     ASI_AIUS, %l7
 214 2:              mov     %g4, %l4
 215                 mov     %g5, %l5
 216                 add     %g7, 0x4, %l2
 217                 wrpr    %g0, ETRAP_PSTATE1, %pstate
 218                 stx     %g1, [%sp + PTREGS_OFF + PT_V9_G1]
 219                 stx     %g2, [%sp + PTREGS_OFF + PT_V9_G2]
 220                 sllx    %l7, 24, %l7
 221
 222                 stx     %g3, [%sp + PTREGS_OFF + PT_V9_G3]
 223                 rdpr    %cwp, %l0
 224                 stx     %g4, [%sp + PTREGS_OFF + PT_V9_G4]
 225                 stx     %g5, [%sp + PTREGS_OFF + PT_V9_G5]
 226                 stx     %g6, [%sp + PTREGS_OFF + PT_V9_G6]
 227                 stx     %g7, [%sp + PTREGS_OFF + PT_V9_G7]
 228                 or      %l7, %l0, %l7
 229                 sethi   %hi(TSTATE_RMO | TSTATE_PEF), %l0
 230
 231                 or      %l7, %l0, %l7
 232                 wrpr    %l2, %tnpc
 233                 wrpr    %l7, (TSTATE_PRIV | TSTATE_IE), %tstate
 234                 stx     %i0, [%sp + PTREGS_OFF + PT_V9_I0]
 235                 stx     %i1, [%sp + PTREGS_OFF + PT_V9_I1]
 236                 stx     %i2, [%sp + PTREGS_OFF + PT_V9_I2]
 237                 stx     %i3, [%sp + PTREGS_OFF + PT_V9_I3]
 238                 stx     %i4, [%sp + PTREGS_OFF + PT_V9_I4]
 239
 240                 stx     %i5, [%sp + PTREGS_OFF + PT_V9_I5]
 241                 stx     %i6, [%sp + PTREGS_OFF + PT_V9_I6]
 242                 mov     %l6, %g6
 243                 stx     %i7, [%sp + PTREGS_OFF + PT_V9_I7]
 244                 ldx     [%g6 + TI_TASK], %g4
 245                 done
 246                 nop
 247                 nop
 248
 249 #undef TASK_REGOFF
 250 #undef ETRAP_PSTATE1
 251 #undef ETRAP_PSTATE2