acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_CHECK_LINUX26
  18 dnl
  19 dnl Configure linux kernel source tree
  20 AC_DEFUN([OVS_CHECK_LINUX26], [
  21   AC_ARG_WITH([l26],
  22               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  23                               [Specify the linux 2.6 kernel sources])],
  24               [KBUILD26="$withval"], [KBUILD26=])dnl
  25   if test -n "$KBUILD26"; then
  26     KBUILD26=`eval echo "$KBUILD26"`
  27
  28     # The build directory is what the user provided.
  29     # Make sure that it exists.
  30     AC_MSG_CHECKING([for Linux 2.6 build directory])
  31     if test -d "$KBUILD26"; then
  32         AC_MSG_RESULT([$KBUILD26])
  33         AC_SUBST(KBUILD26)
  34     else
  35         AC_MSG_RESULT([no])
  36         AC_ERROR([source dir $KBUILD26 doesn't exist])
  37     fi
  38
  39     # Debian breaks kernel headers into "source" header and "build" headers.
  40     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  41     # Use heuristics to find the source headers.
  42     AC_MSG_CHECKING([for Linux 2.6 source directory])
  43     KSRC26=$KBUILD26
  44     if test ! -e $KSRC26/include/linux/kernel.h; then
  45       KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  46       if test ! -e $KSRC26/include/linux/kernel.h; then
  47         AC_MSG_ERROR([cannot find source directory])
  48       fi
  49     fi
  50     AC_MSG_RESULT([$KSRC26])
  51
  52     AC_MSG_CHECKING([for kernel version])
  53     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  54     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  55     if test -z "$patchlevel" || test -z "$sublevel"; then
  56        AC_ERROR([cannot determine kernel version])
  57     fi
  58     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  59     if test "2.$patchlevel" != '2.6'; then
  60        if test "$BUILD26" = "$KSRC26"; then
  61          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
  62        else
  63          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
  64        fi
  65     fi
  66     if ! test -e "$KBUILD26"/include/linux/version.h || \
  67        ! test -e "$KBUILD26"/include/linux/autoconf.h; then
  68         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
  69     fi
  70     OVS_CHECK_LINUX26_COMPAT
  71   fi
  72   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
  73 ])
  74
  75 dnl OVS_GREP_IFELSE(FILE, REGEX, IF-MATCH, IF-NO-MATCH)
  76 dnl
  77 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
  78 AC_DEFUN([OVS_GREP_IFELSE], [
  79   AC_MSG_CHECKING([whether $2 matches in $1])
  80   grep '$2' $1 >/dev/null 2>&1
  81   status=$?
  82   case $status in
  83     0)
  84       AC_MSG_RESULT([yes])
  85       $3
  86       ;;
  87     1)
  88       AC_MSG_RESULT([no])
  89       $4
  90       ;;
  91     *)
  92       AC_MSG_ERROR([grep exited with status $status])
  93       ;;
  94   esac
  95 ])
  96
  97 dnl OVS_DEFINE(NAME)
  98 dnl
  99 dnl Defines NAME to 1 in kcompat.h.
 100 AC_DEFUN([OVS_DEFINE], [
 101   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 102 ])
 103
 104 AC_DEFUN([OVS_CHECK_VETH], [
 105   AC_MSG_CHECKING([whether to build veth module])
 106   if test "$sublevel" = 18; then
 107     AC_MSG_RESULT([yes])
 108     AC_SUBST([BUILD_VETH], 1)
 109   else
 110     AC_MSG_RESULT([no])
 111   fi
 112 ])
 113
 114 AC_DEFUN([OVS_CHECK_GRE], [
 115   AC_MSG_CHECKING([whether to build gre module])
 116   if test "$sublevel" -ge 18; then
 117     AC_MSG_RESULT([yes])
 118     AC_SUBST([BUILD_GRE], 1)
 119   else
 120     AC_MSG_RESULT([no])
 121   fi
 122 ])
 123
 124 AC_DEFUN([OVS_CHECK_LOG2_H], [
 125   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 126   if test -e $KSRC26/include/linux/log2.h; then
 127     AC_MSG_RESULT([yes])
 128     OVS_DEFINE([HAVE_LOG2_H])
 129   else
 130     AC_MSG_RESULT([no])
 131   fi
 132 ])
 133
 134 dnl OVS_CHECK_LINUX26_COMPAT
 135 dnl
 136 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 137 dnl the directory in $KBUILD26.
 138 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 139   rm -f datapath/linux-2.6/kcompat.h.new
 140   mkdir -p datapath/linux-2.6
 141   : > datapath/linux-2.6/kcompat.h.new
 142   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 143                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 144   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 145                   [OVS_DEFINE([HAVE_MAC_RAW])])
 146   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 147                   [skb_copy_from_linear_data_offset],
 148                   [OVS_DEFINE([HAVE_SKB_COPY_FROM_LINEAR_DATA_OFFSET])])
 149   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING],
 150                   [OVS_DEFINE([HAVE_NLA_NUL_STRING])])
 151   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST],
 152                   [OVS_DEFINE([HAVE_ERR_CAST])])
 153   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold],
 154                   [OVS_DEFINE([HAVE_CSUM_UNFOLD])])
 155   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow],
 156                   [OVS_DEFINE([HAVE_SKB_COW])])
 157   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 158   # is necessary because some versions of this header remove the
 159   # member but retain the kerneldoc comment that describes it (which
 160   # starts with @).  The brackets must be doubled because of m4
 161   # quoting rules.
 162   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 163                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 164   OVS_CHECK_LOG2_H
 165   OVS_CHECK_VETH
 166   OVS_CHECK_GRE
 167   if cmp -s datapath/linux-2.6/kcompat.h.new \
 168             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 169     rm datapath/linux-2.6/kcompat.h.new
 170   else
 171     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 172   fi
 173 ])
 174
 175 dnl Checks for net/if_packet.h.
 176 AC_DEFUN([OVS_CHECK_IF_PACKET],
 177   [AC_CHECK_HEADER([net/if_packet.h],
 178                    [HAVE_IF_PACKET=yes],
 179                    [HAVE_IF_PACKET=no])
 180    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 181    if test "$HAVE_IF_PACKET" = yes; then
 182       AC_DEFINE([HAVE_IF_PACKET], [1],
 183                 [Define to 1 if net/if_packet.h is available.])
 184    fi])
 185
 186 dnl Checks for buggy strtok_r.
 187 dnl
 188 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 189 dnl with optimization that can cause segfaults:
 190 dnl
 191 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 192 AC_DEFUN([OVS_CHECK_STRTOK_R],
 193   [AC_CACHE_CHECK(
 194      [whether strtok_r macro segfaults on some inputs],
 195      [ovs_cv_strtok_r_bug],
 196      [AC_RUN_IFELSE(
 197         [AC_LANG_PROGRAM([#include <stdio.h>
 198                           #include <string.h>
 199                          ],
 200                          [[char string[] = ":::";
 201                            char *save_ptr = (char *) 0xc0ffee;
 202                            char *token1, *token2;
 203                            token1 = strtok_r(string, ":", &save_ptr);
 204                            token2 = strtok_r(NULL, ":", &save_ptr);
 205                            printf ("%s %s\n", token1, token2);
 206                            return 0;
 207                           ]])],
 208         [ovs_cv_strtok_r_bug=no],
 209         [ovs_cv_strtok_r_bug=yes],
 210         [ovs_cv_strtok_r_bug=yes])])
 211    if test $ovs_cv_strtok_r_bug = yes; then
 212      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 213                [Define if strtok_r macro segfaults on some inputs])
 214    fi
 215 ])
 216
 217 dnl ----------------------------------------------------------------------
 218 dnl These macros are from GNU PSPP, with the following original license:
 219 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 220 dnl This file is free software; the Free Software Foundation
 221 dnl gives unlimited permission to copy and/or distribute it,
 222 dnl with or without modifications, as long as this notice is preserved.
 223
 224 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 225 dnl Check whether the given C compiler OPTION is accepted.
 226 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 227 AC_DEFUN([OVS_CHECK_CC_OPTION],
 228 [
 229   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 230   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 231     [ovs_save_CFLAGS="$CFLAGS"
 232      CFLAGS="$CFLAGS $1"
 233      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 234      CFLAGS="$ovs_save_CFLAGS"])
 235   if test $ovs_cv_name = yes; then
 236     m4_if([$2], [], [:], [$2])
 237   else
 238     m4_if([$3], [], [:], [$3])
 239   fi
 240 ])
 241
 242 dnl OVS_ENABLE_OPTION([OPTION])
 243 dnl Check whether the given C compiler OPTION is accepted.
 244 dnl If so, add it to WARNING_FLAGS.
 245 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 246 AC_DEFUN([OVS_ENABLE_OPTION],
 247   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 248    AC_SUBST([WARNING_FLAGS])])
 249 dnl ----------------------------------------------------------------------