include/asm-sparc64/ttable.h

   1 /* $Id: ttable.h,v 1.18 2002/02/09 19:49:32 davem Exp $ */
   2 #ifndef _SPARC64_TTABLE_H
   3 #define _SPARC64_TTABLE_H
   4
   5 #include <linux/config.h>
   6 #include <asm/utrap.h>
   7
   8 #ifdef __ASSEMBLY__
   9 #include <asm/thread_info.h>
  10 #endif
  11
  12 #define BOOT_KERNEL b sparc64_boot; nop; nop; nop; nop; nop; nop; nop;
  13
  14 /* We need a "cleaned" instruction... */
  15 #define CLEAN_WINDOW                                                    \
  16         rdpr    %cleanwin, %l0;         add     %l0, 1, %l0;            \
  17         wrpr    %l0, 0x0, %cleanwin;                                    \
  18         clr     %o0;    clr     %o1;    clr     %o2;    clr     %o3;    \
  19         clr     %o4;    clr     %o5;    clr     %o6;    clr     %o7;    \
  20         clr     %l0;    clr     %l1;    clr     %l2;    clr     %l3;    \
  21         clr     %l4;    clr     %l5;    clr     %l6;    clr     %l7;    \
  22         retry;                                                          \
  23         nop;nop;nop;nop;nop;nop;nop;nop;nop;nop;nop;nop;
  24
  25 #define TRAP(routine)                                   \
  26         sethi   %hi(109f), %g7;                         \
  27         ba,pt   %xcc, etrap;                            \
  28 109:     or     %g7, %lo(109b), %g7;                    \
  29         call    routine;                                \
  30          add    %sp, PTREGS_OFF, %o0;                   \
  31         ba,pt   %xcc, rtrap;                            \
  32          clr    %l6;                                    \
  33         nop;
  34
  35 #define TRAP_7INSNS(routine)                            \
  36         sethi   %hi(109f), %g7;                         \
  37         ba,pt   %xcc, etrap;                            \
  38 109:     or     %g7, %lo(109b), %g7;                    \
  39         call    routine;                                \
  40          add    %sp, PTREGS_OFF, %o0;                   \
  41         ba,pt   %xcc, rtrap;                            \
  42          clr    %l6;
  43
  44 #define TRAP_SAVEFPU(routine)                           \
  45         sethi   %hi(109f), %g7;                         \
  46         ba,pt   %xcc, do_fptrap;                        \
  47 109:     or     %g7, %lo(109b), %g7;                    \
  48         call    routine;                                \
  49          add    %sp, PTREGS_OFF, %o0;                   \
  50         ba,pt   %xcc, rtrap;                            \
  51          clr    %l6;                                    \
  52         nop;
  53
  54 #define TRAP_NOSAVE(routine)                            \
  55         ba,pt   %xcc, routine;                          \
  56          nop;                                           \
  57         nop; nop; nop; nop; nop; nop;
  58
  59 #define TRAP_NOSAVE_7INSNS(routine)                     \
  60         ba,pt   %xcc, routine;                          \
  61          nop;                                           \
  62         nop; nop; nop; nop; nop;
  63
  64 #define TRAPTL1(routine)                                \
  65         sethi   %hi(109f), %g7;                         \
  66         ba,pt   %xcc, etraptl1;                         \
  67 109:     or     %g7, %lo(109b), %g7;                    \
  68         call    routine;                                \
  69          add    %sp, PTREGS_OFF, %o0;                   \
  70         ba,pt   %xcc, rtrap;                            \
  71          clr    %l6;                                    \
  72         nop;
  73
  74 #define TRAP_ARG(routine, arg)                          \
  75         sethi   %hi(109f), %g7;                         \
  76         ba,pt   %xcc, etrap;                            \
  77 109:     or     %g7, %lo(109b), %g7;                    \
  78         add     %sp, PTREGS_OFF, %o0;                   \
  79         call    routine;                                \
  80          mov    arg, %o1;                               \
  81         ba,pt   %xcc, rtrap;                            \
  82          clr    %l6;
  83
  84 #define TRAPTL1_ARG(routine, arg)                       \
  85         sethi   %hi(109f), %g7;                         \
  86         ba,pt   %xcc, etraptl1;                         \
  87 109:     or     %g7, %lo(109b), %g7;                    \
  88         add     %sp, PTREGS_OFF, %o0;                   \
  89         call    routine;                                \
  90          mov    arg, %o1;                               \
  91         ba,pt   %xcc, rtrap;                            \
  92          clr    %l6;
  93
  94 #define SYSCALL_TRAP(routine, systbl)                   \
  95         sethi   %hi(109f), %g7;                         \
  96         ba,pt   %xcc, scetrap;                          \
  97 109:     or     %g7, %lo(109b), %g7;                    \
  98         sethi   %hi(systbl), %l7;                       \
  99         ba,pt   %xcc, routine;                          \
 100          or     %l7, %lo(systbl), %l7;                  \
 101         nop; nop;
 102
 103 #define INDIRECT_SOLARIS_SYSCALL(num)                   \
 104         sethi   %hi(109f), %g7;                         \
 105         ba,pt   %xcc, etrap;                            \
 106 109:     or     %g7, %lo(109b), %g7;                    \
 107         ba,pt   %xcc, tl0_solaris + 0xc;                \
 108          mov    num, %g1;                               \
 109         nop;nop;nop;
 110
 111 #define TRAP_UTRAP(handler,lvl)                         \
 112         ldx     [%g6 + TI_UTRAPS], %g1;                 \
 113         sethi   %hi(109f), %g7;                         \
 114         brz,pn  %g1, utrap;                             \
 115          or     %g7, %lo(109f), %g7;                    \
 116         ba,pt   %xcc, utrap;                            \
 117 109:     ldx    [%g1 + handler*8], %g1;                 \
 118         ba,pt   %xcc, utrap_ill;                        \
 119          mov    lvl, %o1;
 120
 121 #ifdef CONFIG_SUNOS_EMUL
 122 #define SUNOS_SYSCALL_TRAP SYSCALL_TRAP(linux_sparc_syscall32, sunos_sys_table)
 123 #else
 124 #define SUNOS_SYSCALL_TRAP TRAP(sunos_syscall)
 125 #endif
 126 #ifdef CONFIG_COMPAT
 127 #define LINUX_32BIT_SYSCALL_TRAP SYSCALL_TRAP(linux_sparc_syscall32, sys_call_table32)
 128 #else
 129 #define LINUX_32BIT_SYSCALL_TRAP BTRAP(0x110)
 130 #endif
 131 #define LINUX_64BIT_SYSCALL_TRAP SYSCALL_TRAP(linux_sparc_syscall, sys_call_table64)
 132 #define GETCC_TRAP TRAP(getcc)
 133 #define SETCC_TRAP TRAP(setcc)
 134 #ifdef CONFIG_SOLARIS_EMUL
 135 #define SOLARIS_SYSCALL_TRAP TRAP(solaris_sparc_syscall)
 136 #else
 137 #define SOLARIS_SYSCALL_TRAP TRAP(solaris_syscall)
 138 #endif
 139 /* FIXME: Write these actually */
 140 #define NETBSD_SYSCALL_TRAP TRAP(netbsd_syscall)
 141 #define BREAKPOINT_TRAP TRAP(breakpoint_trap)
 142
 143 #define TRAP_IRQ(routine, level)                        \
 144         rdpr    %pil, %g2;                              \
 145         wrpr    %g0, 15, %pil;                          \
 146         b,pt    %xcc, etrap_irq;                        \
 147          rd     %pc, %g7;                               \
 148         mov     level, %o0;                             \
 149         call    routine;                                \
 150          add    %sp, PTREGS_OFF, %o1;                   \
 151         ba,a,pt %xcc, rtrap_irq;
 152
 153 #define TICK_SMP_IRQ                                    \
 154         rdpr    %pil, %g2;                              \
 155         wrpr    %g0, 15, %pil;                          \
 156         sethi   %hi(109f), %g7;                         \
 157         b,pt    %xcc, etrap_irq;                        \
 158 109:     or     %g7, %lo(109b), %g7;                    \
 159         call    smp_percpu_timer_interrupt;             \
 160          add    %sp, PTREGS_OFF, %o0;                   \
 161         ba,a,pt %xcc, rtrap_irq;
 162
 163 #define TRAP_IVEC TRAP_NOSAVE(do_ivec)
 164
 165 #define BTRAP(lvl) TRAP_ARG(bad_trap, lvl)
 166
 167 #define BTRAPTL1(lvl) TRAPTL1_ARG(bad_trap_tl1, lvl)
 168
 169 #define FLUSH_WINDOW_TRAP                                               \
 170         ba,pt   %xcc, etrap;                                            \
 171          rd     %pc, %g7;                                               \
 172         flushw;                                                         \
 173         ldx     [%sp + PTREGS_OFF + PT_V9_TNPC], %l1;                   \
 174         add     %l1, 4, %l2;                                            \
 175         stx     %l1, [%sp + PTREGS_OFF + PT_V9_TPC];                    \
 176         ba,pt   %xcc, rtrap_clr_l6;                                     \
 177          stx    %l2, [%sp + PTREGS_OFF + PT_V9_TNPC];
 178
 179 /* Before touching these macros, you owe it to yourself to go and
 180  * see how arch/sparc64/kernel/winfixup.S works... -DaveM
 181  *
 182  * For the user cases we used to use the %asi register, but
 183  * it turns out that the "wr xxx, %asi" costs ~5 cycles, so
 184  * now we use immediate ASI loads and stores instead.  Kudos
 185  * to Greg Onufer for pointing out this performance anomaly.
 186  *
 187  * Further note that we cannot use the g2, g4, g5, and g7 alternate
 188  * globals in the spill routines, check out the save instruction in
 189  * arch/sparc64/kernel/etrap.S to see what I mean about g2, and
 190  * g4/g5 are the globals which are preserved by etrap processing
 191  * for the caller of it.  The g7 register is the return pc for
 192  * etrap.  Finally, g6 is the current thread register so we cannot
 193  * us it in the spill handlers either.  Most of these rules do not
 194  * apply to fill processing, only g6 is not usable.
 195  */
 196
 197 /* Normal kernel spill */
 198 #define SPILL_0_NORMAL                                  \
 199         stx     %l0, [%sp + STACK_BIAS + 0x00];         \
 200         stx     %l1, [%sp + STACK_BIAS + 0x08];         \
 201         stx     %l2, [%sp + STACK_BIAS + 0x10];         \
 202         stx     %l3, [%sp + STACK_BIAS + 0x18];         \
 203         stx     %l4, [%sp + STACK_BIAS + 0x20];         \
 204         stx     %l5, [%sp + STACK_BIAS + 0x28];         \
 205         stx     %l6, [%sp + STACK_BIAS + 0x30];         \
 206         stx     %l7, [%sp + STACK_BIAS + 0x38];         \
 207         stx     %i0, [%sp + STACK_BIAS + 0x40];         \
 208         stx     %i1, [%sp + STACK_BIAS + 0x48];         \
 209         stx     %i2, [%sp + STACK_BIAS + 0x50];         \
 210         stx     %i3, [%sp + STACK_BIAS + 0x58];         \
 211         stx     %i4, [%sp + STACK_BIAS + 0x60];         \
 212         stx     %i5, [%sp + STACK_BIAS + 0x68];         \
 213         stx     %i6, [%sp + STACK_BIAS + 0x70];         \
 214         stx     %i7, [%sp + STACK_BIAS + 0x78];         \
 215         saved; retry; nop; nop; nop; nop; nop; nop;     \
 216         nop; nop; nop; nop; nop; nop; nop; nop;
 217
 218 /* Normal 64bit spill */
 219 #define SPILL_1_GENERIC(ASI)                            \
 220         add     %sp, STACK_BIAS + 0x00, %g1;            \
 221         stxa    %l0, [%g1 + %g0] ASI;                   \
 222         mov     0x08, %g3;                              \
 223         stxa    %l1, [%g1 + %g3] ASI;                   \
 224         add     %g1, 0x10, %g1;                         \
 225         stxa    %l2, [%g1 + %g0] ASI;                   \
 226         stxa    %l3, [%g1 + %g3] ASI;                   \
 227         add     %g1, 0x10, %g1;                         \
 228         stxa    %l4, [%g1 + %g0] ASI;                   \
 229         stxa    %l5, [%g1 + %g3] ASI;                   \
 230         add     %g1, 0x10, %g1;                         \
 231         stxa    %l6, [%g1 + %g0] ASI;                   \
 232         stxa    %l7, [%g1 + %g3] ASI;                   \
 233         add     %g1, 0x10, %g1;                         \
 234         stxa    %i0, [%g1 + %g0] ASI;                   \
 235         stxa    %i1, [%g1 + %g3] ASI;                   \
 236         add     %g1, 0x10, %g1;                         \
 237         stxa    %i2, [%g1 + %g0] ASI;                   \
 238         stxa    %i3, [%g1 + %g3] ASI;                   \
 239         add     %g1, 0x10, %g1;                         \
 240         stxa    %i4, [%g1 + %g0] ASI;                   \
 241         stxa    %i5, [%g1 + %g3] ASI;                   \
 242         add     %g1, 0x10, %g1;                         \
 243         stxa    %i6, [%g1 + %g0] ASI;                   \
 244         stxa    %i7, [%g1 + %g3] ASI;                   \
 245         saved;                                          \
 246         retry; nop; nop;                                \
 247         b,a,pt  %xcc, spill_fixup_dax;                  \
 248         b,a,pt  %xcc, spill_fixup_mna;                  \
 249         b,a,pt  %xcc, spill_fixup;
 250
 251 /* Normal 32bit spill */
 252 #define SPILL_2_GENERIC(ASI)                            \
 253         srl     %sp, 0, %sp;                            \
 254         stwa    %l0, [%sp + %g0] ASI;                   \
 255         mov     0x04, %g3;                              \
 256         stwa    %l1, [%sp + %g3] ASI;                   \
 257         add     %sp, 0x08, %g1;                         \
 258         stwa    %l2, [%g1 + %g0] ASI;                   \
 259         stwa    %l3, [%g1 + %g3] ASI;                   \
 260         add     %g1, 0x08, %g1;                         \
 261         stwa    %l4, [%g1 + %g0] ASI;                   \
 262         stwa    %l5, [%g1 + %g3] ASI;                   \
 263         add     %g1, 0x08, %g1;                         \
 264         stwa    %l6, [%g1 + %g0] ASI;                   \
 265         stwa    %l7, [%g1 + %g3] ASI;                   \
 266         add     %g1, 0x08, %g1;                         \
 267         stwa    %i0, [%g1 + %g0] ASI;                   \
 268         stwa    %i1, [%g1 + %g3] ASI;                   \
 269         add     %g1, 0x08, %g1;                         \
 270         stwa    %i2, [%g1 + %g0] ASI;                   \
 271         stwa    %i3, [%g1 + %g3] ASI;                   \
 272         add     %g1, 0x08, %g1;                         \
 273         stwa    %i4, [%g1 + %g0] ASI;                   \
 274         stwa    %i5, [%g1 + %g3] ASI;                   \
 275         add     %g1, 0x08, %g1;                         \
 276         stwa    %i6, [%g1 + %g0] ASI;                   \
 277         stwa    %i7, [%g1 + %g3] ASI;                   \
 278         saved;                                          \
 279         retry; nop; nop;                                \
 280         b,a,pt  %xcc, spill_fixup_dax;                  \
 281         b,a,pt  %xcc, spill_fixup_mna;                  \
 282         b,a,pt  %xcc, spill_fixup;
 283
 284 #define SPILL_1_NORMAL SPILL_1_GENERIC(ASI_AIUP)
 285 #define SPILL_2_NORMAL SPILL_2_GENERIC(ASI_AIUP)
 286 #define SPILL_3_NORMAL SPILL_0_NORMAL
 287 #define SPILL_4_NORMAL SPILL_0_NORMAL
 288 #define SPILL_5_NORMAL SPILL_0_NORMAL
 289 #define SPILL_6_NORMAL SPILL_0_NORMAL
 290 #define SPILL_7_NORMAL SPILL_0_NORMAL
 291
 292 #define SPILL_0_OTHER SPILL_0_NORMAL
 293 #define SPILL_1_OTHER SPILL_1_GENERIC(ASI_AIUS)
 294 #define SPILL_2_OTHER SPILL_2_GENERIC(ASI_AIUS)
 295 #define SPILL_3_OTHER SPILL_3_NORMAL
 296 #define SPILL_4_OTHER SPILL_4_NORMAL
 297 #define SPILL_5_OTHER SPILL_5_NORMAL
 298 #define SPILL_6_OTHER SPILL_6_NORMAL
 299 #define SPILL_7_OTHER SPILL_7_NORMAL
 300
 301 /* Normal kernel fill */
 302 #define FILL_0_NORMAL                                   \
 303         ldx     [%sp + STACK_BIAS + 0x00], %l0;         \
 304         ldx     [%sp + STACK_BIAS + 0x08], %l1;         \
 305         ldx     [%sp + STACK_BIAS + 0x10], %l2;         \
 306         ldx     [%sp + STACK_BIAS + 0x18], %l3;         \
 307         ldx     [%sp + STACK_BIAS + 0x20], %l4;         \
 308         ldx     [%sp + STACK_BIAS + 0x28], %l5;         \
 309         ldx     [%sp + STACK_BIAS + 0x30], %l6;         \
 310         ldx     [%sp + STACK_BIAS + 0x38], %l7;         \
 311         ldx     [%sp + STACK_BIAS + 0x40], %i0;         \
 312         ldx     [%sp + STACK_BIAS + 0x48], %i1;         \
 313         ldx     [%sp + STACK_BIAS + 0x50], %i2;         \
 314         ldx     [%sp + STACK_BIAS + 0x58], %i3;         \
 315         ldx     [%sp + STACK_BIAS + 0x60], %i4;         \
 316         ldx     [%sp + STACK_BIAS + 0x68], %i5;         \
 317         ldx     [%sp + STACK_BIAS + 0x70], %i6;         \
 318         ldx     [%sp + STACK_BIAS + 0x78], %i7;         \
 319         restored; retry; nop; nop; nop; nop; nop; nop;  \
 320         nop; nop; nop; nop; nop; nop; nop; nop;
 321
 322 /* Normal 64bit fill */
 323 #define FILL_1_GENERIC(ASI)                             \
 324         add     %sp, STACK_BIAS + 0x00, %g1;            \
 325         ldxa    [%g1 + %g0] ASI, %l0;                   \
 326         mov     0x08, %g2;                              \
 327         mov     0x10, %g3;                              \
 328         ldxa    [%g1 + %g2] ASI, %l1;                   \
 329         mov     0x18, %g5;                              \
 330         ldxa    [%g1 + %g3] ASI, %l2;                   \
 331         ldxa    [%g1 + %g5] ASI, %l3;                   \
 332         add     %g1, 0x20, %g1;                         \
 333         ldxa    [%g1 + %g0] ASI, %l4;                   \
 334         ldxa    [%g1 + %g2] ASI, %l5;                   \
 335         ldxa    [%g1 + %g3] ASI, %l6;                   \
 336         ldxa    [%g1 + %g5] ASI, %l7;                   \
 337         add     %g1, 0x20, %g1;                         \
 338         ldxa    [%g1 + %g0] ASI, %i0;                   \
 339         ldxa    [%g1 + %g2] ASI, %i1;                   \
 340         ldxa    [%g1 + %g3] ASI, %i2;                   \
 341         ldxa    [%g1 + %g5] ASI, %i3;                   \
 342         add     %g1, 0x20, %g1;                         \
 343         ldxa    [%g1 + %g0] ASI, %i4;                   \
 344         ldxa    [%g1 + %g2] ASI, %i5;                   \
 345         ldxa    [%g1 + %g3] ASI, %i6;                   \
 346         ldxa    [%g1 + %g5] ASI, %i7;                   \
 347         restored;                                       \
 348         retry; nop; nop; nop; nop;                      \
 349         b,a,pt  %xcc, fill_fixup_dax;                   \
 350         b,a,pt  %xcc, fill_fixup_mna;                   \
 351         b,a,pt  %xcc, fill_fixup;
 352
 353 /* Normal 32bit fill */
 354 #define FILL_2_GENERIC(ASI)                             \
 355         srl     %sp, 0, %sp;                            \
 356         lduwa   [%sp + %g0] ASI, %l0;                   \
 357         mov     0x04, %g2;                              \
 358         mov     0x08, %g3;                              \
 359         lduwa   [%sp + %g2] ASI, %l1;                   \
 360         mov     0x0c, %g5;                              \
 361         lduwa   [%sp + %g3] ASI, %l2;                   \
 362         lduwa   [%sp + %g5] ASI, %l3;                   \
 363         add     %sp, 0x10, %g1;                         \
 364         lduwa   [%g1 + %g0] ASI, %l4;                   \
 365         lduwa   [%g1 + %g2] ASI, %l5;                   \
 366         lduwa   [%g1 + %g3] ASI, %l6;                   \
 367         lduwa   [%g1 + %g5] ASI, %l7;                   \
 368         add     %g1, 0x10, %g1;                         \
 369         lduwa   [%g1 + %g0] ASI, %i0;                   \
 370         lduwa   [%g1 + %g2] ASI, %i1;                   \
 371         lduwa   [%g1 + %g3] ASI, %i2;                   \
 372         lduwa   [%g1 + %g5] ASI, %i3;                   \
 373         add     %g1, 0x10, %g1;                         \
 374         lduwa   [%g1 + %g0] ASI, %i4;                   \
 375         lduwa   [%g1 + %g2] ASI, %i5;                   \
 376         lduwa   [%g1 + %g3] ASI, %i6;                   \
 377         lduwa   [%g1 + %g5] ASI, %i7;                   \
 378         restored;                                       \
 379         retry; nop; nop; nop; nop;                      \
 380         b,a,pt  %xcc, fill_fixup_dax;                   \
 381         b,a,pt  %xcc, fill_fixup_mna;                   \
 382         b,a,pt  %xcc, fill_fixup;
 383
 384 #define FILL_1_NORMAL FILL_1_GENERIC(ASI_AIUP)
 385 #define FILL_2_NORMAL FILL_2_GENERIC(ASI_AIUP)
 386 #define FILL_3_NORMAL FILL_0_NORMAL
 387 #define FILL_4_NORMAL FILL_0_NORMAL
 388 #define FILL_5_NORMAL FILL_0_NORMAL
 389 #define FILL_6_NORMAL FILL_0_NORMAL
 390 #define FILL_7_NORMAL FILL_0_NORMAL
 391
 392 #define FILL_0_OTHER FILL_0_NORMAL
 393 #define FILL_1_OTHER FILL_1_GENERIC(ASI_AIUS)
 394 #define FILL_2_OTHER FILL_2_GENERIC(ASI_AIUS)
 395 #define FILL_3_OTHER FILL_3_NORMAL
 396 #define FILL_4_OTHER FILL_4_NORMAL
 397 #define FILL_5_OTHER FILL_5_NORMAL
 398 #define FILL_6_OTHER FILL_6_NORMAL
 399 #define FILL_7_OTHER FILL_7_NORMAL
 400
 401 #endif /* !(_SPARC64_TTABLE_H) */