arch/v850/kernel/vmlinux.lds.S

   1 /*
   2  * arch/v850/vmlinux.lds.S -- kernel linker script for v850 platforms
   3  *
   4  *  Copyright (C) 2002,03,04  NEC Electronics Corporation
   5  *  Copyright (C) 2002,03,04  Miles Bader <miles@gnu.org>
   6  *
   7  * This file is subject to the terms and conditions of the GNU General
   8  * Public License.  See the file COPYING in the main directory of this
   9  * archive for more details.
  10  *
  11  * Written by Miles Bader <miles@gnu.org>
  12  */
  13
  14 #include <linux/config.h>
  15 #define VMLINUX_SYMBOL(_sym_) _##_sym_
  16 #include <asm-generic/vmlinux.lds.h>
  17
  18 /* For most platforms, this will define useful things like RAM addr/size.  */
  19 #include <asm/machdep.h>
  20
  21
  22 /* The following macros contain the usual definitions for various data areas.
  23    The prefix `RAMK_' is used to indicate macros suitable for kernels loaded
  24    into RAM, and similarly `ROMK_' for ROM-resident kernels.  Note that all
  25    symbols are prefixed with an extra `_' for compatibility with the v850
  26    toolchain.  */
  27
  28
  29 /* Interrupt vectors.  */
  30 #define INTV_CONTENTS                                                         \
  31                 . = ALIGN (0x10) ;                                            \
  32                 __intv_start = . ;                                            \
  33                         *(.intv.reset)  /* Reset vector */                    \
  34                 . = __intv_start + 0x10 ;                                     \
  35                         *(.intv.common) /* Vectors common to all v850e proc */\
  36                 . = __intv_start + 0x80 ;                                     \
  37                         *(.intv.mach)   /* Machine-specific int. vectors.  */ \
  38                 __intv_end = . ;
  39
  40 #define RODATA_CONTENTS                                                       \
  41                 . = ALIGN (16) ;                                              \
  42                         *(.rodata) *(.rodata.*)                               \
  43                         *(__vermagic)           /* Kernel version magic */    \
  44                         *(.rodata1)                                           \
  45                 /* Kernel symbol table: Normal symbols */                     \
  46                 ___start___ksymtab = .;                                       \
  47                         *(__ksymtab)                                          \
  48                 ___stop___ksymtab = .;                                        \
  49                 /* Kernel symbol table: GPL-only symbols */                   \
  50                 ___start___ksymtab_gpl = .;                                   \
  51                         *(__ksymtab_gpl)                                      \
  52                 ___stop___ksymtab_gpl = .;                                    \
  53                 /* Kernel symbol table: strings */                            \
  54                         *(__ksymtab_strings)                                  \
  55                 /* Kernel symbol table: Normal symbols */                     \
  56                 ___start___kcrctab = .;                                       \
  57                         *(__kcrctab)                                          \
  58                 ___stop___kcrctab = .;                                        \
  59                 /* Kernel symbol table: GPL-only symbols */                   \
  60                 ___start___kcrctab_gpl = .;                                   \
  61                         *(__kcrctab_gpl)                                      \
  62                 ___stop___kcrctab_gpl = .;                                    \
  63
  64 /* Kernel text segment, and some constant data areas.  */
  65 #define TEXT_CONTENTS                                                         \
  66                 __stext = . ;                                                 \
  67                 *(.text)                                                      \
  68                 SCHED_TEXT                                                    \
  69                         *(.exit.text)   /* 2.5 convention */                  \
  70                         *(.text.exit)   /* 2.4 convention */                  \
  71                         *(.text.lock)                                         \
  72                         *(.exitcall.exit)                                     \
  73                 __real_etext = . ;      /* There may be data after here.  */  \
  74                 RODATA_CONTENTS                                               \
  75                 . = ALIGN (4) ;                                               \
  76                         *(.call_table_data)                                   \
  77                         *(.call_table_text)                                   \
  78                 . = ALIGN (16) ;        /* Exception table.  */               \
  79                 ___start___ex_table = . ;                                     \
  80                         *(__ex_table)                                         \
  81                 ___stop___ex_table = . ;                                      \
  82                 . = ALIGN (4) ;                                               \
  83                 __etext = . ;
  84
  85 /* Kernel data segment.  */
  86 #define DATA_CONTENTS                                                         \
  87                 __sdata = . ;                                                 \
  88                 *(.data)                                                      \
  89                         *(.exit.data)   /* 2.5 convention */                  \
  90                         *(.data.exit)   /* 2.4 convention */                  \
  91                 . = ALIGN (16) ;                                              \
  92                 *(.data.cacheline_aligned)                                    \
  93                 . = ALIGN (0x2000) ;                                          \
  94                 *(.data.init_task)                                            \
  95                 . = ALIGN (0x2000) ;                                          \
  96                 __edata = . ;
  97
  98 /* Kernel BSS segment.  */
  99 #define BSS_CONTENTS                                                          \
 100                 __sbss = . ;                                                  \
 101                         *(.bss)                                               \
 102                         *(COMMON)                                             \
 103                 . = ALIGN (4) ;                                               \
 104                 __init_stack_end = . ;                                        \
 105                 __ebss = . ;
 106
 107 /* `initcall' tables.  */
 108 #define INITCALL_CONTENTS                                                     \
 109                 . = ALIGN (16) ;                                              \
 110                 ___setup_start = . ;                                          \
 111                         *(.init.setup)  /* 2.5 convention */                  \
 112                         *(.setup.init)  /* 2.4 convention */                  \
 113                 ___setup_end = . ;                                            \
 114                 ___initcall_start = . ;                                       \
 115                         *(.initcall.init)                                     \
 116                         *(.initcall1.init)                                    \
 117                         *(.initcall2.init)                                    \
 118                         *(.initcall3.init)                                    \
 119                         *(.initcall4.init)                                    \
 120                         *(.initcall5.init)                                    \
 121                         *(.initcall6.init)                                    \
 122                         *(.initcall7.init)                                    \
 123                 . = ALIGN (4) ;                                               \
 124                 ___initcall_end = . ;                                         \
 125                 ___con_initcall_start = .;                                    \
 126                         *(.con_initcall.init)                                 \
 127                 ___con_initcall_end = .;
 128
 129 /* Contents of `init' section for a kernel that's loaded into RAM.  */
 130 #define RAMK_INIT_CONTENTS                                                    \
 131                 RAMK_INIT_CONTENTS_NO_END                                     \
 132                 __init_end = . ;
 133 /* Same as RAMK_INIT_CONTENTS, but doesn't define the `__init_end' symbol.  */
 134 #define RAMK_INIT_CONTENTS_NO_END                                             \
 135                 . = ALIGN (4096) ;                                            \
 136                 __init_start = . ;                                            \
 137                         __sinittext = .;                                      \
 138                         *(.init.text)   /* 2.5 convention */                  \
 139                         __einittext = .;                                      \
 140                         *(.init.data)                                         \
 141                         *(.text.init)   /* 2.4 convention */                  \
 142                         *(.data.init)                                         \
 143                 INITCALL_CONTENTS                                             \
 144                 INITRAMFS_CONTENTS
 145
 146 /* The contents of `init' section for a ROM-resident kernel which
 147    should go into RAM.  */
 148 #define ROMK_INIT_RAM_CONTENTS                                                \
 149                 . = ALIGN (4096) ;                                            \
 150                 __init_start = . ;                                            \
 151                         *(.init.data)   /* 2.5 convention */                  \
 152                         *(.data.init)   /* 2.4 convention */                  \
 153                 __init_end = . ;                                              \
 154                 . = ALIGN (4096) ;
 155
 156 /* The contents of `init' section for a ROM-resident kernel which
 157    should go into ROM.  */
 158 #define ROMK_INIT_ROM_CONTENTS                                                \
 159                         _sinittext = .;                                       \
 160                         *(.init.text)   /* 2.5 convention */                  \
 161                         _einittext = .;                                       \
 162                         *(.text.init)   /* 2.4 convention */                  \
 163                 INITCALL_CONTENTS                                             \
 164                 INITRAMFS_CONTENTS
 165
 166 /* A root filesystem image, for kernels with an embedded root filesystem.  */
 167 #define ROOT_FS_CONTENTS                                                      \
 168                 __root_fs_image_start = . ;                                   \
 169                 *(.root)                                                      \
 170                 __root_fs_image_end = . ;
 171 /* The initramfs archive.  */
 172 #define INITRAMFS_CONTENTS                                                    \
 173                 . = ALIGN (4) ;                                               \
 174                 ___initramfs_start = . ;                                      \
 175                         *(.init.ramfs)                                        \
 176                 ___initramfs_end = . ;
 177 /* Where the initial bootmap (bitmap for the boot-time memory allocator)
 178    should be place.  */
 179 #define BOOTMAP_CONTENTS                                                      \
 180                 . = ALIGN (4096) ;                                            \
 181                 __bootmap = . ;                                               \
 182                 . = . + 4096 ;          /* enough for 128MB.   */
 183
 184 /* The contents of a `typical' kram area for a kernel in RAM.  */
 185 #define RAMK_KRAM_CONTENTS                                                    \
 186                 __kram_start = . ;                                            \
 187                 TEXT_CONTENTS                                                 \
 188                 DATA_CONTENTS                                                 \
 189                 BSS_CONTENTS                                                  \
 190                 RAMK_INIT_CONTENTS                                            \
 191                 __kram_end = . ;                                              \
 192                 BOOTMAP_CONTENTS
 193
 194
 195 /* Define output sections normally used for a ROM-resident kernel.
 196    ROM and RAM should be appropriate memory areas to use for kernel
 197    ROM and RAM data.  This assumes that ROM starts at 0 (and thus can
 198    hold the interrupt vectors).  */
 199 #define ROMK_SECTIONS(ROM, RAM)                                               \
 200         .rom : {                                                              \
 201                 INTV_CONTENTS                                                 \
 202                 TEXT_CONTENTS                                                 \
 203                 ROMK_INIT_ROM_CONTENTS                                        \
 204                 ROOT_FS_CONTENTS                                              \
 205         } > ROM                                                               \
 206                                                                               \
 207         __rom_copy_src_start = . ;                                            \
 208                                                                               \
 209         .data : {                                                             \
 210                 __kram_start = . ;                                            \
 211                 __rom_copy_dst_start = . ;                                    \
 212                 DATA_CONTENTS                                                 \
 213                 ROMK_INIT_RAM_CONTENTS                                        \
 214                 __rom_copy_dst_end = . ;                                      \
 215         } > RAM  AT> ROM                                                      \
 216                                                                               \
 217         .bss ALIGN (4) : {                                                    \
 218                 BSS_CONTENTS                                                  \
 219                 __kram_end = . ;                                              \
 220                 BOOTMAP_CONTENTS                                              \
 221         } > RAM
 222
 223
 224 /* The 32-bit variable `jiffies' is just the lower 32-bits of `jiffies_64'.  */
 225 _jiffies = _jiffies_64 ;
 226
 227
 228 /* Include an appropriate platform-dependent linker-script (which
 229    usually should use the above macros to do most of the work).  */
 230
 231 #ifdef CONFIG_V850E_SIM
 232 # include "sim.ld"
 233 #endif
 234
 235 #ifdef CONFIG_V850E2_SIM85E2
 236 # include "sim85e2.ld"
 237 #endif
 238
 239 #ifdef CONFIG_V850E2_FPGA85E2C
 240 # include "fpga85e2c.ld"
 241 #endif
 242
 243 #ifdef CONFIG_V850E2_ANNA
 244 # ifdef CONFIG_ROM_KERNEL
 245 #  include "anna-rom.ld"
 246 # else
 247 #  include "anna.ld"
 248 # endif
 249 #endif
 250
 251 #ifdef CONFIG_V850E_AS85EP1
 252 # ifdef CONFIG_ROM_KERNEL
 253 #  include "as85ep1-rom.ld"
 254 # else
 255 #  include "as85ep1.ld"
 256 # endif
 257 #endif
 258
 259 #ifdef CONFIG_RTE_CB_MA1
 260 # ifdef CONFIG_ROM_KERNEL
 261 #  include "rte_ma1_cb-rom.ld"
 262 # else
 263 #  include "rte_ma1_cb.ld"
 264 # endif
 265 #endif
 266
 267 #ifdef CONFIG_RTE_CB_NB85E
 268 # ifdef CONFIG_ROM_KERNEL
 269 #  include "rte_nb85e_cb-rom.ld"
 270 # elif defined(CONFIG_RTE_CB_MULTI)
 271 #  include "rte_nb85e_cb-multi.ld"
 272 # else
 273 #  include "rte_nb85e_cb.ld"
 274 # endif
 275 #endif
 276
 277 #ifdef CONFIG_RTE_CB_ME2
 278 #  include "rte_me2_cb.ld"
 279 #endif
 280