acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     fi
  61   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  62     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  63   fi
  64
  65   if test -n "$KBUILD"; then
  66     KBUILD=`eval echo "$KBUILD"`
  67     case $KBUILD in
  68         /*) ;;
  69         *) KBUILD=`pwd`/$KBUILD ;;
  70     esac
  71
  72     # The build directory is what the user provided.
  73     # Make sure that it exists.
  74     AC_MSG_CHECKING([for Linux build directory])
  75     if test -d "$KBUILD"; then
  76         AC_MSG_RESULT([$KBUILD])
  77         AC_SUBST(KBUILD)
  78     else
  79         AC_MSG_RESULT([no])
  80         AC_ERROR([source dir $KBUILD doesn't exist])
  81     fi
  82
  83     # Debian breaks kernel headers into "source" header and "build" headers.
  84     # We want the source headers, but $KBUILD gives us the "build" headers.
  85     # Use heuristics to find the source headers.
  86     AC_MSG_CHECKING([for Linux source directory])
  87     if test -n "$KSRC"; then
  88       KSRC=`eval echo "$KSRC"`
  89       case $KSRC in
  90           /*) ;;
  91           *) KSRC=`pwd`/$KSRC ;;
  92       esac
  93       if test ! -e $KSRC/include/linux/kernel.h; then
  94         AC_MSG_ERROR([$KSRC is not a kernel source directory)])
  95       fi
  96     else
  97       KSRC=$KBUILD
  98       if test ! -e $KSRC/include/linux/kernel.h; then
  99         case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 100           */build)
 101             KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 102             ;; # (
 103           *)
 104             KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 105             ;;
 106         esac
 107       fi
 108       if test ! -e $KSRC/include/linux/kernel.h; then
 109         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 110       fi
 111     fi
 112     AC_MSG_RESULT([$KSRC])
 113
 114     AC_MSG_CHECKING([for kernel version])
 115     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 116     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 117     if test -z "$patchlevel" || test -z "$sublevel"; then
 118        AC_ERROR([cannot determine kernel version])
 119     fi
 120     AC_MSG_RESULT([2.$patchlevel.$sublevel])
 121     if test "2.$patchlevel" != '2.6'; then
 122        if test "$KBUILD" = "$KSRC"; then
 123          AC_ERROR([Linux kernel in $KBUILD is not version 2.6])
 124        else
 125          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is not version 2.6])
 126        fi
 127     fi
 128     if test ! -e "$KBUILD"/include/linux/version.h || \
 129        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 130         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 131         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 132     fi
 133     OVS_CHECK_LINUX_COMPAT
 134   fi
 135   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 136 ])
 137
 138 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 139 dnl
 140 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 141 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 142 dnl <REGEX> translated to uppercase.
 143 AC_DEFUN([OVS_GREP_IFELSE], [
 144   AC_MSG_CHECKING([whether $2 matches in $1])
 145   if test -f $1; then
 146     grep '$2' $1 >/dev/null 2>&1
 147     status=$?
 148     case $status in
 149       0)
 150         AC_MSG_RESULT([yes])
 151         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 152         ;;
 153       1)
 154         AC_MSG_RESULT([no])
 155         $4
 156         ;;
 157       *)
 158         AC_MSG_ERROR([grep exited with status $status])
 159         ;;
 160     esac
 161   else
 162     AC_MSG_RESULT([file not found])
 163     $4
 164   fi
 165 ])
 166
 167 dnl OVS_DEFINE(NAME)
 168 dnl
 169 dnl Defines NAME to 1 in kcompat.h.
 170 AC_DEFUN([OVS_DEFINE], [
 171   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 172 ])
 173
 174 AC_DEFUN([OVS_CHECK_LOG2_H], [
 175   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 176   if test -e $KSRC/include/linux/log2.h; then
 177     AC_MSG_RESULT([yes])
 178     OVS_DEFINE([HAVE_LOG2_H])
 179   else
 180     AC_MSG_RESULT([no])
 181   fi
 182 ])
 183
 184 dnl OVS_CHECK_LINUX_COMPAT
 185 dnl
 186 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 187 dnl the directory in $KBUILD.
 188 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 189   rm -f datapath/linux-2.6/kcompat.h.new
 190   mkdir -p datapath/linux-2.6
 191   : > datapath/linux-2.6/kcompat.h.new
 192
 193   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 194                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 195
 196   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 197
 198   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 199
 200   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 201   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 202   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 203
 204   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 205                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 206                                    [rcu_read_lock_held])])
 207
 208   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 209   # is necessary because some versions of this header remove the
 210   # member but retain the kerneldoc comment that describes it (which
 211   # starts with @).  The brackets must be doubled because of m4
 212   # quoting rules.
 213   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 214                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 215   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 216                   [OVS_DEFINE([HAVE_MAC_RAW])])
 217   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 218                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 219   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 220                   [skb_copy_from_linear_data_offset])
 221   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 222   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 223                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 224   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 225                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 226   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 227                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 228   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 229
 230   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 231                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 232
 233   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 234                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 235   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 236                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 237
 238   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 239   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 240
 241   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 242   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 243   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 244
 245   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 246
 247   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 248                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 249
 250   OVS_CHECK_LOG2_H
 251
 252   if cmp -s datapath/linux-2.6/kcompat.h.new \
 253             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 254     rm datapath/linux-2.6/kcompat.h.new
 255   else
 256     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 257   fi
 258 ])
 259
 260 dnl Checks for net/if_packet.h.
 261 AC_DEFUN([OVS_CHECK_IF_PACKET],
 262   [AC_CHECK_HEADER([net/if_packet.h],
 263                    [HAVE_IF_PACKET=yes],
 264                    [HAVE_IF_PACKET=no])
 265    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 266    if test "$HAVE_IF_PACKET" = yes; then
 267       AC_DEFINE([HAVE_IF_PACKET], [1],
 268                 [Define to 1 if net/if_packet.h is available.])
 269    fi])
 270
 271 dnl Checks for buggy strtok_r.
 272 dnl
 273 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 274 dnl with optimization that can cause segfaults:
 275 dnl
 276 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 277 AC_DEFUN([OVS_CHECK_STRTOK_R],
 278   [AC_CACHE_CHECK(
 279      [whether strtok_r macro segfaults on some inputs],
 280      [ovs_cv_strtok_r_bug],
 281      [AC_RUN_IFELSE(
 282         [AC_LANG_PROGRAM([#include <stdio.h>
 283                           #include <string.h>
 284                          ],
 285                          [[char string[] = ":::";
 286                            char *save_ptr = (char *) 0xc0ffee;
 287                            char *token1, *token2;
 288                            token1 = strtok_r(string, ":", &save_ptr);
 289                            token2 = strtok_r(NULL, ":", &save_ptr);
 290                            freopen ("/dev/null", "w", stdout);
 291                            printf ("%s %s\n", token1, token2);
 292                            return 0;
 293                           ]])],
 294         [ovs_cv_strtok_r_bug=no],
 295         [ovs_cv_strtok_r_bug=yes],
 296         [ovs_cv_strtok_r_bug=yes])])
 297    if test $ovs_cv_strtok_r_bug = yes; then
 298      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 299                [Define if strtok_r macro segfaults on some inputs])
 300    fi
 301 ])
 302
 303 dnl ----------------------------------------------------------------------
 304 dnl These macros are from GNU PSPP, with the following original license:
 305 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 306 dnl This file is free software; the Free Software Foundation
 307 dnl gives unlimited permission to copy and/or distribute it,
 308 dnl with or without modifications, as long as this notice is preserved.
 309
 310 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 311 dnl Check whether the given C compiler OPTION is accepted.
 312 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 313 AC_DEFUN([OVS_CHECK_CC_OPTION],
 314 [
 315   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 316   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 317     [ovs_save_CFLAGS="$CFLAGS"
 318      CFLAGS="$CFLAGS $1"
 319      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 320      CFLAGS="$ovs_save_CFLAGS"])
 321   if test $ovs_cv_name = yes; then
 322     m4_if([$2], [], [:], [$2])
 323   else
 324     m4_if([$3], [], [:], [$3])
 325   fi
 326 ])
 327
 328 dnl OVS_ENABLE_OPTION([OPTION])
 329 dnl Check whether the given C compiler OPTION is accepted.
 330 dnl If so, add it to WARNING_FLAGS.
 331 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 332 AC_DEFUN([OVS_ENABLE_OPTION],
 333   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 334    AC_SUBST([WARNING_FLAGS])])
 335
 336 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 337 dnl Check whether the given C compiler OPTION is accepted.
 338 dnl If so, enable the given Automake CONDITIONAL.
 339
 340 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 341 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 342   [OVS_CHECK_CC_OPTION(
 343     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 344    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 345 dnl ----------------------------------------------------------------------
 346
 347 dnl Check for too-old XenServer.
 348 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 349   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 350     [if test -e /etc/redhat-release; then
 351        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 352      fi
 353      if test -z "$ovs_cv_xsversion"; then
 354        ovs_cv_xsversion=none
 355      fi])
 356   case $ovs_cv_xsversion in
 357     none)
 358       ;;
 359
 360     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 361     [[6-9]]* |                           dnl XenServer 6 or later
 362     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 363     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 364     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 365     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 366       ;;
 367
 368     *)
 369       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 370       ;;
 371   esac])
 372
 373 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 374 dnl
 375 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 376 dnl Runs 'if-true' if so, 'if-false' otherwise.
 377 AC_DEFUN([OVS_MAKE_HAS_IF],
 378   [AC_CACHE_CHECK(
 379      [whether ${MAKE-make} has GNU make \$(if) extension],
 380      [ovs_cv_gnu_make_if],
 381      [cat <<'EOF' > conftest.mk
 382 conftest.out:
 383         echo $(if x,y,z) > conftest.out
 384 .PHONY: all
 385 EOF
 386       rm -f conftest.out
 387       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 388       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 389       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 390       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 391       result=`cat conftest.out`
 392       rm -f conftest.mk conftest.out
 393       if test "X$result" = "Xy"; then
 394         ovs_cv_gnu_make_if=yes
 395       else
 396         ovs_cv_gnu_make_if=no
 397       fi])
 398    AS_IF([test $ovs_cv_gnu_make_if = yes], [$1], [$2])])
 399
 400 dnl OVS_ENABLE_SPARSE
 401 AC_DEFUN([OVS_ENABLE_SPARSE],
 402   [OVS_MAKE_HAS_IF(
 403      [AC_CONFIG_COMMANDS_PRE(
 404         [: ${SPARSE=sparse}
 405          AC_SUBST([SPARSE])
 406          CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse" cgcc,'"$CC"')'])])])