acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_CHECK_LINUX26
  18 dnl
  19 dnl Configure linux kernel source tree
  20 AC_DEFUN([OVS_CHECK_LINUX26], [
  21   AC_ARG_WITH([l26],
  22               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  23                               [Specify the linux 2.6 kernel sources])],
  24               [KBUILD26="$withval"], [KBUILD26=])dnl
  25   if test -n "$KBUILD26"; then
  26     KBUILD26=`eval echo "$KBUILD26"`
  27
  28     # The build directory is what the user provided.
  29     # Make sure that it exists.
  30     AC_MSG_CHECKING([for Linux 2.6 build directory])
  31     if test -d "$KBUILD26"; then
  32         AC_MSG_RESULT([$KBUILD26])
  33         AC_SUBST(KBUILD26)
  34     else
  35         AC_MSG_RESULT([no])
  36         AC_ERROR([source dir $KBUILD26 doesn't exist])
  37     fi
  38
  39     # Debian breaks kernel headers into "source" header and "build" headers.
  40     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  41     # Use heuristics to find the source headers.
  42     AC_MSG_CHECKING([for Linux 2.6 source directory])
  43     KSRC26=$KBUILD26
  44     if test ! -e $KSRC26/include/linux/kernel.h; then
  45       case `echo "$KBUILD26" | sed 's,/*$,,'` in # (
  46         */build)
  47           KSRC26=`echo "$KBUILD26" | sed 's,/build/*$,/source,'`
  48           ;; # (
  49         *)
  50           KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  51           ;;
  52       esac
  53       if test ! -e $KSRC26/include/linux/kernel.h; then
  54         AC_MSG_ERROR([cannot find source directory])
  55       fi
  56     fi
  57     AC_MSG_RESULT([$KSRC26])
  58
  59     AC_MSG_CHECKING([for kernel version])
  60     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  61     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  62     if test -z "$patchlevel" || test -z "$sublevel"; then
  63        AC_ERROR([cannot determine kernel version])
  64     fi
  65     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  66     if test "2.$patchlevel" != '2.6'; then
  67        if test "$BUILD26" = "$KSRC26"; then
  68          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
  69        else
  70          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
  71        fi
  72     fi
  73     if ! test -e "$KBUILD26"/include/linux/version.h || \
  74        ! test -e "$KBUILD26"/include/linux/autoconf.h; then
  75         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
  76     fi
  77     OVS_CHECK_LINUX26_COMPAT
  78   fi
  79   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
  80 ])
  81
  82 dnl OVS_GREP_IFELSE(FILE, REGEX, IF-MATCH, IF-NO-MATCH)
  83 dnl
  84 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
  85 AC_DEFUN([OVS_GREP_IFELSE], [
  86   AC_MSG_CHECKING([whether $2 matches in $1])
  87   grep '$2' $1 >/dev/null 2>&1
  88   status=$?
  89   case $status in
  90     0)
  91       AC_MSG_RESULT([yes])
  92       $3
  93       ;;
  94     1)
  95       AC_MSG_RESULT([no])
  96       $4
  97       ;;
  98     *)
  99       AC_MSG_ERROR([grep exited with status $status])
 100       ;;
 101   esac
 102 ])
 103
 104 dnl OVS_DEFINE(NAME)
 105 dnl
 106 dnl Defines NAME to 1 in kcompat.h.
 107 AC_DEFUN([OVS_DEFINE], [
 108   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 109 ])
 110
 111 AC_DEFUN([OVS_CHECK_VETH], [
 112   AC_MSG_CHECKING([whether to build veth module])
 113   if test "$sublevel" = 18; then
 114     AC_MSG_RESULT([yes])
 115     AC_SUBST([BUILD_VETH], 1)
 116   else
 117     AC_MSG_RESULT([no])
 118   fi
 119 ])
 120
 121 AC_DEFUN([OVS_CHECK_GRE], [
 122   AC_MSG_CHECKING([whether to build gre module])
 123   if test "$sublevel" -ge 18; then
 124     AC_MSG_RESULT([yes])
 125     AC_SUBST([BUILD_GRE], 1)
 126   else
 127     AC_MSG_RESULT([no])
 128   fi
 129 ])
 130
 131 AC_DEFUN([OVS_CHECK_LOG2_H], [
 132   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 133   if test -e $KSRC26/include/linux/log2.h; then
 134     AC_MSG_RESULT([yes])
 135     OVS_DEFINE([HAVE_LOG2_H])
 136   else
 137     AC_MSG_RESULT([no])
 138   fi
 139 ])
 140
 141 dnl OVS_CHECK_LINUX26_COMPAT
 142 dnl
 143 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 144 dnl the directory in $KBUILD26.
 145 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 146   rm -f datapath/linux-2.6/kcompat.h.new
 147   mkdir -p datapath/linux-2.6
 148   : > datapath/linux-2.6/kcompat.h.new
 149   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [bool],
 150                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 151   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 152                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 153   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 154                   [OVS_DEFINE([HAVE_MAC_RAW])])
 155   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 156                   [skb_copy_from_linear_data_offset],
 157                   [OVS_DEFINE([HAVE_SKB_COPY_FROM_LINEAR_DATA_OFFSET])])
 158   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING],
 159                   [OVS_DEFINE([HAVE_NLA_NUL_STRING])])
 160   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST],
 161                   [OVS_DEFINE([HAVE_ERR_CAST])])
 162   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold],
 163                   [OVS_DEFINE([HAVE_CSUM_UNFOLD])])
 164   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow],
 165                   [OVS_DEFINE([HAVE_SKB_COW])])
 166   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_get_be16],
 167                   [OVS_DEFINE([HAVE_NLA_GET_BE16])])
 168   OVS_GREP_IFELSE([$KSRC26/include/linux/in.h], [ipv4_is_multicast],
 169                   [OVS_DEFINE([HAVE_IPV4_IS_MULTICAST])])
 170   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 171   # is necessary because some versions of this header remove the
 172   # member but retain the kerneldoc comment that describes it (which
 173   # starts with @).  The brackets must be doubled because of m4
 174   # quoting rules.
 175   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 176                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 177   OVS_CHECK_LOG2_H
 178   OVS_CHECK_VETH
 179   OVS_CHECK_GRE
 180   if cmp -s datapath/linux-2.6/kcompat.h.new \
 181             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 182     rm datapath/linux-2.6/kcompat.h.new
 183   else
 184     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 185   fi
 186 ])
 187
 188 dnl Checks for net/if_packet.h.
 189 AC_DEFUN([OVS_CHECK_IF_PACKET],
 190   [AC_CHECK_HEADER([net/if_packet.h],
 191                    [HAVE_IF_PACKET=yes],
 192                    [HAVE_IF_PACKET=no])
 193    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 194    if test "$HAVE_IF_PACKET" = yes; then
 195       AC_DEFINE([HAVE_IF_PACKET], [1],
 196                 [Define to 1 if net/if_packet.h is available.])
 197    fi])
 198
 199 dnl Checks for buggy strtok_r.
 200 dnl
 201 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 202 dnl with optimization that can cause segfaults:
 203 dnl
 204 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 205 AC_DEFUN([OVS_CHECK_STRTOK_R],
 206   [AC_CACHE_CHECK(
 207      [whether strtok_r macro segfaults on some inputs],
 208      [ovs_cv_strtok_r_bug],
 209      [AC_RUN_IFELSE(
 210         [AC_LANG_PROGRAM([#include <stdio.h>
 211                           #include <string.h>
 212                          ],
 213                          [[char string[] = ":::";
 214                            char *save_ptr = (char *) 0xc0ffee;
 215                            char *token1, *token2;
 216                            token1 = strtok_r(string, ":", &save_ptr);
 217                            token2 = strtok_r(NULL, ":", &save_ptr);
 218                            freopen ("/dev/null", "w", stdout);
 219                            printf ("%s %s\n", token1, token2);
 220                            return 0;
 221                           ]])],
 222         [ovs_cv_strtok_r_bug=no],
 223         [ovs_cv_strtok_r_bug=yes],
 224         [ovs_cv_strtok_r_bug=yes])])
 225    if test $ovs_cv_strtok_r_bug = yes; then
 226      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 227                [Define if strtok_r macro segfaults on some inputs])
 228    fi
 229 ])
 230
 231 dnl ----------------------------------------------------------------------
 232 dnl These macros are from GNU PSPP, with the following original license:
 233 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 234 dnl This file is free software; the Free Software Foundation
 235 dnl gives unlimited permission to copy and/or distribute it,
 236 dnl with or without modifications, as long as this notice is preserved.
 237
 238 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 239 dnl Check whether the given C compiler OPTION is accepted.
 240 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 241 AC_DEFUN([OVS_CHECK_CC_OPTION],
 242 [
 243   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 244   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 245     [ovs_save_CFLAGS="$CFLAGS"
 246      CFLAGS="$CFLAGS $1"
 247      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 248      CFLAGS="$ovs_save_CFLAGS"])
 249   if test $ovs_cv_name = yes; then
 250     m4_if([$2], [], [:], [$2])
 251   else
 252     m4_if([$3], [], [:], [$3])
 253   fi
 254 ])
 255
 256 dnl OVS_ENABLE_OPTION([OPTION])
 257 dnl Check whether the given C compiler OPTION is accepted.
 258 dnl If so, add it to WARNING_FLAGS.
 259 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 260 AC_DEFUN([OVS_ENABLE_OPTION],
 261   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 262    AC_SUBST([WARNING_FLAGS])])
 263
 264 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 265 dnl Check whether the given C compiler OPTION is accepted.
 266 dnl If so, enable the given Automake CONDITIONAL.
 267
 268 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 269 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 270   [OVS_CHECK_CC_OPTION(
 271     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 272    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 273 dnl ----------------------------------------------------------------------