arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #include <asm-generic/vmlinux.lds.h>
   6 #include <linux/config.h>
   7
   8 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
   9 OUTPUT_ARCH(i386:x86-64)
  10 ENTRY(_start)
  11 jiffies_64 = jiffies;
  12 SECTIONS
  13 {
  14   . = 0xffffffff80100000;
  15   _text = .;                    /* Text and read-only data */
  16   .text : {
  17         *(.text)
  18         SCHED_TEXT
  19         *(.fixup)
  20         *(.gnu.warning)
  21         } = 0x9090
  22   .text.lock : { *(.text.lock) }        /* out-of-line lock text */
  23
  24   _etext = .;                   /* End of text section */
  25
  26   . = ALIGN(16);                /* Exception table */
  27   __start___ex_table = .;
  28   __ex_table : { *(__ex_table) }
  29   __stop___ex_table = .;
  30
  31   RODATA
  32
  33   .data : {                     /* Data */
  34         *(.data)
  35         CONSTRUCTORS
  36         }
  37
  38   _edata = .;                   /* End of data section */
  39
  40   __bss_start = .;              /* BSS */
  41   .bss : {
  42         *(.bss.page_aligned)
  43         *(.bss)
  44         }
  45   __bss_end = .;
  46
  47   . = ALIGN(64);
  48   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  49
  50   .vsyscall_0 -10*1024*1024: AT ((LOADADDR(.data.cacheline_aligned) + SIZEOF(.data.cacheline_aligned) + 4095) & ~(4095)) { *(.vsyscall_0) }
  51   __vsyscall_0 = LOADADDR(.vsyscall_0);
  52   . = ALIGN(64);
  53   .xtime_lock : AT ((LOADADDR(.vsyscall_0) + SIZEOF(.vsyscall_0) + 63) & ~(63)) { *(.xtime_lock) }
  54   xtime_lock = LOADADDR(.xtime_lock);
  55   . = ALIGN(16);
  56   .vxtime : AT ((LOADADDR(.xtime_lock) + SIZEOF(.xtime_lock) + 15) & ~(15)) { *(.vxtime) }
  57   vxtime = LOADADDR(.vxtime);
  58   . = ALIGN(16);
  59   .wall_jiffies : AT ((LOADADDR(.vxtime) + SIZEOF(.vxtime) + 15) & ~(15)) { *(.wall_jiffies) }
  60   wall_jiffies = LOADADDR(.wall_jiffies);
  61   . = ALIGN(16);
  62   .sys_tz : AT ((LOADADDR(.wall_jiffies) + SIZEOF(.wall_jiffies) + 15) & ~(15)) { *(.sys_tz) }
  63   sys_tz = LOADADDR(.sys_tz);
  64   . = ALIGN(16);
  65   .sysctl_vsyscall : AT ((LOADADDR(.sys_tz) + SIZEOF(.sys_tz) + 15) & ~(15)) { *(.sysctl_vsyscall) }
  66   sysctl_vsyscall = LOADADDR(.sysctl_vsyscall);
  67   . = ALIGN(16);
  68   .jiffies : AT ((LOADADDR(.sysctl_vsyscall) + SIZEOF(.sysctl_vsyscall) + 15) & ~(15)) { *(.jiffies) }
  69   jiffies = LOADADDR(.jiffies);
  70   . = ALIGN(16);
  71   .xtime : AT ((LOADADDR(.jiffies) + SIZEOF(.jiffies) + 15) & ~(15)) { *(.xtime) }
  72   xtime = LOADADDR(.xtime);
  73   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT (LOADADDR(.vsyscall_0) + 1024) { *(.vsyscall_1) }
  74   . = LOADADDR(.vsyscall_0) + 4096;
  75
  76   . = ALIGN(8192);              /* init_task */
  77   .data.init_task : { *(.data.init_task) }
  78
  79   . = ALIGN(4096);
  80   .data.page_aligned : { *(.data.page_aligned) }
  81
  82   . = ALIGN(4096);              /* Init code and data */
  83   __init_begin = .;
  84   .init.text : {
  85         _sinittext = .;
  86         *(.init.text)
  87         _einittext = .;
  88   }
  89   .init.data : { *(.init.data) }
  90   . = ALIGN(16);
  91   __setup_start = .;
  92   .init.setup : { *(.init.setup) }
  93   __setup_end = .;
  94   __start___param = .;
  95   __param : { *(__param) }
  96   __stop___param = .;
  97   __initcall_start = .;
  98   .initcall.init : {
  99         *(.initcall1.init)
 100         *(.initcall2.init)
 101         *(.initcall3.init)
 102         *(.initcall4.init)
 103         *(.initcall5.init)
 104         *(.initcall6.init)
 105         *(.initcall7.init)
 106   }
 107   __initcall_end = .;
 108   __con_initcall_start = .;
 109   .con_initcall.init : { *(.con_initcall.init) }
 110   __con_initcall_end = .;
 111   SECURITY_INIT
 112   . = ALIGN(8);
 113   __alt_instructions = .;
 114   .altinstructions : { *(.altinstructions) }
 115   __alt_instructions_end = .;
 116  .altinstr_replacement : { *(.altinstr_replacement) }
 117   /* .exit.text is discard at runtime, not link time, to deal with references
 118      from .altinstructions and .eh_frame */
 119   .exit.text : { *(.exit.text) }
 120   .exit.data : { *(.exit.data) }
 121   . = ALIGN(4096);
 122   __initramfs_start = .;
 123   .init.ramfs : { *(.init.ramfs) }
 124   __initramfs_end = .;
 125   . = ALIGN(32);
 126   __per_cpu_start = .;
 127   .data.percpu  : { *(.data.percpu) }
 128   __per_cpu_end = .;
 129   . = ALIGN(4096);
 130   __init_end = .;
 131
 132   . = ALIGN(4096);
 133   __nosave_begin = .;
 134   .data_nosave : { *(.data.nosave) }
 135   . = ALIGN(4096);
 136   __nosave_end = .;
 137
 138   _end = . ;
 139
 140   /* Sections to be discarded */
 141   /DISCARD/ : {
 142         *(.exitcall.exit)
 143 #ifndef CONFIG_DEBUG_INFO
 144         *(.eh_frame)
 145 #endif
 146         }
 147
 148   /* DWARF 2 */
 149   .debug_info     0 : { *(.debug_info) }
 150   .debug_abbrev   0 : { *(.debug_abbrev) }
 151   .debug_line     0 : { *(.debug_line) }
 152   .debug_frame    0 : { *(.debug_frame) }
 153   .debug_str      0 : { *(.debug_str) }
 154   .debug_loc      0 : { *(.debug_loc) }
 155   .debug_macinfo  0 : { *(.debug_macinfo) }
 156   /* SGI/MIPS DWARF 2 extensions */
 157   .debug_weaknames 0 : { *(.debug_weaknames) }
 158   .debug_funcnames 0 : { *(.debug_funcnames) }
 159   .debug_typenames 0 : { *(.debug_typenames) }
 160   .debug_varnames  0 : { *(.debug_varnames) }
 161
 162
 163   .comment 0 : { *(.comment) }
 164 }