Merge citrix into master.
[sliver-openvswitch.git] / acinclude.m4
1 # -*- autoconf -*-
2
3 # Copyright (c) 2008, 2009 Nicira Networks.
4 #
5 # Licensed under the Apache License, Version 2.0 (the "License");
6 # you may not use this file except in compliance with the License.
7 # You may obtain a copy of the License at:
8 #
9 #     http://www.apache.org/licenses/LICENSE-2.0
10 #
11 # Unless required by applicable law or agreed to in writing, software
12 # distributed under the License is distributed on an "AS IS" BASIS,
13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14 # See the License for the specific language governing permissions and
15 # limitations under the License.
16
17 dnl OVS_CHECK_LINUX(OPTION, VERSION, VARIABLE, CONDITIONAL)
18 dnl
19 dnl Configure linux kernel source tree 
20 AC_DEFUN([OVS_CHECK_LINUX], [
21   AC_ARG_WITH([$1],
22               [AC_HELP_STRING([--with-$1=/path/to/linux-$2],
23                               [Specify the linux $2 kernel sources])],
24               [path="$withval"], [path=])dnl
25   if test -n "$path"; then
26     path=`eval echo "$path"`
27
28     AC_MSG_CHECKING([for $path directory])
29     if test -d "$path"; then
30         AC_MSG_RESULT([yes])
31         $3=$path
32         AC_SUBST($3)
33     else
34         AC_MSG_RESULT([no])
35         AC_ERROR([source dir $path doesn't exist])
36     fi
37
38     AC_MSG_CHECKING([for $path kernel version])
39     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$path/Makefile"`
40     sublevel=`sed -n 's/^SUBLEVEL = //p' "$path/Makefile"`
41     AC_MSG_RESULT([2.$patchlevel.$sublevel])
42     if test "2.$patchlevel" != '$2'; then
43        AC_ERROR([Linux kernel source in $path is not version $2])
44     fi
45     if ! test -e "$path"/include/linux/version.h || \
46        ! test -e "$path"/include/linux/autoconf.h; then
47         AC_MSG_ERROR([Linux kernel source in $path is not configured])
48     fi
49     m4_if($2, [2.6], [OVS_CHECK_LINUX26_COMPAT])
50   fi
51   AM_CONDITIONAL($4, test -n "$path")
52 ])
53
54 dnl OVS_GREP_IFELSE(FILE, REGEX, IF-MATCH, IF-NO-MATCH)
55 dnl
56 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
57 AC_DEFUN([OVS_GREP_IFELSE], [
58   AC_MSG_CHECKING([whether $2 matches in $1])
59   grep '$2' $1 >/dev/null 2>&1
60   status=$?
61   case $status in
62     0) 
63       AC_MSG_RESULT([yes])
64       $3
65       ;;
66     1) 
67       AC_MSG_RESULT([no])
68       $4
69       ;;
70     *) 
71       AC_MSG_ERROR([grep exited with status $status]) 
72       ;;
73   esac
74 ])
75
76 dnl OVS_DEFINE(NAME)
77 dnl
78 dnl Defines NAME to 1 in kcompat.h.
79 AC_DEFUN([OVS_DEFINE], [
80   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
81 ])
82
83 AC_DEFUN([OVS_CHECK_VETH], [
84   AC_MSG_CHECKING([whether to build veth module])
85   if test "$sublevel" = 18; then
86     AC_MSG_RESULT([yes])
87     AC_SUBST([BUILD_VETH], 1)
88   else
89     AC_MSG_RESULT([no])
90   fi
91 ])
92
93 AC_DEFUN([OVS_CHECK_LOG2_H], [
94   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
95   if test -e $KSRC26/include/linux/log2.h; then
96     AC_MSG_RESULT([yes])
97     OVS_DEFINE([HAVE_LOG2_H])
98   else
99     AC_MSG_RESULT([no])
100   fi
101 ])
102
103 dnl OVS_CHECK_LINUX26_COMPAT
104 dnl
105 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
106 dnl the directory in $KSRC26.
107 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
108   rm -f datapath/linux-2.6/kcompat.h.new
109   mkdir -p datapath/linux-2.6
110   : > datapath/linux-2.6/kcompat.h.new
111   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
112                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
113   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
114                   [OVS_DEFINE([HAVE_MAC_RAW])])
115   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], 
116                   [skb_copy_from_linear_data_offset],
117                   [OVS_DEFINE([HAVE_SKB_COPY_FROM_LINEAR_DATA_OFFSET])])
118   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING],
119                   [OVS_DEFINE([HAVE_NLA_NUL_STRING])])
120   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST],
121                   [OVS_DEFINE([HAVE_ERR_CAST])])
122   OVS_CHECK_LOG2_H
123   OVS_CHECK_VETH
124   if cmp -s datapath/linux-2.6/kcompat.h.new \
125             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
126     rm datapath/linux-2.6/kcompat.h.new
127   else
128     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
129   fi
130 ])
131
132 dnl Checks for net/if_packet.h.
133 AC_DEFUN([OVS_CHECK_IF_PACKET],
134   [AC_CHECK_HEADER([net/if_packet.h],
135                    [HAVE_IF_PACKET=yes],
136                    [HAVE_IF_PACKET=no])
137    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
138    if test "$HAVE_IF_PACKET" = yes; then
139       AC_DEFINE([HAVE_IF_PACKET], [1],
140                 [Define to 1 if net/if_packet.h is available.])
141    fi])
142
143 dnl Checks for buggy strtok_r.
144 dnl
145 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
146 dnl with optimization that can cause segfaults:
147 dnl
148 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
149 AC_DEFUN([OVS_CHECK_STRTOK_R],
150   [AC_CACHE_CHECK(
151      [whether strtok_r macro segfaults on some inputs],
152      [ovs_cv_strtok_r_bug],
153      [AC_RUN_IFELSE(
154         [AC_LANG_PROGRAM([#include <stdio.h>
155                           #include <string.h>
156                          ],
157                          [[char string[] = ":::";
158                            char *save_ptr = (char *) 0xc0ffee;
159                            char *token1, *token2;
160                            token1 = strtok_r(string, ":", &save_ptr);
161                            token2 = strtok_r(NULL, ":", &save_ptr);
162                            printf ("%s %s\n", token1, token2);
163                            return 0;
164                           ]])],
165         [ovs_cv_strtok_r_bug=no],
166         [ovs_cv_strtok_r_bug=yes],
167         [ovs_cv_strtok_r_bug=yes])])
168    if test $ovs_cv_strtok_r_bug = yes; then
169      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
170                [Define if strtok_r macro segfaults on some inputs])
171    fi
172 ])
173
174 dnl ----------------------------------------------------------------------
175 dnl These macros are from GNU PSPP, with the following original license:
176 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
177 dnl This file is free software; the Free Software Foundation
178 dnl gives unlimited permission to copy and/or distribute it,
179 dnl with or without modifications, as long as this notice is preserved.
180
181 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
182 dnl Check whether the given C compiler OPTION is accepted.
183 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
184 AC_DEFUN([OVS_CHECK_CC_OPTION],
185 [
186   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
187   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name], 
188     [ovs_save_CFLAGS="$CFLAGS"
189      CFLAGS="$CFLAGS $1"
190      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
191      CFLAGS="$ovs_save_CFLAGS"])
192   if test $ovs_cv_name = yes; then
193     m4_if([$2], [], [;], [$2])
194   else
195     m4_if([$3], [], [:], [$3])
196   fi
197 ])
198
199 dnl OVS_ENABLE_OPTION([OPTION])
200 dnl Check whether the given C compiler OPTION is accepted.
201 dnl If so, add it to CFLAGS.
202 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
203 AC_DEFUN([OVS_ENABLE_OPTION], 
204   [OVS_CHECK_CC_OPTION([$1], [CFLAGS="$CFLAGS $1"])])
205 dnl ----------------------------------------------------------------------