arch/um/dyn.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT(ELF_FORMAT)
   4 OUTPUT_ARCH(ELF_ARCH)
   5 ENTRY(_start)
   6 jiffies = jiffies_64;
   7
   8 SEARCH_DIR("/usr/local/i686-pc-linux-gnu/lib"); SEARCH_DIR("/usr/local/lib"); SEARCH_DIR("/lib"); SEARCH_DIR("/usr/lib");
   9 /* Do we need any of these for elf?
  10    __DYNAMIC = 0;    */
  11 SECTIONS
  12 {
  13   . = START + SIZEOF_HEADERS;
  14   .interp         : { *(.interp) }
  15   __binary_start = .;
  16   . = ALIGN(4096);              /* Init code and data */
  17   _stext = .;
  18   __init_begin = .;
  19   .init.text : {
  20         _sinittext = .;
  21         *(.init.text)
  22         _einittext = .;
  23   }
  24
  25   . = ALIGN(4096);
  26
  27   /* Read-only sections, merged into text segment: */
  28   .hash           : { *(.hash) }
  29   .dynsym         : { *(.dynsym) }
  30   .dynstr         : { *(.dynstr) }
  31   .gnu.version    : { *(.gnu.version) }
  32   .gnu.version_d  : { *(.gnu.version_d) }
  33   .gnu.version_r  : { *(.gnu.version_r) }
  34   .rel.init       : { *(.rel.init) }
  35   .rela.init      : { *(.rela.init) }
  36   .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  37   .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  38   .rel.fini       : { *(.rel.fini) }
  39   .rela.fini      : { *(.rela.fini) }
  40   .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  41   .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  42   .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  43   .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  44   .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  45   .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  46   .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  47   .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  48   .rel.ctors      : { *(.rel.ctors) }
  49   .rela.ctors     : { *(.rela.ctors) }
  50   .rel.dtors      : { *(.rel.dtors) }
  51   .rela.dtors     : { *(.rela.dtors) }
  52   .rel.got        : { *(.rel.got) }
  53   .rela.got       : { *(.rela.got) }
  54   .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  55   .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  56   .rel.plt        : { *(.rel.plt) }
  57   .rela.plt       : { *(.rela.plt) }
  58   .init           : {
  59     KEEP (*(.init))
  60   } =0x90909090
  61   .plt            : { *(.plt) }
  62   .text           : {
  63     *(.text)
  64     SCHED_TEXT
  65     *(.stub .text.* .gnu.linkonce.t.*)
  66     /* .gnu.warning sections are handled specially by elf32.em.  */
  67     *(.gnu.warning)
  68   } =0x90909090
  69   .fini           : {
  70     KEEP (*(.fini))
  71   } =0x90909090
  72
  73   .kstrtab : { *(.kstrtab) }
  74
  75   #include "asm/common.lds.S"
  76
  77   init.data : { *(.init.data) }
  78
  79   /* Ensure the __preinit_array_start label is properly aligned.  We
  80      could instead move the label definition inside the section, but
  81      the linker would then create the section even if it turns out to
  82      be empty, which isn't pretty.  */
  83   . = ALIGN(32 / 8);
  84   .preinit_array     : { *(.preinit_array) }
  85   .init_array     : { *(.init_array) }
  86   .fini_array     : { *(.fini_array) }
  87   .data           : {
  88     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  89     *(.data.init_task)
  90     *(.data .data.* .gnu.linkonce.d.*)
  91     SORT(CONSTRUCTORS)
  92   }
  93   .data1          : { *(.data1) }
  94   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  95   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  96   .eh_frame       : { KEEP (*(.eh_frame)) }
  97   .gcc_except_table   : { *(.gcc_except_table) }
  98   .dynamic        : { *(.dynamic) }
  99   .ctors          : {
 100     /* gcc uses crtbegin.o to find the start of
 101        the constructors, so we make sure it is
 102        first.  Because this is a wildcard, it
 103        doesn't matter if the user does not
 104        actually link against crtbegin.o; the
 105        linker won't look for a file to match a
 106        wildcard.  The wildcard also means that it
 107        doesn't matter which directory crtbegin.o
 108        is in.  */
 109     KEEP (*crtbegin.o(.ctors))
 110     /* We don't want to include the .ctor section from
 111        from the crtend.o file until after the sorted ctors.
 112        The .ctor section from the crtend file contains the
 113        end of ctors marker and it must be last */
 114     KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 115     KEEP (*(SORT(.ctors.*)))
 116     KEEP (*(.ctors))
 117   }
 118   .dtors          : {
 119     KEEP (*crtbegin.o(.dtors))
 120     KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 121     KEEP (*(SORT(.dtors.*)))
 122     KEEP (*(.dtors))
 123   }
 124   .jcr            : { KEEP (*(.jcr)) }
 125   .got            : { *(.got.plt) *(.got) }
 126   _edata = .;
 127   PROVIDE (edata = .);
 128   __bss_start = .;
 129   .bss            : {
 130    *(.dynbss)
 131    *(.bss .bss.* .gnu.linkonce.b.*)
 132    *(COMMON)
 133    /* Align here to ensure that the .bss section occupies space up to
 134       _end.  Align after .bss to ensure correct alignment even if the
 135       .bss section disappears because there are no input sections.  */
 136    . = ALIGN(32 / 8);
 137   . = ALIGN(32 / 8);
 138   }
 139   _end = .;
 140   PROVIDE (end = .);
 141    /* Stabs debugging sections.  */
 142   .stab          0 : { *(.stab) }
 143   .stabstr       0 : { *(.stabstr) }
 144   .stab.excl     0 : { *(.stab.excl) }
 145   .stab.exclstr  0 : { *(.stab.exclstr) }
 146   .stab.index    0 : { *(.stab.index) }
 147   .stab.indexstr 0 : { *(.stab.indexstr) }
 148   .comment       0 : { *(.comment) }
 149   /* DWARF debug sections.
 150      Symbols in the DWARF debugging sections are relative to the beginning
 151      of the section so we begin them at 0.  */
 152   /* DWARF 1 */
 153   .debug          0 : { *(.debug) }
 154   .line           0 : { *(.line) }
 155   /* GNU DWARF 1 extensions */
 156   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 157   .debug_sfnames  0 : { *(.debug_sfnames) }
 158   /* DWARF 1.1 and DWARF 2 */
 159   .debug_aranges  0 : { *(.debug_aranges) }
 160   .debug_pubnames 0 : { *(.debug_pubnames) }
 161   /* DWARF 2 */
 162   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 163   .debug_abbrev   0 : { *(.debug_abbrev) }
 164   .debug_line     0 : { *(.debug_line) }
 165   .debug_frame    0 : { *(.debug_frame) }
 166   .debug_str      0 : { *(.debug_str) }
 167   .debug_loc      0 : { *(.debug_loc) }
 168   .debug_macinfo  0 : { *(.debug_macinfo) }
 169   /* SGI/MIPS DWARF 2 extensions */
 170   .debug_weaknames 0 : { *(.debug_weaknames) }
 171   .debug_funcnames 0 : { *(.debug_funcnames) }
 172   .debug_typenames 0 : { *(.debug_typenames) }
 173   .debug_varnames  0 : { *(.debug_varnames) }
 174 }