include/asm-parisc/assembly.h

   1 /*
   2  * Copyright (C) 1999 Hewlett-Packard (Frank Rowand)
   3  * Copyright (C) 1999 Philipp Rumpf <prumpf@tux.org>
   4  * Copyright (C) 1999 SuSE GmbH
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  */
  20
  21 #ifndef _PARISC_ASSEMBLY_H
  22 #define _PARISC_ASSEMBLY_H
  23
  24 #ifdef __LP64__
  25 #define LDREG   ldd
  26 #define STREG   std
  27 #define LDREGX  ldd,s
  28 #define LDREGM  ldd,mb
  29 #define STREGM  std,ma
  30 #define SHRREG  shrd
  31 #define RP_OFFSET       16
  32 #define FRAME_SIZE      128
  33 #define CALLEE_SAVE_FRAME_SIZE  144
  34 #else
  35 #define LDREG   ldw
  36 #define STREG   stw
  37 #define LDREGX  ldwx,s
  38 #define LDREGM  ldwm
  39 #define STREGM  stwm
  40 #define RP_OFFSET       20
  41 #define FRAME_SIZE      64
  42 #define CALLEE_SAVE_FRAME_SIZE  128
  43 #endif
  44
  45 #ifdef CONFIG_PA20
  46 #define BL              b,l
  47 # ifdef CONFIG_PARISC64
  48 #  define LEVEL         2.0w
  49 # else
  50 #  define LEVEL         2.0
  51 # endif
  52 #else
  53 #define BL              bl
  54 #define LEVEL           1.1
  55 #endif
  56
  57 #ifdef __ASSEMBLY__
  58
  59 #ifdef __LP64__
  60 /* the 64-bit pa gnu assembler unfortunately defaults to .level 1.1 or 2.0 so
  61  * work around that for now... */
  62         .level 2.0w
  63 #endif
  64
  65 #include <asm/offsets.h>
  66 #include <asm/page.h>
  67
  68 #include <asm/asmregs.h>
  69
  70         sp      =       30
  71         gp      =       27
  72         ipsw    =       22
  73
  74         /*
  75          * We provide two versions of each macro to convert from physical
  76          * to virtual and vice versa. The "_r1" versions take one argument
  77          * register, but trashes r1 to do the conversion. The other
  78          * version takes two arguments: a src and destination register.
  79          * However, the source and destination registers can not be
  80          * the same register.
  81          */
  82
  83         .macro  tophys  grvirt, grphys
  84         ldil    L%(__PAGE_OFFSET), \grphys
  85         sub     \grvirt, \grphys, \grphys
  86         .endm
  87
  88         .macro  tovirt  grphys, grvirt
  89         ldil    L%(__PAGE_OFFSET), \grvirt
  90         add     \grphys, \grvirt, \grvirt
  91         .endm
  92
  93         .macro  tophys_r1  gr
  94         ldil    L%(__PAGE_OFFSET), %r1
  95         sub     \gr, %r1, \gr
  96         .endm
  97
  98         .macro  tovirt_r1  gr
  99         ldil    L%(__PAGE_OFFSET), %r1
 100         add     \gr, %r1, \gr
 101         .endm
 102
 103         .macro delay value
 104         ldil    L%\value, 1
 105         ldo     R%\value(1), 1
 106         addib,UV,n -1,1,.
 107         addib,NUV,n -1,1,.+8
 108         nop
 109         .endm
 110
 111         .macro  debug value
 112         .endm
 113
 114
 115         /* Shift Left - note the r and t can NOT be the same! */
 116         .macro shl r, sa, t
 117         dep,z   \r, 31-\sa, 32-\sa, \t
 118         .endm
 119
 120         /* The PA 2.0 shift left */
 121         .macro shlw r, sa, t
 122         depw,z  \r, 31-\sa, 32-\sa, \t
 123         .endm
 124
 125         /* And the PA 2.0W shift left */
 126         .macro shld r, sa, t
 127         depd,z  \r, 63-\sa, 64-\sa, \t
 128         .endm
 129
 130         /* Shift Right - note the r and t can NOT be the same! */
 131         .macro shr r, sa, t
 132         extru \r, 31-\sa, 32-\sa, \t
 133         .endm
 134
 135         /* pa20w version of shift right */
 136         .macro shrd r, sa, t
 137         extrd,u \r, 63-\sa, 64-\sa, \t
 138         .endm
 139
 140         /* load 32-bit 'value' into 'reg' compensating for the ldil
 141          * sign-extension when running in wide mode.
 142          * WARNING!! neither 'value' nor 'reg' can be expressions
 143          * containing '.'!!!! */
 144         .macro  load32 value, reg
 145         ldil    L%\value, \reg
 146         ldo     R%\value(\reg), \reg
 147         .endm
 148
 149         .macro loadgp
 150 #ifdef __LP64__
 151         ldil            L%__gp, %r27
 152         ldo             R%__gp(%r27), %r27
 153 #else
 154         ldil            L%$global$, %r27
 155         ldo             R%$global$(%r27), %r27
 156 #endif
 157         .endm
 158
 159 #define SAVE_SP(r, where) mfsp r, %r1 ! STREG %r1, where
 160 #define REST_SP(r, where) LDREG where, %r1 ! mtsp %r1, r
 161 #define SAVE_CR(r, where) mfctl r, %r1 ! STREG %r1, where
 162 #define REST_CR(r, where) LDREG where, %r1 ! mtctl %r1, r
 163
 164         .macro  save_general    regs
 165         STREG %r1, PT_GR1 (\regs)
 166         STREG %r2, PT_GR2 (\regs)
 167         STREG %r3, PT_GR3 (\regs)
 168         STREG %r4, PT_GR4 (\regs)
 169         STREG %r5, PT_GR5 (\regs)
 170         STREG %r6, PT_GR6 (\regs)
 171         STREG %r7, PT_GR7 (\regs)
 172         STREG %r8, PT_GR8 (\regs)
 173         STREG %r9, PT_GR9 (\regs)
 174         STREG %r10, PT_GR10(\regs)
 175         STREG %r11, PT_GR11(\regs)
 176         STREG %r12, PT_GR12(\regs)
 177         STREG %r13, PT_GR13(\regs)
 178         STREG %r14, PT_GR14(\regs)
 179         STREG %r15, PT_GR15(\regs)
 180         STREG %r16, PT_GR16(\regs)
 181         STREG %r17, PT_GR17(\regs)
 182         STREG %r18, PT_GR18(\regs)
 183         STREG %r19, PT_GR19(\regs)
 184         STREG %r20, PT_GR20(\regs)
 185         STREG %r21, PT_GR21(\regs)
 186         STREG %r22, PT_GR22(\regs)
 187         STREG %r23, PT_GR23(\regs)
 188         STREG %r24, PT_GR24(\regs)
 189         STREG %r25, PT_GR25(\regs)
 190         /* r26 is saved in get_stack and used to preserve a value across virt_map */
 191         STREG %r27, PT_GR27(\regs)
 192         STREG %r28, PT_GR28(\regs)
 193         /* r29 is saved in get_stack and used to point to saved registers */
 194         /* r30 stack pointer saved in get_stack */
 195         STREG %r31, PT_GR31(\regs)
 196         .endm
 197
 198         .macro  rest_general    regs
 199         /* r1 used as a temp in rest_stack and is restored there */
 200         LDREG PT_GR2 (\regs), %r2
 201         LDREG PT_GR3 (\regs), %r3
 202         LDREG PT_GR4 (\regs), %r4
 203         LDREG PT_GR5 (\regs), %r5
 204         LDREG PT_GR6 (\regs), %r6
 205         LDREG PT_GR7 (\regs), %r7
 206         LDREG PT_GR8 (\regs), %r8
 207         LDREG PT_GR9 (\regs), %r9
 208         LDREG PT_GR10(\regs), %r10
 209         LDREG PT_GR11(\regs), %r11
 210         LDREG PT_GR12(\regs), %r12
 211         LDREG PT_GR13(\regs), %r13
 212         LDREG PT_GR14(\regs), %r14
 213         LDREG PT_GR15(\regs), %r15
 214         LDREG PT_GR16(\regs), %r16
 215         LDREG PT_GR17(\regs), %r17
 216         LDREG PT_GR18(\regs), %r18
 217         LDREG PT_GR19(\regs), %r19
 218         LDREG PT_GR20(\regs), %r20
 219         LDREG PT_GR21(\regs), %r21
 220         LDREG PT_GR22(\regs), %r22
 221         LDREG PT_GR23(\regs), %r23
 222         LDREG PT_GR24(\regs), %r24
 223         LDREG PT_GR25(\regs), %r25
 224         LDREG PT_GR26(\regs), %r26
 225         LDREG PT_GR27(\regs), %r27
 226         LDREG PT_GR28(\regs), %r28
 227         /* r29 points to register save area, and is restored in rest_stack */
 228         /* r30 stack pointer restored in rest_stack */
 229         LDREG PT_GR31(\regs), %r31
 230         .endm
 231
 232         .macro  save_fp         regs
 233         fstd,ma  %fr0, 8(\regs)
 234         fstd,ma  %fr1, 8(\regs)
 235         fstd,ma  %fr2, 8(\regs)
 236         fstd,ma  %fr3, 8(\regs)
 237         fstd,ma  %fr4, 8(\regs)
 238         fstd,ma  %fr5, 8(\regs)
 239         fstd,ma  %fr6, 8(\regs)
 240         fstd,ma  %fr7, 8(\regs)
 241         fstd,ma  %fr8, 8(\regs)
 242         fstd,ma  %fr9, 8(\regs)
 243         fstd,ma %fr10, 8(\regs)
 244         fstd,ma %fr11, 8(\regs)
 245         fstd,ma %fr12, 8(\regs)
 246         fstd,ma %fr13, 8(\regs)
 247         fstd,ma %fr14, 8(\regs)
 248         fstd,ma %fr15, 8(\regs)
 249         fstd,ma %fr16, 8(\regs)
 250         fstd,ma %fr17, 8(\regs)
 251         fstd,ma %fr18, 8(\regs)
 252         fstd,ma %fr19, 8(\regs)
 253         fstd,ma %fr20, 8(\regs)
 254         fstd,ma %fr21, 8(\regs)
 255         fstd,ma %fr22, 8(\regs)
 256         fstd,ma %fr23, 8(\regs)
 257         fstd,ma %fr24, 8(\regs)
 258         fstd,ma %fr25, 8(\regs)
 259         fstd,ma %fr26, 8(\regs)
 260         fstd,ma %fr27, 8(\regs)
 261         fstd,ma %fr28, 8(\regs)
 262         fstd,ma %fr29, 8(\regs)
 263         fstd,ma %fr30, 8(\regs)
 264         fstd    %fr31, 0(\regs)
 265         .endm
 266
 267         .macro  rest_fp         regs
 268         fldd    0(\regs),        %fr31
 269         fldd,mb -8(\regs),       %fr30
 270         fldd,mb -8(\regs),       %fr29
 271         fldd,mb -8(\regs),       %fr28
 272         fldd,mb -8(\regs),       %fr27
 273         fldd,mb -8(\regs),       %fr26
 274         fldd,mb -8(\regs),       %fr25
 275         fldd,mb -8(\regs),       %fr24
 276         fldd,mb -8(\regs),       %fr23
 277         fldd,mb -8(\regs),       %fr22
 278         fldd,mb -8(\regs),       %fr21
 279         fldd,mb -8(\regs),       %fr20
 280         fldd,mb -8(\regs),       %fr19
 281         fldd,mb -8(\regs),       %fr18
 282         fldd,mb -8(\regs),       %fr17
 283         fldd,mb -8(\regs),       %fr16
 284         fldd,mb -8(\regs),       %fr15
 285         fldd,mb -8(\regs),       %fr14
 286         fldd,mb -8(\regs),       %fr13
 287         fldd,mb -8(\regs),       %fr12
 288         fldd,mb -8(\regs),       %fr11
 289         fldd,mb -8(\regs),       %fr10
 290         fldd,mb -8(\regs),       %fr9
 291         fldd,mb -8(\regs),       %fr8
 292         fldd,mb -8(\regs),       %fr7
 293         fldd,mb -8(\regs),       %fr6
 294         fldd,mb -8(\regs),       %fr5
 295         fldd,mb -8(\regs),       %fr4
 296         fldd,mb -8(\regs),       %fr3
 297         fldd,mb -8(\regs),       %fr2
 298         fldd,mb -8(\regs),       %fr1
 299         fldd,mb -8(\regs),       %fr0
 300         .endm
 301
 302 #ifdef __LP64__
 303         .macro  callee_save
 304         std,ma    %r3,  CALLEE_SAVE_FRAME_SIZE(%r30)
 305         mfctl     %cr27, %r3
 306         std       %r4,  -136(%r30)
 307         std       %r5,  -128(%r30)
 308         std       %r6,  -120(%r30)
 309         std       %r7,  -112(%r30)
 310         std       %r8,  -104(%r30)
 311         std       %r9,   -96(%r30)
 312         std      %r10,   -88(%r30)
 313         std      %r11,   -80(%r30)
 314         std      %r12,   -72(%r30)
 315         std      %r13,   -64(%r30)
 316         std      %r14,   -56(%r30)
 317         std      %r15,   -48(%r30)
 318         std      %r16,   -40(%r30)
 319         std      %r17,   -32(%r30)
 320         std      %r18,   -24(%r30)
 321         std       %r3,   -16(%r30)
 322         .endm
 323
 324         .macro  callee_rest
 325         ldd      -16(%r30),    %r3
 326         ldd      -24(%r30),   %r18
 327         ldd      -32(%r30),   %r17
 328         ldd      -40(%r30),   %r16
 329         ldd      -48(%r30),   %r15
 330         ldd      -56(%r30),   %r14
 331         ldd      -64(%r30),   %r13
 332         ldd      -72(%r30),   %r12
 333         ldd      -80(%r30),   %r11
 334         ldd      -88(%r30),   %r10
 335         ldd      -96(%r30),    %r9
 336         ldd     -104(%r30),    %r8
 337         ldd     -112(%r30),    %r7
 338         ldd     -120(%r30),    %r6
 339         ldd     -128(%r30),    %r5
 340         ldd     -136(%r30),    %r4
 341         mtctl   %r3, %cr27
 342         ldd,mb  -CALLEE_SAVE_FRAME_SIZE(%r30),    %r3
 343         .endm
 344
 345 #else /* ! __LP64__ */
 346
 347         .macro  callee_save
 348         stw,ma   %r3,   CALLEE_SAVE_FRAME_SIZE(%r30)
 349         mfctl    %cr27, %r3
 350         stw      %r4,   -124(%r30)
 351         stw      %r5,   -120(%r30)
 352         stw      %r6,   -116(%r30)
 353         stw      %r7,   -112(%r30)
 354         stw      %r8,   -108(%r30)
 355         stw      %r9,   -104(%r30)
 356         stw      %r10,  -100(%r30)
 357         stw      %r11,   -96(%r30)
 358         stw      %r12,   -92(%r30)
 359         stw      %r13,   -88(%r30)
 360         stw      %r14,   -84(%r30)
 361         stw      %r15,   -80(%r30)
 362         stw      %r16,   -76(%r30)
 363         stw      %r17,   -72(%r30)
 364         stw      %r18,   -68(%r30)
 365         stw       %r3,   -64(%r30)
 366         .endm
 367
 368         .macro  callee_rest
 369         ldw      -64(%r30),    %r3
 370         ldw      -68(%r30),   %r18
 371         ldw      -72(%r30),   %r17
 372         ldw      -76(%r30),   %r16
 373         ldw      -80(%r30),   %r15
 374         ldw      -84(%r30),   %r14
 375         ldw      -88(%r30),   %r13
 376         ldw      -92(%r30),   %r12
 377         ldw      -96(%r30),   %r11
 378         ldw     -100(%r30),   %r10
 379         ldw     -104(%r30),   %r9
 380         ldw     -108(%r30),   %r8
 381         ldw     -112(%r30),   %r7
 382         ldw     -116(%r30),   %r6
 383         ldw     -120(%r30),   %r5
 384         ldw     -124(%r30),   %r4
 385         mtctl   %r3, %cr27
 386         ldw,mb  -CALLEE_SAVE_FRAME_SIZE(%r30),   %r3
 387         .endm
 388 #endif /* ! __LP64__ */
 389
 390         .macro  save_specials   regs
 391
 392         SAVE_SP  (%sr0, PT_SR0 (\regs))
 393         SAVE_SP  (%sr1, PT_SR1 (\regs))
 394         SAVE_SP  (%sr2, PT_SR2 (\regs))
 395         SAVE_SP  (%sr3, PT_SR3 (\regs))
 396         SAVE_SP  (%sr4, PT_SR4 (\regs))
 397         SAVE_SP  (%sr5, PT_SR5 (\regs))
 398         SAVE_SP  (%sr6, PT_SR6 (\regs))
 399         SAVE_SP  (%sr7, PT_SR7 (\regs))
 400
 401         SAVE_CR  (%cr17, PT_IASQ0(\regs))
 402         mtctl    %r0,   %cr17
 403         SAVE_CR  (%cr17, PT_IASQ1(\regs))
 404
 405         SAVE_CR  (%cr18, PT_IAOQ0(\regs))
 406         mtctl    %r0,   %cr18
 407         SAVE_CR  (%cr18, PT_IAOQ1(\regs))
 408
 409 #ifdef __LP64__
 410         /* cr11 (sar) is a funny one.  5 bits on PA1.1 and 6 bit on PA2.0
 411          * For PA2.0 mtsar or mtctl always write 6 bits, but mfctl only
 412          * reads 5 bits.  Use mfctl,w to read all six bits.  Otherwise
 413          * we lose the 6th bit on a save/restore over interrupt.
 414          */
 415         mfctl,w  %cr11, %r1
 416         STREG    %r1, PT_SAR (\regs)
 417 #else
 418         SAVE_CR  (%cr11, PT_SAR  (\regs))
 419 #endif
 420         SAVE_CR  (%cr19, PT_IIR  (\regs))
 421
 422         /*
 423          * Code immediately following this macro (in intr_save) relies
 424          * on r8 containing ipsw.
 425          */
 426         mfctl    %cr22, %r8
 427         STREG    %r8,   PT_PSW(\regs)
 428         .endm
 429
 430         .macro  rest_specials   regs
 431
 432         REST_SP  (%sr0, PT_SR0 (\regs))
 433         REST_SP  (%sr1, PT_SR1 (\regs))
 434         REST_SP  (%sr2, PT_SR2 (\regs))
 435         REST_SP  (%sr3, PT_SR3 (\regs))
 436         REST_SP  (%sr4, PT_SR4 (\regs))
 437         REST_SP  (%sr5, PT_SR5 (\regs))
 438         REST_SP  (%sr6, PT_SR6 (\regs))
 439         REST_SP  (%sr7, PT_SR7 (\regs))
 440
 441         REST_CR (%cr17, PT_IASQ0(\regs))
 442         REST_CR (%cr17, PT_IASQ1(\regs))
 443
 444         REST_CR (%cr18, PT_IAOQ0(\regs))
 445         REST_CR (%cr18, PT_IAOQ1(\regs))
 446
 447         REST_CR (%cr11, PT_SAR  (\regs))
 448
 449         REST_CR (%cr22, PT_PSW  (\regs))
 450         .endm
 451
 452 #endif /* __ASSEMBLY__ */
 453 #endif