acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 13; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.13.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDP build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIBS="$DPDK_LIB_DIR/libintel_dpdk.a"
 174
 175     LIBS="$DPDK_LIBS $LIBS"
 176     CPPFLAGS="-I$DPDK_INCLUDE $CPPFLAGS"
 177
 178     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 179   else
 180     RTE_SDK=
 181   fi
 182
 183   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 184 ])
 185
 186 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 187 dnl
 188 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 189 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 190 dnl <REGEX> translated to uppercase.
 191 AC_DEFUN([OVS_GREP_IFELSE], [
 192   AC_MSG_CHECKING([whether $2 matches in $1])
 193   if test -f $1; then
 194     grep '$2' $1 >/dev/null 2>&1
 195     status=$?
 196     case $status in
 197       0)
 198         AC_MSG_RESULT([yes])
 199         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 200         ;;
 201       1)
 202         AC_MSG_RESULT([no])
 203         $4
 204         ;;
 205       *)
 206         AC_MSG_ERROR([grep exited with status $status])
 207         ;;
 208     esac
 209   else
 210     AC_MSG_RESULT([file not found])
 211     $4
 212   fi
 213 ])
 214
 215 dnl OVS_DEFINE(NAME)
 216 dnl
 217 dnl Defines NAME to 1 in kcompat.h.
 218 AC_DEFUN([OVS_DEFINE], [
 219   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 220 ])
 221
 222 AC_DEFUN([OVS_CHECK_LOG2_H], [
 223   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 224   if test -e $KSRC/include/linux/log2.h; then
 225     AC_MSG_RESULT([yes])
 226     OVS_DEFINE([HAVE_LOG2_H])
 227   else
 228     AC_MSG_RESULT([no])
 229   fi
 230 ])
 231
 232 dnl OVS_CHECK_LINUX_COMPAT
 233 dnl
 234 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 235 dnl the directory in $KBUILD.
 236 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 237   rm -f datapath/linux/kcompat.h.new
 238   mkdir -p datapath/linux
 239   : > datapath/linux/kcompat.h.new
 240
 241   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 242                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 243
 244   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 245
 246   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 247
 248   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 249
 250   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 251
 252   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 254   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 256   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 258
 259   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 260                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 261                                    [rcu_read_lock_held])])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 263
 264   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 265   # is necessary because some versions of this header remove the
 266   # member but retain the kerneldoc comment that describes it (which
 267   # starts with @).  The brackets must be doubled because of m4
 268   # quoting rules.
 269   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 270                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 271   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 272   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 273                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 274   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 275                   [skb_copy_from_linear_data_offset])
 276   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 277                   [skb_reset_tail_pointer])
 278   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 279   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 280                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 281   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 282                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 283   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 284                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 285   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 286   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 287   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 288   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 289   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 291   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 292
 293   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 294                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 295   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 296                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 297   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 298                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 299
 300   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 301   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 302
 303   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 304   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 305   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 306   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 307   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 308   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 309   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 310
 311   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 312
 313   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 314                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 315
 316   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 317
 318   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 319                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 320
 321   OVS_CHECK_LOG2_H
 322
 323   if cmp -s datapath/linux/kcompat.h.new \
 324             datapath/linux/kcompat.h >/dev/null 2>&1; then
 325     rm datapath/linux/kcompat.h.new
 326   else
 327     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 328   fi
 329 ])
 330
 331 dnl Checks for net/if_packet.h.
 332 AC_DEFUN([OVS_CHECK_IF_PACKET],
 333   [AC_CHECK_HEADER([net/if_packet.h],
 334                    [HAVE_IF_PACKET=yes],
 335                    [HAVE_IF_PACKET=no])
 336    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 337    if test "$HAVE_IF_PACKET" = yes; then
 338       AC_DEFINE([HAVE_IF_PACKET], [1],
 339                 [Define to 1 if net/if_packet.h is available.])
 340    fi])
 341
 342 dnl Checks for net/if_dl.h.
 343 dnl
 344 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 345 dnl or NetBSD.)
 346 AC_DEFUN([OVS_CHECK_IF_DL],
 347   [AC_CHECK_HEADER([net/if_dl.h],
 348                    [HAVE_IF_DL=yes],
 349                    [HAVE_IF_DL=no])
 350    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 351    if test "$HAVE_IF_DL" = yes; then
 352       AC_DEFINE([HAVE_IF_DL], [1],
 353                 [Define to 1 if net/if_dl.h is available.])
 354
 355       # On these platforms we use libpcap to access network devices.
 356       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 357    fi])
 358
 359 dnl Checks for buggy strtok_r.
 360 dnl
 361 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 362 dnl with optimization that can cause segfaults:
 363 dnl
 364 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 365 AC_DEFUN([OVS_CHECK_STRTOK_R],
 366   [AC_CACHE_CHECK(
 367      [whether strtok_r macro segfaults on some inputs],
 368      [ovs_cv_strtok_r_bug],
 369      [AC_RUN_IFELSE(
 370         [AC_LANG_PROGRAM([#include <stdio.h>
 371                           #include <string.h>
 372                          ],
 373                          [[char string[] = ":::";
 374                            char *save_ptr = (char *) 0xc0ffee;
 375                            char *token1, *token2;
 376                            token1 = strtok_r(string, ":", &save_ptr);
 377                            token2 = strtok_r(NULL, ":", &save_ptr);
 378                            freopen ("/dev/null", "w", stdout);
 379                            printf ("%s %s\n", token1, token2);
 380                            return 0;
 381                           ]])],
 382         [ovs_cv_strtok_r_bug=no],
 383         [ovs_cv_strtok_r_bug=yes],
 384         [ovs_cv_strtok_r_bug=yes])])
 385    if test $ovs_cv_strtok_r_bug = yes; then
 386      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 387                [Define if strtok_r macro segfaults on some inputs])
 388    fi
 389 ])
 390
 391 dnl ----------------------------------------------------------------------
 392 dnl These macros are from GNU PSPP, with the following original license:
 393 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 394 dnl This file is free software; the Free Software Foundation
 395 dnl gives unlimited permission to copy and/or distribute it,
 396 dnl with or without modifications, as long as this notice is preserved.
 397
 398 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 399   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 400   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 401     [ovs_save_CFLAGS="$CFLAGS"
 402      dnl Include -Werror in the compiler options, because without -Werror
 403      dnl clang's GCC-compatible compiler driver does not return a failure
 404      dnl exit status even though it complains about options it does not
 405      dnl understand.
 406      CFLAGS="$CFLAGS $WERROR $1"
 407      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 408      CFLAGS="$ovs_save_CFLAGS"])
 409   if test $ovs_cv_name = yes; then
 410     m4_if([$2], [], [:], [$2])
 411   else
 412     m4_if([$3], [], [:], [$3])
 413   fi
 414 ])
 415
 416 dnl OVS_CHECK_WERROR
 417 dnl
 418 dnl Check whether the C compiler accepts -Werror.
 419 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 420 AC_DEFUN([OVS_CHECK_WERROR],
 421   [WERROR=
 422    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 423
 424 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 425 dnl Check whether the given C compiler OPTION is accepted.
 426 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 427 AC_DEFUN([OVS_CHECK_CC_OPTION],
 428   [AC_REQUIRE([OVS_CHECK_WERROR])
 429    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 430
 431 dnl OVS_ENABLE_OPTION([OPTION])
 432 dnl Check whether the given C compiler OPTION is accepted.
 433 dnl If so, add it to WARNING_FLAGS.
 434 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 435 AC_DEFUN([OVS_ENABLE_OPTION],
 436   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 437    AC_SUBST([WARNING_FLAGS])])
 438
 439 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 440 dnl Check whether the given C compiler OPTION is accepted.
 441 dnl If so, enable the given Automake CONDITIONAL.
 442
 443 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 444 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 445   [OVS_CHECK_CC_OPTION(
 446     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 447    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 448 dnl ----------------------------------------------------------------------
 449
 450 dnl Check for too-old XenServer.
 451 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 452   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 453     [if test -e /etc/redhat-release; then
 454        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 455      fi
 456      if test -z "$ovs_cv_xsversion"; then
 457        ovs_cv_xsversion=none
 458      fi])
 459   case $ovs_cv_xsversion in
 460     none)
 461       ;;
 462
 463     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 464     [[6-9]]* |                           dnl XenServer 6 or later
 465     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 466     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 467     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 468     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 469       ;;
 470
 471     *)
 472       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 473       ;;
 474   esac])
 475
 476 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 477 dnl
 478 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 479 dnl Runs 'if-true' if so, 'if-false' otherwise.
 480 AC_DEFUN([OVS_CHECK_MAKE_IF],
 481   [AC_CACHE_CHECK(
 482      [whether ${MAKE-make} has GNU make \$(if) extension],
 483      [ovs_cv_gnu_make_if],
 484      [cat <<'EOF' > conftest.mk
 485 conftest.out:
 486         echo $(if x,y,z) > conftest.out
 487 .PHONY: all
 488 EOF
 489       rm -f conftest.out
 490       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 491       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 492       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 493       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 494       result=`cat conftest.out`
 495       rm -f conftest.mk conftest.out
 496       if test "X$result" = "Xy"; then
 497         ovs_cv_gnu_make_if=yes
 498       else
 499         ovs_cv_gnu_make_if=no
 500       fi])])
 501
 502 dnl OVS_CHECK_GNU_MAKE
 503 dnl
 504 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 505 dnl only work with GNU make).
 506 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 507   [AC_CACHE_CHECK(
 508      [whether ${MAKE-make} is GNU make],
 509      [ovs_cv_gnu_make],
 510      [rm -f conftest.out
 511       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 512       ${MAKE-make} --version >conftest.out 2>&1
 513       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 514       result=`cat conftest.out`
 515       rm -f conftest.mk conftest.out
 516
 517       case $result in # (
 518         GNU*) ovs_cv_gnu_make=yes ;; # (
 519         *) ovs_cv_gnu_make=no ;;
 520       esac])
 521    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 522
 523 dnl OVS_CHECK_SPARSE_TARGET
 524 dnl
 525 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 526 dnl target for which the code is being built.  This helps it out.
 527 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 528   [AC_CACHE_CHECK(
 529     [target hint for cgcc],
 530     [ac_cv_sparse_target],
 531     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 532        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 533        [x86_64-*], [ac_cv_sparse_target=x86_64],
 534        [ac_cv_sparse_target=other])])
 535    AS_CASE([$ac_cv_sparse_target],
 536      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 537      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 538      [SPARSEFLAGS= CGCCFLAGS=])
 539    AC_SUBST([SPARSEFLAGS])
 540    AC_SUBST([CGCCFLAGS])])
 541
 542 dnl OVS_SPARSE_EXTRA_INCLUDES
 543 dnl
 544 dnl The cgcc script from "sparse" does not search gcc's default
 545 dnl search path. Get the default search path from GCC and pass
 546 dnl them to sparse.
 547 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 548     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 549            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 550
 551 dnl OVS_ENABLE_SPARSE
 552 AC_DEFUN([OVS_ENABLE_SPARSE],
 553   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 554    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 555    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 556    : ${SPARSE=sparse}
 557    AC_SUBST([SPARSE])
 558    AC_CONFIG_COMMANDS_PRE(
 559      [if test $ovs_cv_gnu_make_if = yes; then
 560         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 561       fi])])
 562
 563 dnl OVS_PTHREAD_SET_NAME
 564 dnl
 565 dnl This checks for three known variants of pthreads functions for setting
 566 dnl the name of the current thread:
 567 dnl
 568 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 569 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 570 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 571 dnl
 572 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 573 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 574 dnl provide to it.
 575 dnl
 576 dnl This macro defines:
 577 dnl
 578 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 579 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 580 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 581 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 582   [AC_CHECK_FUNCS([pthread_set_name_np])
 583    if test $ac_cv_func_pthread_set_name_np != yes; then
 584      AC_CACHE_CHECK(
 585        [for pthread_setname_np() variant],
 586        [ovs_cv_pthread_setname_np],
 587        [AC_LINK_IFELSE(
 588          [AC_LANG_PROGRAM([#include <pthread.h>
 589   ], [pthread_setname_np(pthread_self(), "name");])],
 590          [ovs_cv_pthread_setname_np=glibc],
 591          [AC_LINK_IFELSE(
 592            [AC_LANG_PROGRAM([#include <pthread.h>
 593 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 594            [ovs_cv_pthread_setname_np=netbsd],
 595            [ovs_cv_pthread_setname_np=none])])])
 596      case $ovs_cv_pthread_setname_np in # (
 597        glibc)
 598           AC_DEFINE(
 599             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 600             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 601           ;; # (
 602        netbsd)
 603           AC_DEFINE(
 604             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 605             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 606           ;;
 607      esac
 608    fi])
 609
 610 dnl OVS_CHECK_LINUX_HOST.
 611 dnl
 612 dnl Checks whether we're building for a Linux host, based on the presence of
 613 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 614 dnl LINUX based on the result.
 615 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 616   [AC_CACHE_CHECK(
 617      [whether __linux__ is defined],
 618      [ovs_cv_linux],
 619      [AC_COMPILE_IFELSE(
 620         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 621         [ovs_cv_linux=true],
 622         [ovs_cv_linux=false])])
 623    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])