acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        : # Linux 3.x
 138     elif test "$version" = 2 && test "$patchlevel" -ge 6; then
 139        : # Linux 2.6.x
 140     else
 141        if test "$KBUILD" = "$KSRC"; then
 142          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
 143        else
 144          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
 145        fi
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 159 dnl
 160 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 161 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 162 dnl <REGEX> translated to uppercase.
 163 AC_DEFUN([OVS_GREP_IFELSE], [
 164   AC_MSG_CHECKING([whether $2 matches in $1])
 165   if test -f $1; then
 166     grep '$2' $1 >/dev/null 2>&1
 167     status=$?
 168     case $status in
 169       0)
 170         AC_MSG_RESULT([yes])
 171         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 172         ;;
 173       1)
 174         AC_MSG_RESULT([no])
 175         $4
 176         ;;
 177       *)
 178         AC_MSG_ERROR([grep exited with status $status])
 179         ;;
 180     esac
 181   else
 182     AC_MSG_RESULT([file not found])
 183     $4
 184   fi
 185 ])
 186
 187 dnl OVS_DEFINE(NAME)
 188 dnl
 189 dnl Defines NAME to 1 in kcompat.h.
 190 AC_DEFUN([OVS_DEFINE], [
 191   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 192 ])
 193
 194 AC_DEFUN([OVS_CHECK_LOG2_H], [
 195   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 196   if test -e $KSRC/include/linux/log2.h; then
 197     AC_MSG_RESULT([yes])
 198     OVS_DEFINE([HAVE_LOG2_H])
 199   else
 200     AC_MSG_RESULT([no])
 201   fi
 202 ])
 203
 204 dnl OVS_CHECK_LINUX_COMPAT
 205 dnl
 206 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 207 dnl the directory in $KBUILD.
 208 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 209   rm -f datapath/linux/kcompat.h.new
 210   mkdir -p datapath/linux
 211   : > datapath/linux/kcompat.h.new
 212
 213   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 214                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 215
 216   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 225   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 227
 228   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 229                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 230                                    [rcu_read_lock_held])])
 231
 232   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 233   # is necessary because some versions of this header remove the
 234   # member but retain the kerneldoc comment that describes it (which
 235   # starts with @).  The brackets must be doubled because of m4
 236   # quoting rules.
 237   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 238                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 239   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 240                   [OVS_DEFINE([HAVE_MAC_RAW])])
 241   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 242                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 244                   [skb_copy_from_linear_data_offset])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 246                   [skb_reset_tail_pointer])
 247   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 249                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 251                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 252   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 253                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 254   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 256   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 257
 258   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 259                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 260
 261   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 262                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 263   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 264                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 265
 266   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 267   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 268
 269   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 270   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 271   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 272
 273   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 274                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 275
 276   OVS_CHECK_LOG2_H
 277
 278   if cmp -s datapath/linux/kcompat.h.new \
 279             datapath/linux/kcompat.h >/dev/null 2>&1; then
 280     rm datapath/linux/kcompat.h.new
 281   else
 282     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 283   fi
 284 ])
 285
 286 dnl Checks for net/if_packet.h.
 287 AC_DEFUN([OVS_CHECK_IF_PACKET],
 288   [AC_CHECK_HEADER([net/if_packet.h],
 289                    [HAVE_IF_PACKET=yes],
 290                    [HAVE_IF_PACKET=no])
 291    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 292    if test "$HAVE_IF_PACKET" = yes; then
 293       AC_DEFINE([HAVE_IF_PACKET], [1],
 294                 [Define to 1 if net/if_packet.h is available.])
 295    fi])
 296
 297 dnl Checks for net/if_dl.h.
 298 AC_DEFUN([OVS_CHECK_IF_DL],
 299   [AC_CHECK_HEADER([net/if_dl.h],
 300                    [HAVE_IF_DL=yes],
 301                    [HAVE_IF_DL=no])
 302    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 303    if test "$HAVE_IF_DL" = yes; then
 304       AC_DEFINE([HAVE_IF_DL], [1],
 305                 [Define to 1 if net/if_dl.h is available.])
 306    fi])
 307
 308 dnl Checks for buggy strtok_r.
 309 dnl
 310 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 311 dnl with optimization that can cause segfaults:
 312 dnl
 313 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 314 AC_DEFUN([OVS_CHECK_STRTOK_R],
 315   [AC_CACHE_CHECK(
 316      [whether strtok_r macro segfaults on some inputs],
 317      [ovs_cv_strtok_r_bug],
 318      [AC_RUN_IFELSE(
 319         [AC_LANG_PROGRAM([#include <stdio.h>
 320                           #include <string.h>
 321                          ],
 322                          [[char string[] = ":::";
 323                            char *save_ptr = (char *) 0xc0ffee;
 324                            char *token1, *token2;
 325                            token1 = strtok_r(string, ":", &save_ptr);
 326                            token2 = strtok_r(NULL, ":", &save_ptr);
 327                            freopen ("/dev/null", "w", stdout);
 328                            printf ("%s %s\n", token1, token2);
 329                            return 0;
 330                           ]])],
 331         [ovs_cv_strtok_r_bug=no],
 332         [ovs_cv_strtok_r_bug=yes],
 333         [ovs_cv_strtok_r_bug=yes])])
 334    if test $ovs_cv_strtok_r_bug = yes; then
 335      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 336                [Define if strtok_r macro segfaults on some inputs])
 337    fi
 338 ])
 339
 340 dnl ----------------------------------------------------------------------
 341 dnl These macros are from GNU PSPP, with the following original license:
 342 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 343 dnl This file is free software; the Free Software Foundation
 344 dnl gives unlimited permission to copy and/or distribute it,
 345 dnl with or without modifications, as long as this notice is preserved.
 346
 347 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 348 dnl Check whether the given C compiler OPTION is accepted.
 349 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 350 AC_DEFUN([OVS_CHECK_CC_OPTION],
 351 [
 352   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 353   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 354     [ovs_save_CFLAGS="$CFLAGS"
 355      CFLAGS="$CFLAGS $1"
 356      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 357      CFLAGS="$ovs_save_CFLAGS"])
 358   if test $ovs_cv_name = yes; then
 359     m4_if([$2], [], [:], [$2])
 360   else
 361     m4_if([$3], [], [:], [$3])
 362   fi
 363 ])
 364
 365 dnl OVS_ENABLE_OPTION([OPTION])
 366 dnl Check whether the given C compiler OPTION is accepted.
 367 dnl If so, add it to WARNING_FLAGS.
 368 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 369 AC_DEFUN([OVS_ENABLE_OPTION],
 370   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 371    AC_SUBST([WARNING_FLAGS])])
 372
 373 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 374 dnl Check whether the given C compiler OPTION is accepted.
 375 dnl If so, enable the given Automake CONDITIONAL.
 376
 377 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 378 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 379   [OVS_CHECK_CC_OPTION(
 380     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 381    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 382 dnl ----------------------------------------------------------------------
 383
 384 dnl Check for too-old XenServer.
 385 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 386   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 387     [if test -e /etc/redhat-release; then
 388        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 389      fi
 390      if test -z "$ovs_cv_xsversion"; then
 391        ovs_cv_xsversion=none
 392      fi])
 393   case $ovs_cv_xsversion in
 394     none)
 395       ;;
 396
 397     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 398     [[6-9]]* |                           dnl XenServer 6 or later
 399     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 400     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 401     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 402     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 403       ;;
 404
 405     *)
 406       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 407       ;;
 408   esac])
 409
 410 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 411 dnl
 412 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 413 dnl Runs 'if-true' if so, 'if-false' otherwise.
 414 AC_DEFUN([OVS_CHECK_MAKE_IF],
 415   [AC_CACHE_CHECK(
 416      [whether ${MAKE-make} has GNU make \$(if) extension],
 417      [ovs_cv_gnu_make_if],
 418      [cat <<'EOF' > conftest.mk
 419 conftest.out:
 420         echo $(if x,y,z) > conftest.out
 421 .PHONY: all
 422 EOF
 423       rm -f conftest.out
 424       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 425       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 426       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 427       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 428       result=`cat conftest.out`
 429       rm -f conftest.mk conftest.out
 430       if test "X$result" = "Xy"; then
 431         ovs_cv_gnu_make_if=yes
 432       else
 433         ovs_cv_gnu_make_if=no
 434       fi])])
 435
 436 dnl OVS_CHECK_GNU_MAKE
 437 dnl
 438 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 439 dnl only work with GNU make).
 440 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 441   [AC_CACHE_CHECK(
 442      [whether ${MAKE-make} is GNU make],
 443      [ovs_cv_gnu_make],
 444      [rm -f conftest.out
 445       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 446       ${MAKE-make} --version >conftest.out 2>&1
 447       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 448       result=`cat conftest.out`
 449       rm -f conftest.mk conftest.out
 450
 451       case $result in # (
 452         GNU*) ovs_cv_gnu_make=yes ;; # (
 453         *) ovs_cv_gnu_make=no ;;
 454       esac])
 455    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 456
 457 dnl OVS_CHECK_SPARSE_TARGET
 458 dnl
 459 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 460 dnl target for which the code is being built.  This helps it out.
 461 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 462   [AC_CACHE_CHECK(
 463     [target hint for cgcc],
 464     [ac_cv_sparse_target],
 465     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 466        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 467        [x86_64-*], [ac_cv_sparse_target=x86_64],
 468        [ac_cv_sparse_target=other])])
 469    AS_CASE([$ac_cv_sparse_target],
 470      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 471      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 472      [SPARSEFLAGS= CGCCFLAGS=])
 473    AC_SUBST([SPARSEFLAGS])
 474    AC_SUBST([CGCCFLAGS])])
 475
 476 dnl OVS_ENABLE_SPARSE
 477 AC_DEFUN([OVS_ENABLE_SPARSE],
 478   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 479    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 480    : ${SPARSE=sparse}
 481    AC_SUBST([SPARSE])
 482    AC_CONFIG_COMMANDS_PRE(
 483      [if test $ovs_cv_gnu_make_if = yes; then
 484         CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
 485       fi])])