arch/x86_64/ia32/ia32entry-xen.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <asm/irqflags.h>
  17 #include <linux/linkage.h>
  18
  19 #define __XEN_X86_64 1
  20
  21 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  22
  23         .macro IA32_ARG_FIXUP noebp=0
  24         movl    %edi,%r8d
  25         .if \noebp
  26         .else
  27         movl    %ebp,%r9d
  28         .endif
  29         xchg    %ecx,%esi
  30         movl    %ebx,%edi
  31         movl    %edx,%edx       /* zero extension */
  32         .endm
  33
  34         /* clobbers %eax */
  35         .macro  CLEAR_RREGS
  36         xorl    %eax,%eax
  37         movq    %rax,R11(%rsp)
  38         movq    %rax,R10(%rsp)
  39         movq    %rax,R9(%rsp)
  40         movq    %rax,R8(%rsp)
  41         .endm
  42
  43 #if defined (__XEN_X86_64)
  44 #include "../kernel/xen_entry.S"
  45
  46 #define __swapgs
  47 #define __cli
  48 #define __sti
  49 #else
  50 /*
  51  * Use the native instructions
  52  */
  53 #define __swapgs        swapgs
  54 #define __cli           cli
  55 #define __sti           sti
  56 #endif
  57
  58         .macro CFI_STARTPROC32 simple
  59         CFI_STARTPROC   \simple
  60         CFI_UNDEFINED   r8
  61         CFI_UNDEFINED   r9
  62         CFI_UNDEFINED   r10
  63         CFI_UNDEFINED   r11
  64         CFI_UNDEFINED   r12
  65         CFI_UNDEFINED   r13
  66         CFI_UNDEFINED   r14
  67         CFI_UNDEFINED   r15
  68         .endm
  69
  70 /*
  71  * 32bit SYSENTER instruction entry.
  72  *
  73  * Arguments:
  74  * %eax System call number.
  75  * %ebx Arg1
  76  * %ecx Arg2
  77  * %edx Arg3
  78  * %esi Arg4
  79  * %edi Arg5
  80  * %ebp user stack
  81  * 0(%ebp) Arg6
  82  *
  83  * Interrupts off.
  84  *
  85  * This is purely a fast path. For anything complicated we use the int 0x80
  86  * path below.  Set up a complete hardware stack frame to share code
  87  * with the int 0x80 path.
  88  */
  89 ENTRY(ia32_sysenter_target)
  90         CFI_STARTPROC32 simple
  91         CFI_DEF_CFA     rsp,0
  92         CFI_REGISTER    rsp,rbp
  93         __swapgs
  94         movq    %gs:pda_kernelstack, %rsp
  95         addq    $(PDA_STACKOFFSET),%rsp
  96         /*
  97          * No need to follow this irqs on/off section: the syscall
  98          * disabled irqs, here we enable it straight after entry:
  99          */
 100         XEN_UNBLOCK_EVENTS(%r11)
 101         __sti
 102         movl    %ebp,%ebp               /* zero extension */
 103         pushq   $__USER32_DS
 104         CFI_ADJUST_CFA_OFFSET 8
 105         /*CFI_REL_OFFSET ss,0*/
 106         pushq   %rbp
 107         CFI_ADJUST_CFA_OFFSET 8
 108         CFI_REL_OFFSET rsp,0
 109         pushfq
 110         CFI_ADJUST_CFA_OFFSET 8
 111         /*CFI_REL_OFFSET rflags,0*/
 112         movl    $VSYSCALL32_SYSEXIT, %r10d
 113         CFI_REGISTER rip,r10
 114         pushq   $__USER32_CS
 115         CFI_ADJUST_CFA_OFFSET 8
 116         /*CFI_REL_OFFSET cs,0*/
 117         movl    %eax, %eax
 118         pushq   %r10
 119         CFI_ADJUST_CFA_OFFSET 8
 120         CFI_REL_OFFSET rip,0
 121         pushq   %rax
 122         CFI_ADJUST_CFA_OFFSET 8
 123         cld
 124         SAVE_ARGS 0,0,0
 125         /* no need to do an access_ok check here because rbp has been
 126            32bit zero extended */
 127 1:      movl    (%rbp),%r9d
 128         .section __ex_table,"a"
 129         .quad 1b,ia32_badarg
 130         .previous
 131         GET_THREAD_INFO(%r10)
 132         orl    $TS_COMPAT,threadinfo_status(%r10)
 133         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 134         CFI_REMEMBER_STATE
 135         jnz  sysenter_tracesys
 136 sysenter_do_call:
 137         cmpl    $(IA32_NR_syscalls-1),%eax
 138         ja      ia32_badsys
 139         IA32_ARG_FIXUP 1
 140         call    *ia32_sys_call_table(,%rax,8)
 141         movq    %rax,RAX-ARGOFFSET(%rsp)
 142         GET_THREAD_INFO(%r10)
 143         XEN_BLOCK_EVENTS(%r11)
 144         __cli
 145         TRACE_IRQS_OFF
 146         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 147         jnz     int_ret_from_sys_call
 148         andl    $~TS_COMPAT,threadinfo_status(%r10)
 149         /* clear IF, that popfq doesn't enable interrupts early */
 150         andl  $~0x200,EFLAGS-R11(%rsp)
 151         RESTORE_ARGS 1,24,1,1,1,1
 152         popfq
 153         CFI_ADJUST_CFA_OFFSET -8
 154         /*CFI_RESTORE rflags*/
 155         popq    %rcx                            /* User %esp */
 156         CFI_ADJUST_CFA_OFFSET -8
 157         CFI_REGISTER rsp,rcx
 158         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 159         CFI_REGISTER rip,rdx
 160         TRACE_IRQS_ON
 161         __swapgs
 162         XEN_UNBLOCK_EVENTS(%r11)
 163         __sti           /* sti only takes effect after the next instruction */
 164         /* sysexit */
 165         .byte   0xf, 0x35  /* TBD */
 166
 167 sysenter_tracesys:
 168         CFI_RESTORE_STATE
 169         SAVE_REST
 170         CLEAR_RREGS
 171         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 172         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 173         call    syscall_trace_enter
 174         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 175         RESTORE_REST
 176         movl    %ebp, %ebp
 177         /* no need to do an access_ok check here because rbp has been
 178            32bit zero extended */
 179 1:      movl    (%rbp),%r9d
 180         .section __ex_table,"a"
 181         .quad 1b,ia32_badarg
 182         .previous
 183         jmp     sysenter_do_call
 184         CFI_ENDPROC
 185 ENDPROC(ia32_sysenter_target)
 186
 187 /*
 188  * 32bit SYSCALL instruction entry.
 189  *
 190  * Arguments:
 191  * %eax System call number.
 192  * %ebx Arg1
 193  * %ecx return EIP
 194  * %edx Arg3
 195  * %esi Arg4
 196  * %edi Arg5
 197  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 198  * %esp user stack
 199  * 0(%esp) Arg6
 200  *
 201  * Interrupts off.
 202  *
 203  * This is purely a fast path. For anything complicated we use the int 0x80
 204  * path below.  Set up a complete hardware stack frame to share code
 205  * with the int 0x80 path.
 206  */
 207 ENTRY(ia32_cstar_target)
 208         CFI_STARTPROC32 simple
 209         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 210         CFI_REGISTER    rip,rcx
 211         /*CFI_REGISTER  rflags,r11*/
 212         __swapgs
 213         movl    %esp,%r8d
 214         CFI_REGISTER    rsp,r8
 215         movq    %gs:pda_kernelstack,%rsp
 216         /*
 217          * No need to follow this irqs on/off section: the syscall
 218          * disabled irqs and here we enable it straight after entry:
 219          */
 220         XEN_UNBLOCK_EVENTS(%r11)
 221         __sti
 222         SAVE_ARGS 8,1,1
 223         movl    %eax,%eax       /* zero extension */
 224         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 225         movq    %rcx,RIP-ARGOFFSET(%rsp)
 226         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 227         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 228         movl    %ebp,%ecx
 229         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 230         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 231         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 232         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 233         movq    %r8,RSP-ARGOFFSET(%rsp)
 234         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 235         /* no need to do an access_ok check here because r8 has been
 236            32bit zero extended */
 237         /* hardware stack frame is complete now */
 238 1:      movl    (%r8),%r9d
 239         .section __ex_table,"a"
 240         .quad 1b,ia32_badarg
 241         .previous
 242         GET_THREAD_INFO(%r10)
 243         orl   $TS_COMPAT,threadinfo_status(%r10)
 244         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 245         CFI_REMEMBER_STATE
 246         jnz   cstar_tracesys
 247 cstar_do_call:
 248         cmpl $IA32_NR_syscalls-1,%eax
 249         ja  ia32_badsys
 250         IA32_ARG_FIXUP 1
 251         call *ia32_sys_call_table(,%rax,8)
 252         movq %rax,RAX-ARGOFFSET(%rsp)
 253         GET_THREAD_INFO(%r10)
 254         XEN_BLOCK_EVENTS(%r11)
 255         __cli
 256         TRACE_IRQS_OFF
 257         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 258         jnz  int_ret_from_sys_call
 259         andl $~TS_COMPAT,threadinfo_status(%r10)
 260         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 261         movl RIP-ARGOFFSET(%rsp),%ecx
 262         CFI_REGISTER rip,rcx
 263         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 264         /*CFI_REGISTER rflags,r11*/
 265         TRACE_IRQS_ON
 266         movl RSP-ARGOFFSET(%rsp),%esp
 267         CFI_RESTORE rsp
 268         __swapgs
 269         sysretl  /* TBD */
 270
 271 cstar_tracesys:
 272         CFI_RESTORE_STATE
 273         SAVE_REST
 274         CLEAR_RREGS
 275         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 276         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 277         call syscall_trace_enter
 278         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 279         RESTORE_REST
 280         movl RSP-ARGOFFSET(%rsp), %r8d
 281         /* no need to do an access_ok check here because r8 has been
 282            32bit zero extended */
 283 1:      movl    (%r8),%r9d
 284         .section __ex_table,"a"
 285         .quad 1b,ia32_badarg
 286         .previous
 287         jmp cstar_do_call
 288 END(ia32_cstar_target)
 289
 290 ia32_badarg:
 291         movq $-EFAULT,%rax
 292         jmp ia32_sysret
 293         CFI_ENDPROC
 294
 295 /*
 296  * Emulated IA32 system calls via int 0x80.
 297  *
 298  * Arguments:
 299  * %eax System call number.
 300  * %ebx Arg1
 301  * %ecx Arg2
 302  * %edx Arg3
 303  * %esi Arg4
 304  * %edi Arg5
 305  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 306  *
 307  * Notes:
 308  * Uses the same stack frame as the x86-64 version.
 309  * All registers except %eax must be saved (but ptrace may violate that)
 310  * Arguments are zero extended. For system calls that want sign extension and
 311  * take long arguments a wrapper is needed. Most calls can just be called
 312  * directly.
 313  * Assumes it is only called from user space and entered with interrupts off.
 314  */
 315
 316 ENTRY(ia32_syscall)
 317         CFI_STARTPROC   simple
 318         CFI_DEF_CFA     rsp,SS+8-RIP
 319         /*CFI_REL_OFFSET        ss,SS-RIP*/
 320         CFI_REL_OFFSET  rsp,RSP-RIP
 321         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 322         /*CFI_REL_OFFSET        cs,CS-RIP*/
 323         CFI_REL_OFFSET  rip,RIP-RIP
 324         __swapgs
 325         /*
 326          * No need to follow this irqs on/off section: the syscall
 327          * disabled irqs and here we enable it straight after entry:
 328          */
 329         XEN_UNBLOCK_EVENTS(%r11)
 330         __sti
 331         movq (%rsp),%rcx
 332         movq 8(%rsp),%r11
 333         addq $0x10,%rsp /* skip rcx and r11 */
 334         movl %eax,%eax
 335         pushq %rax
 336         CFI_ADJUST_CFA_OFFSET 8
 337         cld
 338 /* 1:   jmp 1b   */
 339         /* note the registers are not zero extended to the sf.
 340            this could be a problem. */
 341         SAVE_ARGS 0,0,1
 342         GET_THREAD_INFO(%r10)
 343         orl   $TS_COMPAT,threadinfo_status(%r10)
 344         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 345         jnz ia32_tracesys
 346 ia32_do_syscall:
 347         cmpl $(IA32_NR_syscalls-1),%eax
 348         ja  ia32_badsys
 349         IA32_ARG_FIXUP
 350         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 351 ia32_sysret:
 352         movq %rax,RAX-ARGOFFSET(%rsp)
 353         jmp int_ret_from_sys_call
 354
 355 ia32_tracesys:
 356         SAVE_REST
 357         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 358         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 359         call syscall_trace_enter
 360         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 361         RESTORE_REST
 362         jmp ia32_do_syscall
 363 END(ia32_syscall)
 364
 365 ia32_badsys:
 366         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 367         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 368         jmp int_ret_from_sys_call
 369
 370 quiet_ni_syscall:
 371         movq $-ENOSYS,%rax
 372         ret
 373         CFI_ENDPROC
 374
 375         .macro PTREGSCALL label, func, arg
 376         .globl \label
 377 \label:
 378         leaq \func(%rip),%rax
 379         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 380         jmp  ia32_ptregs_common
 381         .endm
 382
 383         CFI_STARTPROC32
 384
 385         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 386         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 387         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 388         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 389         PTREGSCALL stub32_execve, sys32_execve, %rcx
 390         PTREGSCALL stub32_fork, sys_fork, %rdi
 391         PTREGSCALL stub32_clone, sys32_clone, %rdx
 392         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 393         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 394         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 395
 396 ENTRY(ia32_ptregs_common)
 397         popq %r11
 398         CFI_ENDPROC
 399         CFI_STARTPROC32 simple
 400         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 401         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 402         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 403         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 404         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 405         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 406         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 407 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 408 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 409         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 410 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 411         SAVE_REST
 412         call *%rax
 413         RESTORE_REST
 414         jmp  ia32_sysret        /* misbalances the return cache */
 415         CFI_ENDPROC
 416 END(ia32_ptregs_common)
 417
 418         .section .rodata,"a"
 419         .align 8
 420 ia32_sys_call_table:
 421         .quad sys_restart_syscall
 422         .quad sys_exit
 423         .quad stub32_fork
 424         .quad sys_read
 425         .quad sys_write
 426         .quad compat_sys_open           /* 5 */
 427         .quad sys_close
 428         .quad sys32_waitpid
 429         .quad sys_creat
 430         .quad sys_link
 431         .quad sys_unlink                /* 10 */
 432         .quad stub32_execve
 433         .quad sys_chdir
 434         .quad compat_sys_time
 435         .quad sys_mknod
 436         .quad sys_chmod         /* 15 */
 437         .quad sys_lchown16
 438         .quad quiet_ni_syscall                  /* old break syscall holder */
 439         .quad sys_stat
 440         .quad sys32_lseek
 441         .quad sys_getpid                /* 20 */
 442         .quad compat_sys_mount  /* mount  */
 443         .quad sys_oldumount     /* old_umount  */
 444         .quad sys_setuid16
 445         .quad sys_getuid16
 446         .quad compat_sys_stime  /* stime */             /* 25 */
 447         .quad sys32_ptrace      /* ptrace */
 448         .quad sys_alarm
 449         .quad sys_fstat /* (old)fstat */
 450         .quad sys_pause
 451         .quad compat_sys_utime  /* 30 */
 452         .quad quiet_ni_syscall  /* old stty syscall holder */
 453         .quad quiet_ni_syscall  /* old gtty syscall holder */
 454         .quad sys_access
 455         .quad sys_nice
 456         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 457         .quad sys_sync
 458         .quad sys32_kill
 459         .quad sys_rename
 460         .quad sys_mkdir
 461         .quad sys_rmdir         /* 40 */
 462         .quad sys_dup
 463         .quad sys32_pipe
 464         .quad compat_sys_times
 465         .quad quiet_ni_syscall                  /* old prof syscall holder */
 466         .quad sys_brk           /* 45 */
 467         .quad sys_setgid16
 468         .quad sys_getgid16
 469         .quad sys_signal
 470         .quad sys_geteuid16
 471         .quad sys_getegid16     /* 50 */
 472         .quad sys_acct
 473         .quad sys_umount                        /* new_umount */
 474         .quad quiet_ni_syscall                  /* old lock syscall holder */
 475         .quad compat_sys_ioctl
 476         .quad compat_sys_fcntl64                /* 55 */
 477 #ifdef CONFIG_TUX
 478         .quad __sys_tux
 479 #else
 480 # ifdef CONFIG_TUX_MODULE
 481         .quad sys_tux
 482 # else
 483         .quad quiet_ni_syscall
 484 # endif
 485 #endif
 486         .quad sys_setpgid
 487         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 488         .quad sys32_olduname
 489         .quad sys_umask         /* 60 */
 490         .quad sys_chroot
 491         .quad sys32_ustat
 492         .quad sys_dup2
 493         .quad sys_getppid
 494         .quad sys_getpgrp               /* 65 */
 495         .quad sys_setsid
 496         .quad sys32_sigaction
 497         .quad sys_sgetmask
 498         .quad sys_ssetmask
 499         .quad sys_setreuid16    /* 70 */
 500         .quad sys_setregid16
 501         .quad stub32_sigsuspend
 502         .quad compat_sys_sigpending
 503         .quad sys_sethostname
 504         .quad compat_sys_setrlimit      /* 75 */
 505         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 506         .quad compat_sys_getrusage
 507         .quad sys32_gettimeofday
 508         .quad sys32_settimeofday
 509         .quad sys_getgroups16   /* 80 */
 510         .quad sys_setgroups16
 511         .quad sys32_old_select
 512         .quad sys_symlink
 513         .quad sys_lstat
 514         .quad sys_readlink              /* 85 */
 515 #ifdef CONFIG_IA32_AOUT
 516         .quad sys_uselib
 517 #else
 518         .quad quiet_ni_syscall
 519 #endif
 520         .quad sys_swapon
 521         .quad sys_reboot
 522         .quad compat_sys_old_readdir
 523         .quad sys32_mmap                /* 90 */
 524         .quad sys_munmap
 525         .quad sys_truncate
 526         .quad sys_ftruncate
 527         .quad sys_fchmod
 528         .quad sys_fchown16              /* 95 */
 529         .quad sys_getpriority
 530         .quad sys_setpriority
 531         .quad quiet_ni_syscall                  /* old profil syscall holder */
 532         .quad compat_sys_statfs
 533         .quad compat_sys_fstatfs                /* 100 */
 534         .quad sys_ioperm
 535         .quad compat_sys_socketcall
 536         .quad sys_syslog
 537         .quad compat_sys_setitimer
 538         .quad compat_sys_getitimer      /* 105 */
 539         .quad compat_sys_newstat
 540         .quad compat_sys_newlstat
 541         .quad compat_sys_newfstat
 542         .quad sys32_uname
 543         .quad stub32_iopl               /* 110 */
 544         .quad sys_vhangup
 545         .quad quiet_ni_syscall  /* old "idle" system call */
 546         .quad sys32_vm86_warning        /* vm86old */
 547         .quad compat_sys_wait4
 548         .quad sys_swapoff               /* 115 */
 549         .quad sys32_sysinfo
 550         .quad sys32_ipc
 551         .quad sys_fsync
 552         .quad stub32_sigreturn
 553         .quad stub32_clone              /* 120 */
 554         .quad sys_setdomainname
 555         .quad sys_uname
 556         .quad sys_modify_ldt
 557         .quad compat_sys_adjtimex
 558         .quad sys32_mprotect            /* 125 */
 559         .quad compat_sys_sigprocmask
 560         .quad quiet_ni_syscall          /* create_module */
 561         .quad sys_init_module
 562         .quad sys_delete_module
 563         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 564         .quad sys_quotactl
 565         .quad sys_getpgid
 566         .quad sys_fchdir
 567         .quad quiet_ni_syscall  /* bdflush */
 568         .quad sys_sysfs         /* 135 */
 569         .quad sys_personality
 570         .quad quiet_ni_syscall  /* for afs_syscall */
 571         .quad sys_setfsuid16
 572         .quad sys_setfsgid16
 573         .quad sys_llseek                /* 140 */
 574         .quad compat_sys_getdents
 575         .quad compat_sys_select
 576         .quad sys_flock
 577         .quad sys_msync
 578         .quad compat_sys_readv          /* 145 */
 579         .quad compat_sys_writev
 580         .quad sys_getsid
 581         .quad sys_fdatasync
 582         .quad sys32_sysctl      /* sysctl */
 583         .quad sys_mlock         /* 150 */
 584         .quad sys_munlock
 585         .quad sys_mlockall
 586         .quad sys_munlockall
 587         .quad sys_sched_setparam
 588         .quad sys_sched_getparam   /* 155 */
 589         .quad sys_sched_setscheduler
 590         .quad sys_sched_getscheduler
 591         .quad sys_sched_yield
 592         .quad sys_sched_get_priority_max
 593         .quad sys_sched_get_priority_min  /* 160 */
 594         .quad sys_sched_rr_get_interval
 595         .quad compat_sys_nanosleep
 596         .quad sys_mremap
 597         .quad sys_setresuid16
 598         .quad sys_getresuid16   /* 165 */
 599         .quad sys32_vm86_warning        /* vm86 */
 600         .quad quiet_ni_syscall  /* query_module */
 601         .quad sys_poll
 602         .quad compat_sys_nfsservctl
 603         .quad sys_setresgid16   /* 170 */
 604         .quad sys_getresgid16
 605         .quad sys_prctl
 606         .quad stub32_rt_sigreturn
 607         .quad sys32_rt_sigaction
 608         .quad sys32_rt_sigprocmask      /* 175 */
 609         .quad sys32_rt_sigpending
 610         .quad compat_sys_rt_sigtimedwait
 611         .quad sys32_rt_sigqueueinfo
 612         .quad stub32_rt_sigsuspend
 613         .quad sys32_pread               /* 180 */
 614         .quad sys32_pwrite
 615         .quad sys_chown16
 616         .quad sys_getcwd
 617         .quad sys_capget
 618         .quad sys_capset
 619         .quad stub32_sigaltstack
 620         .quad sys32_sendfile
 621         .quad quiet_ni_syscall          /* streams1 */
 622         .quad quiet_ni_syscall          /* streams2 */
 623         .quad stub32_vfork            /* 190 */
 624         .quad compat_sys_getrlimit
 625         .quad sys32_mmap2
 626         .quad sys32_truncate64
 627         .quad sys32_ftruncate64
 628         .quad sys32_stat64              /* 195 */
 629         .quad sys32_lstat64
 630         .quad sys32_fstat64
 631         .quad sys_lchown
 632         .quad sys_getuid
 633         .quad sys_getgid                /* 200 */
 634         .quad sys_geteuid
 635         .quad sys_getegid
 636         .quad sys_setreuid
 637         .quad sys_setregid
 638         .quad sys_getgroups     /* 205 */
 639         .quad sys_setgroups
 640         .quad sys_fchown
 641         .quad sys_setresuid
 642         .quad sys_getresuid
 643         .quad sys_setresgid     /* 210 */
 644         .quad sys_getresgid
 645         .quad sys_chown
 646         .quad sys_setuid
 647         .quad sys_setgid
 648         .quad sys_setfsuid              /* 215 */
 649         .quad sys_setfsgid
 650         .quad sys_pivot_root
 651         .quad sys_mincore
 652         .quad sys_madvise
 653         .quad compat_sys_getdents64     /* 220 getdents64 */
 654         .quad compat_sys_fcntl64
 655         .quad quiet_ni_syscall          /* tux */
 656         .quad quiet_ni_syscall          /* security */
 657         .quad sys_gettid
 658         .quad sys_readahead     /* 225 */
 659         .quad sys_setxattr
 660         .quad sys_lsetxattr
 661         .quad sys_fsetxattr
 662         .quad sys_getxattr
 663         .quad sys_lgetxattr     /* 230 */
 664         .quad sys_fgetxattr
 665         .quad sys_listxattr
 666         .quad sys_llistxattr
 667         .quad sys_flistxattr
 668         .quad sys_removexattr   /* 235 */
 669         .quad sys_lremovexattr
 670         .quad sys_fremovexattr
 671         .quad sys_tkill
 672         .quad sys_sendfile64
 673         .quad compat_sys_futex          /* 240 */
 674         .quad compat_sys_sched_setaffinity
 675         .quad compat_sys_sched_getaffinity
 676         .quad sys32_set_thread_area
 677         .quad sys32_get_thread_area
 678         .quad compat_sys_io_setup       /* 245 */
 679         .quad sys_io_destroy
 680         .quad compat_sys_io_getevents
 681         .quad compat_sys_io_submit
 682         .quad sys_io_cancel
 683         .quad sys_fadvise64             /* 250 */
 684         .quad quiet_ni_syscall  /* free_huge_pages */
 685         .quad sys_exit_group
 686         .quad sys32_lookup_dcookie
 687         .quad sys_epoll_create
 688         .quad sys_epoll_ctl             /* 255 */
 689         .quad sys_epoll_wait
 690         .quad sys_remap_file_pages
 691         .quad sys_set_tid_address
 692         .quad compat_sys_timer_create
 693         .quad compat_sys_timer_settime  /* 260 */
 694         .quad compat_sys_timer_gettime
 695         .quad sys_timer_getoverrun
 696         .quad sys_timer_delete
 697         .quad compat_sys_clock_settime
 698         .quad compat_sys_clock_gettime  /* 265 */
 699         .quad compat_sys_clock_getres
 700         .quad compat_sys_clock_nanosleep
 701         .quad compat_sys_statfs64
 702         .quad compat_sys_fstatfs64
 703         .quad sys_tgkill                /* 270 */
 704         .quad compat_sys_utimes
 705         .quad sys32_fadvise64_64
 706         .quad sys32_vserver
 707         .quad sys_mbind
 708         .quad compat_sys_get_mempolicy  /* 275 */
 709         .quad sys_set_mempolicy
 710         .quad compat_sys_mq_open
 711         .quad sys_mq_unlink
 712         .quad compat_sys_mq_timedsend
 713         .quad compat_sys_mq_timedreceive        /* 280 */
 714         .quad compat_sys_mq_notify
 715         .quad compat_sys_mq_getsetattr
 716         .quad compat_sys_kexec_load     /* reserved for kexec */
 717         .quad compat_sys_waitid
 718         .quad quiet_ni_syscall          /* 285: sys_altroot */
 719         .quad sys_add_key
 720         .quad sys_request_key
 721         .quad sys_keyctl
 722         .quad sys_ioprio_set
 723         .quad sys_ioprio_get            /* 290 */
 724         .quad sys_inotify_init
 725         .quad sys_inotify_add_watch
 726         .quad sys_inotify_rm_watch
 727         .quad sys_migrate_pages
 728         .quad compat_sys_openat         /* 295 */
 729         .quad sys_mkdirat
 730         .quad sys_mknodat
 731         .quad sys_fchownat
 732         .quad compat_sys_futimesat
 733         .quad sys32_fstatat             /* 300 */
 734         .quad sys_unlinkat
 735         .quad sys_renameat
 736         .quad sys_linkat
 737         .quad sys_symlinkat
 738         .quad sys_readlinkat            /* 305 */
 739         .quad sys_fchmodat
 740         .quad sys_faccessat
 741         .quad compat_sys_pselect6
 742         .quad compat_sys_ppoll
 743         .quad sys_unshare               /* 310 */
 744         .quad compat_sys_set_robust_list
 745         .quad compat_sys_get_robust_list
 746         .quad sys_splice
 747         .quad sys_sync_file_range
 748         .quad sys_tee
 749         .quad compat_sys_vmsplice
 750         .quad compat_sys_move_pages
 751 ia32_syscall_end: