include/asm-parisc/assembly.h

   1 /*
   2  * Copyright (C) 1999 Hewlett-Packard (Frank Rowand)
   3  * Copyright (C) 1999 Philipp Rumpf <prumpf@tux.org>
   4  * Copyright (C) 1999 SuSE GmbH
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  */
  20
  21 #ifndef _PARISC_ASSEMBLY_H
  22 #define _PARISC_ASSEMBLY_H
  23
  24 #ifdef __LP64__
  25 #define LDREG   ldd
  26 #define STREG   std
  27 #define LDREGM  ldd,mb
  28 #define STREGM  std,ma
  29 #define RP_OFFSET       16
  30 #define FRAME_SIZE      128
  31 #else
  32 #define LDREG   ldw
  33 #define STREG   stw
  34 #define LDREGM  ldwm
  35 #define STREGM  stwm
  36 #define RP_OFFSET       20
  37 #define FRAME_SIZE      64
  38 #endif
  39
  40 #ifdef __ASSEMBLY__
  41
  42 #ifdef __LP64__
  43 /* the 64-bit pa gnu assembler unfortunately defaults to .level 1.1 or 2.0 so
  44  * work around that for now... */
  45         .level 2.0w
  46 #endif
  47
  48 #include <asm/offsets.h>
  49 #include <asm/page.h>
  50
  51 #include <asm/asmregs.h>
  52
  53         sp      =       30
  54         gp      =       27
  55         ipsw    =       22
  56
  57         /*
  58          * We provide two versions of each macro to convert from physical
  59          * to virtual and vice versa. The "_r1" versions take one argument
  60          * register, but trashes r1 to do the conversion. The other
  61          * version takes two arguments: a src and destination register.
  62          * However, the source and destination registers can not be
  63          * the same register.
  64          */
  65
  66         .macro  tophys  grvirt, grphys
  67         ldil    L%(__PAGE_OFFSET), \grphys
  68         sub     \grvirt, \grphys, \grphys
  69         .endm
  70
  71         .macro  tovirt  grphys, grvirt
  72         ldil    L%(__PAGE_OFFSET), \grvirt
  73         add     \grphys, \grvirt, \grvirt
  74         .endm
  75
  76         .macro  tophys_r1  gr
  77         ldil    L%(__PAGE_OFFSET), %r1
  78         sub     \gr, %r1, \gr
  79         .endm
  80
  81         .macro  tovirt_r1  gr
  82         ldil    L%(__PAGE_OFFSET), %r1
  83         add     \gr, %r1, \gr
  84         .endm
  85
  86         .macro delay value
  87         ldil    L%\value, 1
  88         ldo     R%\value(1), 1
  89         addib,UV,n -1,1,.
  90         addib,NUV,n -1,1,.+8
  91         nop
  92         .endm
  93
  94         .macro  debug value
  95         .endm
  96
  97
  98         /* Shift Left - note the r and t can NOT be the same! */
  99         .macro shl r, sa, t
 100         dep,z   \r, 31-\sa, 32-\sa, \t
 101         .endm
 102
 103         /* The PA 2.0 shift left */
 104         .macro shlw r, sa, t
 105         depw,z  \r, 31-\sa, 32-\sa, \t
 106         .endm
 107
 108         /* And the PA 2.0W shift left */
 109         .macro shld r, sa, t
 110         depd,z  \r, 63-\sa, 64-\sa, \t
 111         .endm
 112
 113         /* load 32-bit 'value' into 'reg' compensating for the ldil
 114          * sign-extension when running in wide mode.
 115          * WARNING!! neither 'value' nor 'reg' can be expressions
 116          * containing '.'!!!! */
 117         .macro  load32 value, reg
 118         ldil    L%\value, \reg
 119         ldo     R%\value(\reg), \reg
 120         .endm
 121
 122         .macro loadgp
 123 #ifdef __LP64__
 124         ldil            L%__gp, %r27
 125         ldo             R%__gp(%r27), %r27
 126 #else
 127         ldil            L%$global$, %r27
 128         ldo             R%$global$(%r27), %r27
 129 #endif
 130         .endm
 131
 132 #define SAVE_SP(r, where) mfsp r, %r1 ! STREG %r1, where
 133 #define REST_SP(r, where) LDREG where, %r1 ! mtsp %r1, r
 134 #define SAVE_CR(r, where) mfctl r, %r1 ! STREG %r1, where
 135 #define REST_CR(r, where) LDREG where, %r1 ! mtctl %r1, r
 136
 137         .macro  save_general    regs
 138         STREG %r1, PT_GR1 (\regs)
 139         STREG %r2, PT_GR2 (\regs)
 140         STREG %r3, PT_GR3 (\regs)
 141         STREG %r4, PT_GR4 (\regs)
 142         STREG %r5, PT_GR5 (\regs)
 143         STREG %r6, PT_GR6 (\regs)
 144         STREG %r7, PT_GR7 (\regs)
 145         STREG %r8, PT_GR8 (\regs)
 146         STREG %r9, PT_GR9 (\regs)
 147         STREG %r10, PT_GR10(\regs)
 148         STREG %r11, PT_GR11(\regs)
 149         STREG %r12, PT_GR12(\regs)
 150         STREG %r13, PT_GR13(\regs)
 151         STREG %r14, PT_GR14(\regs)
 152         STREG %r15, PT_GR15(\regs)
 153         STREG %r16, PT_GR16(\regs)
 154         STREG %r17, PT_GR17(\regs)
 155         STREG %r18, PT_GR18(\regs)
 156         STREG %r19, PT_GR19(\regs)
 157         STREG %r20, PT_GR20(\regs)
 158         STREG %r21, PT_GR21(\regs)
 159         STREG %r22, PT_GR22(\regs)
 160         STREG %r23, PT_GR23(\regs)
 161         STREG %r24, PT_GR24(\regs)
 162         STREG %r25, PT_GR25(\regs)
 163         /* r26 is saved in get_stack and used to preserve a value across virt_map */
 164         STREG %r27, PT_GR27(\regs)
 165         STREG %r28, PT_GR28(\regs)
 166         /* r29 is saved in get_stack and used to point to saved registers */
 167         /* r30 stack pointer saved in get_stack */
 168         STREG %r31, PT_GR31(\regs)
 169         .endm
 170
 171         .macro  rest_general    regs
 172         /* r1 used as a temp in rest_stack and is restored there */
 173         LDREG PT_GR2 (\regs), %r2
 174         LDREG PT_GR3 (\regs), %r3
 175         LDREG PT_GR4 (\regs), %r4
 176         LDREG PT_GR5 (\regs), %r5
 177         LDREG PT_GR6 (\regs), %r6
 178         LDREG PT_GR7 (\regs), %r7
 179         LDREG PT_GR8 (\regs), %r8
 180         LDREG PT_GR9 (\regs), %r9
 181         LDREG PT_GR10(\regs), %r10
 182         LDREG PT_GR11(\regs), %r11
 183         LDREG PT_GR12(\regs), %r12
 184         LDREG PT_GR13(\regs), %r13
 185         LDREG PT_GR14(\regs), %r14
 186         LDREG PT_GR15(\regs), %r15
 187         LDREG PT_GR16(\regs), %r16
 188         LDREG PT_GR17(\regs), %r17
 189         LDREG PT_GR18(\regs), %r18
 190         LDREG PT_GR19(\regs), %r19
 191         LDREG PT_GR20(\regs), %r20
 192         LDREG PT_GR21(\regs), %r21
 193         LDREG PT_GR22(\regs), %r22
 194         LDREG PT_GR23(\regs), %r23
 195         LDREG PT_GR24(\regs), %r24
 196         LDREG PT_GR25(\regs), %r25
 197         LDREG PT_GR26(\regs), %r26
 198         LDREG PT_GR27(\regs), %r27
 199         LDREG PT_GR28(\regs), %r28
 200         /* r29 points to register save area, and is restored in rest_stack */
 201         /* r30 stack pointer restored in rest_stack */
 202         LDREG PT_GR31(\regs), %r31
 203         .endm
 204
 205         .macro  save_fp         regs
 206         fstd,ma  %fr0, 8(\regs)
 207         fstd,ma  %fr1, 8(\regs)
 208         fstd,ma  %fr2, 8(\regs)
 209         fstd,ma  %fr3, 8(\regs)
 210         fstd,ma  %fr4, 8(\regs)
 211         fstd,ma  %fr5, 8(\regs)
 212         fstd,ma  %fr6, 8(\regs)
 213         fstd,ma  %fr7, 8(\regs)
 214         fstd,ma  %fr8, 8(\regs)
 215         fstd,ma  %fr9, 8(\regs)
 216         fstd,ma %fr10, 8(\regs)
 217         fstd,ma %fr11, 8(\regs)
 218         fstd,ma %fr12, 8(\regs)
 219         fstd,ma %fr13, 8(\regs)
 220         fstd,ma %fr14, 8(\regs)
 221         fstd,ma %fr15, 8(\regs)
 222         fstd,ma %fr16, 8(\regs)
 223         fstd,ma %fr17, 8(\regs)
 224         fstd,ma %fr18, 8(\regs)
 225         fstd,ma %fr19, 8(\regs)
 226         fstd,ma %fr20, 8(\regs)
 227         fstd,ma %fr21, 8(\regs)
 228         fstd,ma %fr22, 8(\regs)
 229         fstd,ma %fr23, 8(\regs)
 230         fstd,ma %fr24, 8(\regs)
 231         fstd,ma %fr25, 8(\regs)
 232         fstd,ma %fr26, 8(\regs)
 233         fstd,ma %fr27, 8(\regs)
 234         fstd,ma %fr28, 8(\regs)
 235         fstd,ma %fr29, 8(\regs)
 236         fstd,ma %fr30, 8(\regs)
 237         fstd    %fr31, 0(\regs)
 238         .endm
 239
 240         .macro  rest_fp         regs
 241         fldd    0(\regs),        %fr31
 242         fldd,mb -8(\regs),       %fr30
 243         fldd,mb -8(\regs),       %fr29
 244         fldd,mb -8(\regs),       %fr28
 245         fldd,mb -8(\regs),       %fr27
 246         fldd,mb -8(\regs),       %fr26
 247         fldd,mb -8(\regs),       %fr25
 248         fldd,mb -8(\regs),       %fr24
 249         fldd,mb -8(\regs),       %fr23
 250         fldd,mb -8(\regs),       %fr22
 251         fldd,mb -8(\regs),       %fr21
 252         fldd,mb -8(\regs),       %fr20
 253         fldd,mb -8(\regs),       %fr19
 254         fldd,mb -8(\regs),       %fr18
 255         fldd,mb -8(\regs),       %fr17
 256         fldd,mb -8(\regs),       %fr16
 257         fldd,mb -8(\regs),       %fr15
 258         fldd,mb -8(\regs),       %fr14
 259         fldd,mb -8(\regs),       %fr13
 260         fldd,mb -8(\regs),       %fr12
 261         fldd,mb -8(\regs),       %fr11
 262         fldd,mb -8(\regs),       %fr10
 263         fldd,mb -8(\regs),       %fr9
 264         fldd,mb -8(\regs),       %fr8
 265         fldd,mb -8(\regs),       %fr7
 266         fldd,mb -8(\regs),       %fr6
 267         fldd,mb -8(\regs),       %fr5
 268         fldd,mb -8(\regs),       %fr4
 269         fldd,mb -8(\regs),       %fr3
 270         fldd,mb -8(\regs),       %fr2
 271         fldd,mb -8(\regs),       %fr1
 272         fldd,mb -8(\regs),       %fr0
 273         .endm
 274
 275 #ifdef __LP64__
 276         .macro  callee_save
 277         std,ma    %r3,  144(%r30)
 278         mfctl     %cr27, %r3
 279         std       %r4,  -136(%r30)
 280         std       %r5,  -128(%r30)
 281         std       %r6,  -120(%r30)
 282         std       %r7,  -112(%r30)
 283         std       %r8,  -104(%r30)
 284         std       %r9,   -96(%r30)
 285         std      %r10,   -88(%r30)
 286         std      %r11,   -80(%r30)
 287         std      %r12,   -72(%r30)
 288         std      %r13,   -64(%r30)
 289         std      %r14,   -56(%r30)
 290         std      %r15,   -48(%r30)
 291         std      %r16,   -40(%r30)
 292         std      %r17,   -32(%r30)
 293         std      %r18,   -24(%r30)
 294         std       %r3,   -16(%r30)
 295         .endm
 296
 297         .macro  callee_rest
 298         ldd      -16(%r30),    %r3
 299         ldd      -24(%r30),   %r18
 300         ldd      -32(%r30),   %r17
 301         ldd      -40(%r30),   %r16
 302         ldd      -48(%r30),   %r15
 303         ldd      -56(%r30),   %r14
 304         ldd      -64(%r30),   %r13
 305         ldd      -72(%r30),   %r12
 306         ldd      -80(%r30),   %r11
 307         ldd      -88(%r30),   %r10
 308         ldd      -96(%r30),    %r9
 309         ldd     -104(%r30),    %r8
 310         ldd     -112(%r30),    %r7
 311         ldd     -120(%r30),    %r6
 312         ldd     -128(%r30),    %r5
 313         ldd     -136(%r30),    %r4
 314         mtctl   %r3, %cr27
 315         ldd,mb  -144(%r30),    %r3
 316         .endm
 317
 318 #else /* ! __LP64__ */
 319
 320         .macro  callee_save
 321         stw,ma   %r3,   128(%r30)
 322         mfctl    %cr27, %r3
 323         stw      %r4,   -124(%r30)
 324         stw      %r5,   -120(%r30)
 325         stw      %r6,   -116(%r30)
 326         stw      %r7,   -112(%r30)
 327         stw      %r8,   -108(%r30)
 328         stw      %r9,   -104(%r30)
 329         stw      %r10,  -100(%r30)
 330         stw      %r11,   -96(%r30)
 331         stw      %r12,   -92(%r30)
 332         stw      %r13,   -88(%r30)
 333         stw      %r14,   -84(%r30)
 334         stw      %r15,   -80(%r30)
 335         stw      %r16,   -76(%r30)
 336         stw      %r17,   -72(%r30)
 337         stw      %r18,   -68(%r30)
 338         stw       %r3,   -64(%r30)
 339         .endm
 340
 341         .macro  callee_rest
 342         ldw      -64(%r30),    %r3
 343         ldw      -68(%r30),   %r18
 344         ldw      -72(%r30),   %r17
 345         ldw      -76(%r30),   %r16
 346         ldw      -80(%r30),   %r15
 347         ldw      -84(%r30),   %r14
 348         ldw      -88(%r30),   %r13
 349         ldw      -92(%r30),   %r12
 350         ldw      -96(%r30),   %r11
 351         ldw     -100(%r30),   %r10
 352         ldw     -104(%r30),   %r9
 353         ldw     -108(%r30),   %r8
 354         ldw     -112(%r30),   %r7
 355         ldw     -116(%r30),   %r6
 356         ldw     -120(%r30),   %r5
 357         ldw     -124(%r30),   %r4
 358         mtctl   %r3, %cr27
 359         ldw,mb  -128(%r30),   %r3
 360         .endm
 361 #endif /* ! __LP64__ */
 362
 363         .macro  save_specials   regs
 364
 365         SAVE_SP  (%sr0, PT_SR0 (\regs))
 366         SAVE_SP  (%sr1, PT_SR1 (\regs))
 367         SAVE_SP  (%sr2, PT_SR2 (\regs))
 368         SAVE_SP  (%sr3, PT_SR3 (\regs))
 369         SAVE_SP  (%sr4, PT_SR4 (\regs))
 370         SAVE_SP  (%sr5, PT_SR5 (\regs))
 371         SAVE_SP  (%sr6, PT_SR6 (\regs))
 372         SAVE_SP  (%sr7, PT_SR7 (\regs))
 373
 374         SAVE_CR  (%cr17, PT_IASQ0(\regs))
 375         mtctl    %r0,   %cr17
 376         SAVE_CR  (%cr17, PT_IASQ1(\regs))
 377
 378         SAVE_CR  (%cr18, PT_IAOQ0(\regs))
 379         mtctl    %r0,   %cr18
 380         SAVE_CR  (%cr18, PT_IAOQ1(\regs))
 381
 382 #ifdef __LP64__
 383         /* cr11 (sar) is a funny one.  5 bits on PA1.1 and 6 bit on PA2.0
 384          * For PA2.0 mtsar or mtctl always write 6 bits, but mfctl only
 385          * reads 5 bits.  Use mfctl,w to read all six bits.  Otherwise
 386          * we lose the 6th bit on a save/restore over interrupt.
 387          */
 388         mfctl,w  %cr11, %r1
 389         STREG    %r1, PT_SAR (\regs)
 390 #else
 391         SAVE_CR  (%cr11, PT_SAR  (\regs))
 392 #endif
 393         SAVE_CR  (%cr19, PT_IIR  (\regs))
 394
 395         /*
 396          * Code immediately following this macro (in intr_save) relies
 397          * on r8 containing ipsw.
 398          */
 399         mfctl    %cr22, %r8
 400         STREG    %r8,   PT_PSW(\regs)
 401         .endm
 402
 403         .macro  rest_specials   regs
 404
 405         REST_SP  (%sr0, PT_SR0 (\regs))
 406         REST_SP  (%sr1, PT_SR1 (\regs))
 407         REST_SP  (%sr2, PT_SR2 (\regs))
 408         REST_SP  (%sr3, PT_SR3 (\regs))
 409         REST_SP  (%sr4, PT_SR4 (\regs))
 410         REST_SP  (%sr5, PT_SR5 (\regs))
 411         REST_SP  (%sr6, PT_SR6 (\regs))
 412         REST_SP  (%sr7, PT_SR7 (\regs))
 413
 414         REST_CR (%cr17, PT_IASQ0(\regs))
 415         REST_CR (%cr17, PT_IASQ1(\regs))
 416
 417         REST_CR (%cr18, PT_IAOQ0(\regs))
 418         REST_CR (%cr18, PT_IAOQ1(\regs))
 419
 420         REST_CR (%cr11, PT_SAR  (\regs))
 421
 422         REST_CR (%cr22, PT_PSW  (\regs))
 423         .endm
 424
 425 #endif /* __ASSEMBLY__ */
 426 #endif