arch/x86_64/ia32/ia32entry-xen.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <asm/irqflags.h>
  17 #include <linux/linkage.h>
  18
  19 #define __XEN_X86_64 1
  20
  21 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  22
  23         .macro IA32_ARG_FIXUP noebp=0
  24         movl    %edi,%r8d
  25         .if \noebp
  26         .else
  27         movl    %ebp,%r9d
  28         .endif
  29         xchg    %ecx,%esi
  30         movl    %ebx,%edi
  31         movl    %edx,%edx       /* zero extension */
  32         .endm
  33
  34         /* clobbers %eax */
  35         .macro  CLEAR_RREGS
  36         xorl    %eax,%eax
  37         movq    %rax,R11(%rsp)
  38         movq    %rax,R10(%rsp)
  39         movq    %rax,R9(%rsp)
  40         movq    %rax,R8(%rsp)
  41         .endm
  42
  43 #if defined (__XEN_X86_64)
  44 #include "../kernel/xen_entry.S"
  45
  46 #define __swapgs
  47 #define __cli
  48 #define __sti
  49 #else
  50 /*
  51  * Use the native instructions
  52  */
  53 #define __swapgs        swapgs
  54 #define __cli           cli
  55 #define __sti           sti
  56 #endif
  57
  58         .macro CFI_STARTPROC32 simple
  59         CFI_STARTPROC   \simple
  60         CFI_UNDEFINED   r8
  61         CFI_UNDEFINED   r9
  62         CFI_UNDEFINED   r10
  63         CFI_UNDEFINED   r11
  64         CFI_UNDEFINED   r12
  65         CFI_UNDEFINED   r13
  66         CFI_UNDEFINED   r14
  67         CFI_UNDEFINED   r15
  68         .endm
  69
  70 /*
  71  * 32bit SYSENTER instruction entry.
  72  *
  73  * Arguments:
  74  * %eax System call number.
  75  * %ebx Arg1
  76  * %ecx Arg2
  77  * %edx Arg3
  78  * %esi Arg4
  79  * %edi Arg5
  80  * %ebp user stack
  81  * 0(%ebp) Arg6
  82  *
  83  * Interrupts off.
  84  *
  85  * This is purely a fast path. For anything complicated we use the int 0x80
  86  * path below.  Set up a complete hardware stack frame to share code
  87  * with the int 0x80 path.
  88  */
  89 ENTRY(ia32_sysenter_target)
  90         CFI_STARTPROC32 simple
  91         CFI_DEF_CFA     rsp,0
  92         CFI_REGISTER    rsp,rbp
  93         __swapgs
  94         movq    %gs:pda_kernelstack, %rsp
  95         addq    $(PDA_STACKOFFSET),%rsp
  96         /*
  97          * No need to follow this irqs on/off section: the syscall
  98          * disabled irqs, here we enable it straight after entry:
  99          */
 100         XEN_UNBLOCK_EVENTS(%r11)
 101         __sti
 102         movl    %ebp,%ebp               /* zero extension */
 103         pushq   $__USER32_DS
 104         CFI_ADJUST_CFA_OFFSET 8
 105         /*CFI_REL_OFFSET ss,0*/
 106         pushq   %rbp
 107         CFI_ADJUST_CFA_OFFSET 8
 108         CFI_REL_OFFSET rsp,0
 109         pushfq
 110         CFI_ADJUST_CFA_OFFSET 8
 111         /*CFI_REL_OFFSET rflags,0*/
 112         movl    $VSYSCALL32_SYSEXIT, %r10d
 113         CFI_REGISTER rip,r10
 114         pushq   $__USER32_CS
 115         CFI_ADJUST_CFA_OFFSET 8
 116         /*CFI_REL_OFFSET cs,0*/
 117         movl    %eax, %eax
 118         pushq   %r10
 119         CFI_ADJUST_CFA_OFFSET 8
 120         CFI_REL_OFFSET rip,0
 121         pushq   %rax
 122         CFI_ADJUST_CFA_OFFSET 8
 123         cld
 124         SAVE_ARGS 0,0,0
 125         /* no need to do an access_ok check here because rbp has been
 126            32bit zero extended */
 127 1:      movl    (%rbp),%r9d
 128         .section __ex_table,"a"
 129         .quad 1b,ia32_badarg
 130         .previous
 131         GET_THREAD_INFO(%r10)
 132         orl    $TS_COMPAT,threadinfo_status(%r10)
 133         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 134         CFI_REMEMBER_STATE
 135         jnz  sysenter_tracesys
 136 sysenter_do_call:
 137         cmpl    $(IA32_NR_syscalls-1),%eax
 138         ja      ia32_badsys
 139         IA32_ARG_FIXUP 1
 140         call    *ia32_sys_call_table(,%rax,8)
 141         movq    %rax,RAX-ARGOFFSET(%rsp)
 142         GET_THREAD_INFO(%r10)
 143         XEN_BLOCK_EVENTS(%r11)
 144         __cli
 145         TRACE_IRQS_OFF
 146         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 147         jnz     int_ret_from_sys_call
 148         andl    $~TS_COMPAT,threadinfo_status(%r10)
 149         /* clear IF, that popfq doesn't enable interrupts early */
 150         andl  $~0x200,EFLAGS-R11(%rsp)
 151         RESTORE_ARGS 1,24,1,1,1,1
 152         popfq
 153         CFI_ADJUST_CFA_OFFSET -8
 154         /*CFI_RESTORE rflags*/
 155         popq    %rcx                            /* User %esp */
 156         CFI_ADJUST_CFA_OFFSET -8
 157         CFI_REGISTER rsp,rcx
 158         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 159         CFI_REGISTER rip,rdx
 160         TRACE_IRQS_ON
 161         __swapgs
 162         XEN_UNBLOCK_EVENTS(%r11)
 163         __sti           /* sti only takes effect after the next instruction */
 164         /* sysexit */
 165         .byte   0xf, 0x35
 166
 167 sysenter_tracesys:
 168         CFI_RESTORE_STATE
 169         SAVE_REST
 170         CLEAR_RREGS
 171         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 172         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 173         call    syscall_trace_enter
 174         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 175         RESTORE_REST
 176         movl    %ebp, %ebp
 177         /* no need to do an access_ok check here because rbp has been
 178            32bit zero extended */
 179 1:      movl    (%rbp),%r9d
 180         .section __ex_table,"a"
 181         .quad 1b,ia32_badarg
 182         .previous
 183         jmp     sysenter_do_call
 184         CFI_ENDPROC
 185 ENDPROC(ia32_sysenter_target)
 186
 187 /*
 188  * 32bit SYSCALL instruction entry.
 189  *
 190  * Arguments:
 191  * %eax System call number.
 192  * %ebx Arg1
 193  * %ecx return EIP
 194  * %edx Arg3
 195  * %esi Arg4
 196  * %edi Arg5
 197  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 198  * %esp user stack
 199  * 0(%esp) Arg6
 200  *
 201  * Interrupts off.
 202  *
 203  * This is purely a fast path. For anything complicated we use the int 0x80
 204  * path below.  Set up a complete hardware stack frame to share code
 205  * with the int 0x80 path.
 206  */
 207 ENTRY(ia32_cstar_target)
 208         CFI_STARTPROC32 simple
 209         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 210         CFI_REGISTER    rip,rcx
 211         /*CFI_REGISTER  rflags,r11*/
 212         __swapgs
 213         movl    %esp,%r8d
 214         CFI_REGISTER    rsp,r8
 215         movq    %gs:pda_kernelstack,%rsp
 216         /*
 217          * No need to follow this irqs on/off section: the syscall
 218          * disabled irqs and here we enable it straight after entry:
 219          */
 220         XEN_UNBLOCK_EVENTS(%r11)
 221         __sti
 222         SAVE_ARGS 8,1,1
 223         movl    %eax,%eax       /* zero extension */
 224         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 225         movq    %rcx,RIP-ARGOFFSET(%rsp)
 226         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 227         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 228         movl    %ebp,%ecx
 229         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 230         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 231         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 232         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 233         movq    %r8,RSP-ARGOFFSET(%rsp)
 234         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 235         /* no need to do an access_ok check here because r8 has been
 236            32bit zero extended */
 237         /* hardware stack frame is complete now */
 238 1:      movl    (%r8),%r9d
 239         .section __ex_table,"a"
 240         .quad 1b,ia32_badarg
 241         .previous
 242         GET_THREAD_INFO(%r10)
 243         orl   $TS_COMPAT,threadinfo_status(%r10)
 244         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 245         CFI_REMEMBER_STATE
 246         jnz   cstar_tracesys
 247 cstar_do_call:
 248         cmpl $IA32_NR_syscalls-1,%eax
 249         ja  ia32_badsys
 250         IA32_ARG_FIXUP 1
 251         call *ia32_sys_call_table(,%rax,8)
 252         movq %rax,RAX-ARGOFFSET(%rsp)
 253         GET_THREAD_INFO(%r10)
 254         XEN_BLOCK_EVENTS(%r11)
 255         __cli
 256         TRACE_IRQS_OFF
 257         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 258         jnz  int_ret_from_sys_call
 259         andl $~TS_COMPAT,threadinfo_status(%r10)
 260         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 261         movl RIP-ARGOFFSET(%rsp),%ecx
 262         CFI_REGISTER rip,rcx
 263         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 264         /*CFI_REGISTER rflags,r11*/
 265         TRACE_IRQS_ON
 266         movl RSP-ARGOFFSET(%rsp),%esp
 267         CFI_RESTORE rsp
 268         __swapgs
 269         sysretl
 270
 271 cstar_tracesys:
 272         CFI_RESTORE_STATE
 273         SAVE_REST
 274         CLEAR_RREGS
 275         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 276         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 277         call syscall_trace_enter
 278         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 279         RESTORE_REST
 280         movl RSP-ARGOFFSET(%rsp), %r8d
 281         /* no need to do an access_ok check here because r8 has been
 282            32bit zero extended */
 283 1:      movl    (%r8),%r9d
 284         .section __ex_table,"a"
 285         .quad 1b,ia32_badarg
 286         .previous
 287         jmp cstar_do_call
 288 END(ia32_cstar_target)
 289
 290 ia32_badarg:
 291         movq $-EFAULT,%rax
 292         jmp ia32_sysret
 293         CFI_ENDPROC
 294
 295 /*
 296  * Emulated IA32 system calls via int 0x80.
 297  *
 298  * Arguments:
 299  * %eax System call number.
 300  * %ebx Arg1
 301  * %ecx Arg2
 302  * %edx Arg3
 303  * %esi Arg4
 304  * %edi Arg5
 305  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 306  *
 307  * Notes:
 308  * Uses the same stack frame as the x86-64 version.
 309  * All registers except %eax must be saved (but ptrace may violate that)
 310  * Arguments are zero extended. For system calls that want sign extension and
 311  * take long arguments a wrapper is needed. Most calls can just be called
 312  * directly.
 313  * Assumes it is only called from user space and entered with interrupts off.
 314  */
 315
 316 ENTRY(ia32_syscall)
 317         CFI_STARTPROC   simple
 318         CFI_DEF_CFA     rsp,SS+8-RIP
 319         /*CFI_REL_OFFSET        ss,SS-RIP*/
 320         CFI_REL_OFFSET  rsp,RSP-RIP
 321         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 322         /*CFI_REL_OFFSET        cs,CS-RIP*/
 323         CFI_REL_OFFSET  rip,RIP-RIP
 324         __swapgs
 325         /*
 326          * No need to follow this irqs on/off section: the syscall
 327          * disabled irqs and here we enable it straight after entry:
 328          */
 329         XEN_UNBLOCK_EVENTS(%r11)
 330         __sti
 331         movq (%rsp),%rcx
 332         movq 8(%rsp),%r11
 333         addq $0x10,%rsp /* skip rcx and r11 */
 334         movl %eax,%eax
 335         pushq %rax
 336         CFI_ADJUST_CFA_OFFSET 8
 337         cld
 338         /* note the registers are not zero extended to the sf.
 339            this could be a problem. */
 340         SAVE_ARGS 0,0,1
 341         GET_THREAD_INFO(%r10)
 342         orl   $TS_COMPAT,threadinfo_status(%r10)
 343         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 344         jnz ia32_tracesys
 345 ia32_do_syscall:
 346         cmpl $(IA32_NR_syscalls-1),%eax
 347         ja  ia32_badsys
 348         IA32_ARG_FIXUP
 349         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 350 ia32_sysret:
 351         movq %rax,RAX-ARGOFFSET(%rsp)
 352         jmp int_ret_from_sys_call
 353
 354 ia32_tracesys:
 355         SAVE_REST
 356         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 357         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 358         call syscall_trace_enter
 359         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 360         RESTORE_REST
 361         jmp ia32_do_syscall
 362 END(ia32_syscall)
 363
 364 ia32_badsys:
 365         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 366         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 367         jmp int_ret_from_sys_call
 368
 369 quiet_ni_syscall:
 370         movq $-ENOSYS,%rax
 371         ret
 372         CFI_ENDPROC
 373
 374         .macro PTREGSCALL label, func, arg
 375         .globl \label
 376 \label:
 377         leaq \func(%rip),%rax
 378         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 379         jmp  ia32_ptregs_common
 380         .endm
 381
 382         CFI_STARTPROC32
 383
 384         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 385         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 386         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 387         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 388         PTREGSCALL stub32_execve, sys32_execve, %rcx
 389         PTREGSCALL stub32_fork, sys_fork, %rdi
 390         PTREGSCALL stub32_clone, sys32_clone, %rdx
 391         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 392         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 393         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 394
 395 ENTRY(ia32_ptregs_common)
 396         popq %r11
 397         CFI_ENDPROC
 398         CFI_STARTPROC32 simple
 399         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 400         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 401         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 402         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 403         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 404         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 405         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 406 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 407 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 408         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 409 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 410         SAVE_REST
 411         call *%rax
 412         RESTORE_REST
 413         jmp  ia32_sysret        /* misbalances the return cache */
 414         CFI_ENDPROC
 415 END(ia32_ptregs_common)
 416
 417         .section .rodata,"a"
 418         .align 8
 419 ia32_sys_call_table:
 420         .quad sys_restart_syscall
 421         .quad sys_exit
 422         .quad stub32_fork
 423         .quad sys_read
 424         .quad sys_write
 425         .quad compat_sys_open           /* 5 */
 426         .quad sys_close
 427         .quad sys32_waitpid
 428         .quad sys_creat
 429         .quad sys_link
 430         .quad sys_unlink                /* 10 */
 431         .quad stub32_execve
 432         .quad sys_chdir
 433         .quad compat_sys_time
 434         .quad sys_mknod
 435         .quad sys_chmod         /* 15 */
 436         .quad sys_lchown16
 437         .quad quiet_ni_syscall                  /* old break syscall holder */
 438         .quad sys_stat
 439         .quad sys32_lseek
 440         .quad sys_getpid                /* 20 */
 441         .quad compat_sys_mount  /* mount  */
 442         .quad sys_oldumount     /* old_umount  */
 443         .quad sys_setuid16
 444         .quad sys_getuid16
 445         .quad compat_sys_stime  /* stime */             /* 25 */
 446         .quad compat_sys_ptrace /* ptrace */
 447         .quad sys_alarm
 448         .quad sys_fstat /* (old)fstat */
 449         .quad sys_pause
 450         .quad compat_sys_utime  /* 30 */
 451         .quad quiet_ni_syscall  /* old stty syscall holder */
 452         .quad quiet_ni_syscall  /* old gtty syscall holder */
 453         .quad sys_access
 454         .quad sys_nice
 455         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 456         .quad sys_sync
 457         .quad sys32_kill
 458         .quad sys_rename
 459         .quad sys_mkdir
 460         .quad sys_rmdir         /* 40 */
 461         .quad sys_dup
 462         .quad sys32_pipe
 463         .quad compat_sys_times
 464         .quad quiet_ni_syscall                  /* old prof syscall holder */
 465         .quad sys_brk           /* 45 */
 466         .quad sys_setgid16
 467         .quad sys_getgid16
 468         .quad sys_signal
 469         .quad sys_geteuid16
 470         .quad sys_getegid16     /* 50 */
 471         .quad sys_acct
 472         .quad sys_umount                        /* new_umount */
 473         .quad quiet_ni_syscall                  /* old lock syscall holder */
 474         .quad compat_sys_ioctl
 475         .quad compat_sys_fcntl64                /* 55 */
 476 #ifdef CONFIG_TUX
 477         .quad __sys_tux
 478 #else
 479 # ifdef CONFIG_TUX_MODULE
 480         .quad sys_tux
 481 # else
 482         .quad quiet_ni_syscall
 483 # endif
 484 #endif
 485         .quad sys_setpgid
 486         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 487         .quad sys32_olduname
 488         .quad sys_umask         /* 60 */
 489         .quad sys_chroot
 490         .quad sys32_ustat
 491         .quad sys_dup2
 492         .quad sys_getppid
 493         .quad sys_getpgrp               /* 65 */
 494         .quad sys_setsid
 495         .quad sys32_sigaction
 496         .quad sys_sgetmask
 497         .quad sys_ssetmask
 498         .quad sys_setreuid16    /* 70 */
 499         .quad sys_setregid16
 500         .quad stub32_sigsuspend
 501         .quad compat_sys_sigpending
 502         .quad sys_sethostname
 503         .quad compat_sys_setrlimit      /* 75 */
 504         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 505         .quad compat_sys_getrusage
 506         .quad sys32_gettimeofday
 507         .quad sys32_settimeofday
 508         .quad sys_getgroups16   /* 80 */
 509         .quad sys_setgroups16
 510         .quad sys32_old_select
 511         .quad sys_symlink
 512         .quad sys_lstat
 513         .quad sys_readlink              /* 85 */
 514 #ifdef CONFIG_IA32_AOUT
 515         .quad sys_uselib
 516 #else
 517         .quad quiet_ni_syscall
 518 #endif
 519         .quad sys_swapon
 520         .quad sys_reboot
 521         .quad compat_sys_old_readdir
 522         .quad sys32_mmap                /* 90 */
 523         .quad sys_munmap
 524         .quad sys_truncate
 525         .quad sys_ftruncate
 526         .quad sys_fchmod
 527         .quad sys_fchown16              /* 95 */
 528         .quad sys_getpriority
 529         .quad sys_setpriority
 530         .quad quiet_ni_syscall                  /* old profil syscall holder */
 531         .quad compat_sys_statfs
 532         .quad compat_sys_fstatfs                /* 100 */
 533         .quad sys_ioperm
 534         .quad compat_sys_socketcall
 535         .quad sys_syslog
 536         .quad compat_sys_setitimer
 537         .quad compat_sys_getitimer      /* 105 */
 538         .quad compat_sys_newstat
 539         .quad compat_sys_newlstat
 540         .quad compat_sys_newfstat
 541         .quad sys32_uname
 542         .quad stub32_iopl               /* 110 */
 543         .quad sys_vhangup
 544         .quad quiet_ni_syscall  /* old "idle" system call */
 545         .quad sys32_vm86_warning        /* vm86old */
 546         .quad compat_sys_wait4
 547         .quad sys_swapoff               /* 115 */
 548         .quad sys32_sysinfo
 549         .quad sys32_ipc
 550         .quad sys_fsync
 551         .quad stub32_sigreturn
 552         .quad stub32_clone              /* 120 */
 553         .quad sys_setdomainname
 554         .quad sys_uname
 555         .quad sys_modify_ldt
 556         .quad compat_sys_adjtimex
 557         .quad sys32_mprotect            /* 125 */
 558         .quad compat_sys_sigprocmask
 559         .quad quiet_ni_syscall          /* create_module */
 560         .quad sys_init_module
 561         .quad sys_delete_module
 562         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 563         .quad sys_quotactl
 564         .quad sys_getpgid
 565         .quad sys_fchdir
 566         .quad quiet_ni_syscall  /* bdflush */
 567         .quad sys_sysfs         /* 135 */
 568         .quad sys_personality
 569         .quad quiet_ni_syscall  /* for afs_syscall */
 570         .quad sys_setfsuid16
 571         .quad sys_setfsgid16
 572         .quad sys_llseek                /* 140 */
 573         .quad compat_sys_getdents
 574         .quad compat_sys_select
 575         .quad sys_flock
 576         .quad sys_msync
 577         .quad compat_sys_readv          /* 145 */
 578         .quad compat_sys_writev
 579         .quad sys_getsid
 580         .quad sys_fdatasync
 581         .quad sys32_sysctl      /* sysctl */
 582         .quad sys_mlock         /* 150 */
 583         .quad sys_munlock
 584         .quad sys_mlockall
 585         .quad sys_munlockall
 586         .quad sys_sched_setparam
 587         .quad sys_sched_getparam   /* 155 */
 588         .quad sys_sched_setscheduler
 589         .quad sys_sched_getscheduler
 590         .quad sys_sched_yield
 591         .quad sys_sched_get_priority_max
 592         .quad sys_sched_get_priority_min  /* 160 */
 593         .quad sys_sched_rr_get_interval
 594         .quad compat_sys_nanosleep
 595         .quad sys_mremap
 596         .quad sys_setresuid16
 597         .quad sys_getresuid16   /* 165 */
 598         .quad sys32_vm86_warning        /* vm86 */
 599         .quad quiet_ni_syscall  /* query_module */
 600         .quad sys_poll
 601         .quad compat_sys_nfsservctl
 602         .quad sys_setresgid16   /* 170 */
 603         .quad sys_getresgid16
 604         .quad sys_prctl
 605         .quad stub32_rt_sigreturn
 606         .quad sys32_rt_sigaction
 607         .quad sys32_rt_sigprocmask      /* 175 */
 608         .quad sys32_rt_sigpending
 609         .quad compat_sys_rt_sigtimedwait
 610         .quad sys32_rt_sigqueueinfo
 611         .quad stub32_rt_sigsuspend
 612         .quad sys32_pread               /* 180 */
 613         .quad sys32_pwrite
 614         .quad sys_chown16
 615         .quad sys_getcwd
 616         .quad sys_capget
 617         .quad sys_capset
 618         .quad stub32_sigaltstack
 619         .quad sys32_sendfile
 620         .quad quiet_ni_syscall          /* streams1 */
 621         .quad quiet_ni_syscall          /* streams2 */
 622         .quad stub32_vfork            /* 190 */
 623         .quad compat_sys_getrlimit
 624         .quad sys32_mmap2
 625         .quad sys32_truncate64
 626         .quad sys32_ftruncate64
 627         .quad sys32_stat64              /* 195 */
 628         .quad sys32_lstat64
 629         .quad sys32_fstat64
 630         .quad sys_lchown
 631         .quad sys_getuid
 632         .quad sys_getgid                /* 200 */
 633         .quad sys_geteuid
 634         .quad sys_getegid
 635         .quad sys_setreuid
 636         .quad sys_setregid
 637         .quad sys_getgroups     /* 205 */
 638         .quad sys_setgroups
 639         .quad sys_fchown
 640         .quad sys_setresuid
 641         .quad sys_getresuid
 642         .quad sys_setresgid     /* 210 */
 643         .quad sys_getresgid
 644         .quad sys_chown
 645         .quad sys_setuid
 646         .quad sys_setgid
 647         .quad sys_setfsuid              /* 215 */
 648         .quad sys_setfsgid
 649         .quad sys_pivot_root
 650         .quad sys_mincore
 651         .quad sys_madvise
 652         .quad compat_sys_getdents64     /* 220 getdents64 */
 653         .quad compat_sys_fcntl64
 654         .quad quiet_ni_syscall          /* tux */
 655         .quad quiet_ni_syscall          /* security */
 656         .quad sys_gettid
 657         .quad sys_readahead     /* 225 */
 658         .quad sys_setxattr
 659         .quad sys_lsetxattr
 660         .quad sys_fsetxattr
 661         .quad sys_getxattr
 662         .quad sys_lgetxattr     /* 230 */
 663         .quad sys_fgetxattr
 664         .quad sys_listxattr
 665         .quad sys_llistxattr
 666         .quad sys_flistxattr
 667         .quad sys_removexattr   /* 235 */
 668         .quad sys_lremovexattr
 669         .quad sys_fremovexattr
 670         .quad sys_tkill
 671         .quad sys_sendfile64
 672         .quad compat_sys_futex          /* 240 */
 673         .quad compat_sys_sched_setaffinity
 674         .quad compat_sys_sched_getaffinity
 675         .quad sys32_set_thread_area
 676         .quad sys32_get_thread_area
 677         .quad compat_sys_io_setup       /* 245 */
 678         .quad sys_io_destroy
 679         .quad compat_sys_io_getevents
 680         .quad compat_sys_io_submit
 681         .quad sys_io_cancel
 682         .quad sys_fadvise64             /* 250 */
 683         .quad quiet_ni_syscall  /* free_huge_pages */
 684         .quad sys_exit_group
 685         .quad sys32_lookup_dcookie
 686         .quad sys_epoll_create
 687         .quad sys_epoll_ctl             /* 255 */
 688         .quad sys_epoll_wait
 689         .quad sys_remap_file_pages
 690         .quad sys_set_tid_address
 691         .quad compat_sys_timer_create
 692         .quad compat_sys_timer_settime  /* 260 */
 693         .quad compat_sys_timer_gettime
 694         .quad sys_timer_getoverrun
 695         .quad sys_timer_delete
 696         .quad compat_sys_clock_settime
 697         .quad compat_sys_clock_gettime  /* 265 */
 698         .quad compat_sys_clock_getres
 699         .quad compat_sys_clock_nanosleep
 700         .quad compat_sys_statfs64
 701         .quad compat_sys_fstatfs64
 702         .quad sys_tgkill                /* 270 */
 703         .quad compat_sys_utimes
 704         .quad sys32_fadvise64_64
 705         .quad sys32_vserver
 706         .quad sys_mbind
 707         .quad compat_sys_get_mempolicy  /* 275 */
 708         .quad sys_set_mempolicy
 709         .quad compat_sys_mq_open
 710         .quad sys_mq_unlink
 711         .quad compat_sys_mq_timedsend
 712         .quad compat_sys_mq_timedreceive        /* 280 */
 713         .quad compat_sys_mq_notify
 714         .quad compat_sys_mq_getsetattr
 715         .quad compat_sys_kexec_load     /* reserved for kexec */
 716         .quad compat_sys_waitid
 717         .quad quiet_ni_syscall          /* 285: sys_altroot */
 718         .quad sys_add_key
 719         .quad sys_request_key
 720         .quad sys_keyctl
 721         .quad sys_ioprio_set
 722         .quad sys_ioprio_get            /* 290 */
 723         .quad sys_inotify_init
 724         .quad sys_inotify_add_watch
 725         .quad sys_inotify_rm_watch
 726         .quad sys_migrate_pages
 727         .quad compat_sys_openat         /* 295 */
 728         .quad sys_mkdirat
 729         .quad sys_mknodat
 730         .quad sys_fchownat
 731         .quad compat_sys_futimesat
 732         .quad sys32_fstatat             /* 300 */
 733         .quad sys_unlinkat
 734         .quad sys_renameat
 735         .quad sys_linkat
 736         .quad sys_symlinkat
 737         .quad sys_readlinkat            /* 305 */
 738         .quad sys_fchmodat
 739         .quad sys_faccessat
 740         .quad compat_sys_pselect6
 741         .quad compat_sys_ppoll
 742         .quad sys_unshare               /* 310 */
 743         .quad compat_sys_set_robust_list
 744         .quad compat_sys_get_robust_list
 745         .quad sys_splice
 746         .quad sys_sync_file_range
 747         .quad sys_tee
 748         .quad compat_sys_vmsplice
 749         .quad compat_sys_move_pages
 750         .quad sys_getcpu
 751 ia32_syscall_end: