acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 11; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.11.x is not supported])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 161 dnl
 162 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 163 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 164 dnl <REGEX> translated to uppercase.
 165 AC_DEFUN([OVS_GREP_IFELSE], [
 166   AC_MSG_CHECKING([whether $2 matches in $1])
 167   if test -f $1; then
 168     grep '$2' $1 >/dev/null 2>&1
 169     status=$?
 170     case $status in
 171       0)
 172         AC_MSG_RESULT([yes])
 173         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 174         ;;
 175       1)
 176         AC_MSG_RESULT([no])
 177         $4
 178         ;;
 179       *)
 180         AC_MSG_ERROR([grep exited with status $status])
 181         ;;
 182     esac
 183   else
 184     AC_MSG_RESULT([file not found])
 185     $4
 186   fi
 187 ])
 188
 189 dnl OVS_DEFINE(NAME)
 190 dnl
 191 dnl Defines NAME to 1 in kcompat.h.
 192 AC_DEFUN([OVS_DEFINE], [
 193   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 194 ])
 195
 196 AC_DEFUN([OVS_CHECK_LOG2_H], [
 197   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 198   if test -e $KSRC/include/linux/log2.h; then
 199     AC_MSG_RESULT([yes])
 200     OVS_DEFINE([HAVE_LOG2_H])
 201   else
 202     AC_MSG_RESULT([no])
 203   fi
 204 ])
 205
 206 dnl OVS_CHECK_LINUX_COMPAT
 207 dnl
 208 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 209 dnl the directory in $KBUILD.
 210 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 211   rm -f datapath/linux/kcompat.h.new
 212   mkdir -p datapath/linux
 213   : > datapath/linux/kcompat.h.new
 214
 215   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 216                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 225
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 227   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 228   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 229   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 230   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 231   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 232
 233   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 234                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 235                                    [rcu_read_lock_held])])
 236   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 237
 238   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 239   # is necessary because some versions of this header remove the
 240   # member but retain the kerneldoc comment that describes it (which
 241   # starts with @).  The brackets must be doubled because of m4
 242   # quoting rules.
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 244                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 246   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 247                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 249                   [skb_copy_from_linear_data_offset])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 251                   [skb_reset_tail_pointer])
 252   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 254                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 256                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 258                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 259   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 260   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 261   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 263   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 264   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 265
 266   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 267                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 268   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 269                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 270   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 271                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 272
 273   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 274   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 275
 276   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 277   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 278   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 279   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 280   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 281   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 282   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 283
 284   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 285
 286   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 287                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 288
 289   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 290
 291   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 292                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 293
 294   OVS_CHECK_LOG2_H
 295
 296   if cmp -s datapath/linux/kcompat.h.new \
 297             datapath/linux/kcompat.h >/dev/null 2>&1; then
 298     rm datapath/linux/kcompat.h.new
 299   else
 300     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 301   fi
 302 ])
 303
 304 dnl Checks for net/if_packet.h.
 305 AC_DEFUN([OVS_CHECK_IF_PACKET],
 306   [AC_CHECK_HEADER([net/if_packet.h],
 307                    [HAVE_IF_PACKET=yes],
 308                    [HAVE_IF_PACKET=no])
 309    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 310    if test "$HAVE_IF_PACKET" = yes; then
 311       AC_DEFINE([HAVE_IF_PACKET], [1],
 312                 [Define to 1 if net/if_packet.h is available.])
 313    fi])
 314
 315 dnl Checks for net/if_dl.h.
 316 dnl
 317 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 318 dnl or NetBSD.)
 319 AC_DEFUN([OVS_CHECK_IF_DL],
 320   [AC_CHECK_HEADER([net/if_dl.h],
 321                    [HAVE_IF_DL=yes],
 322                    [HAVE_IF_DL=no])
 323    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 324    if test "$HAVE_IF_DL" = yes; then
 325       AC_DEFINE([HAVE_IF_DL], [1],
 326                 [Define to 1 if net/if_dl.h is available.])
 327
 328       # On these platforms we use libpcap to access network devices.
 329       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 330    fi])
 331
 332 dnl Checks for buggy strtok_r.
 333 dnl
 334 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 335 dnl with optimization that can cause segfaults:
 336 dnl
 337 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 338 AC_DEFUN([OVS_CHECK_STRTOK_R],
 339   [AC_CACHE_CHECK(
 340      [whether strtok_r macro segfaults on some inputs],
 341      [ovs_cv_strtok_r_bug],
 342      [AC_RUN_IFELSE(
 343         [AC_LANG_PROGRAM([#include <stdio.h>
 344                           #include <string.h>
 345                          ],
 346                          [[char string[] = ":::";
 347                            char *save_ptr = (char *) 0xc0ffee;
 348                            char *token1, *token2;
 349                            token1 = strtok_r(string, ":", &save_ptr);
 350                            token2 = strtok_r(NULL, ":", &save_ptr);
 351                            freopen ("/dev/null", "w", stdout);
 352                            printf ("%s %s\n", token1, token2);
 353                            return 0;
 354                           ]])],
 355         [ovs_cv_strtok_r_bug=no],
 356         [ovs_cv_strtok_r_bug=yes],
 357         [ovs_cv_strtok_r_bug=yes])])
 358    if test $ovs_cv_strtok_r_bug = yes; then
 359      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 360                [Define if strtok_r macro segfaults on some inputs])
 361    fi
 362 ])
 363
 364 dnl ----------------------------------------------------------------------
 365 dnl These macros are from GNU PSPP, with the following original license:
 366 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 367 dnl This file is free software; the Free Software Foundation
 368 dnl gives unlimited permission to copy and/or distribute it,
 369 dnl with or without modifications, as long as this notice is preserved.
 370
 371 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 372   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 373   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 374     [ovs_save_CFLAGS="$CFLAGS"
 375      dnl Include -Werror in the compiler options, because without -Werror
 376      dnl clang's GCC-compatible compiler driver does not return a failure
 377      dnl exit status even though it complains about options it does not
 378      dnl understand.
 379      CFLAGS="$CFLAGS $WERROR $1"
 380      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 381      CFLAGS="$ovs_save_CFLAGS"])
 382   if test $ovs_cv_name = yes; then
 383     m4_if([$2], [], [:], [$2])
 384   else
 385     m4_if([$3], [], [:], [$3])
 386   fi
 387 ])
 388
 389 dnl OVS_CHECK_WERROR
 390 dnl
 391 dnl Check whether the C compiler accepts -Werror.
 392 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 393 AC_DEFUN([OVS_CHECK_WERROR],
 394   [WERROR=
 395    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 396
 397 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 398 dnl Check whether the given C compiler OPTION is accepted.
 399 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 400 AC_DEFUN([OVS_CHECK_CC_OPTION],
 401   [AC_REQUIRE([OVS_CHECK_WERROR])
 402    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 403
 404 dnl OVS_ENABLE_OPTION([OPTION])
 405 dnl Check whether the given C compiler OPTION is accepted.
 406 dnl If so, add it to WARNING_FLAGS.
 407 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 408 AC_DEFUN([OVS_ENABLE_OPTION],
 409   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 410    AC_SUBST([WARNING_FLAGS])])
 411
 412 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 413 dnl Check whether the given C compiler OPTION is accepted.
 414 dnl If so, enable the given Automake CONDITIONAL.
 415
 416 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 417 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 418   [OVS_CHECK_CC_OPTION(
 419     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 420    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 421 dnl ----------------------------------------------------------------------
 422
 423 dnl Check for too-old XenServer.
 424 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 425   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 426     [if test -e /etc/redhat-release; then
 427        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 428      fi
 429      if test -z "$ovs_cv_xsversion"; then
 430        ovs_cv_xsversion=none
 431      fi])
 432   case $ovs_cv_xsversion in
 433     none)
 434       ;;
 435
 436     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 437     [[6-9]]* |                           dnl XenServer 6 or later
 438     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 439     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 440     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 441     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 442       ;;
 443
 444     *)
 445       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 446       ;;
 447   esac])
 448
 449 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 450 dnl
 451 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 452 dnl Runs 'if-true' if so, 'if-false' otherwise.
 453 AC_DEFUN([OVS_CHECK_MAKE_IF],
 454   [AC_CACHE_CHECK(
 455      [whether ${MAKE-make} has GNU make \$(if) extension],
 456      [ovs_cv_gnu_make_if],
 457      [cat <<'EOF' > conftest.mk
 458 conftest.out:
 459         echo $(if x,y,z) > conftest.out
 460 .PHONY: all
 461 EOF
 462       rm -f conftest.out
 463       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 464       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 465       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 466       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 467       result=`cat conftest.out`
 468       rm -f conftest.mk conftest.out
 469       if test "X$result" = "Xy"; then
 470         ovs_cv_gnu_make_if=yes
 471       else
 472         ovs_cv_gnu_make_if=no
 473       fi])])
 474
 475 dnl OVS_CHECK_GNU_MAKE
 476 dnl
 477 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 478 dnl only work with GNU make).
 479 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 480   [AC_CACHE_CHECK(
 481      [whether ${MAKE-make} is GNU make],
 482      [ovs_cv_gnu_make],
 483      [rm -f conftest.out
 484       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 485       ${MAKE-make} --version >conftest.out 2>&1
 486       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 487       result=`cat conftest.out`
 488       rm -f conftest.mk conftest.out
 489
 490       case $result in # (
 491         GNU*) ovs_cv_gnu_make=yes ;; # (
 492         *) ovs_cv_gnu_make=no ;;
 493       esac])
 494    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 495
 496 dnl OVS_CHECK_SPARSE_TARGET
 497 dnl
 498 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 499 dnl target for which the code is being built.  This helps it out.
 500 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 501   [AC_CACHE_CHECK(
 502     [target hint for cgcc],
 503     [ac_cv_sparse_target],
 504     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 505        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 506        [x86_64-*], [ac_cv_sparse_target=x86_64],
 507        [ac_cv_sparse_target=other])])
 508    AS_CASE([$ac_cv_sparse_target],
 509      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 510      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 511      [SPARSEFLAGS= CGCCFLAGS=])
 512    AC_SUBST([SPARSEFLAGS])
 513    AC_SUBST([CGCCFLAGS])])
 514
 515 dnl OVS_SPARSE_EXTRA_INCLUDES
 516 dnl
 517 dnl The cgcc script from "sparse" does not search gcc's default
 518 dnl search path. Get the default search path from GCC and pass
 519 dnl them to sparse.
 520 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 521     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 522            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 523
 524 dnl OVS_ENABLE_SPARSE
 525 AC_DEFUN([OVS_ENABLE_SPARSE],
 526   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 527    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 528    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 529    : ${SPARSE=sparse}
 530    AC_SUBST([SPARSE])
 531    AC_CONFIG_COMMANDS_PRE(
 532      [if test $ovs_cv_gnu_make_if = yes; then
 533         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 534       fi])])
 535
 536 dnl OVS_PTHREAD_SET_NAME
 537 dnl
 538 dnl This checks for three known variants of pthreads functions for setting
 539 dnl the name of the current thread:
 540 dnl
 541 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 542 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 543 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 544 dnl
 545 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 546 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 547 dnl provide to it.
 548 dnl
 549 dnl This macro defines:
 550 dnl
 551 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 552 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 553 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 554 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 555   [AC_CHECK_FUNCS([pthread_set_name_np])
 556    if test $ac_cv_func_pthread_set_name_np != yes; then
 557      AC_CACHE_CHECK(
 558        [for pthread_setname_np() variant],
 559        [ovs_cv_pthread_setname_np],
 560        [AC_LINK_IFELSE(
 561          [AC_LANG_PROGRAM([#include <pthread.h>
 562   ], [pthread_setname_np(pthread_self(), "name");])],
 563          [ovs_cv_pthread_setname_np=glibc],
 564          [AC_LINK_IFELSE(
 565            [AC_LANG_PROGRAM([#include <pthread.h>
 566 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 567            [ovs_cv_pthread_setname_np=netbsd],
 568            [ovs_cv_pthread_setname_np=none])])])
 569      case $ovs_cv_pthread_setname_np in # (
 570        glibc)
 571           AC_DEFINE(
 572             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 573             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 574           ;; # (
 575        netbsd)
 576           AC_DEFINE(
 577             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 578             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 579           ;;
 580      esac
 581    fi])
 582
 583 dnl OVS_CHECK_LINUX_HOST.
 584 dnl
 585 dnl Checks whether we're building for a Linux host, based on the presence of
 586 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 587 dnl LINUX based on the result.
 588 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 589   [AC_CACHE_CHECK(
 590      [whether __linux__ is defined],
 591      [ovs_cv_linux],
 592      [AC_COMPILE_IFELSE(
 593         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 594         [ovs_cv_linux=true],
 595         [ovs_cv_linux=false])])
 596    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])