acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 13; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.13.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDP build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIBS="$DPDK_LIB_DIR/libintel_dpdk.a"
 174
 175     LIBS="$DPDK_LIBS $LIBS"
 176     CPPFLAGS="-I$DPDK_INCLUDE $CPPFLAGS"
 177
 178     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 179   else
 180     RTE_SDK=
 181   fi
 182
 183   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 184 ])
 185
 186 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 187 dnl
 188 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 189 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 190 dnl <REGEX> translated to uppercase.
 191 AC_DEFUN([OVS_GREP_IFELSE], [
 192   AC_MSG_CHECKING([whether $2 matches in $1])
 193   if test -f $1; then
 194     grep '$2' $1 >/dev/null 2>&1
 195     status=$?
 196     case $status in
 197       0)
 198         AC_MSG_RESULT([yes])
 199         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 200         ;;
 201       1)
 202         AC_MSG_RESULT([no])
 203         $4
 204         ;;
 205       *)
 206         AC_MSG_ERROR([grep exited with status $status])
 207         ;;
 208     esac
 209   else
 210     AC_MSG_RESULT([file not found])
 211     $4
 212   fi
 213 ])
 214
 215 dnl OVS_DEFINE(NAME)
 216 dnl
 217 dnl Defines NAME to 1 in kcompat.h.
 218 AC_DEFUN([OVS_DEFINE], [
 219   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 220 ])
 221
 222 AC_DEFUN([OVS_CHECK_LOG2_H], [
 223   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 224   if test -e $KSRC/include/linux/log2.h; then
 225     AC_MSG_RESULT([yes])
 226     OVS_DEFINE([HAVE_LOG2_H])
 227   else
 228     AC_MSG_RESULT([no])
 229   fi
 230 ])
 231
 232 dnl OVS_CHECK_LINUX_COMPAT
 233 dnl
 234 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 235 dnl the directory in $KBUILD.
 236 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 237   rm -f datapath/linux/kcompat.h.new
 238   mkdir -p datapath/linux
 239   : > datapath/linux/kcompat.h.new
 240
 241   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 242                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 243
 244   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 245
 246   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 247
 248   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 249
 250   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 251
 252   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 254   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 256   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 258
 259   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 260                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 261                                    [rcu_read_lock_held])])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 263
 264   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 265   # is necessary because some versions of this header remove the
 266   # member but retain the kerneldoc comment that describes it (which
 267   # starts with @).  The brackets must be doubled because of m4
 268   # quoting rules.
 269   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 270                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 271   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 272   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 273                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 274   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 275                   [skb_copy_from_linear_data_offset])
 276   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 277                   [skb_reset_tail_pointer])
 278   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 279   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 280                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 281   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 282                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 283   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 284                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 285   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 286   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 287   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 288   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 289   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 291
 292   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 293                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 294   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 295                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 296   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 297                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 298
 299   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 300   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 301
 302   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 303   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 304   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 305   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 306   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 307   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 308   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 309
 310   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 311
 312   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 313                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 314
 315   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 316
 317   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 318                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 319
 320   OVS_CHECK_LOG2_H
 321
 322   if cmp -s datapath/linux/kcompat.h.new \
 323             datapath/linux/kcompat.h >/dev/null 2>&1; then
 324     rm datapath/linux/kcompat.h.new
 325   else
 326     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 327   fi
 328 ])
 329
 330 dnl Checks for net/if_packet.h.
 331 AC_DEFUN([OVS_CHECK_IF_PACKET],
 332   [AC_CHECK_HEADER([net/if_packet.h],
 333                    [HAVE_IF_PACKET=yes],
 334                    [HAVE_IF_PACKET=no])
 335    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 336    if test "$HAVE_IF_PACKET" = yes; then
 337       AC_DEFINE([HAVE_IF_PACKET], [1],
 338                 [Define to 1 if net/if_packet.h is available.])
 339    fi])
 340
 341 dnl Checks for net/if_dl.h.
 342 dnl
 343 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 344 dnl or NetBSD.)
 345 AC_DEFUN([OVS_CHECK_IF_DL],
 346   [AC_CHECK_HEADER([net/if_dl.h],
 347                    [HAVE_IF_DL=yes],
 348                    [HAVE_IF_DL=no])
 349    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 350    if test "$HAVE_IF_DL" = yes; then
 351       AC_DEFINE([HAVE_IF_DL], [1],
 352                 [Define to 1 if net/if_dl.h is available.])
 353
 354       # On these platforms we use libpcap to access network devices.
 355       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 356    fi])
 357
 358 dnl Checks for buggy strtok_r.
 359 dnl
 360 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 361 dnl with optimization that can cause segfaults:
 362 dnl
 363 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 364 AC_DEFUN([OVS_CHECK_STRTOK_R],
 365   [AC_CACHE_CHECK(
 366      [whether strtok_r macro segfaults on some inputs],
 367      [ovs_cv_strtok_r_bug],
 368      [AC_RUN_IFELSE(
 369         [AC_LANG_PROGRAM([#include <stdio.h>
 370                           #include <string.h>
 371                          ],
 372                          [[char string[] = ":::";
 373                            char *save_ptr = (char *) 0xc0ffee;
 374                            char *token1, *token2;
 375                            token1 = strtok_r(string, ":", &save_ptr);
 376                            token2 = strtok_r(NULL, ":", &save_ptr);
 377                            freopen ("/dev/null", "w", stdout);
 378                            printf ("%s %s\n", token1, token2);
 379                            return 0;
 380                           ]])],
 381         [ovs_cv_strtok_r_bug=no],
 382         [ovs_cv_strtok_r_bug=yes],
 383         [ovs_cv_strtok_r_bug=yes])])
 384    if test $ovs_cv_strtok_r_bug = yes; then
 385      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 386                [Define if strtok_r macro segfaults on some inputs])
 387    fi
 388 ])
 389
 390 dnl ----------------------------------------------------------------------
 391 dnl These macros are from GNU PSPP, with the following original license:
 392 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 393 dnl This file is free software; the Free Software Foundation
 394 dnl gives unlimited permission to copy and/or distribute it,
 395 dnl with or without modifications, as long as this notice is preserved.
 396
 397 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 398   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 399   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 400     [ovs_save_CFLAGS="$CFLAGS"
 401      dnl Include -Werror in the compiler options, because without -Werror
 402      dnl clang's GCC-compatible compiler driver does not return a failure
 403      dnl exit status even though it complains about options it does not
 404      dnl understand.
 405      CFLAGS="$CFLAGS $WERROR $1"
 406      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 407      CFLAGS="$ovs_save_CFLAGS"])
 408   if test $ovs_cv_name = yes; then
 409     m4_if([$2], [], [:], [$2])
 410   else
 411     m4_if([$3], [], [:], [$3])
 412   fi
 413 ])
 414
 415 dnl OVS_CHECK_WERROR
 416 dnl
 417 dnl Check whether the C compiler accepts -Werror.
 418 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 419 AC_DEFUN([OVS_CHECK_WERROR],
 420   [WERROR=
 421    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 422
 423 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 424 dnl Check whether the given C compiler OPTION is accepted.
 425 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 426 AC_DEFUN([OVS_CHECK_CC_OPTION],
 427   [AC_REQUIRE([OVS_CHECK_WERROR])
 428    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 429
 430 dnl OVS_ENABLE_OPTION([OPTION])
 431 dnl Check whether the given C compiler OPTION is accepted.
 432 dnl If so, add it to WARNING_FLAGS.
 433 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 434 AC_DEFUN([OVS_ENABLE_OPTION],
 435   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 436    AC_SUBST([WARNING_FLAGS])])
 437
 438 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 439 dnl Check whether the given C compiler OPTION is accepted.
 440 dnl If so, enable the given Automake CONDITIONAL.
 441
 442 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 443 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 444   [OVS_CHECK_CC_OPTION(
 445     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 446    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 447 dnl ----------------------------------------------------------------------
 448
 449 dnl Check for too-old XenServer.
 450 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 451   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 452     [if test -e /etc/redhat-release; then
 453        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 454      fi
 455      if test -z "$ovs_cv_xsversion"; then
 456        ovs_cv_xsversion=none
 457      fi])
 458   case $ovs_cv_xsversion in
 459     none)
 460       ;;
 461
 462     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 463     [[6-9]]* |                           dnl XenServer 6 or later
 464     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 465     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 466     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 467     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 468       ;;
 469
 470     *)
 471       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 472       ;;
 473   esac])
 474
 475 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 476 dnl
 477 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 478 dnl Runs 'if-true' if so, 'if-false' otherwise.
 479 AC_DEFUN([OVS_CHECK_MAKE_IF],
 480   [AC_CACHE_CHECK(
 481      [whether ${MAKE-make} has GNU make \$(if) extension],
 482      [ovs_cv_gnu_make_if],
 483      [cat <<'EOF' > conftest.mk
 484 conftest.out:
 485         echo $(if x,y,z) > conftest.out
 486 .PHONY: all
 487 EOF
 488       rm -f conftest.out
 489       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 490       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 491       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 492       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 493       result=`cat conftest.out`
 494       rm -f conftest.mk conftest.out
 495       if test "X$result" = "Xy"; then
 496         ovs_cv_gnu_make_if=yes
 497       else
 498         ovs_cv_gnu_make_if=no
 499       fi])])
 500
 501 dnl OVS_CHECK_GNU_MAKE
 502 dnl
 503 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 504 dnl only work with GNU make).
 505 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 506   [AC_CACHE_CHECK(
 507      [whether ${MAKE-make} is GNU make],
 508      [ovs_cv_gnu_make],
 509      [rm -f conftest.out
 510       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 511       ${MAKE-make} --version >conftest.out 2>&1
 512       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 513       result=`cat conftest.out`
 514       rm -f conftest.mk conftest.out
 515
 516       case $result in # (
 517         GNU*) ovs_cv_gnu_make=yes ;; # (
 518         *) ovs_cv_gnu_make=no ;;
 519       esac])
 520    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 521
 522 dnl OVS_CHECK_SPARSE_TARGET
 523 dnl
 524 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 525 dnl target for which the code is being built.  This helps it out.
 526 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 527   [AC_CACHE_CHECK(
 528     [target hint for cgcc],
 529     [ac_cv_sparse_target],
 530     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 531        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 532        [x86_64-*], [ac_cv_sparse_target=x86_64],
 533        [ac_cv_sparse_target=other])])
 534    AS_CASE([$ac_cv_sparse_target],
 535      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 536      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 537      [SPARSEFLAGS= CGCCFLAGS=])
 538    AC_SUBST([SPARSEFLAGS])
 539    AC_SUBST([CGCCFLAGS])])
 540
 541 dnl OVS_SPARSE_EXTRA_INCLUDES
 542 dnl
 543 dnl The cgcc script from "sparse" does not search gcc's default
 544 dnl search path. Get the default search path from GCC and pass
 545 dnl them to sparse.
 546 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 547     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 548            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 549
 550 dnl OVS_ENABLE_SPARSE
 551 AC_DEFUN([OVS_ENABLE_SPARSE],
 552   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 553    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 554    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 555    : ${SPARSE=sparse}
 556    AC_SUBST([SPARSE])
 557    AC_CONFIG_COMMANDS_PRE(
 558      [if test $ovs_cv_gnu_make_if = yes; then
 559         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 560       fi])])
 561
 562 dnl OVS_PTHREAD_SET_NAME
 563 dnl
 564 dnl This checks for three known variants of pthreads functions for setting
 565 dnl the name of the current thread:
 566 dnl
 567 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 568 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 569 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 570 dnl
 571 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 572 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 573 dnl provide to it.
 574 dnl
 575 dnl This macro defines:
 576 dnl
 577 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 578 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 579 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 580 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 581   [AC_CHECK_FUNCS([pthread_set_name_np])
 582    if test $ac_cv_func_pthread_set_name_np != yes; then
 583      AC_CACHE_CHECK(
 584        [for pthread_setname_np() variant],
 585        [ovs_cv_pthread_setname_np],
 586        [AC_LINK_IFELSE(
 587          [AC_LANG_PROGRAM([#include <pthread.h>
 588   ], [pthread_setname_np(pthread_self(), "name");])],
 589          [ovs_cv_pthread_setname_np=glibc],
 590          [AC_LINK_IFELSE(
 591            [AC_LANG_PROGRAM([#include <pthread.h>
 592 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 593            [ovs_cv_pthread_setname_np=netbsd],
 594            [ovs_cv_pthread_setname_np=none])])])
 595      case $ovs_cv_pthread_setname_np in # (
 596        glibc)
 597           AC_DEFINE(
 598             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 599             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 600           ;; # (
 601        netbsd)
 602           AC_DEFINE(
 603             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 604             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 605           ;;
 606      esac
 607    fi])
 608
 609 dnl OVS_CHECK_LINUX_HOST.
 610 dnl
 611 dnl Checks whether we're building for a Linux host, based on the presence of
 612 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 613 dnl LINUX based on the result.
 614 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 615   [AC_CACHE_CHECK(
 616      [whether __linux__ is defined],
 617      [ovs_cv_linux],
 618      [AC_COMPILE_IFELSE(
 619         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 620         [ovs_cv_linux=true],
 621         [ovs_cv_linux=false])])
 622    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])