acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_CHECK_LINUX26
  18 dnl
  19 dnl Configure linux kernel source tree
  20 AC_DEFUN([OVS_CHECK_LINUX26], [
  21   AC_ARG_WITH([l26],
  22               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  23                               [Specify the linux 2.6 kernel sources])],
  24               [KBUILD26="$withval"], [KBUILD26=])dnl
  25   if test -n "$KBUILD26"; then
  26     KBUILD26=`eval echo "$KBUILD26"`
  27
  28     # The build directory is what the user provided.
  29     # Make sure that it exists.
  30     AC_MSG_CHECKING([for Linux 2.6 build directory])
  31     if test -d "$KBUILD26"; then
  32         AC_MSG_RESULT([$KBUILD26])
  33         AC_SUBST(KBUILD26)
  34     else
  35         AC_MSG_RESULT([no])
  36         AC_ERROR([source dir $KBUILD26 doesn't exist])
  37     fi
  38
  39     # Debian breaks kernel headers into "source" header and "build" headers.
  40     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  41     # Use heuristics to find the source headers.
  42     AC_MSG_CHECKING([for Linux 2.6 source directory])
  43     KSRC26=$KBUILD26
  44     if test ! -e $KSRC26/include/linux/kernel.h; then
  45       case `echo "$KBUILD26" | sed 's,/*$,,'` in # (
  46         */build)
  47           KSRC26=`echo "$KBUILD26" | sed 's,/build/*$,/source,'`
  48           ;; # (
  49         *)
  50           KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  51           ;;
  52       esac
  53       if test ! -e $KSRC26/include/linux/kernel.h; then
  54         AC_MSG_ERROR([cannot find source directory])
  55       fi
  56     fi
  57     AC_MSG_RESULT([$KSRC26])
  58
  59     AC_MSG_CHECKING([for kernel version])
  60     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  61     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  62     if test -z "$patchlevel" || test -z "$sublevel"; then
  63        AC_ERROR([cannot determine kernel version])
  64     fi
  65     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  66     if test "2.$patchlevel" != '2.6'; then
  67        if test "$BUILD26" = "$KSRC26"; then
  68          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
  69        else
  70          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
  71        fi
  72     fi
  73     if test ! -e "$KBUILD26"/include/linux/version.h || \
  74        (test ! -e "$KBUILD26"/include/linux/autoconf.h && \
  75         test ! -e "$KBUILD26"/include/generated/autoconf.h); then
  76         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
  77     fi
  78     OVS_CHECK_LINUX26_COMPAT
  79   fi
  80   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
  81 ])
  82
  83 dnl OVS_GREP_IFELSE(FILE, REGEX, IF-MATCH, IF-NO-MATCH)
  84 dnl
  85 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
  86 AC_DEFUN([OVS_GREP_IFELSE], [
  87   AC_MSG_CHECKING([whether $2 matches in $1])
  88   grep '$2' $1 >/dev/null 2>&1
  89   status=$?
  90   case $status in
  91     0)
  92       AC_MSG_RESULT([yes])
  93       $3
  94       ;;
  95     1)
  96       AC_MSG_RESULT([no])
  97       $4
  98       ;;
  99     *)
 100       AC_MSG_ERROR([grep exited with status $status])
 101       ;;
 102   esac
 103 ])
 104
 105 dnl OVS_DEFINE(NAME)
 106 dnl
 107 dnl Defines NAME to 1 in kcompat.h.
 108 AC_DEFUN([OVS_DEFINE], [
 109   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 110 ])
 111
 112 AC_DEFUN([OVS_CHECK_VETH], [
 113   AC_MSG_CHECKING([whether to build veth module])
 114   if test "$sublevel" = 18; then
 115     AC_MSG_RESULT([yes])
 116     AC_SUBST([BUILD_VETH], 1)
 117   else
 118     AC_MSG_RESULT([no])
 119   fi
 120 ])
 121
 122 AC_DEFUN([OVS_CHECK_GRE], [
 123   AC_MSG_CHECKING([whether to build gre module])
 124   if test "$sublevel" -ge 18; then
 125     AC_MSG_RESULT([yes])
 126     AC_SUBST([BUILD_GRE], 1)
 127   else
 128     AC_MSG_RESULT([no])
 129   fi
 130 ])
 131
 132 AC_DEFUN([OVS_CHECK_LOG2_H], [
 133   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 134   if test -e $KSRC26/include/linux/log2.h; then
 135     AC_MSG_RESULT([yes])
 136     OVS_DEFINE([HAVE_LOG2_H])
 137   else
 138     AC_MSG_RESULT([no])
 139   fi
 140 ])
 141
 142 dnl OVS_CHECK_LINUX26_COMPAT
 143 dnl
 144 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 145 dnl the directory in $KBUILD26.
 146 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 147   rm -f datapath/linux-2.6/kcompat.h.new
 148   mkdir -p datapath/linux-2.6
 149   : > datapath/linux-2.6/kcompat.h.new
 150   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [bool],
 151                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 152   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 153                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 154   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 155                   [OVS_DEFINE([HAVE_MAC_RAW])])
 156   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 157                   [skb_copy_from_linear_data_offset],
 158                   [OVS_DEFINE([HAVE_SKB_COPY_FROM_LINEAR_DATA_OFFSET])])
 159   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING],
 160                   [OVS_DEFINE([HAVE_NLA_NUL_STRING])])
 161   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST],
 162                   [OVS_DEFINE([HAVE_ERR_CAST])])
 163   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold],
 164                   [OVS_DEFINE([HAVE_CSUM_UNFOLD])])
 165   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow],
 166                   [OVS_DEFINE([HAVE_SKB_COW])])
 167   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_get_be16],
 168                   [OVS_DEFINE([HAVE_NLA_GET_BE16])])
 169   OVS_GREP_IFELSE([$KSRC26/include/linux/in.h], [ipv4_is_multicast],
 170                   [OVS_DEFINE([HAVE_IPV4_IS_MULTICAST])])
 171   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 172   # is necessary because some versions of this header remove the
 173   # member but retain the kerneldoc comment that describes it (which
 174   # starts with @).  The brackets must be doubled because of m4
 175   # quoting rules.
 176   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 177                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 178   OVS_CHECK_LOG2_H
 179   OVS_CHECK_VETH
 180   OVS_CHECK_GRE
 181   if cmp -s datapath/linux-2.6/kcompat.h.new \
 182             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 183     rm datapath/linux-2.6/kcompat.h.new
 184   else
 185     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 186   fi
 187 ])
 188
 189 dnl Checks for net/if_packet.h.
 190 AC_DEFUN([OVS_CHECK_IF_PACKET],
 191   [AC_CHECK_HEADER([net/if_packet.h],
 192                    [HAVE_IF_PACKET=yes],
 193                    [HAVE_IF_PACKET=no])
 194    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 195    if test "$HAVE_IF_PACKET" = yes; then
 196       AC_DEFINE([HAVE_IF_PACKET], [1],
 197                 [Define to 1 if net/if_packet.h is available.])
 198    fi])
 199
 200 dnl Checks for buggy strtok_r.
 201 dnl
 202 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 203 dnl with optimization that can cause segfaults:
 204 dnl
 205 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 206 AC_DEFUN([OVS_CHECK_STRTOK_R],
 207   [AC_CACHE_CHECK(
 208      [whether strtok_r macro segfaults on some inputs],
 209      [ovs_cv_strtok_r_bug],
 210      [AC_RUN_IFELSE(
 211         [AC_LANG_PROGRAM([#include <stdio.h>
 212                           #include <string.h>
 213                          ],
 214                          [[char string[] = ":::";
 215                            char *save_ptr = (char *) 0xc0ffee;
 216                            char *token1, *token2;
 217                            token1 = strtok_r(string, ":", &save_ptr);
 218                            token2 = strtok_r(NULL, ":", &save_ptr);
 219                            freopen ("/dev/null", "w", stdout);
 220                            printf ("%s %s\n", token1, token2);
 221                            return 0;
 222                           ]])],
 223         [ovs_cv_strtok_r_bug=no],
 224         [ovs_cv_strtok_r_bug=yes],
 225         [ovs_cv_strtok_r_bug=yes])])
 226    if test $ovs_cv_strtok_r_bug = yes; then
 227      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 228                [Define if strtok_r macro segfaults on some inputs])
 229    fi
 230 ])
 231
 232 dnl ----------------------------------------------------------------------
 233 dnl These macros are from GNU PSPP, with the following original license:
 234 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 235 dnl This file is free software; the Free Software Foundation
 236 dnl gives unlimited permission to copy and/or distribute it,
 237 dnl with or without modifications, as long as this notice is preserved.
 238
 239 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 240 dnl Check whether the given C compiler OPTION is accepted.
 241 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 242 AC_DEFUN([OVS_CHECK_CC_OPTION],
 243 [
 244   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 245   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 246     [ovs_save_CFLAGS="$CFLAGS"
 247      CFLAGS="$CFLAGS $1"
 248      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 249      CFLAGS="$ovs_save_CFLAGS"])
 250   if test $ovs_cv_name = yes; then
 251     m4_if([$2], [], [:], [$2])
 252   else
 253     m4_if([$3], [], [:], [$3])
 254   fi
 255 ])
 256
 257 dnl OVS_ENABLE_OPTION([OPTION])
 258 dnl Check whether the given C compiler OPTION is accepted.
 259 dnl If so, add it to WARNING_FLAGS.
 260 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 261 AC_DEFUN([OVS_ENABLE_OPTION],
 262   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 263    AC_SUBST([WARNING_FLAGS])])
 264
 265 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 266 dnl Check whether the given C compiler OPTION is accepted.
 267 dnl If so, enable the given Automake CONDITIONAL.
 268
 269 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 270 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 271   [OVS_CHECK_CC_OPTION(
 272     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 273    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 274 dnl ----------------------------------------------------------------------